lib/PublicInbox/OverIdx.pm

   1 # Copyright (C) 2018-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # for XOVER, OVER in NNTP, and feeds/homepage/threads in PSGI
   5 # Unlike Msgmap, this is an _UNSTABLE_ cache which can be
   6 # tweaked/updated over time and rebuilt.
   7 #
   8 # Ghost messages (messages which are only referenced in References/In-Reply-To)
   9 # are denoted by a negative NNTP article number.
  10 package PublicInbox::OverIdx;
  11 use strict;
  12 use v5.10.1;
  13 use parent qw(PublicInbox::Over);
  14 use IO::Handle;
  15 use DBI qw(:sql_types); # SQL_BLOB
  16 use PublicInbox::MID qw/id_compress mids_for_index references/;
  17 use PublicInbox::Smsg qw(subject_normalized);
  18 use Compress::Zlib qw(compress);
  19 use Carp qw(croak);
  20
  21 sub dbh_new {
  22         my ($self) = @_;
  23         my $dbh = $self->SUPER::dbh_new($self->{-no_fsync} ? 2 : 1);
  24
  25         # 80000 pages (80MiB on SQLite <3.12.0, 320MiB on 3.12.0+)
  26         # was found to be good in 2018 during the large LKML import
  27         # at the time.  This ought to be configurable based on HW
  28         # and inbox size; I suspect it's overkill for many inboxes.
  29         $dbh->do('PRAGMA cache_size = 80000');
  30
  31         create_tables($dbh);
  32         $dbh;
  33 }
  34
  35 sub new {
  36         my ($class, $f) = @_;
  37         my $self = $class->SUPER::new($f);
  38         $self->{min_tid} = 0;
  39         $self;
  40 }
  41
  42 sub get_counter ($$) {
  43         my ($dbh, $key) = @_;
  44         my $sth = $dbh->prepare_cached(<<'', undef, 1);
  45 SELECT val FROM counter WHERE key = ? LIMIT 1
  46
  47         $sth->execute($key);
  48         $sth->fetchrow_array;
  49 }
  50
  51 sub adj_counter ($$$) {
  52         my ($self, $key, $op) = @_;
  53         my $dbh = $self->{dbh};
  54         my $sth = $dbh->prepare_cached(<<"");
  55 UPDATE counter SET val = val $op 1 WHERE key = ?
  56
  57         $sth->execute($key);
  58
  59         get_counter($dbh, $key);
  60 }
  61
  62 sub next_tid { adj_counter($_[0], 'thread', '+') }
  63 sub next_ghost_num { adj_counter($_[0], 'ghost', '-') }
  64
  65 sub id_for ($$$$$) {
  66         my ($self, $tbl, $id_col, $val_col, $val) = @_;
  67         my $dbh = $self->{dbh};
  68         my $in = $dbh->prepare_cached(<<"")->execute($val);
  69 INSERT OR IGNORE INTO $tbl ($val_col) VALUES (?)
  70
  71         if ($in == 0) {
  72                 my $sth = $dbh->prepare_cached(<<"", undef, 1);
  73 SELECT $id_col FROM $tbl WHERE $val_col = ? LIMIT 1
  74
  75                 $sth->execute($val);
  76                 $sth->fetchrow_array;
  77         } else {
  78                 $dbh->last_insert_id(undef, undef, $tbl, $id_col);
  79         }
  80 }
  81
  82 sub ibx_id {
  83         my ($self, $eidx_key) = @_;
  84         id_for($self, 'inboxes', 'ibx_id', eidx_key => $eidx_key);
  85 }
  86
  87 sub sid {
  88         my ($self, $path) = @_;
  89         return unless defined $path && $path ne '';
  90         id_for($self, 'subject', 'sid', 'path' => $path);
  91 }
  92
  93 sub mid2id {
  94         my ($self, $mid) = @_;
  95         id_for($self, 'msgid', 'id', 'mid' => $mid);
  96 }
  97
  98 sub delete_by_num {
  99         my ($self, $num, $tid_ref) = @_;
 100         my $dbh = $self->{dbh};
 101         if ($tid_ref) {
 102                 my $sth = $dbh->prepare_cached(<<'', undef, 1);
 103 SELECT tid FROM over WHERE num = ? LIMIT 1
 104
 105                 $sth->execute($num);
 106                 $$tid_ref = $sth->fetchrow_array; # may be undef
 107         }
 108         foreach (qw(over id2num)) {
 109                 $dbh->prepare_cached(<<"")->execute($num);
 110 DELETE FROM $_ WHERE num = ?
 111
 112         }
 113 }
 114
 115 # this includes ghosts
 116 sub each_by_mid {
 117         my ($self, $mid, $cols, $cb, @arg) = @_;
 118         my $dbh = $self->{dbh};
 119
 120 =over
 121         I originally wanted to stuff everything into a single query:
 122
 123         SELECT over.* FROM over
 124         LEFT JOIN id2num ON over.num = id2num.num
 125         LEFT JOIN msgid ON msgid.id = id2num.id
 126         WHERE msgid.mid = ? AND over.num >= ?
 127         ORDER BY over.num ASC
 128         LIMIT 1000
 129
 130         But it's faster broken out (and we're always in a
 131         transaction for subroutines in this file)
 132 =cut
 133
 134         my $sth = $dbh->prepare_cached(<<'', undef, 1);
 135 SELECT id FROM msgid WHERE mid = ? LIMIT 1
 136
 137         $sth->execute($mid);
 138         my $id = $sth->fetchrow_array;
 139         defined $id or return;
 140
 141         push(@$cols, 'num');
 142         $cols = join(',', map { $_ } @$cols);
 143         my $lim = 10;
 144         my $prev = get_counter($dbh, 'ghost');
 145         while (1) {
 146                 $sth = $dbh->prepare_cached(<<"", undef, 1);
 147 SELECT num FROM id2num WHERE id = ? AND num >= ?
 148 ORDER BY num ASC
 149 LIMIT $lim
 150
 151                 $sth->execute($id, $prev);
 152                 my $nums = $sth->fetchall_arrayref;
 153                 my $nr = scalar(@$nums) or return;
 154                 $prev = $nums->[-1]->[0];
 155
 156                 $sth = $dbh->prepare_cached(<<"", undef, 1);
 157 SELECT $cols FROM over WHERE over.num = ? LIMIT 1
 158
 159                 foreach (@$nums) {
 160                         $sth->execute($_->[0]);
 161                         my $smsg = $sth->fetchrow_hashref;
 162                         $smsg = PublicInbox::Over::load_from_row($smsg);
 163                         $cb->($self, $smsg, @arg) or return;
 164                 }
 165                 return if $nr != $lim;
 166         }
 167 }
 168
 169 sub _resolve_mid_to_tid {
 170         my ($self, $smsg, $tid) = @_;
 171         my $cur_tid = $smsg->{tid};
 172         if (defined $$tid) {
 173                 merge_threads($self, $$tid, $cur_tid);
 174         } elsif ($cur_tid > $self->{min_tid}) {
 175                 $$tid = $cur_tid;
 176         } else { # rethreading, queue up dead ghosts
 177                 $$tid = next_tid($self);
 178                 my $n = $smsg->{num};
 179                 if ($n > 0) {
 180                         $self->{dbh}->prepare_cached(<<'')->execute($$tid, $n);
 181 UPDATE over SET tid = ? WHERE num = ?
 182
 183                 } elsif ($n < 0) {
 184                         push(@{$self->{-ghosts_to_delete}}, $n);
 185                 }
 186         }
 187         1;
 188 }
 189
 190 # this will create a ghost as necessary
 191 sub resolve_mid_to_tid {
 192         my ($self, $mid) = @_;
 193         my $tid;
 194         each_by_mid($self, $mid, ['tid'], \&_resolve_mid_to_tid, \$tid);
 195         if (my $del = delete $self->{-ghosts_to_delete}) {
 196                 delete_by_num($self, $_) for @$del;
 197         }
 198         $tid // do { # create a new ghost
 199                 my $id = mid2id($self, $mid);
 200                 my $num = next_ghost_num($self);
 201                 $num < 0 or die "ghost num is non-negative: $num\n";
 202                 $tid = next_tid($self);
 203                 my $dbh = $self->{dbh};
 204                 $dbh->prepare_cached(<<'')->execute($num, $tid);
 205 INSERT INTO over (num, tid) VALUES (?,?)
 206
 207                 $dbh->prepare_cached(<<'')->execute($id, $num);
 208 INSERT INTO id2num (id, num) VALUES (?,?)
 209
 210                 $tid;
 211         };
 212 }
 213
 214 sub merge_threads {
 215         my ($self, $winner_tid, $loser_tid) = @_;
 216         return if $winner_tid == $loser_tid;
 217         my $dbh = $self->{dbh};
 218         $dbh->prepare_cached(<<'')->execute($winner_tid, $loser_tid);
 219 UPDATE over SET tid = ? WHERE tid = ?
 220
 221 }
 222
 223 sub link_refs {
 224         my ($self, $refs, $old_tid) = @_;
 225         my $tid;
 226
 227         if (@$refs) {
 228                 # first ref *should* be the thread root,
 229                 # but we can never trust clients to do the right thing
 230                 my $ref = $refs->[0];
 231                 $tid = resolve_mid_to_tid($self, $ref);
 232                 merge_threads($self, $tid, $old_tid) if defined $old_tid;
 233
 234                 # the rest of the refs should point to this tid:
 235                 foreach my $i (1..$#$refs) {
 236                         $ref = $refs->[$i];
 237                         my $ptid = resolve_mid_to_tid($self, $ref);
 238                         merge_threads($self, $tid, $ptid);
 239                 }
 240         } else {
 241                 $tid = $old_tid // next_tid($self);
 242         }
 243         $tid;
 244 }
 245
 246 sub parse_references ($$$) {
 247         my ($smsg, $hdr, $mids) = @_;
 248         my $refs = references($hdr);
 249         push(@$refs, @$mids) if scalar(@$mids) > 1;
 250         return $refs if scalar(@$refs) == 0;
 251
 252         # prevent circular references here:
 253         my %seen = ( $smsg->{mid} => 1 );
 254         my @keep;
 255         foreach my $ref (@$refs) {
 256                 if (length($ref) > PublicInbox::MID::MAX_MID_SIZE) {
 257                         warn "References: <$ref> too long, ignoring\n";
 258                         next;
 259                 }
 260                 push(@keep, $ref) unless $seen{$ref}++;
 261         }
 262         $smsg->{references} = '<'.join('> <', @keep).'>' if @keep;
 263         \@keep;
 264 }
 265
 266 # normalize subjects so they are suitable as pathnames for URLs
 267 # XXX: consider for removal
 268 sub subject_path ($) {
 269         my ($subj) = @_;
 270         $subj = subject_normalized($subj);
 271         $subj =~ s![^a-zA-Z0-9_\.~/\-]+!_!g;
 272         lc($subj);
 273 }
 274
 275 sub ddd_for ($) {
 276         my ($smsg) = @_;
 277         my $dd = $smsg->to_doc_data;
 278         utf8::encode($dd);
 279         compress($dd);
 280 }
 281
 282 sub add_overview {
 283         my ($self, $eml, $smsg) = @_;
 284         $smsg->{lines} = $eml->body_raw =~ tr!\n!\n!;
 285         my $mids = mids_for_index($eml);
 286         my $refs = parse_references($smsg, $eml, $mids);
 287         my $subj = $smsg->{subject};
 288         my $xpath;
 289         if ($subj ne '') {
 290                 $xpath = subject_path($subj);
 291                 $xpath = id_compress($xpath);
 292         }
 293         add_over($self, $smsg, $mids, $refs, $xpath, ddd_for($smsg));
 294 }
 295
 296 sub _add_over {
 297         my ($self, $smsg, $mid, $refs, $old_tid, $v) = @_;
 298         my $cur_tid = $smsg->{tid};
 299         my $n = $smsg->{num};
 300         die "num must not be zero for $mid" if !$n;
 301         my $cur_valid = $cur_tid > $self->{min_tid};
 302
 303         if ($n > 0) { # regular mail
 304                 if ($cur_valid) {
 305                         $$old_tid //= $cur_tid;
 306                         merge_threads($self, $$old_tid, $cur_tid);
 307                 } else {
 308                         $$old_tid //= next_tid($self);
 309                 }
 310         } elsif ($n < 0) { # ghost
 311                 $$old_tid //= $cur_valid ? $cur_tid : next_tid($self);
 312                 $$old_tid = link_refs($self, $refs, $$old_tid);
 313                 delete_by_num($self, $n);
 314                 $$v++;
 315         }
 316         1;
 317 }
 318
 319 sub add_over {
 320         my ($self, $smsg, $mids, $refs, $xpath, $ddd) = @_;
 321         my $old_tid;
 322         my $vivified = 0;
 323         my $num = $smsg->{num};
 324
 325         begin_lazy($self);
 326         delete_by_num($self, $num, \$old_tid);
 327         $old_tid = undef if ($old_tid // 0) <= $self->{min_tid};
 328         foreach my $mid (@$mids) {
 329                 my $v = 0;
 330                 each_by_mid($self, $mid, ['tid'], \&_add_over,
 331                                 $mid, $refs, \$old_tid, \$v);
 332                 $v > 1 and warn "BUG: vivified multiple ($v) ghosts for $mid\n";
 333                 $vivified += $v;
 334         }
 335         $smsg->{tid} = $vivified ? $old_tid : link_refs($self, $refs, $old_tid);
 336         $smsg->{sid} = sid($self, $xpath);
 337         my $dbh = $self->{dbh};
 338         my $sth = $dbh->prepare_cached(<<'');
 339 INSERT INTO over (num, tid, sid, ts, ds, ddd)
 340 VALUES (?,?,?,?,?,?)
 341
 342         my $nc = 1;
 343         $sth->bind_param($nc, $num);
 344         $sth->bind_param(++$nc, $smsg->{$_}) for (qw(tid sid ts ds));
 345         $sth->bind_param(++$nc, $ddd, SQL_BLOB);
 346         $sth->execute;
 347         $sth = $dbh->prepare_cached(<<'');
 348 INSERT INTO id2num (id, num) VALUES (?,?)
 349
 350         foreach my $mid (@$mids) {
 351                 my $id = mid2id($self, $mid);
 352                 $sth->execute($id, $num);
 353         }
 354 }
 355
 356 sub _remove_oid {
 357         my ($self, $smsg, $oid, $removed) = @_;
 358         if (!defined($oid) || $smsg->{blob} eq $oid) {
 359                 delete_by_num($self, $smsg->{num});
 360                 push @$removed, $smsg->{num};
 361         }
 362         1;
 363 }
 364
 365 # returns number of removed messages in scalar context,
 366 # array of removed article numbers in array context.
 367 # $oid may be undef to match only on $mid
 368 sub remove_oid {
 369         my ($self, $oid, $mid) = @_;
 370         my $removed = [];
 371         begin_lazy($self);
 372         each_by_mid($self, $mid, ['ddd'], \&_remove_oid, $oid, $removed);
 373         @$removed;
 374 }
 375
 376 sub _num_mid0_for_oid {
 377         my ($self, $smsg, $oid, $res) = @_;
 378         my $blob = $smsg->{blob};
 379         return 1 if (!defined($blob) || $blob ne $oid); # continue;
 380         @$res = ($smsg->{num}, $smsg->{mid});
 381         0; # done
 382 }
 383
 384 sub num_mid0_for_oid {
 385         my ($self, $oid, $mid) = @_;
 386         my $res = [];
 387         begin_lazy($self);
 388         each_by_mid($self, $mid, ['ddd'], \&_num_mid0_for_oid, $oid, $res);
 389         @$res, # ($num, $mid0);
 390 }
 391
 392 sub create_tables {
 393         my ($dbh) = @_;
 394
 395         $dbh->do(<<'');
 396 CREATE TABLE IF NOT EXISTS over (
 397         num INTEGER PRIMARY KEY NOT NULL, /* NNTP article number == IMAP UID */
 398         tid INTEGER NOT NULL, /* THREADID (IMAP REFERENCES threading, JMAP) */
 399         sid INTEGER, /* Subject ID (IMAP ORDEREDSUBJECT "threading") */
 400         ts INTEGER, /* IMAP INTERNALDATE (Received: header, git commit time) */
 401         ds INTEGER, /* RFC-2822 sent Date: header, git author time */
 402         ddd VARBINARY /* doc-data-deflated (->to_doc_data, ->load_from_data) */
 403 )
 404
 405         $dbh->do('CREATE INDEX IF NOT EXISTS idx_tid ON over (tid)');
 406         $dbh->do('CREATE INDEX IF NOT EXISTS idx_sid ON over (sid)');
 407         $dbh->do('CREATE INDEX IF NOT EXISTS idx_ts ON over (ts)');
 408         $dbh->do('CREATE INDEX IF NOT EXISTS idx_ds ON over (ds)');
 409
 410         $dbh->do(<<'');
 411 CREATE TABLE IF NOT EXISTS counter (
 412         key VARCHAR(8) PRIMARY KEY NOT NULL,
 413         val INTEGER DEFAULT 0,
 414         UNIQUE (key)
 415 )
 416
 417         $dbh->do("INSERT OR IGNORE INTO counter (key) VALUES ('thread')");
 418         $dbh->do("INSERT OR IGNORE INTO counter (key) VALUES ('ghost')");
 419
 420         $dbh->do(<<'');
 421 CREATE TABLE IF NOT EXISTS subject (
 422         sid INTEGER PRIMARY KEY AUTOINCREMENT,
 423         path VARCHAR(40) NOT NULL, /* SHA-1 of normalized subject */
 424         UNIQUE (path)
 425 )
 426
 427         $dbh->do(<<'');
 428 CREATE TABLE IF NOT EXISTS id2num (
 429         id INTEGER NOT NULL, /* <=> msgid.id */
 430         num INTEGER NOT NULL,
 431         UNIQUE (id, num)
 432 )
 433
 434         # performance critical:
 435         $dbh->do('CREATE INDEX IF NOT EXISTS idx_inum ON id2num (num)');
 436         $dbh->do('CREATE INDEX IF NOT EXISTS idx_id ON id2num (id)');
 437
 438         $dbh->do(<<'');
 439 CREATE TABLE IF NOT EXISTS msgid (
 440         id INTEGER PRIMARY KEY AUTOINCREMENT, /* <=> id2num.id */
 441         mid VARCHAR(244) NOT NULL,
 442         UNIQUE (mid)
 443 )
 444
 445 }
 446
 447 sub commit_lazy {
 448         my ($self) = @_;
 449         delete $self->{txn} or return;
 450         $self->{dbh}->commit;
 451 }
 452
 453 sub begin_lazy {
 454         my ($self) = @_;
 455         return if $self->{txn};
 456         my $dbh = $self->dbh or return;
 457         $dbh->begin_work;
 458         # $dbh->{Profile} = 2;
 459         $self->{txn} = 1;
 460 }
 461
 462 sub rollback_lazy {
 463         my ($self) = @_;
 464         delete $self->{txn} or return;
 465         $self->{dbh}->rollback;
 466 }
 467
 468 sub dbh_close {
 469         my ($self) = @_;
 470         die "in transaction" if $self->{txn};
 471         $self->SUPER::dbh_close;
 472 }
 473
 474 sub create {
 475         my ($self) = @_;
 476         my $fn = $self->{filename} // do {
 477                 Carp::confess('BUG: no {filename}') unless $self->{dbh};
 478                 return;
 479         };
 480         unless (-r $fn) {
 481                 require File::Path;
 482                 require File::Basename;
 483                 File::Path::mkpath(File::Basename::dirname($fn));
 484         }
 485         # create the DB:
 486         PublicInbox::Over::dbh($self);
 487         $self->dbh_close;
 488 }
 489
 490 sub rethread_prepare {
 491         my ($self, $opt) = @_;
 492         return unless $opt->{rethread};
 493         begin_lazy($self);
 494         my $min = $self->{min_tid} = get_counter($self->{dbh}, 'thread') // 0;
 495         my $pr = $opt->{-progress};
 496         $pr->("rethread min THREADID ".($min + 1)."\n") if $pr && $min;
 497 }
 498
 499 sub rethread_done {
 500         my ($self, $opt) = @_;
 501         return unless $opt->{rethread} && $self->{txn};
 502         defined(my $min = $self->{min_tid}) or croak('BUG: no min_tid');
 503         my $dbh = $self->{dbh} or croak('BUG: no dbh');
 504         my $rows = $dbh->selectall_arrayref(<<'', { Slice => {} }, $min);
 505 SELECT num,tid FROM over WHERE num < 0 AND tid < ?
 506
 507         my $show_id = $dbh->prepare('SELECT id FROM id2num WHERE num = ?');
 508         my $show_mid = $dbh->prepare('SELECT mid FROM msgid WHERE id = ?');
 509         my $pr = $opt->{-progress};
 510         my $total = 0;
 511         for my $r (@$rows) {
 512                 my $exp = 0;
 513                 $show_id->execute($r->{num});
 514                 while (defined(my $id = $show_id->fetchrow_array)) {
 515                         ++$exp;
 516                         $show_mid->execute($id);
 517                         my $mid = $show_mid->fetchrow_array;
 518                         if (!defined($mid)) {
 519                                 warn <<EOF;
 520 E: ghost NUM=$r->{num} ID=$id THREADID=$r->{tid} has no Message-ID
 521 EOF
 522                                 next;
 523                         }
 524                         $pr->(<<EOM) if $pr;
 525 I: ghost $r->{num} <$mid> THREADID=$r->{tid} culled
 526 EOM
 527                 }
 528                 delete_by_num($self, $r->{num});
 529         }
 530         $pr->("I: rethread culled $total ghosts\n") if $pr && $total;
 531 }
 532
 533 # used for cross-inbox search
 534 sub eidx_prep ($) {
 535         my ($self) = @_;
 536         $self->{-eidx_prep} //= do {
 537                 my $dbh = $self->dbh;
 538                 $dbh->do(<<"");
 539 INSERT OR IGNORE INTO counter (key) VALUES ('eidx_docid')
 540
 541                 $dbh->do(<<'');
 542 CREATE TABLE IF NOT EXISTS inboxes (
 543         ibx_id INTEGER PRIMARY KEY AUTOINCREMENT,
 544         eidx_key VARCHAR(255) NOT NULL, /* {newsgroup} // {inboxdir} */
 545         UNIQUE (eidx_key)
 546 )
 547
 548                 $dbh->do(<<'');
 549 CREATE TABLE IF NOT EXISTS xref3 (
 550         docid INTEGER NOT NULL, /* <=> over.num */
 551         ibx_id INTEGER NOT NULL, /* <=> inboxes.ibx_id */
 552         xnum INTEGER NOT NULL, /* NNTP article number in ibx */
 553         oidbin VARBINARY NOT NULL, /* 20-byte SHA-1 or 32-byte SHA-256 */
 554         UNIQUE (docid, ibx_id, xnum, oidbin)
 555 )
 556
 557         $dbh->do('CREATE INDEX IF NOT EXISTS idx_docid ON xref3 (docid)');
 558
 559         # performance critical, this is not UNIQUE since we may need to
 560         # tolerate some old bugs from indexing mirrors
 561         $dbh->do('CREATE INDEX IF NOT EXISTS idx_nntp ON '.
 562                 'xref3 (oidbin,xnum,ibx_id)');
 563
 564                 $dbh->do(<<'');
 565 CREATE TABLE IF NOT EXISTS eidx_meta (
 566         key VARCHAR(255) PRIMARY KEY,
 567         val VARCHAR(255) NOT NULL
 568 )
 569
 570                 # A queue of current docids which need reindexing.
 571                 # eidxq persists across aborted -extindex invocations
 572                 # Currently used for "-extindex --reindex" for Xapian
 573                 # data, but may be used in more places down the line.
 574                 $dbh->do(<<'');
 575 CREATE TABLE IF NOT EXISTS eidxq (
 576         docid INTEGER PRIMARY KEY NOT NULL
 577 )
 578
 579                 $dbh;
 580         };
 581 }
 582
 583 sub eidx_meta { # requires transaction
 584         my ($self, $key, $val) = @_;
 585
 586         my $sql = 'SELECT val FROM eidx_meta WHERE key = ? LIMIT 1';
 587         my $dbh = $self->{dbh};
 588         defined($val) or return $dbh->selectrow_array($sql, undef, $key);
 589
 590         my $prev = $dbh->selectrow_array($sql, undef, $key);
 591         if (defined $prev) {
 592                 $sql = 'UPDATE eidx_meta SET val = ? WHERE key = ?';
 593                 $dbh->do($sql, undef, $val, $key);
 594         } else {
 595                 $sql = 'INSERT INTO eidx_meta (key,val) VALUES (?,?)';
 596                 $dbh->do($sql, undef, $key, $val);
 597         }
 598         $prev;
 599 }
 600
 601 sub eidx_max {
 602         my ($self) = @_;
 603         get_counter($self->{dbh}, 'eidx_docid');
 604 }
 605
 606 sub add_xref3 {
 607         my ($self, $docid, $xnum, $oidhex, $eidx_key) = @_;
 608         begin_lazy($self);
 609         my $ibx_id = ibx_id($self, $eidx_key);
 610         my $oidbin = pack('H*', $oidhex);
 611         my $sth = $self->{dbh}->prepare_cached(<<'');
 612 INSERT OR IGNORE INTO xref3 (docid, ibx_id, xnum, oidbin) VALUES (?, ?, ?, ?)
 613
 614         $sth->bind_param(1, $docid);
 615         $sth->bind_param(2, $ibx_id);
 616         $sth->bind_param(3, $xnum);
 617         $sth->bind_param(4, $oidbin, SQL_BLOB);
 618         $sth->execute;
 619 }
 620
 621 # returns remaining reference count to $docid
 622 sub remove_xref3 {
 623         my ($self, $docid, $oidhex, $eidx_key, $rm_eidx_info) = @_;
 624         begin_lazy($self);
 625         my $oidbin = pack('H*', $oidhex);
 626         my ($sth, $ibx_id);
 627         if (defined $eidx_key) {
 628                 $ibx_id = ibx_id($self, $eidx_key);
 629                 $sth = $self->{dbh}->prepare_cached(<<'');
 630 DELETE FROM xref3 WHERE docid = ? AND ibx_id = ? AND oidbin = ?
 631
 632                 $sth->bind_param(1, $docid);
 633                 $sth->bind_param(2, $ibx_id);
 634                 $sth->bind_param(3, $oidbin, SQL_BLOB);
 635         } else {
 636                 $sth = $self->{dbh}->prepare_cached(<<'');
 637 DELETE FROM xref3 WHERE docid = ? AND oidbin = ?
 638
 639                 $sth->bind_param(1, $docid);
 640                 $sth->bind_param(2, $oidbin, SQL_BLOB);
 641         }
 642         $sth->execute;
 643         $sth = $self->{dbh}->prepare_cached(<<'', undef, 1);
 644 SELECT COUNT(*) FROM xref3 WHERE docid = ?
 645
 646         $sth->execute($docid);
 647         my $nr = $sth->fetchrow_array;
 648         if ($nr == 0) {
 649                 delete_by_num($self, $docid);
 650         } elsif (defined($ibx_id) && $rm_eidx_info) {
 651                 # if deduplication rules in ContentHash change, it's
 652                 # possible a docid can have multiple rows with the
 653                 # same ibx_id.  This governs whether or not we call
 654                 # ->shard_remove_eidx_info in ExtSearchIdx.
 655                 $sth = $self->{dbh}->prepare_cached(<<'', undef, 1);
 656 SELECT COUNT(*) FROM xref3 WHERE docid = ? AND ibx_id = ?
 657
 658                 $sth->execute($docid, $ibx_id);
 659                 my $count = $sth->fetchrow_array;
 660                 $$rm_eidx_info = ($count == 0);
 661         }
 662         $nr;
 663 }
 664
 665 # for when an xref3 goes missing, this does NOT update {ts}
 666 sub update_blob {
 667         my ($self, $smsg, $oidhex) = @_;
 668         my $sth = $self->{dbh}->prepare(<<'');
 669 UPDATE over SET ddd = ? WHERE num = ?
 670
 671         $smsg->{blob} = $oidhex;
 672         $sth->bind_param(1, ddd_for($smsg), SQL_BLOB);
 673         $sth->bind_param(2, $smsg->{num});
 674         $sth->execute;
 675 }
 676
 677 sub eidxq_add {
 678         my ($self, $docid) = @_;
 679         $self->dbh->prepare_cached(<<'')->execute($docid);
 680 INSERT OR IGNORE INTO eidxq (docid) VALUES (?)
 681
 682 }
 683
 684 sub eidxq_del {
 685         my ($self, $docid) = @_;
 686         $self->dbh->prepare_cached(<<'')->execute($docid);
 687 DELETE FROM eidxq WHERE docid = ?
 688
 689 }
 690
 691 sub blob_exists {
 692         my ($self, $oidhex) = @_;
 693         my $sth = $self->dbh->prepare_cached(<<'', undef, 1);
 694 SELECT COUNT(*) FROM xref3 WHERE oidbin = ?
 695
 696         $sth->bind_param(1, pack('H*', $oidhex), SQL_BLOB);
 697         $sth->execute;
 698         $sth->fetchrow_array;
 699 }
 700
 701 1;