lib/PublicInbox/Over.pm

   1 # Copyright (C) 2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # for XOVER, OVER in NNTP, and feeds/homepage/threads in PSGI
   5 # Unlike Msgmap, this is an _UNSTABLE_ database which can be
   6 # tweaked/updated over time and rebuilt.
   7 package PublicInbox::Over;
   8 use strict;
   9 use warnings;
  10 use DBI;
  11 use DBD::SQLite;
  12 use PublicInbox::SearchMsg;
  13 use Compress::Zlib qw(uncompress);
  14
  15 sub dbh_new {
  16         my ($self) = @_;
  17         my $ro = ref($self) eq 'PublicInbox::Over';
  18         my $dbh = DBI->connect("dbi:SQLite:dbname=$self->{filename}",'','', {
  19                 AutoCommit => 1,
  20                 RaiseError => 1,
  21                 PrintError => 0,
  22                 ReadOnly => $ro,
  23                 sqlite_use_immediate_transaction => 1,
  24         });
  25         $dbh->{sqlite_unicode} = 1;
  26         $dbh;
  27 }
  28
  29 sub new {
  30         my ($class, $f) = @_;
  31         bless { filename => $f }, $class;
  32 }
  33
  34 sub disconnect { $_[0]->{dbh} = undef }
  35
  36 sub connect { $_[0]->{dbh} ||= $_[0]->dbh_new }
  37
  38 sub load_from_row {
  39         my ($smsg) = @_;
  40         bless $smsg, 'PublicInbox::SearchMsg';
  41         if (defined(my $data = delete $smsg->{ddd})) {
  42                 $data = uncompress($data);
  43                 utf8::decode($data);
  44                 $smsg->load_from_data($data);
  45         }
  46         $smsg
  47 }
  48
  49 sub do_get {
  50         my ($self, $sql, $opts, @args) = @_;
  51         my $dbh = $self->connect;
  52         my $lim = (($opts->{limit} || 0) + 0) || 1000;
  53         $sql .= "LIMIT $lim";
  54         my $msgs = $dbh->selectall_arrayref($sql, { Slice => {} }, @args);
  55         load_from_row($_) for @$msgs;
  56         $msgs
  57 }
  58
  59 sub query_xover {
  60         my ($self, $beg, $end) = @_;
  61         do_get($self, <<'', {}, $beg, $end);
  62 SELECT * FROM over WHERE num >= ? AND num <= ?
  63 ORDER BY num ASC
  64
  65 }
  66
  67 sub query_ts {
  68         my ($self, $ts, $prev) = @_;
  69         do_get($self, <<'', {}, $ts, $prev);
  70 SELECT num,ddd FROM over WHERE ts >= ? AND num > ?
  71 ORDER BY num ASC
  72
  73 }
  74
  75 sub nothing () { wantarray ? (0, []) : [] };
  76
  77 sub get_thread {
  78         my ($self, $mid, $prev) = @_;
  79         my $dbh = $self->connect;
  80
  81         my $id = $dbh->selectrow_array(<<'', undef, $mid);
  82 SELECT id FROM msgid WHERE mid = ? LIMIT 1
  83
  84         defined $id or return nothing;
  85
  86         my $num = $dbh->selectrow_array(<<'', undef, $id);
  87 SELECT num FROM id2num WHERE id = ? AND num > 0
  88 ORDER BY num ASC LIMIT 1
  89
  90         defined $num or return nothing;
  91
  92         my ($tid, $sid) = $dbh->selectrow_array(<<'', undef, $num);
  93 SELECT tid,sid FROM over WHERE num = ? LIMIT 1
  94
  95         defined $tid or return nothing; # $sid may be undef
  96         my $sort_col = 'ds';
  97         $num = 0;
  98         if ($prev) {
  99                 $num = $prev->{num} || 0;
 100                 $sort_col = 'num';
 101         }
 102         my $cond = '(tid = ? OR sid = ?) AND num > ?';
 103         my $msgs = do_get($self, <<"", {}, $tid, $sid, $num);
 104 SELECT num,ts,ds,ddd FROM over WHERE $cond ORDER BY $sort_col ASC
 105
 106         return $msgs unless wantarray;
 107
 108         my $nr = $dbh->selectrow_array(<<"", undef, $tid, $sid, $num);
 109 SELECT COUNT(num) FROM over WHERE $cond
 110
 111         ($nr, $msgs);
 112 }
 113
 114 sub recent {
 115         my ($self, $opts, $after, $before) = @_;
 116         my ($s, @v);
 117         if (defined($before)) {
 118                 if (defined($after)) {
 119                         $s = 'num > 0 AND ts >= ? AND ts <= ? ORDER BY ts DESC';
 120                         @v = ($after, $before);
 121                 } else {
 122                         $s = 'num > 0 AND ts <= ? ORDER BY ts DESC';
 123                         @v = ($before);
 124                 }
 125         } else {
 126                 if (defined($after)) {
 127                         $s = 'num > 0 AND ts >= ? ORDER BY ts ASC';
 128                         @v = ($after);
 129                 } else {
 130                         $s = 'num > 0 ORDER BY ts DESC';
 131                 }
 132         }
 133         my $msgs = do_get($self, <<"", $opts, @v);
 134 SELECT * FROM over WHERE $s
 135
 136         return $msgs unless wantarray;
 137
 138         my $nr = $self->{dbh}->selectrow_array(<<'');
 139 SELECT COUNT(num) FROM over WHERE num > 0
 140
 141         ($nr, $msgs);
 142 }
 143
 144 sub get_art {
 145         my ($self, $num) = @_;
 146         my $dbh = $self->connect;
 147         my $smsg = $dbh->selectrow_hashref(<<'', undef, $num);
 148 SELECT * from OVER where num = ? LIMIT 1
 149
 150         return load_from_row($smsg) if $smsg;
 151         undef;
 152 }
 153
 154 sub next_by_mid {
 155         my ($self, $mid, $id, $prev) = @_;
 156         my $dbh = $self->connect;
 157
 158         unless (defined $$id) {
 159                 my $sth = $dbh->prepare_cached(<<'', undef, 1);
 160         SELECT id FROM msgid WHERE mid = ? LIMIT 1
 161
 162                 $sth->execute($mid);
 163                 $$id = $sth->fetchrow_array;
 164                 defined $$id or return;
 165         }
 166         my $sth = $dbh->prepare_cached(<<"", undef, 1);
 167 SELECT num FROM id2num WHERE id = ? AND num > ?
 168 ORDER BY num ASC LIMIT 1
 169
 170         $$prev ||= 0;
 171         $sth->execute($$id, $$prev);
 172         my $num = $sth->fetchrow_array or return;
 173         $$prev = $num;
 174
 175         $sth = $dbh->prepare_cached(<<"", undef, 1);
 176 SELECT num,ts,ds,ddd FROM over WHERE num = ? LIMIT 1
 177
 178         $sth->execute($num);
 179         my $smsg = $sth->fetchrow_hashref or return;
 180         load_from_row($smsg);
 181 }
 182
 183 1;