lib/PublicInbox/Qspawn.pm

   1 # Copyright (C) 2016-2019 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Like most Perl modules in public-inbox, this is internal and
   5 # NOT subject to any stability guarantees!  It is only documented
   6 # for other hackers.
   7 #
   8 # This is used to limit the number of processes spawned by the
   9 # PSGI server, so it acts like a semaphore and queues up extra
  10 # commands to be run if currently at the limit.  Multiple "limiters"
  11 # may be configured which give inboxes different channels to
  12 # operate in.  This can be useful to ensure smaller inboxes can
  13 # be cloned while cloning of large inboxes is maxed out.
  14 #
  15 # This does not depend on PublicInbox::DS or any other external
  16 # scheduling mechanism, you just need to call start() and finish()
  17 # appropriately. However, public-inbox-httpd (which uses PublicInbox::DS)
  18 # will be able to schedule this based on readability of stdout from
  19 # the spawned process.  See GitHTTPBackend.pm and SolverGit.pm for
  20 # usage examples.  It does not depend on any form of threading.
  21 #
  22 # This is useful for scheduling CGI execution of both long-lived
  23 # git-http-backend(1) process (for "git clone") as well as short-lived
  24 # processes such as git-apply(1).
  25
  26 package PublicInbox::Qspawn;
  27 use strict;
  28 use warnings;
  29 use PublicInbox::Spawn qw(popen_rd);
  30 require Plack::Util;
  31
  32 # n.b.: we get EAGAIN with public-inbox-httpd, and EINTR on other PSGI servers
  33 use Errno qw(EAGAIN EINTR);
  34
  35 my $def_limiter;
  36
  37 # declares a command to spawn (but does not spawn it).
  38 # $cmd is the command to spawn
  39 # $env is the environ for the child process
  40 # $opt can include redirects and perhaps other process spawning options
  41 sub new ($$$;) {
  42         my ($class, $cmd, $env, $opt) = @_;
  43         bless { args => [ $cmd, $env, $opt ] }, $class;
  44 }
  45
  46 sub _do_spawn {
  47         my ($self, $start_cb, $limiter) = @_;
  48         my $err;
  49         my ($cmd, $env, $opts) = @{$self->{args}};
  50         my %opts = %{$opts || {}};
  51         $self->{limiter} = $limiter;
  52         foreach my $k (PublicInbox::Spawn::RLIMITS()) {
  53                 if (defined(my $rlimit = $limiter->{$k})) {
  54                         $opts{$k} = $rlimit;
  55                 }
  56         }
  57
  58         ($self->{rpipe}, $self->{pid}) = popen_rd($cmd, $env, \%opts);
  59
  60         # drop any IO handles opt was holding open via $opt->{hold}
  61         # No need to hold onto the descriptor once the child process has it.
  62         $self->{args} = $cmd; # keep this around for logging
  63
  64         if (defined $self->{pid}) {
  65                 $limiter->{running}++;
  66         } else {
  67                 $self->{err} = $!;
  68         }
  69         $start_cb->($self->{rpipe});
  70 }
  71
  72 sub child_err ($) {
  73         my ($child_error) = @_; # typically $?
  74         my $exitstatus = ($child_error >> 8) or return;
  75         my $sig = $child_error & 127;
  76         my $msg = "exit status=$exitstatus";
  77         $msg .= " signal=$sig" if $sig;
  78         $msg;
  79 }
  80
  81 sub log_err ($$) {
  82         my ($env, $msg) = @_;
  83         $env->{'psgi.errors'}->print($msg, "\n");
  84 }
  85
  86 # callback for dwaitpid
  87 sub waitpid_err ($$) {
  88         my ($self, $pid) = @_;
  89         my $xpid = delete $self->{pid};
  90         my $err;
  91         if ($pid > 0) { # success!
  92                 $err = child_err($?);
  93         } elsif ($pid < 0) { # ??? does this happen in our case?
  94                 $err = "W: waitpid($xpid, 0) => $pid: $!";
  95         } # else should not be called with pid == 0
  96
  97         my $env = delete $self->{env};
  98
  99         # done, spawn whatever's in the queue
 100         my $limiter = $self->{limiter};
 101         my $running = --$limiter->{running};
 102
 103         if ($running < $limiter->{max}) {
 104                 if (my $next = shift(@{$limiter->{run_queue}})) {
 105                         _do_spawn(@$next, $limiter);
 106                 }
 107         }
 108
 109         if ($err) {
 110                 $self->{err} = $err;
 111                 if ($env && !$env->{'qspawn.quiet'}) {
 112                         log_err($env, join(' ', @{$self->{args}}) . ": $err");
 113                 }
 114         }
 115         if (my $fin_cb = delete $self->{fin_cb}) {
 116                 eval { $fin_cb->() }
 117         }
 118 }
 119
 120 sub do_waitpid ($;$$) {
 121         my ($self, $env, $fin_cb) = @_;
 122         my $pid = $self->{pid};
 123         $self->{env} = $env;
 124         $self->{fin_cb} = $fin_cb;
 125         # PublicInbox::DS may not be loaded
 126         eval { PublicInbox::DS::dwaitpid($pid, \&waitpid_err, $self) };
 127         # done if we're running in PublicInbox::DS::EventLoop
 128         if ($@) {
 129                 # non public-inbox-{httpd,nntpd} callers may block:
 130                 my $ret = waitpid($pid, 0);
 131                 waitpid_err($self, $ret);
 132         }
 133 }
 134
 135 sub finish ($;$$) {
 136         my ($self, $env, $fin_cb) = @_;
 137         if (delete $self->{rpipe}) {
 138                 do_waitpid($self, $env, $fin_cb);
 139         } elsif ($fin_cb) {
 140                 eval { $fin_cb->() };
 141         }
 142 }
 143
 144 sub start {
 145         my ($self, $limiter, $start_cb) = @_;
 146         if ($limiter->{running} < $limiter->{max}) {
 147                 _do_spawn($self, $start_cb, $limiter);
 148         } else {
 149                 push @{$limiter->{run_queue}}, [ $self, $start_cb ];
 150         }
 151 }
 152
 153 # Similar to `backtick` or "qx" ("perldoc -f qx"), it calls $qx_cb with
 154 # the stdout of the given command when done; but respects the given limiter
 155 # $env is the PSGI env.  As with ``/qx; only use this when output is small
 156 # and safe to slurp.
 157 sub psgi_qx {
 158         my ($self, $env, $limiter, $qx_cb) = @_;
 159         my $scalar = '';
 160         open(my $qx, '+>', \$scalar) or die; # PerlIO::scalar
 161         my $end = sub {
 162                 my $err = $_[0]; # $!
 163                 log_err($env, "psgi_qx: $err") if defined($err);
 164                 finish($self, $env, sub { $qx_cb->(\$scalar) });
 165                 $qx = undef;
 166         };
 167         my $rpipe; # comes from popen_rd
 168         my $async = $env->{'pi-httpd.async'};
 169         my $cb = sub {
 170                 my ($r, $buf);
 171 reread:
 172                 $r = sysread($rpipe, $buf, 65536);
 173                 if ($async) {
 174                         $async->async_pass($env->{'psgix.io'}, $qx, \$buf);
 175                 } elsif (defined $r) {
 176                         $r ? $qx->write($buf) : $end->();
 177                 } else {
 178                         return if $! == EAGAIN; # try again when notified
 179                         goto reread if $! == EINTR;
 180                         $end->($!);
 181                 }
 182         };
 183         $limiter ||= $def_limiter ||= PublicInbox::Qspawn::Limiter->new(32);
 184         $self->start($limiter, sub { # start_cb, may run later, much later...
 185                 ($rpipe) = @_; # popen_rd result
 186                 if ($async) {
 187                 # PublicInbox::HTTPD::Async->new($rpipe, $cb, $end)
 188                         $async = $async->($rpipe, $cb, $end);
 189                         # $cb will call ->async_pass or ->close
 190                 } else { # generic PSGI
 191                         $cb->() while $qx;
 192                 }
 193         });
 194 }
 195
 196 # create a filter for "push"-based streaming PSGI writes used by HTTPD::Async
 197 sub filter_fh ($$) {
 198         my ($fh, $filter) = @_;
 199         Plack::Util::inline_object(
 200                 close => sub {
 201                         $fh->write($filter->(undef));
 202                         $fh->close;
 203                 },
 204                 write => sub {
 205                         $fh->write($filter->($_[0]));
 206                 });
 207 }
 208
 209 # Used for streaming the stdout of one process as a PSGI response.
 210 #
 211 # $env is the PSGI env.
 212 # optional keys in $env:
 213 #   $env->{'qspawn.wcb'} - the write callback from the PSGI server
 214 #                          optional, use this if you've already
 215 #                          captured it elsewhere.  If not given,
 216 #                          psgi_return will return an anonymous
 217 #                          sub for the PSGI server to call
 218 #
 219 #   $env->{'qspawn.filter'} - filter callback, receives a string as input,
 220 #                             undef on EOF
 221 #
 222 # $limiter - the Limiter object to use (uses the def_limiter if not given)
 223 #
 224 # $parse_hdr - Initial read function; often for parsing CGI header output.
 225 #              It will be given the return value of sysread from the pipe
 226 #              and a string ref of the current buffer.  Returns an arrayref
 227 #              for PSGI responses.  2-element arrays in PSGI mean the
 228 #              body will be streamed, later, via writes (push-based) to
 229 #              psgix.io.  3-element arrays means the body is available
 230 #              immediately (or streamed via ->getline (pull-based)).
 231 sub psgi_return {
 232         my ($self, $env, $limiter, $parse_hdr) = @_;
 233         my ($fh, $rpipe);
 234         my $end = sub {
 235                 my $err = $_[0]; # $!
 236                 log_err($env, "psgi_return: $err") if defined($err);
 237                 finish($self, $env);
 238                 $fh->close if $fh; # async-only
 239         };
 240
 241         my $buf = '';
 242         my $rd_hdr = sub {
 243                 # typically used for reading CGI headers
 244                 # we must loop until EAGAIN for EPOLLET in HTTPD/Async.pm
 245                 # We also need to check EINTR for generic PSGI servers.
 246                 my $ret;
 247                 my $total_rd = 0;
 248                 do {
 249                         my $r = sysread($rpipe, $buf, 4096, length($buf));
 250                         if (defined($r)) {
 251                                 $total_rd += $r;
 252                                 $ret = $parse_hdr->($r ? $total_rd : 0, \$buf);
 253                         } else {
 254                                 # caller should notify us when it's ready:
 255                                 return if $! == EAGAIN;
 256                                 next if $! == EINTR; # immediate retry
 257                                 log_err($env, "error reading header: $!");
 258                                 $ret = [ 500, [], [ "Internal error\n" ] ];
 259                         }
 260                 } until (defined $ret);
 261                 $ret;
 262         };
 263
 264         my $wcb = delete $env->{'qspawn.wcb'}; # or PSGI server supplies it
 265         my $async = $env->{'pi-httpd.async'};
 266
 267         my $cb = sub {
 268                 my $r = $rd_hdr->() or return;
 269                 $rd_hdr = undef; # done reading headers
 270                 my $filter = delete $env->{'qspawn.filter'};
 271                 if (scalar(@$r) == 3) { # error
 272                         if ($async) {
 273                                 $async->close; # calls rpipe->close and $end
 274                         } else {
 275                                 $rpipe->close;
 276                                 $end->();
 277                         }
 278                         $wcb->($r);
 279                 } elsif ($async) {
 280                         # done reading headers, handoff to read body
 281                         $fh = $wcb->($r); # scalar @$r == 2
 282                         $fh = filter_fh($fh, $filter) if $filter;
 283                         $async->async_pass($env->{'psgix.io'}, $fh, \$buf);
 284                 } else { # for synchronous PSGI servers
 285                         require PublicInbox::GetlineBody;
 286                         $r->[2] = PublicInbox::GetlineBody->new($rpipe, $end,
 287                                                                 $buf, $filter);
 288                         $wcb->($r);
 289                 }
 290
 291                 # Workaround a leak under Perl 5.16.3 when combined with
 292                 # Plack::Middleware::Deflater:
 293                 $wcb = undef;
 294         };
 295         $limiter ||= $def_limiter ||= PublicInbox::Qspawn::Limiter->new(32);
 296         my $start_cb = sub { # may run later, much later...
 297                 ($rpipe) = @_;
 298                 if ($async) {
 299                         # PublicInbox::HTTPD::Async->new($rpipe, $cb, $end)
 300                         $async = $async->($rpipe, $cb, $end);
 301                         # $cb will call ->async_pass or ->close
 302                 } else { # generic PSGI
 303                         $cb->() while $rd_hdr;
 304                 }
 305         };
 306
 307         # the caller already captured the PSGI write callback from
 308         # the PSGI server, so we can call ->start, here:
 309         return $self->start($limiter, $start_cb) if $wcb;
 310
 311         # the caller will return this sub to the PSGI server, so
 312         # it can set the response callback (that is, for PublicInbox::HTTP,
 313         # the chunked_wcb or identity_wcb callback), but other HTTP servers
 314         # are supported:
 315         sub {
 316                 ($wcb) = @_;
 317                 $self->start($limiter, $start_cb);
 318         };
 319 }
 320
 321 package PublicInbox::Qspawn::Limiter;
 322 use strict;
 323 use warnings;
 324
 325 sub new {
 326         my ($class, $max) = @_;
 327         bless {
 328                 # 32 is same as the git-daemon connection limit
 329                 max => $max || 32,
 330                 running => 0,
 331                 run_queue => [],
 332                 # RLIMIT_CPU => undef,
 333                 # RLIMIT_DATA => undef,
 334                 # RLIMIT_CORE => undef,
 335         }, $class;
 336 }
 337
 338 sub setup_rlimit {
 339         my ($self, $name, $config) = @_;
 340         foreach my $rlim (PublicInbox::Spawn::RLIMITS()) {
 341                 my $k = lc($rlim);
 342                 $k =~ tr/_//d;
 343                 $k = "publicinboxlimiter.$name.$k";
 344                 defined(my $v = $config->{$k}) or next;
 345                 my @rlimit = split(/\s*,\s*/, $v);
 346                 if (scalar(@rlimit) == 1) {
 347                         push @rlimit, $rlimit[0];
 348                 } elsif (scalar(@rlimit) != 2) {
 349                         warn "could not parse $k: $v\n";
 350                 }
 351                 eval { require BSD::Resource };
 352                 if ($@) {
 353                         warn "BSD::Resource missing for $rlim";
 354                         next;
 355                 }
 356                 foreach my $i (0..$#rlimit) {
 357                         next if $rlimit[$i] ne 'INFINITY';
 358                         $rlimit[$i] = BSD::Resource::RLIM_INFINITY();
 359                 }
 360                 $self->{$rlim} = \@rlimit;
 361         }
 362 }
 363
 364 1;