lib/PublicInbox/Qspawn.pm

   1 # Copyright (C) 2016-2019 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Like most Perl modules in public-inbox, this is internal and
   5 # NOT subject to any stability guarantees!  It is only documented
   6 # for other hackers.
   7 #
   8 # This is used to limit the number of processes spawned by the
   9 # PSGI server, so it acts like a semaphore and queues up extra
  10 # commands to be run if currently at the limit.  Multiple "limiters"
  11 # may be configured which give inboxes different channels to
  12 # operate in.  This can be useful to ensure smaller inboxes can
  13 # be cloned while cloning of large inboxes is maxed out.
  14 #
  15 # This does not depend on PublicInbox::DS or any other external
  16 # scheduling mechanism, you just need to call start() and finish()
  17 # appropriately. However, public-inbox-httpd (which uses PublicInbox::DS)
  18 # will be able to schedule this based on readability of stdout from
  19 # the spawned process.  See GitHTTPBackend.pm and SolverGit.pm for
  20 # usage examples.  It does not depend on any form of threading.
  21 #
  22 # This is useful for scheduling CGI execution of both long-lived
  23 # git-http-backend(1) process (for "git clone") as well as short-lived
  24 # processes such as git-apply(1).
  25
  26 package PublicInbox::Qspawn;
  27 use strict;
  28 use warnings;
  29 use PublicInbox::Spawn qw(popen_rd);
  30 use POSIX qw(WNOHANG);
  31 require Plack::Util;
  32
  33 # n.b.: we get EAGAIN with public-inbox-httpd, and EINTR on other PSGI servers
  34 use Errno qw(EAGAIN EINTR);
  35
  36 my $def_limiter;
  37
  38 # declares a command to spawn (but does not spawn it).
  39 # $cmd is the command to spawn
  40 # $env is the environ for the child process
  41 # $opt can include redirects and perhaps other process spawning options
  42 sub new ($$$;) {
  43         my ($class, $cmd, $env, $opt) = @_;
  44         bless { args => [ $cmd, $env, $opt ] }, $class;
  45 }
  46
  47 sub _do_spawn {
  48         my ($self, $cb) = @_;
  49         my $err;
  50         my ($cmd, $env, $opts) = @{$self->{args}};
  51         my %opts = %{$opts || {}};
  52         my $limiter = $self->{limiter};
  53         foreach my $k (PublicInbox::Spawn::RLIMITS()) {
  54                 if (defined(my $rlimit = $limiter->{$k})) {
  55                         $opts{$k} = $rlimit;
  56                 }
  57         }
  58
  59         ($self->{rpipe}, $self->{pid}) = popen_rd($cmd, $env, \%opts);
  60         if (defined $self->{pid}) {
  61                 $limiter->{running}++;
  62         } else {
  63                 $self->{err} = $!;
  64         }
  65         $cb->($self->{rpipe});
  66 }
  67
  68 sub child_err ($) {
  69         my ($child_error) = @_; # typically $?
  70         my $exitstatus = ($child_error >> 8) or return;
  71         my $sig = $child_error & 127;
  72         my $msg = "exit status=$exitstatus";
  73         $msg .= " signal=$sig" if $sig;
  74         $msg;
  75 }
  76
  77 # callback for dwaitpid
  78 sub waitpid_err ($$) {
  79         my ($self, $pid) = @_;
  80         my $xpid = delete $self->{pid};
  81         my $err;
  82         if ($pid > 0) { # success!
  83                 $err = child_err($?);
  84         } elsif ($pid < 0) { # ??? does this happen in our case?
  85                 $err = "W: waitpid($xpid, 0) => $pid: $!";
  86         } # else should not be called with pid == 0
  87
  88         # done, spawn whatever's in the queue
  89         my $limiter = $self->{limiter};
  90         my $running = --$limiter->{running};
  91
  92         # limiter->{max} may change dynamically
  93         if (($running || $limiter->{running}) < $limiter->{max}) {
  94                 if (my $next = shift @{$limiter->{run_queue}}) {
  95                         _do_spawn(@$next);
  96                 }
  97         }
  98
  99         return unless $err;
 100         $self->{err} = $err;
 101         my $env = $self->{env} or return;
 102         if (!$env->{'qspawn.quiet'}) {
 103                 $err = join(' ', @{$self->{args}->[0]}).": $err\n";
 104                 $env->{'psgi.errors'}->print($err);
 105         }
 106 }
 107
 108 sub do_waitpid ($;$) {
 109         my ($self, $env) = @_;
 110         my $pid = $self->{pid};
 111         eval { # PublicInbox::DS may not be loaded
 112                 PublicInbox::DS::dwaitpid($pid, \&waitpid_err, $self);
 113                 $self->{env} = $env;
 114         };
 115         # done if we're running in PublicInbox::DS::EventLoop
 116         if ($@) {
 117                 # non public-inbox-{httpd,nntpd} callers may block:
 118                 my $ret = waitpid($pid, 0);
 119                 waitpid_err($self, $ret);
 120         }
 121 }
 122
 123 sub finish ($;$) {
 124         my ($self, $env) = @_;
 125         if (delete $self->{rpipe}) {
 126                 do_waitpid($self, $env);
 127         }
 128
 129         # limiter->{max} may change dynamically
 130         my $limiter = $self->{limiter};
 131         if ($limiter->{running} < $limiter->{max}) {
 132                 if (my $next = shift @{$limiter->{run_queue}}) {
 133                         _do_spawn(@$next);
 134                 }
 135         }
 136         $self->{err}; # may be meaningless if non-blocking
 137 }
 138
 139 sub start {
 140         my ($self, $limiter, $cb) = @_;
 141         $self->{limiter} = $limiter;
 142
 143         if ($limiter->{running} < $limiter->{max}) {
 144                 _do_spawn($self, $cb);
 145         } else {
 146                 push @{$limiter->{run_queue}}, [ $self, $cb ];
 147         }
 148 }
 149
 150 # Similar to `backtick` or "qx" ("perldoc -f qx"), it calls $qx_cb with
 151 # the stdout of the given command when done; but respects the given limiter
 152 # $env is the PSGI env.  As with ``/qx; only use this when output is small
 153 # and safe to slurp.
 154 sub psgi_qx {
 155         my ($self, $env, $limiter, $qx_cb) = @_;
 156         my $scalar = '';
 157         open(my $qx, '+>', \$scalar) or die; # PerlIO::scalar
 158         my $end = sub {
 159                 finish($self, $env);
 160                 eval { $qx_cb->(\$scalar) };
 161                 $qx = $scalar = undef;
 162         };
 163         my $rpipe; # comes from popen_rd
 164         my $async = $env->{'pi-httpd.async'};
 165         my $cb = sub {
 166                 my $r = sysread($rpipe, my $buf, 65536);
 167                 if ($async) {
 168                         $async->async_pass($env->{'psgix.io'}, $qx, \$buf);
 169                 } elsif (defined $r) {
 170                         $r ? $qx->write($buf) : $end->();
 171                 } else {
 172                         return if $! == EAGAIN || $! == EINTR; # loop again
 173                         $end->();
 174                 }
 175         };
 176         $limiter ||= $def_limiter ||= PublicInbox::Qspawn::Limiter->new(32);
 177         $self->start($limiter, sub { # may run later, much later...
 178                 ($rpipe) = @_; # popen_rd result
 179                 if ($async) {
 180                 # PublicInbox::HTTPD::Async->new($rpipe, $cb, $end)
 181                         $async = $async->($rpipe, $cb, $end);
 182                 } else { # generic PSGI
 183                         $cb->() while $qx;
 184                 }
 185         });
 186 }
 187
 188 # create a filter for "push"-based streaming PSGI writes used by HTTPD::Async
 189 sub filter_fh ($$) {
 190         my ($fh, $filter) = @_;
 191         Plack::Util::inline_object(
 192                 close => sub {
 193                         $fh->write($filter->(undef));
 194                         $fh->close;
 195                 },
 196                 write => sub {
 197                         $fh->write($filter->($_[0]));
 198                 });
 199 }
 200
 201 # Used for streaming the stdout of one process as a PSGI response.
 202 #
 203 # $env is the PSGI env.
 204 # optional keys in $env:
 205 #   $env->{'qspawn.wcb'} - the write callback from the PSGI server
 206 #                          optional, use this if you've already
 207 #                          captured it elsewhere.  If not given,
 208 #                          psgi_return will return an anonymous
 209 #                          sub for the PSGI server to call
 210 #
 211 #   $env->{'qspawn.filter'} - filter callback, receives a string as input,
 212 #                             undef on EOF
 213 #
 214 # $limiter - the Limiter object to use (uses the def_limiter if not given)
 215 #
 216 # $parse_hdr - Initial read function; often for parsing CGI header output.
 217 #              It will be given the return value of sysread from the pipe
 218 #              and a string ref of the current buffer.  Returns an arrayref
 219 #              for PSGI responses.  2-element arrays in PSGI mean the
 220 #              body will be streamed, later, via writes (push-based) to
 221 #              psgix.io.  3-element arrays means the body is available
 222 #              immediately (or streamed via ->getline (pull-based)).
 223 sub psgi_return {
 224         my ($self, $env, $limiter, $parse_hdr) = @_;
 225         my ($fh, $rpipe);
 226         my $end = sub {
 227                 finish($self, $env);
 228                 $fh->close if $fh; # async-only
 229         };
 230
 231         my $buf = '';
 232         my $rd_hdr = sub {
 233                 # typically used for reading CGI headers
 234                 # we must loop until EAGAIN for EPOLLET in HTTPD/Async.pm
 235                 # We also need to check EINTR for generic PSGI servers.
 236                 my $ret;
 237                 my $n = 0;
 238                 do {
 239                         my $r = sysread($rpipe, $buf, 4096, length($buf));
 240                         return if !defined($r) && $! == EAGAIN || $! == EINTR;
 241
 242                         # $r may be undef, here:
 243                         $n += $r if $r;
 244                         $ret = $parse_hdr->($r ? $n : $r, \$buf);
 245                 } until (defined $ret);
 246                 $ret;
 247         };
 248
 249         my $wcb = delete $env->{'qspawn.wcb'};
 250         my $async = $env->{'pi-httpd.async'};
 251
 252         my $cb = sub {
 253                 my $r = $rd_hdr->() or return;
 254                 $rd_hdr = undef; # done reading headers
 255                 my $filter = delete $env->{'qspawn.filter'};
 256                 if (scalar(@$r) == 3) { # error
 257                         if ($async) {
 258                                 $async->close; # calls rpipe->close and $end
 259                         } else {
 260                                 $rpipe->close;
 261                                 $end->();
 262                         }
 263                         $wcb->($r);
 264                 } elsif ($async) {
 265                         # done reading headers, handoff to read body
 266                         $fh = $wcb->($r); # scalar @$r == 2
 267                         $fh = filter_fh($fh, $filter) if $filter;
 268                         $async->async_pass($env->{'psgix.io'}, $fh, \$buf);
 269                 } else { # for synchronous PSGI servers
 270                         require PublicInbox::GetlineBody;
 271                         $r->[2] = PublicInbox::GetlineBody->new($rpipe, $end,
 272                                                                 $buf, $filter);
 273                         $wcb->($r);
 274                 }
 275         };
 276         $limiter ||= $def_limiter ||= PublicInbox::Qspawn::Limiter->new(32);
 277         my $start_cb = sub { # may run later, much later...
 278                 ($rpipe) = @_;
 279                 if ($async) {
 280                         # PublicInbox::HTTPD::Async->new($rpipe, $cb, $end)
 281                         $async = $async->($rpipe, $cb, $end);
 282                 } else { # generic PSGI
 283                         $cb->() while $rd_hdr;
 284                 }
 285         };
 286
 287         # the caller already captured the PSGI write callback from
 288         # the PSGI server, so we can call ->start, here:
 289         return $self->start($limiter, $start_cb) if $wcb;
 290
 291         # the caller will return this sub to the PSGI server, so
 292         # it can set the response callback (that is, for PublicInbox::HTTP,
 293         # the chunked_wcb or identity_wcb callback), but other HTTP servers
 294         # are supported:
 295         sub {
 296                 ($wcb) = @_;
 297                 $self->start($limiter, $start_cb);
 298         };
 299 }
 300
 301 package PublicInbox::Qspawn::Limiter;
 302 use strict;
 303 use warnings;
 304
 305 sub new {
 306         my ($class, $max) = @_;
 307         bless {
 308                 # 32 is same as the git-daemon connection limit
 309                 max => $max || 32,
 310                 running => 0,
 311                 run_queue => [],
 312                 # RLIMIT_CPU => undef,
 313                 # RLIMIT_DATA => undef,
 314                 # RLIMIT_CORE => undef,
 315         }, $class;
 316 }
 317
 318 sub setup_rlimit {
 319         my ($self, $name, $config) = @_;
 320         foreach my $rlim (PublicInbox::Spawn::RLIMITS()) {
 321                 my $k = lc($rlim);
 322                 $k =~ tr/_//d;
 323                 $k = "publicinboxlimiter.$name.$k";
 324                 defined(my $v = $config->{$k}) or next;
 325                 my @rlimit = split(/\s*,\s*/, $v);
 326                 if (scalar(@rlimit) == 1) {
 327                         push @rlimit, $rlimit[0];
 328                 } elsif (scalar(@rlimit) != 2) {
 329                         warn "could not parse $k: $v\n";
 330                 }
 331                 eval { require BSD::Resource };
 332                 if ($@) {
 333                         warn "BSD::Resource missing for $rlim";
 334                         next;
 335                 }
 336                 foreach my $i (0..$#rlimit) {
 337                         next if $rlimit[$i] ne 'INFINITY';
 338                         $rlimit[$i] = BSD::Resource::RLIM_INFINITY();
 339                 }
 340                 $self->{$rlim} = \@rlimit;
 341         }
 342 }
 343
 344 1;