lib/PublicInbox/Qspawn.pm

   1 # Copyright (C) 2016-2019 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3
   4 # Like most Perl modules in public-inbox, this is internal and
   5 # NOT subject to any stability guarantees!  It is only documented
   6 # for other hackers.
   7 #
   8 # This is used to limit the number of processes spawned by the
   9 # PSGI server, so it acts like a semaphore and queues up extra
  10 # commands to be run if currently at the limit.  Multiple "limiters"
  11 # may be configured which give inboxes different channels to
  12 # operate in.  This can be useful to ensure smaller inboxes can
  13 # be cloned while cloning of large inboxes is maxed out.
  14 #
  15 # This does not depend on PublicInbox::DS or any other external
  16 # scheduling mechanism, you just need to call start() and finish()
  17 # appropriately. However, public-inbox-httpd (which uses PublicInbox::DS)
  18 # will be able to schedule this based on readability of stdout from
  19 # the spawned process.  See GitHTTPBackend.pm and SolverGit.pm for
  20 # usage examples.  It does not depend on any form of threading.
  21 #
  22 # This is useful for scheduling CGI execution of both long-lived
  23 # git-http-backend(1) process (for "git clone") as well as short-lived
  24 # processes such as git-apply(1).
  25
  26 package PublicInbox::Qspawn;
  27 use strict;
  28 use warnings;
  29 use PublicInbox::Spawn qw(popen_rd);
  30 require Plack::Util;
  31
  32 # n.b.: we get EAGAIN with public-inbox-httpd, and EINTR on other PSGI servers
  33 use Errno qw(EAGAIN EINTR);
  34
  35 my $def_limiter;
  36
  37 # declares a command to spawn (but does not spawn it).
  38 # $cmd is the command to spawn
  39 # $cmd_env is the environ for the child process (not PSGI env)
  40 # $opt can include redirects and perhaps other process spawning options
  41 sub new ($$$;) {
  42         my ($class, $cmd, $cmd_env, $opt) = @_;
  43         bless { args => [ $cmd, $cmd_env, $opt ] }, $class;
  44 }
  45
  46 sub _do_spawn {
  47         my ($self, $start_cb, $limiter) = @_;
  48         my $err;
  49         my ($cmd, $cmd_env, $opts) = @{$self->{args}};
  50         my %opts = %{$opts || {}};
  51         $self->{limiter} = $limiter;
  52         foreach my $k (PublicInbox::Spawn::RLIMITS()) {
  53                 if (defined(my $rlimit = $limiter->{$k})) {
  54                         $opts{$k} = $rlimit;
  55                 }
  56         }
  57
  58         ($self->{rpipe}, $self->{pid}) = popen_rd($cmd, $cmd_env, \%opts);
  59
  60         # drop any IO handles opt was holding open via $opt->{hold}
  61         # No need to hold onto the descriptor once the child process has it.
  62         $self->{args} = $cmd; # keep this around for logging
  63
  64         if (defined $self->{pid}) {
  65                 $limiter->{running}++;
  66         } else {
  67                 $self->{err} = $!;
  68         }
  69         $start_cb->($self->{rpipe});
  70 }
  71
  72 sub child_err ($) {
  73         my ($child_error) = @_; # typically $?
  74         my $exitstatus = ($child_error >> 8) or return;
  75         my $sig = $child_error & 127;
  76         my $msg = "exit status=$exitstatus";
  77         $msg .= " signal=$sig" if $sig;
  78         $msg;
  79 }
  80
  81 sub log_err ($$) {
  82         my ($env, $msg) = @_;
  83         $env->{'psgi.errors'}->print($msg, "\n");
  84 }
  85
  86 # callback for dwaitpid
  87 sub waitpid_err ($$) {
  88         my ($self, $pid) = @_;
  89         my $xpid = delete $self->{pid};
  90         my $err;
  91         if ($pid > 0) { # success!
  92                 $err = child_err($?);
  93         } elsif ($pid < 0) { # ??? does this happen in our case?
  94                 $err = "W: waitpid($xpid, 0) => $pid: $!";
  95         } # else should not be called with pid == 0
  96
  97         my ($env, $qx_cb, $qx_arg, $qx_buf) =
  98                 delete @$self{qw(psgi_env qx_cb qx_arg qx_buf)};
  99
 100         # done, spawn whatever's in the queue
 101         my $limiter = $self->{limiter};
 102         my $running = --$limiter->{running};
 103
 104         if ($running < $limiter->{max}) {
 105                 if (my $next = shift(@{$limiter->{run_queue}})) {
 106                         _do_spawn(@$next, $limiter);
 107                 }
 108         }
 109
 110         if ($err) {
 111                 $self->{err} = $err;
 112                 if ($env && !$env->{'qspawn.quiet'}) {
 113                         log_err($env, join(' ', @{$self->{args}}) . ": $err");
 114                 }
 115         }
 116         eval { $qx_cb->($qx_buf, $qx_arg) } if $qx_cb;
 117 }
 118
 119 sub do_waitpid ($) {
 120         my ($self) = @_;
 121         my $pid = $self->{pid};
 122         # PublicInbox::DS may not be loaded
 123         eval { PublicInbox::DS::dwaitpid($pid, \&waitpid_err, $self) };
 124         # done if we're running in PublicInbox::DS::EventLoop
 125         if ($@) {
 126                 # non public-inbox-{httpd,nntpd} callers may block:
 127                 my $ret = waitpid($pid, 0);
 128                 waitpid_err($self, $ret);
 129         }
 130 }
 131
 132 sub finish ($) {
 133         my ($self) = @_;
 134         if (delete $self->{rpipe}) {
 135                 do_waitpid($self);
 136         } else {
 137                 my ($env, $qx_cb, $qx_arg, $qx_buf) =
 138                         delete @$self{qw(psgi_env qx_cb qx_arg qx_buf)};
 139                 eval { $qx_cb->($qx_buf, $qx_arg) } if $qx_cb;
 140         }
 141 }
 142
 143 sub start {
 144         my ($self, $limiter, $start_cb) = @_;
 145         if ($limiter->{running} < $limiter->{max}) {
 146                 _do_spawn($self, $start_cb, $limiter);
 147         } else {
 148                 push @{$limiter->{run_queue}}, [ $self, $start_cb ];
 149         }
 150 }
 151
 152 # Similar to `backtick` or "qx" ("perldoc -f qx"), it calls $qx_cb with
 153 # the stdout of the given command when done; but respects the given limiter
 154 # $env is the PSGI env.  As with ``/qx; only use this when output is small
 155 # and safe to slurp.
 156 sub psgi_qx {
 157         my ($self, $env, $limiter, $qx_cb, $qx_arg) = @_;
 158         $self->{psgi_env} = $env;
 159         my $qx_buf = '';
 160         open(my $qx_fh, '+>', \$qx_buf) or die; # PerlIO::scalar
 161         $self->{qx_cb} = $qx_cb;
 162         $self->{qx_arg} = $qx_arg;
 163         $self->{qx_fh} = $qx_fh;
 164         $self->{qx_buf} = \$qx_buf;
 165         my $async = $env->{'pi-httpd.async'};
 166         my $cb = sub {
 167                 my ($r, $buf);
 168 reread:
 169                 $r = sysread($self->{rpipe}, $buf, 65536);
 170                 if ($async) {
 171                         $async->async_pass($env->{'psgix.io'}, $qx_fh, \$buf);
 172                 } elsif (defined $r) {
 173                         $r ? $qx_fh->write($buf) : event_step($self, undef);
 174                 } else {
 175                         return if $! == EAGAIN; # try again when notified
 176                         goto reread if $! == EINTR;
 177                         event_step($self, $!);
 178                 }
 179         };
 180         $limiter ||= $def_limiter ||= PublicInbox::Qspawn::Limiter->new(32);
 181         $self->start($limiter, sub { # start_cb, may run later, much later...
 182                 if ($async) {
 183                 # PublicInbox::HTTPD::Async->new(rpipe, $cb, $end_obj)
 184                         $async = $async->($self->{rpipe}, $cb, undef, $self);
 185                         # $cb will call ->async_pass or ->close
 186                 } else { # generic PSGI
 187                         $cb->() while $self->{qx_fh};
 188                 }
 189         });
 190 }
 191
 192 # create a filter for "push"-based streaming PSGI writes used by HTTPD::Async
 193 sub filter_fh ($$) {
 194         my ($fh, $filter) = @_;
 195         Plack::Util::inline_object(
 196                 close => sub {
 197                         $fh->write($filter->(undef));
 198                         $fh->close;
 199                 },
 200                 write => sub {
 201                         $fh->write($filter->($_[0]));
 202                 });
 203 }
 204
 205 # this is called on pipe EOF to reap the process, may be called
 206 # via PublicInbox::DS event loop OR via GetlineBody for generic
 207 # PSGI servers.
 208 sub event_step {
 209         my ($self, $err) = @_; # $err: $!
 210         log_err($self->{psgi_env}, "psgi_{return,qx} $err") if defined($err);
 211         finish($self);
 212         my ($fh, $qx_fh) = delete(@$self{qw(fh qx_fh)});
 213         $fh->close if $fh; # async-only (psgi_return)
 214 }
 215
 216 sub rd_hdr ($) {
 217         my ($self) = @_;
 218         # typically used for reading CGI headers
 219         # we must loop until EAGAIN for EPOLLET in HTTPD/Async.pm
 220         # We also need to check EINTR for generic PSGI servers.
 221         my $ret;
 222         my $total_rd = 0;
 223         my $hdr_buf = $self->{hdr_buf};
 224         do {
 225                 my $r = sysread($self->{rpipe}, $$hdr_buf, 4096,
 226                                 length($$hdr_buf));
 227                 if (defined($r)) {
 228                         $total_rd += $r;
 229                         $ret = $self->{parse_hdr}->($total_rd, $hdr_buf);
 230                 } else {
 231                         # caller should notify us when it's ready:
 232                         return if $! == EAGAIN;
 233                         next if $! == EINTR; # immediate retry
 234                         log_err($self->{psgi_env}, "error reading header: $!");
 235                         $ret = [ 500, [], [ "Internal error\n" ] ];
 236                 }
 237         } until (defined $ret);
 238         delete $self->{parse_hdr}; # done parsing headers
 239         $ret;
 240 }
 241
 242 sub psgi_return_init_cb {
 243         my ($self) = @_;
 244         my $r = rd_hdr($self) or return;
 245         my $env = $self->{psgi_env};
 246         my $filter = delete $env->{'qspawn.filter'};
 247         my $wcb = delete $env->{'qspawn.wcb'};
 248         my $async = delete $self->{async};
 249         if (scalar(@$r) == 3) { # error
 250                 if ($async) {
 251                         # calls rpipe->close && ->event_step
 252                         $async->close;
 253                 } else {
 254                         $self->{rpipe}->close;
 255                         event_step($self);
 256                 }
 257                 $wcb->($r);
 258         } elsif ($async) {
 259                 # done reading headers, handoff to read body
 260                 my $fh = $wcb->($r); # scalar @$r == 2
 261                 $fh = filter_fh($fh, $filter) if $filter;
 262                 $self->{fh} = $fh;
 263                 $async->async_pass($env->{'psgix.io'}, $fh,
 264                                         delete($self->{hdr_buf}));
 265         } else { # for synchronous PSGI servers
 266                 require PublicInbox::GetlineBody;
 267                 $r->[2] = PublicInbox::GetlineBody->new($self->{rpipe},
 268                                         \&event_step, $self,
 269                                         ${$self->{hdr_buf}}, $filter);
 270                 $wcb->($r);
 271         }
 272
 273         # Workaround a leak under Perl 5.16.3 when combined with
 274         # Plack::Middleware::Deflater:
 275         $wcb = undef;
 276 }
 277
 278 # Used for streaming the stdout of one process as a PSGI response.
 279 #
 280 # $env is the PSGI env.
 281 # optional keys in $env:
 282 #   $env->{'qspawn.wcb'} - the write callback from the PSGI server
 283 #                          optional, use this if you've already
 284 #                          captured it elsewhere.  If not given,
 285 #                          psgi_return will return an anonymous
 286 #                          sub for the PSGI server to call
 287 #
 288 #   $env->{'qspawn.filter'} - filter callback, receives a string as input,
 289 #                             undef on EOF
 290 #
 291 # $limiter - the Limiter object to use (uses the def_limiter if not given)
 292 #
 293 # $parse_hdr - Initial read function; often for parsing CGI header output.
 294 #              It will be given the return value of sysread from the pipe
 295 #              and a string ref of the current buffer.  Returns an arrayref
 296 #              for PSGI responses.  2-element arrays in PSGI mean the
 297 #              body will be streamed, later, via writes (push-based) to
 298 #              psgix.io.  3-element arrays means the body is available
 299 #              immediately (or streamed via ->getline (pull-based)).
 300 sub psgi_return {
 301         my ($self, $env, $limiter, $parse_hdr) = @_;
 302         $self->{psgi_env} = $env;
 303         $self->{hdr_buf} = \(my $hdr_buf = '');
 304         $self->{parse_hdr} = $parse_hdr;
 305         $limiter ||= $def_limiter ||= PublicInbox::Qspawn::Limiter->new(32);
 306         my $start_cb = sub { # may run later, much later...
 307                 if (my $async = $env->{'pi-httpd.async'}) {
 308                         # PublicInbox::HTTPD::Async->new(rpipe, $cb, $cb_arg,
 309                         #                                $end_obj)
 310                         $self->{async} = $async->($self->{rpipe},
 311                                                 \&psgi_return_init_cb, $self,
 312                                                 $self);
 313                 } else { # generic PSGI
 314                         psgi_return_init_cb($self) while $self->{parse_hdr};
 315                 }
 316         };
 317
 318         # the caller already captured the PSGI write callback from
 319         # the PSGI server, so we can call ->start, here:
 320         return $self->start($limiter, $start_cb) if $env->{'qspawn.wcb'};
 321
 322         # the caller will return this sub to the PSGI server, so
 323         # it can set the response callback (that is, for PublicInbox::HTTP,
 324         # the chunked_wcb or identity_wcb callback), but other HTTP servers
 325         # are supported:
 326         sub {
 327                 $self->{psgi_env}->{'qspawn.wcb'} = $_[0];
 328                 $self->start($limiter, $start_cb);
 329         };
 330 }
 331
 332 package PublicInbox::Qspawn::Limiter;
 333 use strict;
 334 use warnings;
 335
 336 sub new {
 337         my ($class, $max) = @_;
 338         bless {
 339                 # 32 is same as the git-daemon connection limit
 340                 max => $max || 32,
 341                 running => 0,
 342                 run_queue => [],
 343                 # RLIMIT_CPU => undef,
 344                 # RLIMIT_DATA => undef,
 345                 # RLIMIT_CORE => undef,
 346         }, $class;
 347 }
 348
 349 sub setup_rlimit {
 350         my ($self, $name, $config) = @_;
 351         foreach my $rlim (PublicInbox::Spawn::RLIMITS()) {
 352                 my $k = lc($rlim);
 353                 $k =~ tr/_//d;
 354                 $k = "publicinboxlimiter.$name.$k";
 355                 defined(my $v = $config->{$k}) or next;
 356                 my @rlimit = split(/\s*,\s*/, $v);
 357                 if (scalar(@rlimit) == 1) {
 358                         push @rlimit, $rlimit[0];
 359                 } elsif (scalar(@rlimit) != 2) {
 360                         warn "could not parse $k: $v\n";
 361                 }
 362                 eval { require BSD::Resource };
 363                 if ($@) {
 364                         warn "BSD::Resource missing for $rlim";
 365                         next;
 366                 }
 367                 foreach my $i (0..$#rlimit) {
 368                         next if $rlimit[$i] ne 'INFINITY';
 369                         $rlimit[$i] = BSD::Resource::RLIM_INFINITY();
 370                 }
 371                 $self->{$rlim} = \@rlimit;
 372         }
 373 }
 374
 375 1;