lib/PublicInbox/OverIdx.pm

   1 # Copyright (C) 2018-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # for XOVER, OVER in NNTP, and feeds/homepage/threads in PSGI
   5 # Unlike Msgmap, this is an _UNSTABLE_ cache which can be
   6 # tweaked/updated over time and rebuilt.
   7 #
   8 # Ghost messages (messages which are only referenced in References/In-Reply-To)
   9 # are denoted by a negative NNTP article number.
  10 package PublicInbox::OverIdx;
  11 use strict;
  12 use v5.10.1;
  13 use parent qw(PublicInbox::Over);
  14 use IO::Handle;
  15 use DBI qw(:sql_types); # SQL_BLOB
  16 use PublicInbox::MID qw/id_compress mids_for_index references/;
  17 use PublicInbox::Smsg qw(subject_normalized);
  18 use Compress::Zlib qw(compress);
  19 use Carp qw(croak);
  20
  21 sub dbh_new {
  22         my ($self) = @_;
  23         my $dbh = $self->SUPER::dbh_new($self->{-no_fsync} ? 2 : 1);
  24
  25         # 80000 pages (80MiB on SQLite <3.12.0, 320MiB on 3.12.0+)
  26         # was found to be good in 2018 during the large LKML import
  27         # at the time.  This ought to be configurable based on HW
  28         # and inbox size; I suspect it's overkill for many inboxes.
  29         $dbh->do('PRAGMA cache_size = 80000');
  30
  31         create_tables($dbh);
  32         $dbh;
  33 }
  34
  35 sub new {
  36         my ($class, $f) = @_;
  37         my $self = $class->SUPER::new($f);
  38         $self->{min_tid} = 0;
  39         $self;
  40 }
  41
  42 sub get_counter ($$) {
  43         my ($dbh, $key) = @_;
  44         my $sth = $dbh->prepare_cached(<<'', undef, 1);
  45 SELECT val FROM counter WHERE key = ? LIMIT 1
  46
  47         $sth->execute($key);
  48         $sth->fetchrow_array;
  49 }
  50
  51 sub adj_counter ($$$) {
  52         my ($self, $key, $op) = @_;
  53         my $dbh = $self->{dbh};
  54         my $sth = $dbh->prepare_cached(<<"");
  55 UPDATE counter SET val = val $op 1 WHERE key = ?
  56
  57         $sth->execute($key);
  58
  59         get_counter($dbh, $key);
  60 }
  61
  62 sub next_tid { adj_counter($_[0], 'thread', '+') }
  63 sub next_ghost_num { adj_counter($_[0], 'ghost', '-') }
  64
  65 sub id_for ($$$$$) {
  66         my ($self, $tbl, $id_col, $val_col, $val) = @_;
  67         my $dbh = $self->{dbh};
  68         my $in = $dbh->prepare_cached(<<"")->execute($val);
  69 INSERT OR IGNORE INTO $tbl ($val_col) VALUES (?)
  70
  71         if ($in == 0) {
  72                 my $sth = $dbh->prepare_cached(<<"", undef, 1);
  73 SELECT $id_col FROM $tbl WHERE $val_col = ? LIMIT 1
  74
  75                 $sth->execute($val);
  76                 $sth->fetchrow_array;
  77         } else {
  78                 $dbh->last_insert_id(undef, undef, $tbl, $id_col);
  79         }
  80 }
  81
  82 sub ibx_id {
  83         my ($self, $eidx_key) = @_;
  84         id_for($self, 'inboxes', 'ibx_id', eidx_key => $eidx_key);
  85 }
  86
  87 sub sid {
  88         my ($self, $path) = @_;
  89         return unless defined $path && $path ne '';
  90         id_for($self, 'subject', 'sid', 'path' => $path);
  91 }
  92
  93 sub mid2id {
  94         my ($self, $mid) = @_;
  95         id_for($self, 'msgid', 'id', 'mid' => $mid);
  96 }
  97
  98 sub delete_by_num {
  99         my ($self, $num, $tid_ref) = @_;
 100         my $dbh = $self->{dbh};
 101         if ($tid_ref) {
 102                 my $sth = $dbh->prepare_cached(<<'', undef, 1);
 103 SELECT tid FROM over WHERE num = ? LIMIT 1
 104
 105                 $sth->execute($num);
 106                 $$tid_ref = $sth->fetchrow_array; # may be undef
 107         }
 108         foreach (qw(over id2num)) {
 109                 $dbh->prepare_cached(<<"")->execute($num);
 110 DELETE FROM $_ WHERE num = ?
 111
 112         }
 113 }
 114
 115 # this includes ghosts
 116 sub each_by_mid {
 117         my ($self, $mid, $cols, $cb, @arg) = @_;
 118         my $dbh = $self->{dbh};
 119
 120 =over
 121         I originally wanted to stuff everything into a single query:
 122
 123         SELECT over.* FROM over
 124         LEFT JOIN id2num ON over.num = id2num.num
 125         LEFT JOIN msgid ON msgid.id = id2num.id
 126         WHERE msgid.mid = ? AND over.num >= ?
 127         ORDER BY over.num ASC
 128         LIMIT 1000
 129
 130         But it's faster broken out (and we're always in a
 131         transaction for subroutines in this file)
 132 =cut
 133
 134         my $sth = $dbh->prepare_cached(<<'', undef, 1);
 135 SELECT id FROM msgid WHERE mid = ? LIMIT 1
 136
 137         $sth->execute($mid);
 138         my $id = $sth->fetchrow_array;
 139         defined $id or return;
 140
 141         push(@$cols, 'num');
 142         $cols = join(',', map { $_ } @$cols);
 143         my $lim = 10;
 144         my $prev = get_counter($dbh, 'ghost');
 145         while (1) {
 146                 $sth = $dbh->prepare_cached(<<"", undef, 1);
 147 SELECT num FROM id2num WHERE id = ? AND num >= ?
 148 ORDER BY num ASC
 149 LIMIT $lim
 150
 151                 $sth->execute($id, $prev);
 152                 my $nums = $sth->fetchall_arrayref;
 153                 my $nr = scalar(@$nums) or return;
 154                 $prev = $nums->[-1]->[0];
 155
 156                 $sth = $dbh->prepare_cached(<<"", undef, 1);
 157 SELECT $cols FROM over WHERE over.num = ? LIMIT 1
 158
 159                 foreach (@$nums) {
 160                         $sth->execute($_->[0]);
 161                         my $smsg = $sth->fetchrow_hashref;
 162                         $smsg = PublicInbox::Over::load_from_row($smsg);
 163                         $cb->($self, $smsg, @arg) or return;
 164                 }
 165                 return if $nr != $lim;
 166         }
 167 }
 168
 169 sub _resolve_mid_to_tid {
 170         my ($self, $smsg, $tid) = @_;
 171         my $cur_tid = $smsg->{tid};
 172         if (defined $$tid) {
 173                 merge_threads($self, $$tid, $cur_tid);
 174         } elsif ($cur_tid > $self->{min_tid}) {
 175                 $$tid = $cur_tid;
 176         } else { # rethreading, queue up dead ghosts
 177                 $$tid = next_tid($self);
 178                 my $n = $smsg->{num};
 179                 if ($n > 0) {
 180                         $self->{dbh}->prepare_cached(<<'')->execute($$tid, $n);
 181 UPDATE over SET tid = ? WHERE num = ?
 182
 183                 } elsif ($n < 0) {
 184                         push(@{$self->{-ghosts_to_delete}}, $n);
 185                 }
 186         }
 187         1;
 188 }
 189
 190 # this will create a ghost as necessary
 191 sub resolve_mid_to_tid {
 192         my ($self, $mid) = @_;
 193         my $tid;
 194         each_by_mid($self, $mid, ['tid'], \&_resolve_mid_to_tid, \$tid);
 195         if (my $del = delete $self->{-ghosts_to_delete}) {
 196                 delete_by_num($self, $_) for @$del;
 197         }
 198         $tid // do { # create a new ghost
 199                 my $id = mid2id($self, $mid);
 200                 my $num = next_ghost_num($self);
 201                 $num < 0 or die "ghost num is non-negative: $num\n";
 202                 $tid = next_tid($self);
 203                 my $dbh = $self->{dbh};
 204                 $dbh->prepare_cached(<<'')->execute($num, $tid);
 205 INSERT INTO over (num, tid) VALUES (?,?)
 206
 207                 $dbh->prepare_cached(<<'')->execute($id, $num);
 208 INSERT INTO id2num (id, num) VALUES (?,?)
 209
 210                 $tid;
 211         };
 212 }
 213
 214 sub merge_threads {
 215         my ($self, $winner_tid, $loser_tid) = @_;
 216         return if $winner_tid == $loser_tid;
 217         my $dbh = $self->{dbh};
 218         $dbh->prepare_cached(<<'')->execute($winner_tid, $loser_tid);
 219 UPDATE over SET tid = ? WHERE tid = ?
 220
 221 }
 222
 223 sub link_refs {
 224         my ($self, $refs, $old_tid) = @_;
 225         my $tid;
 226
 227         if (@$refs) {
 228                 # first ref *should* be the thread root,
 229                 # but we can never trust clients to do the right thing
 230                 my $ref = $refs->[0];
 231                 $tid = resolve_mid_to_tid($self, $ref);
 232                 merge_threads($self, $tid, $old_tid) if defined $old_tid;
 233
 234                 # the rest of the refs should point to this tid:
 235                 foreach my $i (1..$#$refs) {
 236                         $ref = $refs->[$i];
 237                         my $ptid = resolve_mid_to_tid($self, $ref);
 238                         merge_threads($self, $tid, $ptid);
 239                 }
 240         } else {
 241                 $tid = $old_tid // next_tid($self);
 242         }
 243         $tid;
 244 }
 245
 246 # normalize subjects so they are suitable as pathnames for URLs
 247 # XXX: consider for removal
 248 sub subject_path ($) {
 249         my ($subj) = @_;
 250         $subj = subject_normalized($subj);
 251         $subj =~ s![^a-zA-Z0-9_\.~/\-]+!_!g;
 252         lc($subj);
 253 }
 254
 255 sub ddd_for ($) {
 256         my ($smsg) = @_;
 257         my $dd = $smsg->to_doc_data;
 258         utf8::encode($dd);
 259         compress($dd);
 260 }
 261
 262 sub add_overview {
 263         my ($self, $eml, $smsg) = @_;
 264         $smsg->{lines} = $eml->body_raw =~ tr!\n!\n!;
 265         my $mids = mids_for_index($eml);
 266         my $refs = $smsg->parse_references($eml, $mids);
 267         $mids->[0] //= $smsg->{mid} //= $eml->{-lei_fake_mid};
 268         $smsg->{mid} //= '';
 269         my $subj = $smsg->{subject};
 270         my $xpath;
 271         if ($subj ne '') {
 272                 $xpath = subject_path($subj);
 273                 $xpath = id_compress($xpath);
 274         }
 275         add_over($self, $smsg, $mids, $refs, $xpath, ddd_for($smsg));
 276 }
 277
 278 sub _add_over {
 279         my ($self, $smsg, $mid, $refs, $old_tid, $v) = @_;
 280         my $cur_tid = $smsg->{tid};
 281         my $n = $smsg->{num};
 282         die "num must not be zero for $mid" if !$n;
 283         my $cur_valid = $cur_tid > $self->{min_tid};
 284
 285         if ($n > 0) { # regular mail
 286                 if ($cur_valid) {
 287                         $$old_tid //= $cur_tid;
 288                         merge_threads($self, $$old_tid, $cur_tid);
 289                 } else {
 290                         $$old_tid //= next_tid($self);
 291                 }
 292         } elsif ($n < 0) { # ghost
 293                 $$old_tid //= $cur_valid ? $cur_tid : next_tid($self);
 294                 $$old_tid = link_refs($self, $refs, $$old_tid);
 295                 delete_by_num($self, $n);
 296                 $$v++;
 297         }
 298         1;
 299 }
 300
 301 sub add_over {
 302         my ($self, $smsg, $mids, $refs, $xpath, $ddd) = @_;
 303         my $old_tid;
 304         my $vivified = 0;
 305         my $num = $smsg->{num};
 306
 307         begin_lazy($self);
 308         delete_by_num($self, $num, \$old_tid);
 309         $old_tid = undef if ($old_tid // 0) <= $self->{min_tid};
 310         foreach my $mid (@$mids) {
 311                 my $v = 0;
 312                 each_by_mid($self, $mid, ['tid'], \&_add_over,
 313                                 $mid, $refs, \$old_tid, \$v);
 314                 $v > 1 and warn "BUG: vivified multiple ($v) ghosts for $mid\n";
 315                 $vivified += $v;
 316         }
 317         $smsg->{tid} = $vivified ? $old_tid : link_refs($self, $refs, $old_tid);
 318         $smsg->{sid} = sid($self, $xpath);
 319         my $dbh = $self->{dbh};
 320         my $sth = $dbh->prepare_cached(<<'');
 321 INSERT INTO over (num, tid, sid, ts, ds, ddd)
 322 VALUES (?,?,?,?,?,?)
 323
 324         my $nc = 1;
 325         $sth->bind_param($nc, $num);
 326         $sth->bind_param(++$nc, $smsg->{$_}) for (qw(tid sid ts ds));
 327         $sth->bind_param(++$nc, $ddd, SQL_BLOB);
 328         $sth->execute;
 329         $sth = $dbh->prepare_cached(<<'');
 330 INSERT INTO id2num (id, num) VALUES (?,?)
 331
 332         foreach my $mid (@$mids) {
 333                 my $id = mid2id($self, $mid);
 334                 $sth->execute($id, $num);
 335         }
 336 }
 337
 338 sub _remove_oid {
 339         my ($self, $smsg, $oid, $removed) = @_;
 340         if (!defined($oid) || $smsg->{blob} eq $oid) {
 341                 delete_by_num($self, $smsg->{num});
 342                 push @$removed, $smsg->{num};
 343         }
 344         1;
 345 }
 346
 347 # returns number of removed messages in scalar context,
 348 # array of removed article numbers in array context.
 349 # $oid may be undef to match only on $mid
 350 sub remove_oid {
 351         my ($self, $oid, $mid) = @_;
 352         my $removed = [];
 353         begin_lazy($self);
 354         each_by_mid($self, $mid, ['ddd'], \&_remove_oid, $oid, $removed);
 355         @$removed;
 356 }
 357
 358 sub _num_mid0_for_oid {
 359         my ($self, $smsg, $oid, $res) = @_;
 360         my $blob = $smsg->{blob};
 361         return 1 if (!defined($blob) || $blob ne $oid); # continue;
 362         @$res = ($smsg->{num}, $smsg->{mid});
 363         0; # done
 364 }
 365
 366 sub num_mid0_for_oid {
 367         my ($self, $oid, $mid) = @_;
 368         my $res = [];
 369         begin_lazy($self);
 370         each_by_mid($self, $mid, ['ddd'], \&_num_mid0_for_oid, $oid, $res);
 371         @$res, # ($num, $mid0);
 372 }
 373
 374 sub create_tables {
 375         my ($dbh) = @_;
 376
 377         $dbh->do(<<'');
 378 CREATE TABLE IF NOT EXISTS over (
 379         num INTEGER PRIMARY KEY NOT NULL, /* NNTP article number == IMAP UID */
 380         tid INTEGER NOT NULL, /* THREADID (IMAP REFERENCES threading, JMAP) */
 381         sid INTEGER, /* Subject ID (IMAP ORDEREDSUBJECT "threading") */
 382         ts INTEGER, /* IMAP INTERNALDATE (Received: header, git commit time) */
 383         ds INTEGER, /* RFC-2822 sent Date: header, git author time */
 384         ddd VARBINARY /* doc-data-deflated (->to_doc_data, ->load_from_data) */
 385 )
 386
 387         $dbh->do('CREATE INDEX IF NOT EXISTS idx_tid ON over (tid)');
 388         $dbh->do('CREATE INDEX IF NOT EXISTS idx_sid ON over (sid)');
 389         $dbh->do('CREATE INDEX IF NOT EXISTS idx_ts ON over (ts)');
 390         $dbh->do('CREATE INDEX IF NOT EXISTS idx_ds ON over (ds)');
 391
 392         $dbh->do(<<'');
 393 CREATE TABLE IF NOT EXISTS counter (
 394         key VARCHAR(8) PRIMARY KEY NOT NULL,
 395         val INTEGER DEFAULT 0,
 396         UNIQUE (key)
 397 )
 398
 399         $dbh->do("INSERT OR IGNORE INTO counter (key) VALUES ('thread')");
 400         $dbh->do("INSERT OR IGNORE INTO counter (key) VALUES ('ghost')");
 401
 402         $dbh->do(<<'');
 403 CREATE TABLE IF NOT EXISTS subject (
 404         sid INTEGER PRIMARY KEY AUTOINCREMENT,
 405         path VARCHAR(40) NOT NULL, /* SHA-1 of normalized subject */
 406         UNIQUE (path)
 407 )
 408
 409         $dbh->do(<<'');
 410 CREATE TABLE IF NOT EXISTS id2num (
 411         id INTEGER NOT NULL, /* <=> msgid.id */
 412         num INTEGER NOT NULL,
 413         UNIQUE (id, num)
 414 )
 415
 416         # performance critical:
 417         $dbh->do('CREATE INDEX IF NOT EXISTS idx_inum ON id2num (num)');
 418         $dbh->do('CREATE INDEX IF NOT EXISTS idx_id ON id2num (id)');
 419
 420         $dbh->do(<<'');
 421 CREATE TABLE IF NOT EXISTS msgid (
 422         id INTEGER PRIMARY KEY AUTOINCREMENT, /* <=> id2num.id */
 423         mid VARCHAR(244) NOT NULL,
 424         UNIQUE (mid)
 425 )
 426
 427 }
 428
 429 sub commit_lazy {
 430         my ($self) = @_;
 431         delete $self->{txn} or return;
 432         $self->{dbh}->commit;
 433 }
 434
 435 sub begin_lazy {
 436         my ($self) = @_;
 437         return if $self->{txn};
 438         my $dbh = $self->dbh or return;
 439         $dbh->begin_work;
 440         # $dbh->{Profile} = 2;
 441         $self->{txn} = 1;
 442 }
 443
 444 sub rollback_lazy {
 445         my ($self) = @_;
 446         delete $self->{txn} or return;
 447         $self->{dbh}->rollback;
 448 }
 449
 450 sub dbh_close {
 451         my ($self) = @_;
 452         die "in transaction" if $self->{txn};
 453         $self->SUPER::dbh_close;
 454 }
 455
 456 sub create {
 457         my ($self) = @_;
 458         my $fn = $self->{filename} // do {
 459                 croak('BUG: no {filename}') unless $self->{dbh};
 460                 return;
 461         };
 462         unless (-r $fn) {
 463                 require File::Path;
 464                 require File::Basename;
 465                 File::Path::mkpath(File::Basename::dirname($fn));
 466         }
 467         # create the DB:
 468         PublicInbox::Over::dbh($self);
 469         $self->dbh_close;
 470 }
 471
 472 sub rethread_prepare {
 473         my ($self, $opt) = @_;
 474         return unless $opt->{rethread};
 475         begin_lazy($self);
 476         my $min = $self->{min_tid} = get_counter($self->{dbh}, 'thread') // 0;
 477         my $pr = $opt->{-progress};
 478         $pr->("rethread min THREADID ".($min + 1)."\n") if $pr && $min;
 479 }
 480
 481 sub rethread_done {
 482         my ($self, $opt) = @_;
 483         return unless $opt->{rethread} && $self->{txn};
 484         defined(my $min = $self->{min_tid}) or croak('BUG: no min_tid');
 485         my $dbh = $self->{dbh} or croak('BUG: no dbh');
 486         my $rows = $dbh->selectall_arrayref(<<'', { Slice => {} }, $min);
 487 SELECT num,tid FROM over WHERE num < 0 AND tid < ?
 488
 489         my $show_id = $dbh->prepare('SELECT id FROM id2num WHERE num = ?');
 490         my $show_mid = $dbh->prepare('SELECT mid FROM msgid WHERE id = ?');
 491         my $pr = $opt->{-progress};
 492         my $total = 0;
 493         for my $r (@$rows) {
 494                 my $exp = 0;
 495                 $show_id->execute($r->{num});
 496                 while (defined(my $id = $show_id->fetchrow_array)) {
 497                         ++$exp;
 498                         $show_mid->execute($id);
 499                         my $mid = $show_mid->fetchrow_array;
 500                         if (!defined($mid)) {
 501                                 warn <<EOF;
 502 E: ghost NUM=$r->{num} ID=$id THREADID=$r->{tid} has no Message-ID
 503 EOF
 504                                 next;
 505                         }
 506                         $pr->(<<EOM) if $pr;
 507 I: ghost $r->{num} <$mid> THREADID=$r->{tid} culled
 508 EOM
 509                 }
 510                 delete_by_num($self, $r->{num});
 511         }
 512         $pr->("I: rethread culled $total ghosts\n") if $pr && $total;
 513 }
 514
 515 # used for cross-inbox search
 516 sub eidx_prep ($) {
 517         my ($self) = @_;
 518         $self->{-eidx_prep} //= do {
 519                 my $dbh = $self->dbh;
 520                 $dbh->do(<<'');
 521 INSERT OR IGNORE INTO counter (key) VALUES ('eidx_docid')
 522
 523                 $dbh->do(<<'');
 524 CREATE TABLE IF NOT EXISTS inboxes (
 525         ibx_id INTEGER PRIMARY KEY AUTOINCREMENT,
 526         eidx_key VARCHAR(255) NOT NULL, /* {newsgroup} // {inboxdir} */
 527         UNIQUE (eidx_key)
 528 )
 529
 530                 $dbh->do(<<'');
 531 CREATE TABLE IF NOT EXISTS xref3 (
 532         docid INTEGER NOT NULL, /* <=> over.num */
 533         ibx_id INTEGER NOT NULL, /* <=> inboxes.ibx_id */
 534         xnum INTEGER NOT NULL, /* NNTP article number in ibx */
 535         oidbin VARBINARY NOT NULL, /* 20-byte SHA-1 or 32-byte SHA-256 */
 536         UNIQUE (docid, ibx_id, xnum, oidbin)
 537 )
 538
 539         $dbh->do('CREATE INDEX IF NOT EXISTS idx_docid ON xref3 (docid)');
 540
 541         # performance critical, this is not UNIQUE since we may need to
 542         # tolerate some old bugs from indexing mirrors
 543         $dbh->do('CREATE INDEX IF NOT EXISTS idx_nntp ON '.
 544                 'xref3 (oidbin,xnum,ibx_id)');
 545
 546                 $dbh->do(<<'');
 547 CREATE TABLE IF NOT EXISTS eidx_meta (
 548         key VARCHAR(255) PRIMARY KEY,
 549         val VARCHAR(255) NOT NULL
 550 )
 551
 552                 # A queue of current docids which need reindexing.
 553                 # eidxq persists across aborted -extindex invocations
 554                 # Currently used for "-extindex --reindex" for Xapian
 555                 # data, but may be used in more places down the line.
 556                 $dbh->do(<<'');
 557 CREATE TABLE IF NOT EXISTS eidxq (docid INTEGER PRIMARY KEY NOT NULL)
 558
 559                 1;
 560         };
 561 }
 562
 563 sub eidx_meta { # requires transaction
 564         my ($self, $key, $val) = @_;
 565
 566         my $sql = 'SELECT val FROM eidx_meta WHERE key = ? LIMIT 1';
 567         my $dbh = $self->{dbh};
 568         defined($val) or return $dbh->selectrow_array($sql, undef, $key);
 569
 570         my $prev = $dbh->selectrow_array($sql, undef, $key);
 571         if (defined $prev) {
 572                 $sql = 'UPDATE eidx_meta SET val = ? WHERE key = ?';
 573                 $dbh->do($sql, undef, $val, $key);
 574         } else {
 575                 $sql = 'INSERT INTO eidx_meta (key,val) VALUES (?,?)';
 576                 $dbh->do($sql, undef, $key, $val);
 577         }
 578         $prev;
 579 }
 580
 581 sub eidx_max {
 582         my ($self) = @_;
 583         get_counter($self->{dbh}, 'eidx_docid');
 584 }
 585
 586 sub add_xref3 {
 587         my ($self, $docid, $xnum, $oidhex, $eidx_key) = @_;
 588         begin_lazy($self);
 589         my $ibx_id = ibx_id($self, $eidx_key);
 590         my $oidbin = pack('H*', $oidhex);
 591         my $sth = $self->{dbh}->prepare_cached(<<'');
 592 INSERT OR IGNORE INTO xref3 (docid, ibx_id, xnum, oidbin) VALUES (?, ?, ?, ?)
 593
 594         $sth->bind_param(1, $docid);
 595         $sth->bind_param(2, $ibx_id);
 596         $sth->bind_param(3, $xnum);
 597         $sth->bind_param(4, $oidbin, SQL_BLOB);
 598         $sth->execute;
 599 }
 600
 601 # returns remaining reference count to $docid
 602 sub remove_xref3 {
 603         my ($self, $docid, $oidhex, $eidx_key, $rm_eidx_info) = @_;
 604         begin_lazy($self);
 605         my $oidbin = pack('H*', $oidhex);
 606         my ($sth, $ibx_id);
 607         if (defined $eidx_key) {
 608                 $ibx_id = ibx_id($self, $eidx_key);
 609                 $sth = $self->{dbh}->prepare_cached(<<'');
 610 DELETE FROM xref3 WHERE docid = ? AND ibx_id = ? AND oidbin = ?
 611
 612                 $sth->bind_param(1, $docid);
 613                 $sth->bind_param(2, $ibx_id);
 614                 $sth->bind_param(3, $oidbin, SQL_BLOB);
 615         } else {
 616                 $sth = $self->{dbh}->prepare_cached(<<'');
 617 DELETE FROM xref3 WHERE docid = ? AND oidbin = ?
 618
 619                 $sth->bind_param(1, $docid);
 620                 $sth->bind_param(2, $oidbin, SQL_BLOB);
 621         }
 622         $sth->execute;
 623         $sth = $self->{dbh}->prepare_cached(<<'', undef, 1);
 624 SELECT COUNT(*) FROM xref3 WHERE docid = ?
 625
 626         $sth->execute($docid);
 627         my $nr = $sth->fetchrow_array;
 628         if ($nr == 0) {
 629                 delete_by_num($self, $docid);
 630         } elsif (defined($ibx_id) && $rm_eidx_info) {
 631                 # if deduplication rules in ContentHash change, it's
 632                 # possible a docid can have multiple rows with the
 633                 # same ibx_id.  This governs whether or not we call
 634                 # ->shard_remove_eidx_info in ExtSearchIdx.
 635                 $sth = $self->{dbh}->prepare_cached(<<'', undef, 1);
 636 SELECT COUNT(*) FROM xref3 WHERE docid = ? AND ibx_id = ?
 637
 638                 $sth->execute($docid, $ibx_id);
 639                 my $count = $sth->fetchrow_array;
 640                 $$rm_eidx_info = ($count == 0);
 641         }
 642         $nr;
 643 }
 644
 645 # for when an xref3 goes missing, this does NOT update {ts}
 646 sub update_blob {
 647         my ($self, $smsg, $oidhex) = @_;
 648         my $sth = $self->{dbh}->prepare(<<'');
 649 UPDATE over SET ddd = ? WHERE num = ?
 650
 651         $smsg->{blob} = $oidhex;
 652         $sth->bind_param(1, ddd_for($smsg), SQL_BLOB);
 653         $sth->bind_param(2, $smsg->{num});
 654         $sth->execute;
 655 }
 656
 657 sub eidxq_add {
 658         my ($self, $docid) = @_;
 659         $self->dbh->prepare_cached(<<'')->execute($docid);
 660 INSERT OR IGNORE INTO eidxq (docid) VALUES (?)
 661
 662 }
 663
 664 sub eidxq_del {
 665         my ($self, $docid) = @_;
 666         $self->dbh->prepare_cached(<<'')->execute($docid);
 667 DELETE FROM eidxq WHERE docid = ?
 668
 669 }
 670
 671 sub blob_exists {
 672         my ($self, $oidhex) = @_;
 673         my $sth = $self->dbh->prepare_cached(<<'', undef, 1);
 674 SELECT COUNT(*) FROM xref3 WHERE oidbin = ?
 675
 676         $sth->bind_param(1, pack('H*', $oidhex), SQL_BLOB);
 677         $sth->execute;
 678         $sth->fetchrow_array;
 679 }
 680
 681 1;