lib/PublicInbox/OverIdx.pm

   1 # Copyright (C) 2018-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # for XOVER, OVER in NNTP, and feeds/homepage/threads in PSGI
   5 # Unlike Msgmap, this is an _UNSTABLE_ cache which can be
   6 # tweaked/updated over time and rebuilt.
   7 #
   8 # Ghost messages (messages which are only referenced in References/In-Reply-To)
   9 # are denoted by a negative NNTP article number.
  10 package PublicInbox::OverIdx;
  11 use strict;
  12 use v5.10.1;
  13 use parent qw(PublicInbox::Over);
  14 use IO::Handle;
  15 use DBI qw(:sql_types); # SQL_BLOB
  16 use PublicInbox::MID qw/id_compress mids_for_index references/;
  17 use PublicInbox::Smsg qw(subject_normalized);
  18 use Compress::Zlib qw(compress);
  19 use Carp qw(croak);
  20
  21 sub dbh_new {
  22         my ($self) = @_;
  23         my $dbh = $self->SUPER::dbh_new($self->{-no_fsync} ? 2 : 1);
  24
  25         # 80000 pages (80MiB on SQLite <3.12.0, 320MiB on 3.12.0+)
  26         # was found to be good in 2018 during the large LKML import
  27         # at the time.  This ought to be configurable based on HW
  28         # and inbox size; I suspect it's overkill for many inboxes.
  29         $dbh->do('PRAGMA cache_size = 80000');
  30
  31         create_tables($dbh);
  32         $dbh;
  33 }
  34
  35 sub new {
  36         my ($class, $f) = @_;
  37         my $self = $class->SUPER::new($f);
  38         $self->{min_tid} = 0;
  39         $self;
  40 }
  41
  42 sub get_counter ($$) {
  43         my ($dbh, $key) = @_;
  44         my $sth = $dbh->prepare_cached(<<'', undef, 1);
  45 SELECT val FROM counter WHERE key = ? LIMIT 1
  46
  47         $sth->execute($key);
  48         $sth->fetchrow_array;
  49 }
  50
  51 sub adj_counter ($$$) {
  52         my ($self, $key, $op) = @_;
  53         my $dbh = $self->{dbh};
  54         my $sth = $dbh->prepare_cached(<<"");
  55 UPDATE counter SET val = val $op 1 WHERE key = ?
  56
  57         $sth->execute($key);
  58
  59         get_counter($dbh, $key);
  60 }
  61
  62 sub next_tid { adj_counter($_[0], 'thread', '+') }
  63 sub next_ghost_num { adj_counter($_[0], 'ghost', '-') }
  64
  65 sub id_for ($$$$$) {
  66         my ($self, $tbl, $id_col, $val_col, $val) = @_;
  67         my $dbh = $self->{dbh};
  68         my $in = $dbh->prepare_cached(<<"")->execute($val);
  69 INSERT OR IGNORE INTO $tbl ($val_col) VALUES (?)
  70
  71         if ($in == 0) {
  72                 my $sth = $dbh->prepare_cached(<<"", undef, 1);
  73 SELECT $id_col FROM $tbl WHERE $val_col = ? LIMIT 1
  74
  75                 $sth->execute($val);
  76                 $sth->fetchrow_array;
  77         } else {
  78                 $dbh->last_insert_id(undef, undef, $tbl, $id_col);
  79         }
  80 }
  81
  82 sub ibx_id {
  83         my ($self, $eidx_key) = @_;
  84         id_for($self, 'inboxes', 'ibx_id', eidx_key => $eidx_key);
  85 }
  86
  87 sub sid {
  88         my ($self, $path) = @_;
  89         return unless defined $path && $path ne '';
  90         id_for($self, 'subject', 'sid', 'path' => $path);
  91 }
  92
  93 sub mid2id {
  94         my ($self, $mid) = @_;
  95         id_for($self, 'msgid', 'id', 'mid' => $mid);
  96 }
  97
  98 sub delete_by_num {
  99         my ($self, $num, $tid_ref) = @_;
 100         my $dbh = $self->{dbh};
 101         if ($tid_ref) {
 102                 my $sth = $dbh->prepare_cached(<<'', undef, 1);
 103 SELECT tid FROM over WHERE num = ? LIMIT 1
 104
 105                 $sth->execute($num);
 106                 $$tid_ref = $sth->fetchrow_array; # may be undef
 107         }
 108         foreach (qw(over id2num)) {
 109                 $dbh->prepare_cached(<<"")->execute($num);
 110 DELETE FROM $_ WHERE num = ?
 111
 112         }
 113 }
 114
 115 # this includes ghosts
 116 sub each_by_mid {
 117         my ($self, $mid, $cols, $cb, @arg) = @_;
 118         my $dbh = $self->{dbh};
 119
 120 =over
 121         I originally wanted to stuff everything into a single query:
 122
 123         SELECT over.* FROM over
 124         LEFT JOIN id2num ON over.num = id2num.num
 125         LEFT JOIN msgid ON msgid.id = id2num.id
 126         WHERE msgid.mid = ? AND over.num >= ?
 127         ORDER BY over.num ASC
 128         LIMIT 1000
 129
 130         But it's faster broken out (and we're always in a
 131         transaction for subroutines in this file)
 132 =cut
 133
 134         my $sth = $dbh->prepare_cached(<<'', undef, 1);
 135 SELECT id FROM msgid WHERE mid = ? LIMIT 1
 136
 137         $sth->execute($mid);
 138         my $id = $sth->fetchrow_array;
 139         defined $id or return;
 140
 141         push(@$cols, 'num');
 142         $cols = join(',', map { $_ } @$cols);
 143         my $lim = 10;
 144         my $prev = get_counter($dbh, 'ghost');
 145         while (1) {
 146                 $sth = $dbh->prepare_cached(<<"", undef, 1);
 147 SELECT num FROM id2num WHERE id = ? AND num >= ?
 148 ORDER BY num ASC
 149 LIMIT $lim
 150
 151                 $sth->execute($id, $prev);
 152                 my $nums = $sth->fetchall_arrayref;
 153                 my $nr = scalar(@$nums) or return;
 154                 $prev = $nums->[-1]->[0];
 155
 156                 $sth = $dbh->prepare_cached(<<"", undef, 1);
 157 SELECT $cols FROM over WHERE over.num = ? LIMIT 1
 158
 159                 foreach (@$nums) {
 160                         $sth->execute($_->[0]);
 161                         my $smsg = $sth->fetchrow_hashref;
 162                         $smsg = PublicInbox::Over::load_from_row($smsg);
 163                         $cb->($self, $smsg, @arg) or return;
 164                 }
 165                 return if $nr != $lim;
 166         }
 167 }
 168
 169 sub _resolve_mid_to_tid {
 170         my ($self, $smsg, $tid) = @_;
 171         my $cur_tid = $smsg->{tid};
 172         if (defined $$tid) {
 173                 merge_threads($self, $$tid, $cur_tid);
 174         } elsif ($cur_tid > $self->{min_tid}) {
 175                 $$tid = $cur_tid;
 176         } else { # rethreading, queue up dead ghosts
 177                 $$tid = next_tid($self);
 178                 my $n = $smsg->{num};
 179                 if ($n > 0) {
 180                         $self->{dbh}->prepare_cached(<<'')->execute($$tid, $n);
 181 UPDATE over SET tid = ? WHERE num = ?
 182
 183                 } elsif ($n < 0) {
 184                         push(@{$self->{-ghosts_to_delete}}, $n);
 185                 }
 186         }
 187         1;
 188 }
 189
 190 # this will create a ghost as necessary
 191 sub resolve_mid_to_tid {
 192         my ($self, $mid) = @_;
 193         my $tid;
 194         each_by_mid($self, $mid, ['tid'], \&_resolve_mid_to_tid, \$tid);
 195         if (my $del = delete $self->{-ghosts_to_delete}) {
 196                 delete_by_num($self, $_) for @$del;
 197         }
 198         $tid // do { # create a new ghost
 199                 my $id = mid2id($self, $mid);
 200                 my $num = next_ghost_num($self);
 201                 $num < 0 or die "ghost num is non-negative: $num\n";
 202                 $tid = next_tid($self);
 203                 my $dbh = $self->{dbh};
 204                 $dbh->prepare_cached(<<'')->execute($num, $tid);
 205 INSERT INTO over (num, tid) VALUES (?,?)
 206
 207                 $dbh->prepare_cached(<<'')->execute($id, $num);
 208 INSERT INTO id2num (id, num) VALUES (?,?)
 209
 210                 $tid;
 211         };
 212 }
 213
 214 sub merge_threads {
 215         my ($self, $winner_tid, $loser_tid) = @_;
 216         return if $winner_tid == $loser_tid;
 217         my $dbh = $self->{dbh};
 218         $dbh->prepare_cached(<<'')->execute($winner_tid, $loser_tid);
 219 UPDATE over SET tid = ? WHERE tid = ?
 220
 221 }
 222
 223 sub link_refs {
 224         my ($self, $refs, $old_tid) = @_;
 225         my $tid;
 226
 227         if (@$refs) {
 228                 # first ref *should* be the thread root,
 229                 # but we can never trust clients to do the right thing
 230                 my $ref = $refs->[0];
 231                 $tid = resolve_mid_to_tid($self, $ref);
 232                 merge_threads($self, $tid, $old_tid) if defined $old_tid;
 233
 234                 # the rest of the refs should point to this tid:
 235                 foreach my $i (1..$#$refs) {
 236                         $ref = $refs->[$i];
 237                         my $ptid = resolve_mid_to_tid($self, $ref);
 238                         merge_threads($self, $tid, $ptid);
 239                 }
 240         } else {
 241                 $tid = $old_tid // next_tid($self);
 242         }
 243         $tid;
 244 }
 245
 246 # normalize subjects so they are suitable as pathnames for URLs
 247 # XXX: consider for removal
 248 sub subject_path ($) {
 249         my ($subj) = @_;
 250         $subj = subject_normalized($subj);
 251         $subj =~ s![^a-zA-Z0-9_\.~/\-]+!_!g;
 252         lc($subj);
 253 }
 254
 255 sub ddd_for ($) {
 256         my ($smsg) = @_;
 257         my $dd = $smsg->to_doc_data;
 258         utf8::encode($dd);
 259         compress($dd);
 260 }
 261
 262 sub add_overview {
 263         my ($self, $eml, $smsg) = @_;
 264         $smsg->{lines} = $eml->body_raw =~ tr!\n!\n!;
 265         my $mids = mids_for_index($eml);
 266         my $refs = $smsg->parse_references($eml, $mids);
 267         $mids->[0] //= do {
 268                 $smsg->{mid} //= '';
 269                 $eml->{-lei_fake_mid};
 270         };
 271         my $subj = $smsg->{subject};
 272         my $xpath;
 273         if ($subj ne '') {
 274                 $xpath = subject_path($subj);
 275                 $xpath = id_compress($xpath);
 276         }
 277         add_over($self, $smsg, $mids, $refs, $xpath, ddd_for($smsg));
 278 }
 279
 280 sub _add_over {
 281         my ($self, $smsg, $mid, $refs, $old_tid, $v) = @_;
 282         my $cur_tid = $smsg->{tid};
 283         my $n = $smsg->{num};
 284         die "num must not be zero for $mid" if !$n;
 285         my $cur_valid = $cur_tid > $self->{min_tid};
 286
 287         if ($n > 0) { # regular mail
 288                 if ($cur_valid) {
 289                         $$old_tid //= $cur_tid;
 290                         merge_threads($self, $$old_tid, $cur_tid);
 291                 } else {
 292                         $$old_tid //= next_tid($self);
 293                 }
 294         } elsif ($n < 0) { # ghost
 295                 $$old_tid //= $cur_valid ? $cur_tid : next_tid($self);
 296                 $$old_tid = link_refs($self, $refs, $$old_tid);
 297                 delete_by_num($self, $n);
 298                 $$v++;
 299         }
 300         1;
 301 }
 302
 303 sub add_over {
 304         my ($self, $smsg, $mids, $refs, $xpath, $ddd) = @_;
 305         my $old_tid;
 306         my $vivified = 0;
 307         my $num = $smsg->{num};
 308
 309         begin_lazy($self);
 310         delete_by_num($self, $num, \$old_tid);
 311         $old_tid = undef if ($old_tid // 0) <= $self->{min_tid};
 312         foreach my $mid (@$mids) {
 313                 my $v = 0;
 314                 each_by_mid($self, $mid, ['tid'], \&_add_over,
 315                                 $mid, $refs, \$old_tid, \$v);
 316                 $v > 1 and warn "BUG: vivified multiple ($v) ghosts for $mid\n";
 317                 $vivified += $v;
 318         }
 319         $smsg->{tid} = $vivified ? $old_tid : link_refs($self, $refs, $old_tid);
 320         $smsg->{sid} = sid($self, $xpath);
 321         my $dbh = $self->{dbh};
 322         my $sth = $dbh->prepare_cached(<<'');
 323 INSERT INTO over (num, tid, sid, ts, ds, ddd)
 324 VALUES (?,?,?,?,?,?)
 325
 326         my $nc = 1;
 327         $sth->bind_param($nc, $num);
 328         $sth->bind_param(++$nc, $smsg->{$_}) for (qw(tid sid ts ds));
 329         $sth->bind_param(++$nc, $ddd, SQL_BLOB);
 330         $sth->execute;
 331         $sth = $dbh->prepare_cached(<<'');
 332 INSERT INTO id2num (id, num) VALUES (?,?)
 333
 334         foreach my $mid (@$mids) {
 335                 my $id = mid2id($self, $mid);
 336                 $sth->execute($id, $num);
 337         }
 338 }
 339
 340 sub _remove_oid {
 341         my ($self, $smsg, $oid, $removed) = @_;
 342         if (!defined($oid) || $smsg->{blob} eq $oid) {
 343                 delete_by_num($self, $smsg->{num});
 344                 push @$removed, $smsg->{num};
 345         }
 346         1;
 347 }
 348
 349 # returns number of removed messages in scalar context,
 350 # array of removed article numbers in array context.
 351 # $oid may be undef to match only on $mid
 352 sub remove_oid {
 353         my ($self, $oid, $mid) = @_;
 354         my $removed = [];
 355         begin_lazy($self);
 356         each_by_mid($self, $mid, ['ddd'], \&_remove_oid, $oid, $removed);
 357         @$removed;
 358 }
 359
 360 sub _num_mid0_for_oid {
 361         my ($self, $smsg, $oid, $res) = @_;
 362         my $blob = $smsg->{blob};
 363         return 1 if (!defined($blob) || $blob ne $oid); # continue;
 364         @$res = ($smsg->{num}, $smsg->{mid});
 365         0; # done
 366 }
 367
 368 sub num_mid0_for_oid {
 369         my ($self, $oid, $mid) = @_;
 370         my $res = [];
 371         begin_lazy($self);
 372         each_by_mid($self, $mid, ['ddd'], \&_num_mid0_for_oid, $oid, $res);
 373         @$res, # ($num, $mid0);
 374 }
 375
 376 sub create_tables {
 377         my ($dbh) = @_;
 378
 379         $dbh->do(<<'');
 380 CREATE TABLE IF NOT EXISTS over (
 381         num INTEGER PRIMARY KEY NOT NULL, /* NNTP article number == IMAP UID */
 382         tid INTEGER NOT NULL, /* THREADID (IMAP REFERENCES threading, JMAP) */
 383         sid INTEGER, /* Subject ID (IMAP ORDEREDSUBJECT "threading") */
 384         ts INTEGER, /* IMAP INTERNALDATE (Received: header, git commit time) */
 385         ds INTEGER, /* RFC-2822 sent Date: header, git author time */
 386         ddd VARBINARY /* doc-data-deflated (->to_doc_data, ->load_from_data) */
 387 )
 388
 389         $dbh->do('CREATE INDEX IF NOT EXISTS idx_tid ON over (tid)');
 390         $dbh->do('CREATE INDEX IF NOT EXISTS idx_sid ON over (sid)');
 391         $dbh->do('CREATE INDEX IF NOT EXISTS idx_ts ON over (ts)');
 392         $dbh->do('CREATE INDEX IF NOT EXISTS idx_ds ON over (ds)');
 393
 394         $dbh->do(<<'');
 395 CREATE TABLE IF NOT EXISTS counter (
 396         key VARCHAR(8) PRIMARY KEY NOT NULL,
 397         val INTEGER DEFAULT 0,
 398         UNIQUE (key)
 399 )
 400
 401         $dbh->do("INSERT OR IGNORE INTO counter (key) VALUES ('thread')");
 402         $dbh->do("INSERT OR IGNORE INTO counter (key) VALUES ('ghost')");
 403
 404         $dbh->do(<<'');
 405 CREATE TABLE IF NOT EXISTS subject (
 406         sid INTEGER PRIMARY KEY AUTOINCREMENT,
 407         path VARCHAR(40) NOT NULL, /* SHA-1 of normalized subject */
 408         UNIQUE (path)
 409 )
 410
 411         $dbh->do(<<'');
 412 CREATE TABLE IF NOT EXISTS id2num (
 413         id INTEGER NOT NULL, /* <=> msgid.id */
 414         num INTEGER NOT NULL,
 415         UNIQUE (id, num)
 416 )
 417
 418         # performance critical:
 419         $dbh->do('CREATE INDEX IF NOT EXISTS idx_inum ON id2num (num)');
 420         $dbh->do('CREATE INDEX IF NOT EXISTS idx_id ON id2num (id)');
 421
 422         $dbh->do(<<'');
 423 CREATE TABLE IF NOT EXISTS msgid (
 424         id INTEGER PRIMARY KEY AUTOINCREMENT, /* <=> id2num.id */
 425         mid VARCHAR(244) NOT NULL,
 426         UNIQUE (mid)
 427 )
 428
 429 }
 430
 431 sub commit_lazy {
 432         my ($self) = @_;
 433         delete $self->{txn} or return;
 434         $self->{dbh}->commit;
 435 }
 436
 437 sub begin_lazy {
 438         my ($self) = @_;
 439         return if $self->{txn};
 440         my $dbh = $self->dbh or return;
 441         $dbh->begin_work;
 442         # $dbh->{Profile} = 2;
 443         $self->{txn} = 1;
 444 }
 445
 446 sub rollback_lazy {
 447         my ($self) = @_;
 448         delete $self->{txn} or return;
 449         $self->{dbh}->rollback;
 450 }
 451
 452 sub dbh_close {
 453         my ($self) = @_;
 454         die "in transaction" if $self->{txn};
 455         $self->SUPER::dbh_close;
 456 }
 457
 458 sub create {
 459         my ($self) = @_;
 460         my $fn = $self->{filename} // do {
 461                 croak('BUG: no {filename}') unless $self->{dbh};
 462                 return;
 463         };
 464         unless (-r $fn) {
 465                 require File::Path;
 466                 require File::Basename;
 467                 File::Path::mkpath(File::Basename::dirname($fn));
 468         }
 469         # create the DB:
 470         PublicInbox::Over::dbh($self);
 471         $self->dbh_close;
 472 }
 473
 474 sub rethread_prepare {
 475         my ($self, $opt) = @_;
 476         return unless $opt->{rethread};
 477         begin_lazy($self);
 478         my $min = $self->{min_tid} = get_counter($self->{dbh}, 'thread') // 0;
 479         my $pr = $opt->{-progress};
 480         $pr->("rethread min THREADID ".($min + 1)."\n") if $pr && $min;
 481 }
 482
 483 sub rethread_done {
 484         my ($self, $opt) = @_;
 485         return unless $opt->{rethread} && $self->{txn};
 486         defined(my $min = $self->{min_tid}) or croak('BUG: no min_tid');
 487         my $dbh = $self->{dbh} or croak('BUG: no dbh');
 488         my $rows = $dbh->selectall_arrayref(<<'', { Slice => {} }, $min);
 489 SELECT num,tid FROM over WHERE num < 0 AND tid < ?
 490
 491         my $show_id = $dbh->prepare('SELECT id FROM id2num WHERE num = ?');
 492         my $show_mid = $dbh->prepare('SELECT mid FROM msgid WHERE id = ?');
 493         my $pr = $opt->{-progress};
 494         my $total = 0;
 495         for my $r (@$rows) {
 496                 my $exp = 0;
 497                 $show_id->execute($r->{num});
 498                 while (defined(my $id = $show_id->fetchrow_array)) {
 499                         ++$exp;
 500                         $show_mid->execute($id);
 501                         my $mid = $show_mid->fetchrow_array;
 502                         if (!defined($mid)) {
 503                                 warn <<EOF;
 504 E: ghost NUM=$r->{num} ID=$id THREADID=$r->{tid} has no Message-ID
 505 EOF
 506                                 next;
 507                         }
 508                         $pr->(<<EOM) if $pr;
 509 I: ghost $r->{num} <$mid> THREADID=$r->{tid} culled
 510 EOM
 511                 }
 512                 delete_by_num($self, $r->{num});
 513         }
 514         $pr->("I: rethread culled $total ghosts\n") if $pr && $total;
 515 }
 516
 517 # used for cross-inbox search
 518 sub eidx_prep ($) {
 519         my ($self) = @_;
 520         $self->{-eidx_prep} //= do {
 521                 my $dbh = $self->dbh;
 522                 $dbh->do(<<'');
 523 INSERT OR IGNORE INTO counter (key) VALUES ('eidx_docid')
 524
 525                 $dbh->do(<<'');
 526 CREATE TABLE IF NOT EXISTS inboxes (
 527         ibx_id INTEGER PRIMARY KEY AUTOINCREMENT,
 528         eidx_key VARCHAR(255) NOT NULL, /* {newsgroup} // {inboxdir} */
 529         UNIQUE (eidx_key)
 530 )
 531
 532                 $dbh->do(<<'');
 533 CREATE TABLE IF NOT EXISTS xref3 (
 534         docid INTEGER NOT NULL, /* <=> over.num */
 535         ibx_id INTEGER NOT NULL, /* <=> inboxes.ibx_id */
 536         xnum INTEGER NOT NULL, /* NNTP article number in ibx */
 537         oidbin VARBINARY NOT NULL, /* 20-byte SHA-1 or 32-byte SHA-256 */
 538         UNIQUE (docid, ibx_id, xnum, oidbin)
 539 )
 540
 541         $dbh->do('CREATE INDEX IF NOT EXISTS idx_docid ON xref3 (docid)');
 542
 543         # performance critical, this is not UNIQUE since we may need to
 544         # tolerate some old bugs from indexing mirrors
 545         $dbh->do('CREATE INDEX IF NOT EXISTS idx_nntp ON '.
 546                 'xref3 (oidbin,xnum,ibx_id)');
 547
 548                 $dbh->do(<<'');
 549 CREATE TABLE IF NOT EXISTS eidx_meta (
 550         key VARCHAR(255) PRIMARY KEY,
 551         val VARCHAR(255) NOT NULL
 552 )
 553
 554                 # A queue of current docids which need reindexing.
 555                 # eidxq persists across aborted -extindex invocations
 556                 # Currently used for "-extindex --reindex" for Xapian
 557                 # data, but may be used in more places down the line.
 558                 $dbh->do(<<'');
 559 CREATE TABLE IF NOT EXISTS eidxq (docid INTEGER PRIMARY KEY NOT NULL)
 560
 561                 1;
 562         };
 563 }
 564
 565 sub eidx_meta { # requires transaction
 566         my ($self, $key, $val) = @_;
 567
 568         my $sql = 'SELECT val FROM eidx_meta WHERE key = ? LIMIT 1';
 569         my $dbh = $self->{dbh};
 570         defined($val) or return $dbh->selectrow_array($sql, undef, $key);
 571
 572         my $prev = $dbh->selectrow_array($sql, undef, $key);
 573         if (defined $prev) {
 574                 $sql = 'UPDATE eidx_meta SET val = ? WHERE key = ?';
 575                 $dbh->do($sql, undef, $val, $key);
 576         } else {
 577                 $sql = 'INSERT INTO eidx_meta (key,val) VALUES (?,?)';
 578                 $dbh->do($sql, undef, $key, $val);
 579         }
 580         $prev;
 581 }
 582
 583 sub eidx_max {
 584         my ($self) = @_;
 585         get_counter($self->{dbh}, 'eidx_docid');
 586 }
 587
 588 sub add_xref3 {
 589         my ($self, $docid, $xnum, $oidhex, $eidx_key) = @_;
 590         begin_lazy($self);
 591         my $ibx_id = ibx_id($self, $eidx_key);
 592         my $oidbin = pack('H*', $oidhex);
 593         my $sth = $self->{dbh}->prepare_cached(<<'');
 594 INSERT OR IGNORE INTO xref3 (docid, ibx_id, xnum, oidbin) VALUES (?, ?, ?, ?)
 595
 596         $sth->bind_param(1, $docid);
 597         $sth->bind_param(2, $ibx_id);
 598         $sth->bind_param(3, $xnum);
 599         $sth->bind_param(4, $oidbin, SQL_BLOB);
 600         $sth->execute;
 601 }
 602
 603 # returns remaining reference count to $docid
 604 sub remove_xref3 {
 605         my ($self, $docid, $oidhex, $eidx_key, $rm_eidx_info) = @_;
 606         begin_lazy($self);
 607         my $oidbin = pack('H*', $oidhex);
 608         my ($sth, $ibx_id);
 609         if (defined $eidx_key) {
 610                 $ibx_id = ibx_id($self, $eidx_key);
 611                 $sth = $self->{dbh}->prepare_cached(<<'');
 612 DELETE FROM xref3 WHERE docid = ? AND ibx_id = ? AND oidbin = ?
 613
 614                 $sth->bind_param(1, $docid);
 615                 $sth->bind_param(2, $ibx_id);
 616                 $sth->bind_param(3, $oidbin, SQL_BLOB);
 617         } else {
 618                 $sth = $self->{dbh}->prepare_cached(<<'');
 619 DELETE FROM xref3 WHERE docid = ? AND oidbin = ?
 620
 621                 $sth->bind_param(1, $docid);
 622                 $sth->bind_param(2, $oidbin, SQL_BLOB);
 623         }
 624         $sth->execute;
 625         $sth = $self->{dbh}->prepare_cached(<<'', undef, 1);
 626 SELECT COUNT(*) FROM xref3 WHERE docid = ?
 627
 628         $sth->execute($docid);
 629         my $nr = $sth->fetchrow_array;
 630         if ($nr == 0) {
 631                 delete_by_num($self, $docid);
 632         } elsif (defined($ibx_id) && $rm_eidx_info) {
 633                 # if deduplication rules in ContentHash change, it's
 634                 # possible a docid can have multiple rows with the
 635                 # same ibx_id.  This governs whether or not we call
 636                 # ->shard_remove_eidx_info in ExtSearchIdx.
 637                 $sth = $self->{dbh}->prepare_cached(<<'', undef, 1);
 638 SELECT COUNT(*) FROM xref3 WHERE docid = ? AND ibx_id = ?
 639
 640                 $sth->execute($docid, $ibx_id);
 641                 my $count = $sth->fetchrow_array;
 642                 $$rm_eidx_info = ($count == 0);
 643         }
 644         $nr;
 645 }
 646
 647 # for when an xref3 goes missing, this does NOT update {ts}
 648 sub update_blob {
 649         my ($self, $smsg, $oidhex) = @_;
 650         my $sth = $self->{dbh}->prepare(<<'');
 651 UPDATE over SET ddd = ? WHERE num = ?
 652
 653         $smsg->{blob} = $oidhex;
 654         $sth->bind_param(1, ddd_for($smsg), SQL_BLOB);
 655         $sth->bind_param(2, $smsg->{num});
 656         $sth->execute;
 657 }
 658
 659 sub eidxq_add {
 660         my ($self, $docid) = @_;
 661         $self->dbh->prepare_cached(<<'')->execute($docid);
 662 INSERT OR IGNORE INTO eidxq (docid) VALUES (?)
 663
 664 }
 665
 666 sub eidxq_del {
 667         my ($self, $docid) = @_;
 668         $self->dbh->prepare_cached(<<'')->execute($docid);
 669 DELETE FROM eidxq WHERE docid = ?
 670
 671 }
 672
 673 1;