lib/PublicInbox/Qspawn.pm

   1 # Copyright (C) 2016-2019 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Like most Perl modules in public-inbox, this is internal and
   5 # NOT subject to any stability guarantees!  It is only documented
   6 # for other hackers.
   7 #
   8 # This is used to limit the number of processes spawned by the
   9 # PSGI server, so it acts like a semaphore and queues up extra
  10 # commands to be run if currently at the limit.  Multiple "limiters"
  11 # may be configured which give inboxes different channels to
  12 # operate in.  This can be useful to ensure smaller inboxes can
  13 # be cloned while cloning of large inboxes is maxed out.
  14 #
  15 # This does not depend on PublicInbox::DS or any other external
  16 # scheduling mechanism, you just need to call start() and finish()
  17 # appropriately. However, public-inbox-httpd (which uses PublicInbox::DS)
  18 # will be able to schedule this based on readability of stdout from
  19 # the spawned process.  See GitHTTPBackend.pm and SolverGit.pm for
  20 # usage examples.  It does not depend on any form of threading.
  21 #
  22 # This is useful for scheduling CGI execution of both long-lived
  23 # git-http-backend(1) process (for "git clone") as well as short-lived
  24 # processes such as git-apply(1).
  25
  26 package PublicInbox::Qspawn;
  27 use strict;
  28 use warnings;
  29 use PublicInbox::Spawn qw(popen_rd);
  30 require Plack::Util;
  31
  32 # n.b.: we get EAGAIN with public-inbox-httpd, and EINTR on other PSGI servers
  33 use Errno qw(EAGAIN EINTR);
  34
  35 my $def_limiter;
  36
  37 # declares a command to spawn (but does not spawn it).
  38 # $cmd is the command to spawn
  39 # $cmd_env is the environ for the child process (not PSGI env)
  40 # $opt can include redirects and perhaps other process spawning options
  41 sub new ($$$;) {
  42         my ($class, $cmd, $cmd_env, $opt) = @_;
  43         bless { args => [ $cmd, $cmd_env, $opt ] }, $class;
  44 }
  45
  46 sub _do_spawn {
  47         my ($self, $start_cb, $limiter) = @_;
  48         my $err;
  49         my ($cmd, $cmd_env, $opts) = @{$self->{args}};
  50         my %opts = %{$opts || {}};
  51         $self->{limiter} = $limiter;
  52         foreach my $k (PublicInbox::Spawn::RLIMITS()) {
  53                 if (defined(my $rlimit = $limiter->{$k})) {
  54                         $opts{$k} = $rlimit;
  55                 }
  56         }
  57
  58         ($self->{rpipe}, $self->{pid}) = popen_rd($cmd, $cmd_env, \%opts);
  59
  60         # drop any IO handles opt was holding open via $opt->{hold}
  61         # No need to hold onto the descriptor once the child process has it.
  62         $self->{args} = $cmd; # keep this around for logging
  63
  64         if (defined $self->{pid}) {
  65                 $limiter->{running}++;
  66         } else {
  67                 $self->{err} = $!;
  68         }
  69         $start_cb->($self->{rpipe});
  70 }
  71
  72 sub child_err ($) {
  73         my ($child_error) = @_; # typically $?
  74         my $exitstatus = ($child_error >> 8) or return;
  75         my $sig = $child_error & 127;
  76         my $msg = "exit status=$exitstatus";
  77         $msg .= " signal=$sig" if $sig;
  78         $msg;
  79 }
  80
  81 sub log_err ($$) {
  82         my ($env, $msg) = @_;
  83         $env->{'psgi.errors'}->print($msg, "\n");
  84 }
  85
  86 # callback for dwaitpid
  87 sub waitpid_err ($$) {
  88         my ($self, $pid) = @_;
  89         my $xpid = delete $self->{pid};
  90         my $err;
  91         if ($pid > 0) { # success!
  92                 $err = child_err($?);
  93         } elsif ($pid < 0) { # ??? does this happen in our case?
  94                 $err = "W: waitpid($xpid, 0) => $pid: $!";
  95         } # else should not be called with pid == 0
  96
  97         my ($env, $qx_cb, $qx_arg, $qx_buf) =
  98                 delete @$self{qw(psgi_env qx_cb qx_arg qx_buf)};
  99
 100         # done, spawn whatever's in the queue
 101         my $limiter = $self->{limiter};
 102         my $running = --$limiter->{running};
 103
 104         if ($running < $limiter->{max}) {
 105                 if (my $next = shift(@{$limiter->{run_queue}})) {
 106                         _do_spawn(@$next, $limiter);
 107                 }
 108         }
 109
 110         if ($err) {
 111                 $self->{err} = $err;
 112                 if ($env && !$env->{'qspawn.quiet'}) {
 113                         log_err($env, join(' ', @{$self->{args}}) . ": $err");
 114                 }
 115         }
 116         eval { $qx_cb->($qx_buf, $qx_arg) } if $qx_cb;
 117 }
 118
 119 sub do_waitpid ($) {
 120         my ($self) = @_;
 121         my $pid = $self->{pid};
 122         # PublicInbox::DS may not be loaded
 123         eval { PublicInbox::DS::dwaitpid($pid, \&waitpid_err, $self) };
 124         # done if we're running in PublicInbox::DS::EventLoop
 125         if ($@) {
 126                 # non public-inbox-{httpd,nntpd} callers may block:
 127                 my $ret = waitpid($pid, 0);
 128                 waitpid_err($self, $ret);
 129         }
 130 }
 131
 132 sub finish ($) {
 133         my ($self) = @_;
 134         if (delete $self->{rpipe}) {
 135                 do_waitpid($self);
 136         } else {
 137                 my ($env, $qx_cb, $qx_arg, $qx_buf) =
 138                         delete @$self{qw(psgi_env qx_cb qx_arg qx_buf)};
 139                 eval { $qx_cb->($qx_buf, $qx_arg) } if $qx_cb;
 140         }
 141 }
 142
 143 sub start {
 144         my ($self, $limiter, $start_cb) = @_;
 145         if ($limiter->{running} < $limiter->{max}) {
 146                 _do_spawn($self, $start_cb, $limiter);
 147         } else {
 148                 push @{$limiter->{run_queue}}, [ $self, $start_cb ];
 149         }
 150 }
 151
 152 # Similar to `backtick` or "qx" ("perldoc -f qx"), it calls $qx_cb with
 153 # the stdout of the given command when done; but respects the given limiter
 154 # $env is the PSGI env.  As with ``/qx; only use this when output is small
 155 # and safe to slurp.
 156 sub psgi_qx {
 157         my ($self, $env, $limiter, $qx_cb, $qx_arg) = @_;
 158         $self->{psgi_env} = $env;
 159         my $qx_buf = '';
 160         open(my $qx_fh, '+>', \$qx_buf) or die; # PerlIO::scalar
 161         $self->{qx_cb} = $qx_cb;
 162         $self->{qx_arg} = $qx_arg;
 163         $self->{qx_fh} = $qx_fh;
 164         $self->{qx_buf} = \$qx_buf;
 165         my $async = $env->{'pi-httpd.async'};
 166         my $cb = sub {
 167                 my ($r, $buf);
 168 reread:
 169                 $r = sysread($self->{rpipe}, $buf, 65536);
 170                 if ($async) {
 171                         $async->async_pass($env->{'psgix.io'}, $qx_fh, \$buf);
 172                 } elsif (defined $r) {
 173                         $r ? $qx_fh->write($buf) : event_step($self, undef);
 174                 } else {
 175                         return if $! == EAGAIN; # try again when notified
 176                         goto reread if $! == EINTR;
 177                         event_step($self, $!);
 178                 }
 179         };
 180         $limiter ||= $def_limiter ||= PublicInbox::Qspawn::Limiter->new(32);
 181         $self->start($limiter, sub { # start_cb, may run later, much later...
 182                 if ($async) {
 183                 # PublicInbox::HTTPD::Async->new(rpipe, $cb, $end_obj)
 184                         $async = $async->($self->{rpipe}, $cb, undef, $self);
 185                         # $cb will call ->async_pass or ->close
 186                 } else { # generic PSGI
 187                         $cb->() while $self->{qx_fh};
 188                 }
 189         });
 190 }
 191
 192 # create a filter for "push"-based streaming PSGI writes used by HTTPD::Async
 193 sub filter_fh ($$) {
 194         my ($fh, $filter) = @_;
 195         Plack::Util::inline_object(
 196                 close => sub {
 197                         $fh->write($filter->(undef));
 198                         $fh->close;
 199                 },
 200                 write => sub {
 201                         $fh->write($filter->($_[0]));
 202                 });
 203 }
 204
 205 # this is called on pipe EOF to reap the process, may be called
 206 # via PublicInbox::DS event loop OR via GetlineBody for generic
 207 # PSGI servers.
 208 sub event_step {
 209         my ($self, $err) = @_; # $err: $!
 210         log_err($self->{psgi_env}, "psgi_{return,qx} $err") if defined($err);
 211         finish($self);
 212         my ($fh, $qx_fh) = delete(@$self{qw(fh qx_fh)});
 213         $fh->close if $fh; # async-only (psgi_return)
 214 }
 215
 216 sub rd_hdr ($) {
 217         my ($self) = @_;
 218         # typically used for reading CGI headers
 219         # we must loop until EAGAIN for EPOLLET in HTTPD/Async.pm
 220         # We also need to check EINTR for generic PSGI servers.
 221         my $ret;
 222         my $total_rd = 0;
 223         my $hdr_buf = $self->{hdr_buf};
 224         do {
 225                 my $r = sysread($self->{rpipe}, $$hdr_buf, 4096,
 226                                 length($$hdr_buf));
 227                 if (defined($r)) {
 228                         $total_rd += $r;
 229                         $ret = $self->{parse_hdr}->($total_rd, $hdr_buf);
 230                 } else {
 231                         # caller should notify us when it's ready:
 232                         return if $! == EAGAIN;
 233                         next if $! == EINTR; # immediate retry
 234                         log_err($self->{psgi_env}, "error reading header: $!");
 235                         $ret = [ 500, [], [ "Internal error\n" ] ];
 236                 }
 237         } until (defined $ret);
 238         delete $self->{parse_hdr}; # done parsing headers
 239         $ret;
 240 }
 241
 242 # Used for streaming the stdout of one process as a PSGI response.
 243 #
 244 # $env is the PSGI env.
 245 # optional keys in $env:
 246 #   $env->{'qspawn.wcb'} - the write callback from the PSGI server
 247 #                          optional, use this if you've already
 248 #                          captured it elsewhere.  If not given,
 249 #                          psgi_return will return an anonymous
 250 #                          sub for the PSGI server to call
 251 #
 252 #   $env->{'qspawn.filter'} - filter callback, receives a string as input,
 253 #                             undef on EOF
 254 #
 255 # $limiter - the Limiter object to use (uses the def_limiter if not given)
 256 #
 257 # $parse_hdr - Initial read function; often for parsing CGI header output.
 258 #              It will be given the return value of sysread from the pipe
 259 #              and a string ref of the current buffer.  Returns an arrayref
 260 #              for PSGI responses.  2-element arrays in PSGI mean the
 261 #              body will be streamed, later, via writes (push-based) to
 262 #              psgix.io.  3-element arrays means the body is available
 263 #              immediately (or streamed via ->getline (pull-based)).
 264 sub psgi_return {
 265         my ($self, $env, $limiter, $parse_hdr) = @_;
 266         $self->{psgi_env} = $env;
 267         $self->{hdr_buf} = \(my $hdr_buf = '');
 268         $self->{parse_hdr} = $parse_hdr;
 269         my $wcb = delete $env->{'qspawn.wcb'}; # or PSGI server supplies it
 270         my $async = $env->{'pi-httpd.async'};
 271
 272         my $cb = sub {
 273                 my $r = rd_hdr($self) or return;
 274                 my $filter = delete $env->{'qspawn.filter'};
 275                 if (scalar(@$r) == 3) { # error
 276                         if ($async) {
 277                                 # calls rpipe->close && ->event_step
 278                                 $async->close;
 279                         } else {
 280                                 $self->{rpipe}->close;
 281                                 event_step($self);
 282                         }
 283                         $wcb->($r);
 284                 } elsif ($async) {
 285                         # done reading headers, handoff to read body
 286                         my $fh = $wcb->($r); # scalar @$r == 2
 287                         $fh = filter_fh($fh, $filter) if $filter;
 288                         $self->{fh} = $fh;
 289                         $async->async_pass($env->{'psgix.io'}, $fh,
 290                                                 delete($self->{hdr_buf}));
 291                 } else { # for synchronous PSGI servers
 292                         require PublicInbox::GetlineBody;
 293                         $r->[2] = PublicInbox::GetlineBody->new($self->{rpipe},
 294                                                 \&event_step, $self,
 295                                                 ${$self->{hdr_buf}}, $filter);
 296                         $wcb->($r);
 297                 }
 298
 299                 # Workaround a leak under Perl 5.16.3 when combined with
 300                 # Plack::Middleware::Deflater:
 301                 $wcb = undef;
 302         };
 303         $limiter ||= $def_limiter ||= PublicInbox::Qspawn::Limiter->new(32);
 304         my $start_cb = sub { # may run later, much later...
 305                 if ($async) {
 306                         # PublicInbox::HTTPD::Async->new(rpipe, $cb, $cb_arg,
 307                         #                                $end_obj)
 308                         $async = $async->($self->{rpipe}, $cb, undef, $self);
 309                         # $cb will call ->async_pass or ->close
 310                 } else { # generic PSGI
 311                         $cb->() while $self->{parse_hdr};
 312                 }
 313         };
 314
 315         # the caller already captured the PSGI write callback from
 316         # the PSGI server, so we can call ->start, here:
 317         return $self->start($limiter, $start_cb) if $wcb;
 318
 319         # the caller will return this sub to the PSGI server, so
 320         # it can set the response callback (that is, for PublicInbox::HTTP,
 321         # the chunked_wcb or identity_wcb callback), but other HTTP servers
 322         # are supported:
 323         sub {
 324                 ($wcb) = @_;
 325                 $self->start($limiter, $start_cb);
 326         };
 327 }
 328
 329 package PublicInbox::Qspawn::Limiter;
 330 use strict;
 331 use warnings;
 332
 333 sub new {
 334         my ($class, $max) = @_;
 335         bless {
 336                 # 32 is same as the git-daemon connection limit
 337                 max => $max || 32,
 338                 running => 0,
 339                 run_queue => [],
 340                 # RLIMIT_CPU => undef,
 341                 # RLIMIT_DATA => undef,
 342                 # RLIMIT_CORE => undef,
 343         }, $class;
 344 }
 345
 346 sub setup_rlimit {
 347         my ($self, $name, $config) = @_;
 348         foreach my $rlim (PublicInbox::Spawn::RLIMITS()) {
 349                 my $k = lc($rlim);
 350                 $k =~ tr/_//d;
 351                 $k = "publicinboxlimiter.$name.$k";
 352                 defined(my $v = $config->{$k}) or next;
 353                 my @rlimit = split(/\s*,\s*/, $v);
 354                 if (scalar(@rlimit) == 1) {
 355                         push @rlimit, $rlimit[0];
 356                 } elsif (scalar(@rlimit) != 2) {
 357                         warn "could not parse $k: $v\n";
 358                 }
 359                 eval { require BSD::Resource };
 360                 if ($@) {
 361                         warn "BSD::Resource missing for $rlim";
 362                         next;
 363                 }
 364                 foreach my $i (0..$#rlimit) {
 365                         next if $rlimit[$i] ne 'INFINITY';
 366                         $rlimit[$i] = BSD::Resource::RLIM_INFINITY();
 367                 }
 368                 $self->{$rlim} = \@rlimit;
 369         }
 370 }
 371
 372 1;