lib/PublicInbox/OverIdx.pm

   1 # Copyright (C) 2018-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # for XOVER, OVER in NNTP, and feeds/homepage/threads in PSGI
   5 # Unlike Msgmap, this is an _UNSTABLE_ cache which can be
   6 # tweaked/updated over time and rebuilt.
   7 #
   8 # Ghost messages (messages which are only referenced in References/In-Reply-To)
   9 # are denoted by a negative NNTP article number.
  10 package PublicInbox::OverIdx;
  11 use strict;
  12 use v5.10.1;
  13 use parent qw(PublicInbox::Over);
  14 use IO::Handle;
  15 use DBI qw(:sql_types); # SQL_BLOB
  16 use PublicInbox::MID qw/id_compress mids_for_index references/;
  17 use PublicInbox::Smsg qw(subject_normalized);
  18 use Compress::Zlib qw(compress);
  19 use Carp qw(croak);
  20
  21 sub dbh_new {
  22         my ($self) = @_;
  23         my $dbh = $self->SUPER::dbh_new($self->{-no_fsync} ? 2 : 1);
  24
  25         # 80000 pages (80MiB on SQLite <3.12.0, 320MiB on 3.12.0+)
  26         # was found to be good in 2018 during the large LKML import
  27         # at the time.  This ought to be configurable based on HW
  28         # and inbox size; I suspect it's overkill for many inboxes.
  29         $dbh->do('PRAGMA cache_size = 80000');
  30
  31         create_tables($dbh);
  32         $dbh;
  33 }
  34
  35 sub new {
  36         my ($class, $f) = @_;
  37         my $self = $class->SUPER::new($f);
  38         $self->{min_tid} = 0;
  39         $self;
  40 }
  41
  42 sub get_counter ($$) {
  43         my ($dbh, $key) = @_;
  44         my $sth = $dbh->prepare_cached(<<'', undef, 1);
  45 SELECT val FROM counter WHERE key = ? LIMIT 1
  46
  47         $sth->execute($key);
  48         $sth->fetchrow_array;
  49 }
  50
  51 sub adj_counter ($$$) {
  52         my ($self, $key, $op) = @_;
  53         my $dbh = $self->{dbh};
  54         my $sth = $dbh->prepare_cached(<<"");
  55 UPDATE counter SET val = val $op 1 WHERE key = ?
  56
  57         $sth->execute($key);
  58
  59         get_counter($dbh, $key);
  60 }
  61
  62 sub next_tid { adj_counter($_[0], 'thread', '+') }
  63 sub next_ghost_num { adj_counter($_[0], 'ghost', '-') }
  64
  65 sub id_for ($$$$$) {
  66         my ($self, $tbl, $id_col, $val_col, $val) = @_;
  67         my $dbh = $self->{dbh};
  68         my $in = $dbh->prepare_cached(<<"")->execute($val);
  69 INSERT OR IGNORE INTO $tbl ($val_col) VALUES (?)
  70
  71         if ($in == 0) {
  72                 my $sth = $dbh->prepare_cached(<<"", undef, 1);
  73 SELECT $id_col FROM $tbl WHERE $val_col = ? LIMIT 1
  74
  75                 $sth->execute($val);
  76                 $sth->fetchrow_array;
  77         } else {
  78                 $dbh->last_insert_id(undef, undef, $tbl, $id_col);
  79         }
  80 }
  81
  82 sub sid {
  83         my ($self, $path) = @_;
  84         return unless defined $path && $path ne '';
  85         id_for($self, 'subject', 'sid', 'path' => $path);
  86 }
  87
  88 sub mid2id {
  89         my ($self, $mid) = @_;
  90         id_for($self, 'msgid', 'id', 'mid' => $mid);
  91 }
  92
  93 sub delete_by_num {
  94         my ($self, $num, $tid_ref) = @_;
  95         my $dbh = $self->{dbh};
  96         if ($tid_ref) {
  97                 my $sth = $dbh->prepare_cached(<<'', undef, 1);
  98 SELECT tid FROM over WHERE num = ? LIMIT 1
  99
 100                 $sth->execute($num);
 101                 $$tid_ref = $sth->fetchrow_array; # may be undef
 102         }
 103         foreach (qw(over id2num)) {
 104                 $dbh->prepare_cached(<<"")->execute($num);
 105 DELETE FROM $_ WHERE num = ?
 106
 107         }
 108 }
 109
 110 # this includes ghosts
 111 sub each_by_mid {
 112         my ($self, $mid, $cols, $cb, @arg) = @_;
 113         my $dbh = $self->{dbh};
 114
 115 =over
 116         I originally wanted to stuff everything into a single query:
 117
 118         SELECT over.* FROM over
 119         LEFT JOIN id2num ON over.num = id2num.num
 120         LEFT JOIN msgid ON msgid.id = id2num.id
 121         WHERE msgid.mid = ? AND over.num >= ?
 122         ORDER BY over.num ASC
 123         LIMIT 1000
 124
 125         But it's faster broken out (and we're always in a
 126         transaction for subroutines in this file)
 127 =cut
 128
 129         my $sth = $dbh->prepare_cached(<<'', undef, 1);
 130 SELECT id FROM msgid WHERE mid = ? LIMIT 1
 131
 132         $sth->execute($mid);
 133         my $id = $sth->fetchrow_array;
 134         defined $id or return;
 135
 136         push(@$cols, 'num');
 137         $cols = join(',', map { $_ } @$cols);
 138         my $lim = 10;
 139         my $prev = get_counter($dbh, 'ghost');
 140         while (1) {
 141                 $sth = $dbh->prepare_cached(<<"", undef, 1);
 142 SELECT num FROM id2num WHERE id = ? AND num >= ?
 143 ORDER BY num ASC
 144 LIMIT $lim
 145
 146                 $sth->execute($id, $prev);
 147                 my $nums = $sth->fetchall_arrayref;
 148                 my $nr = scalar(@$nums) or return;
 149                 $prev = $nums->[-1]->[0];
 150
 151                 $sth = $dbh->prepare_cached(<<"", undef, 1);
 152 SELECT $cols FROM over WHERE over.num = ? LIMIT 1
 153
 154                 foreach (@$nums) {
 155                         $sth->execute($_->[0]);
 156                         my $smsg = $sth->fetchrow_hashref;
 157                         $smsg = PublicInbox::Over::load_from_row($smsg);
 158                         $cb->($self, $smsg, @arg) or return;
 159                 }
 160                 return if $nr != $lim;
 161         }
 162 }
 163
 164 sub _resolve_mid_to_tid {
 165         my ($self, $smsg, $tid) = @_;
 166         my $cur_tid = $smsg->{tid};
 167         if (defined $$tid) {
 168                 merge_threads($self, $$tid, $cur_tid);
 169         } elsif ($cur_tid > $self->{min_tid}) {
 170                 $$tid = $cur_tid;
 171         } else { # rethreading, queue up dead ghosts
 172                 $$tid = next_tid($self);
 173                 my $n = $smsg->{num};
 174                 if ($n > 0) {
 175                         $self->{dbh}->prepare_cached(<<'')->execute($$tid, $n);
 176 UPDATE over SET tid = ? WHERE num = ?
 177
 178                 } elsif ($n < 0) {
 179                         push(@{$self->{-ghosts_to_delete}}, $n);
 180                 }
 181         }
 182         1;
 183 }
 184
 185 # this will create a ghost as necessary
 186 sub resolve_mid_to_tid {
 187         my ($self, $mid) = @_;
 188         my $tid;
 189         each_by_mid($self, $mid, ['tid'], \&_resolve_mid_to_tid, \$tid);
 190         if (my $del = delete $self->{-ghosts_to_delete}) {
 191                 delete_by_num($self, $_) for @$del;
 192         }
 193         $tid // do { # create a new ghost
 194                 my $id = mid2id($self, $mid);
 195                 my $num = next_ghost_num($self);
 196                 $num < 0 or die "ghost num is non-negative: $num\n";
 197                 $tid = next_tid($self);
 198                 my $dbh = $self->{dbh};
 199                 $dbh->prepare_cached(<<'')->execute($num, $tid);
 200 INSERT INTO over (num, tid) VALUES (?,?)
 201
 202                 $dbh->prepare_cached(<<'')->execute($id, $num);
 203 INSERT INTO id2num (id, num) VALUES (?,?)
 204
 205                 $tid;
 206         };
 207 }
 208
 209 sub merge_threads {
 210         my ($self, $winner_tid, $loser_tid) = @_;
 211         return if $winner_tid == $loser_tid;
 212         my $dbh = $self->{dbh};
 213         $dbh->prepare_cached(<<'')->execute($winner_tid, $loser_tid);
 214 UPDATE over SET tid = ? WHERE tid = ?
 215
 216 }
 217
 218 sub link_refs {
 219         my ($self, $refs, $old_tid) = @_;
 220         my $tid;
 221
 222         if (@$refs) {
 223                 # first ref *should* be the thread root,
 224                 # but we can never trust clients to do the right thing
 225                 my $ref = $refs->[0];
 226                 $tid = resolve_mid_to_tid($self, $ref);
 227                 merge_threads($self, $tid, $old_tid) if defined $old_tid;
 228
 229                 # the rest of the refs should point to this tid:
 230                 foreach my $i (1..$#$refs) {
 231                         $ref = $refs->[$i];
 232                         my $ptid = resolve_mid_to_tid($self, $ref);
 233                         merge_threads($self, $tid, $ptid);
 234                 }
 235         } else {
 236                 $tid = $old_tid // next_tid($self);
 237         }
 238         $tid;
 239 }
 240
 241 sub parse_references ($$$) {
 242         my ($smsg, $hdr, $mids) = @_;
 243         my $refs = references($hdr);
 244         push(@$refs, @$mids) if scalar(@$mids) > 1;
 245         return $refs if scalar(@$refs) == 0;
 246
 247         # prevent circular references here:
 248         my %seen = ( $smsg->{mid} => 1 );
 249         my @keep;
 250         foreach my $ref (@$refs) {
 251                 if (length($ref) > PublicInbox::MID::MAX_MID_SIZE) {
 252                         warn "References: <$ref> too long, ignoring\n";
 253                         next;
 254                 }
 255                 push(@keep, $ref) unless $seen{$ref}++;
 256         }
 257         $smsg->{references} = '<'.join('> <', @keep).'>' if @keep;
 258         \@keep;
 259 }
 260
 261 # normalize subjects so they are suitable as pathnames for URLs
 262 # XXX: consider for removal
 263 sub subject_path ($) {
 264         my ($subj) = @_;
 265         $subj = subject_normalized($subj);
 266         $subj =~ s![^a-zA-Z0-9_\.~/\-]+!_!g;
 267         lc($subj);
 268 }
 269
 270 sub add_overview {
 271         my ($self, $eml, $smsg) = @_;
 272         $smsg->{lines} = $eml->body_raw =~ tr!\n!\n!;
 273         my $mids = mids_for_index($eml);
 274         my $refs = parse_references($smsg, $eml, $mids);
 275         my $subj = $smsg->{subject};
 276         my $xpath;
 277         if ($subj ne '') {
 278                 $xpath = subject_path($subj);
 279                 $xpath = id_compress($xpath);
 280         }
 281         my $dd = $smsg->to_doc_data;
 282         utf8::encode($dd);
 283         $dd = compress($dd);
 284         add_over($self, $smsg, $mids, $refs, $xpath, $dd);
 285 }
 286
 287 sub _add_over {
 288         my ($self, $smsg, $mid, $refs, $old_tid, $v) = @_;
 289         my $cur_tid = $smsg->{tid};
 290         my $n = $smsg->{num};
 291         die "num must not be zero for $mid" if !$n;
 292         my $cur_valid = $cur_tid > $self->{min_tid};
 293
 294         if ($n > 0) { # regular mail
 295                 if ($cur_valid) {
 296                         $$old_tid //= $cur_tid;
 297                         merge_threads($self, $$old_tid, $cur_tid);
 298                 } else {
 299                         $$old_tid //= next_tid($self);
 300                 }
 301         } elsif ($n < 0) { # ghost
 302                 $$old_tid //= $cur_valid ? $cur_tid : next_tid($self);
 303                 $$old_tid = link_refs($self, $refs, $$old_tid);
 304                 delete_by_num($self, $n);
 305                 $$v++;
 306         }
 307         1;
 308 }
 309
 310 sub add_over {
 311         my ($self, $smsg, $mids, $refs, $xpath, $ddd) = @_;
 312         my $old_tid;
 313         my $vivified = 0;
 314         my $num = $smsg->{num};
 315
 316         begin_lazy($self);
 317         delete_by_num($self, $num, \$old_tid);
 318         $old_tid = undef if ($old_tid // 0) <= $self->{min_tid};
 319         foreach my $mid (@$mids) {
 320                 my $v = 0;
 321                 each_by_mid($self, $mid, ['tid'], \&_add_over,
 322                                 $mid, $refs, \$old_tid, \$v);
 323                 $v > 1 and warn "BUG: vivified multiple ($v) ghosts for $mid\n";
 324                 $vivified += $v;
 325         }
 326         $smsg->{tid} = $vivified ? $old_tid : link_refs($self, $refs, $old_tid);
 327         $smsg->{sid} = sid($self, $xpath);
 328         my $dbh = $self->{dbh};
 329         my $sth = $dbh->prepare_cached(<<'');
 330 INSERT INTO over (num, tid, sid, ts, ds, ddd)
 331 VALUES (?,?,?,?,?,?)
 332
 333         my $nc = 1;
 334         $sth->bind_param($nc, $num);
 335         $sth->bind_param(++$nc, $smsg->{$_}) for (qw(tid sid ts ds));
 336         $sth->bind_param(++$nc, $ddd, SQL_BLOB);
 337         $sth->execute;
 338         $sth = $dbh->prepare_cached(<<'');
 339 INSERT INTO id2num (id, num) VALUES (?,?)
 340
 341         foreach my $mid (@$mids) {
 342                 my $id = mid2id($self, $mid);
 343                 $sth->execute($id, $num);
 344         }
 345 }
 346
 347 sub _remove_oid {
 348         my ($self, $smsg, $oid, $removed) = @_;
 349         if (!defined($oid) || $smsg->{blob} eq $oid) {
 350                 delete_by_num($self, $smsg->{num});
 351                 push @$removed, $smsg->{num};
 352         }
 353         1;
 354 }
 355
 356 # returns number of removed messages in scalar context,
 357 # array of removed article numbers in array context.
 358 # $oid may be undef to match only on $mid
 359 sub remove_oid {
 360         my ($self, $oid, $mid) = @_;
 361         my $removed = [];
 362         begin_lazy($self);
 363         each_by_mid($self, $mid, ['ddd'], \&_remove_oid, $oid, $removed);
 364         @$removed;
 365 }
 366
 367 sub _num_mid0_for_oid {
 368         my ($self, $smsg, $oid, $res) = @_;
 369         my $blob = $smsg->{blob};
 370         return 1 if (!defined($blob) || $blob ne $oid); # continue;
 371         @$res = ($smsg->{num}, $smsg->{mid});
 372         0; # done
 373 }
 374
 375 sub num_mid0_for_oid {
 376         my ($self, $oid, $mid) = @_;
 377         my $res = [];
 378         begin_lazy($self);
 379         each_by_mid($self, $mid, ['ddd'], \&_num_mid0_for_oid, $oid, $res);
 380         @$res, # ($num, $mid0);
 381 }
 382
 383 sub create_tables {
 384         my ($dbh) = @_;
 385
 386         $dbh->do(<<'');
 387 CREATE TABLE IF NOT EXISTS over (
 388         num INTEGER NOT NULL, /* NNTP article number == IMAP UID */
 389         tid INTEGER NOT NULL, /* THREADID (IMAP REFERENCES threading, JMAP) */
 390         sid INTEGER, /* Subject ID (IMAP ORDEREDSUBJECT "threading") */
 391         ts INTEGER, /* IMAP INTERNALDATE (Received: header, git commit time) */
 392         ds INTEGER, /* RFC-2822 sent Date: header, git author time */
 393         ddd VARBINARY, /* doc-data-deflated (->to_doc_data, ->load_from_data) */
 394         UNIQUE (num)
 395 )
 396
 397         $dbh->do('CREATE INDEX IF NOT EXISTS idx_tid ON over (tid)');
 398         $dbh->do('CREATE INDEX IF NOT EXISTS idx_sid ON over (sid)');
 399         $dbh->do('CREATE INDEX IF NOT EXISTS idx_ts ON over (ts)');
 400         $dbh->do('CREATE INDEX IF NOT EXISTS idx_ds ON over (ds)');
 401
 402         $dbh->do(<<'');
 403 CREATE TABLE IF NOT EXISTS counter (
 404         key VARCHAR(8) PRIMARY KEY NOT NULL,
 405         val INTEGER DEFAULT 0,
 406         UNIQUE (key)
 407 )
 408
 409         $dbh->do("INSERT OR IGNORE INTO counter (key) VALUES ('thread')");
 410         $dbh->do("INSERT OR IGNORE INTO counter (key) VALUES ('ghost')");
 411
 412         $dbh->do(<<'');
 413 CREATE TABLE IF NOT EXISTS subject (
 414         sid INTEGER PRIMARY KEY AUTOINCREMENT,
 415         path VARCHAR(40) NOT NULL, /* SHA-1 of normalized subject */
 416         UNIQUE (path)
 417 )
 418
 419         $dbh->do(<<'');
 420 CREATE TABLE IF NOT EXISTS id2num (
 421         id INTEGER NOT NULL, /* <=> msgid.id */
 422         num INTEGER NOT NULL,
 423         UNIQUE (id, num)
 424 )
 425
 426         # performance critical:
 427         $dbh->do('CREATE INDEX IF NOT EXISTS idx_inum ON id2num (num)');
 428         $dbh->do('CREATE INDEX IF NOT EXISTS idx_id ON id2num (id)');
 429
 430         $dbh->do(<<'');
 431 CREATE TABLE IF NOT EXISTS msgid (
 432         id INTEGER PRIMARY KEY AUTOINCREMENT, /* <=> id2num.id */
 433         mid VARCHAR(244) NOT NULL,
 434         UNIQUE (mid)
 435 )
 436
 437 }
 438
 439 sub commit_lazy {
 440         my ($self) = @_;
 441         delete $self->{txn} or return;
 442         $self->{dbh}->commit;
 443 }
 444
 445 sub begin_lazy {
 446         my ($self) = @_;
 447         return if $self->{txn};
 448         my $dbh = $self->dbh or return;
 449         $dbh->begin_work;
 450         # $dbh->{Profile} = 2;
 451         $self->{txn} = 1;
 452 }
 453
 454 sub rollback_lazy {
 455         my ($self) = @_;
 456         delete $self->{txn} or return;
 457         $self->{dbh}->rollback;
 458 }
 459
 460 sub dbh_close {
 461         my ($self) = @_;
 462         die "in transaction" if $self->{txn};
 463         $self->SUPER::dbh_close;
 464 }
 465
 466 sub create {
 467         my ($self) = @_;
 468         unless (-r $self->{filename}) {
 469                 require File::Path;
 470                 require File::Basename;
 471                 File::Path::mkpath(File::Basename::dirname($self->{filename}));
 472         }
 473         # create the DB:
 474         PublicInbox::Over::dbh($self);
 475         $self->dbh_close;
 476 }
 477
 478 sub rethread_prepare {
 479         my ($self, $opt) = @_;
 480         return unless $opt->{rethread};
 481         begin_lazy($self);
 482         my $min = $self->{min_tid} = get_counter($self->{dbh}, 'thread') // 0;
 483         my $pr = $opt->{-progress};
 484         $pr->("rethread min THREADID ".($min + 1)."\n") if $pr && $min;
 485 }
 486
 487 sub rethread_done {
 488         my ($self, $opt) = @_;
 489         return unless $opt->{rethread} && $self->{txn};
 490         defined(my $min = $self->{min_tid}) or croak('BUG: no min_tid');
 491         my $dbh = $self->{dbh} or croak('BUG: no dbh');
 492         my $rows = $dbh->selectall_arrayref(<<'', { Slice => {} }, $min);
 493 SELECT num,tid FROM over WHERE num < 0 AND tid < ?
 494
 495         my $show_id = $dbh->prepare('SELECT id FROM id2num WHERE num = ?');
 496         my $show_mid = $dbh->prepare('SELECT mid FROM msgid WHERE id = ?');
 497         my $pr = $opt->{-progress};
 498         my $total = 0;
 499         for my $r (@$rows) {
 500                 my $exp = 0;
 501                 $show_id->execute($r->{num});
 502                 while (defined(my $id = $show_id->fetchrow_array)) {
 503                         ++$exp;
 504                         $show_mid->execute($id);
 505                         my $mid = $show_mid->fetchrow_array;
 506                         if (!defined($mid)) {
 507                                 warn <<EOF;
 508 E: ghost NUM=$r->{num} ID=$id THREADID=$r->{tid} has no Message-ID
 509 EOF
 510                                 next;
 511                         }
 512                         $pr->(<<EOM) if $pr;
 513 I: ghost $r->{num} <$mid> THREADID=$r->{tid} culled
 514 EOM
 515                 }
 516                 delete_by_num($self, $r->{num});
 517         }
 518         $pr->("I: rethread culled $total ghosts\n") if $pr && $total;
 519 }
 520
 521 1;