lib/PublicInbox/Search.pm

   1 # Copyright (C) 2015-2019 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 # based on notmuch, but with no concept of folders, files or flags
   4 #
   5 # Read-only search interface for use by the web and NNTP interfaces
   6 package PublicInbox::Search;
   7 use strict;
   8 use warnings;
   9
  10 # values for searching
  11 use constant TS => 0;  # Received: header in Unix time
  12 use constant YYYYMMDD => 1; # Date: header for searching in the WWW UI
  13 use constant DT => 2; # Date: YYYYMMDDHHMMSS
  14
  15 use PublicInbox::SearchMsg;
  16 use PublicInbox::MIME;
  17 use PublicInbox::MID qw/id_compress/;
  18 use PublicInbox::Over;
  19 my $QP_FLAGS;
  20 sub load_xapian () {
  21         $QP_FLAGS ||= eval {
  22                 require Search::Xapian;
  23                 Search::Xapian->import(qw(:standard));
  24
  25                 # n.b. FLAG_PURE_NOT is expensive not suitable for a public
  26                 # website as it could become a denial-of-service vector
  27                 # FLAG_PHRASE also seems to cause performance problems chert
  28                 # (and probably earlier Xapian DBs).  glass seems fine...
  29                 # TODO: make this an option, maybe?
  30                 # or make indexlevel=medium as default
  31                 FLAG_PHRASE()|FLAG_BOOLEAN()|FLAG_LOVEHATE()|FLAG_WILDCARD();
  32         };
  33 };
  34
  35 # This is English-only, everything else is non-standard and may be confused as
  36 # a prefix common in patch emails
  37 our $LANG = 'english';
  38
  39 use constant {
  40         # SCHEMA_VERSION history
  41         # 0 - initial
  42         # 1 - subject_path is lower-cased
  43         # 2 - subject_path is id_compress in the index, only
  44         # 3 - message-ID is compressed if it includes '%' (hack!)
  45         # 4 - change "Re: " normalization, avoid circular Reference ghosts
  46         # 5 - subject_path drops trailing '.'
  47         # 6 - preserve References: order in document data
  48         # 7 - remove references and inreplyto terms
  49         # 8 - remove redundant/unneeded document data
  50         # 9 - disable Message-ID compression (SHA-1)
  51         # 10 - optimize doc for NNTP overviews
  52         # 11 - merge threads when vivifying ghosts
  53         # 12 - change YYYYMMDD value column to numeric
  54         # 13 - fix threading for empty References/In-Reply-To
  55         #      (commit 83425ef12e4b65cdcecd11ddcb38175d4a91d5a0)
  56         # 14 - fix ghost root vivification
  57         SCHEMA_VERSION => 15,
  58 };
  59
  60 my %bool_pfx_external = (
  61         mid => 'Q', # Message-ID (full/exact), this is mostly uniQue
  62         dfpre => 'XDFPRE',
  63         dfpost => 'XDFPOST',
  64         dfblob => 'XDFPRE XDFPOST',
  65 );
  66
  67 my $non_quoted_body = 'XNQ XDFN XDFA XDFB XDFHH XDFCTX XDFPRE XDFPOST';
  68 my %prob_prefix = (
  69         # for mairix compatibility
  70         s => 'S',
  71         m => 'XM', # 'mid:' (bool) is exact, 'm:' (prob) can do partial
  72         f => 'A',
  73         t => 'XTO',
  74         tc => 'XTO XCC',
  75         c => 'XCC',
  76         tcf => 'XTO XCC A',
  77         a => 'XTO XCC A',
  78         b => $non_quoted_body . ' XQUOT',
  79         bs => $non_quoted_body . ' XQUOT S',
  80         n => 'XFN',
  81
  82         q => 'XQUOT',
  83         nq => $non_quoted_body,
  84         dfn => 'XDFN',
  85         dfa => 'XDFA',
  86         dfb => 'XDFB',
  87         dfhh => 'XDFHH',
  88         dfctx => 'XDFCTX',
  89
  90         # default:
  91         '' => 'XM S A XQUOT XFN ' . $non_quoted_body,
  92 );
  93
  94 # not documenting m: and mid: for now, the using the URLs works w/o Xapian
  95 our @HELP = (
  96         's:' => 'match within Subject  e.g. s:"a quick brown fox"',
  97         'd:' => <<EOF,
  98 date range as YYYYMMDD  e.g. d:19931002..20101002
  99 Open-ended ranges such as d:19931002.. and d:..20101002
 100 are also supported
 101 EOF
 102         'dt:' => <<EOF,
 103 date-time range as YYYYMMDDhhmmss (e.g. dt:19931002011000..19931002011200)
 104 EOF
 105         'b:' => 'match within message body, including text attachments',
 106         'nq:' => 'match non-quoted text within message body',
 107         'q:' => 'match quoted text within message body',
 108         'n:' => 'match filename of attachment(s)',
 109         't:' => 'match within the To header',
 110         'c:' => 'match within the Cc header',
 111         'f:' => 'match within the From header',
 112         'a:' => 'match within the To, Cc, and From headers',
 113         'tc:' => 'match within the To and Cc headers',
 114         'bs:' => 'match within the Subject and body',
 115         'dfn:' => 'match filename from diff',
 116         'dfa:' => 'match diff removed (-) lines',
 117         'dfb:' => 'match diff added (+) lines',
 118         'dfhh:' => 'match diff hunk header context (usually a function name)',
 119         'dfctx:' => 'match diff context lines',
 120         'dfpre:' => 'match pre-image git blob ID',
 121         'dfpost:' => 'match post-image git blob ID',
 122         'dfblob:' => 'match either pre or post-image git blob ID',
 123 );
 124 chomp @HELP;
 125
 126 sub xdir ($;$) {
 127         my ($self, $rdonly) = @_;
 128         if ($self->{version} == 1) {
 129                 "$self->{inboxdir}/public-inbox/xapian" . SCHEMA_VERSION;
 130         } else {
 131                 my $dir = "$self->{inboxdir}/xap" . SCHEMA_VERSION;
 132                 return $dir if $rdonly;
 133
 134                 my $shard = $self->{shard};
 135                 defined $shard or die "shard not given";
 136                 $dir .= "/$shard";
 137         }
 138 }
 139
 140 sub _xdb ($) {
 141         my ($self) = @_;
 142         my $dir = xdir($self, 1);
 143         my ($xdb, $slow_phrase);
 144         my $qpf = \($self->{qp_flags} ||= $QP_FLAGS);
 145         if ($self->{version} >= 2) {
 146                 foreach my $shard (<$dir/*>) {
 147                         -d $shard && $shard =~ m!/[0-9]+\z! or next;
 148                         my $sub = Search::Xapian::Database->new($shard);
 149                         if ($xdb) {
 150                                 $xdb->add_database($sub);
 151                         } else {
 152                                 $xdb = $sub;
 153                         }
 154                         $slow_phrase ||= -f "$shard/iamchert";
 155                 }
 156         } else {
 157                 $slow_phrase = -f "$dir/iamchert";
 158                 $xdb = Search::Xapian::Database->new($dir);
 159         }
 160         $$qpf |= FLAG_PHRASE() unless $slow_phrase;
 161         $xdb;
 162 }
 163
 164 sub xdb ($) {
 165         my ($self) = @_;
 166         $self->{xdb} ||= do {
 167                 load_xapian();
 168                 _xdb($self);
 169         };
 170 }
 171
 172 sub new {
 173         my ($class, $ibx) = @_;
 174         ref $ibx or die "BUG: expected PublicInbox::Inbox object: $ibx";
 175         my $self = bless {
 176                 inboxdir => $ibx->{inboxdir},
 177                 altid => $ibx->{altid},
 178                 version => $ibx->{version} // 1,
 179         }, $class;
 180         my $dir = xdir($self, 1);
 181         $self->{over_ro} = PublicInbox::Over->new("$dir/over.sqlite3");
 182         $self;
 183 }
 184
 185 sub reopen {
 186         my ($self) = @_;
 187         if (my $xdb = $self->{xdb}) {
 188                 $xdb->reopen;
 189         }
 190         $self; # make chaining easier
 191 }
 192
 193 # read-only
 194 sub query {
 195         my ($self, $query_string, $opts) = @_;
 196         $opts ||= {};
 197         if ($query_string eq '' && !$opts->{mset}) {
 198                 $self->{over_ro}->recent($opts);
 199         } else {
 200                 my $qp = qp($self);
 201                 my $qp_flags = $self->{qp_flags};
 202                 my $query = $qp->parse_query($query_string, $qp_flags);
 203                 $opts->{relevance} = 1 unless exists $opts->{relevance};
 204                 _do_enquire($self, $query, $opts);
 205         }
 206 }
 207
 208 sub retry_reopen {
 209         my ($self, $cb) = @_;
 210         for my $i (1..10) {
 211                 if (wantarray) {
 212                         my @ret;
 213                         eval { @ret = $cb->() };
 214                         return @ret unless $@;
 215                 } else {
 216                         my $ret;
 217                         eval { $ret = $cb->() };
 218                         return $ret unless $@;
 219                 }
 220                 # Exception: The revision being read has been discarded -
 221                 # you should call Xapian::Database::reopen()
 222                 if (ref($@) eq 'Search::Xapian::DatabaseModifiedError') {
 223                         warn "reopen try #$i on $@\n";
 224                         reopen($self);
 225                 } else {
 226                         # let caller decide how to spew, because ExtMsg queries
 227                         # get wonky and trigger:
 228                         # "something terrible happened at .../Xapian/Enquire.pm"
 229                         die;
 230                 }
 231         }
 232         die "Too many Xapian database modifications in progress\n";
 233 }
 234
 235 sub _do_enquire {
 236         my ($self, $query, $opts) = @_;
 237         retry_reopen($self, sub { _enquire_once($self, $query, $opts) });
 238 }
 239
 240 sub _enquire_once {
 241         my ($self, $query, $opts) = @_;
 242         my $xdb = xdb($self);
 243         my $enquire = Search::Xapian::Enquire->new($xdb);
 244         $enquire->set_query($query);
 245         $opts ||= {};
 246         my $desc = !$opts->{asc};
 247         if (($opts->{mset} || 0) == 2) {
 248                 $enquire->set_docid_order(Search::Xapian::ENQ_ASCENDING());
 249                 $enquire->set_weighting_scheme(Search::Xapian::BoolWeight->new);
 250         } elsif ($opts->{relevance}) {
 251                 $enquire->set_sort_by_relevance_then_value(TS, $desc);
 252         } else {
 253                 $enquire->set_sort_by_value_then_relevance(TS, $desc);
 254         }
 255         my $offset = $opts->{offset} || 0;
 256         my $limit = $opts->{limit} || 50;
 257         my $mset = $enquire->get_mset($offset, $limit);
 258         return $mset if $opts->{mset};
 259         my @msgs = map {
 260                 PublicInbox::SearchMsg->load_doc($_->get_document);
 261         } $mset->items;
 262         return \@msgs unless wantarray;
 263
 264         ($mset->get_matches_estimated, \@msgs)
 265 }
 266
 267 # read-write
 268 sub stemmer { Search::Xapian::Stem->new($LANG) }
 269
 270 # read-only
 271 sub qp {
 272         my ($self) = @_;
 273
 274         my $qp = $self->{query_parser};
 275         return $qp if $qp;
 276         my $xdb = xdb($self);
 277         # new parser
 278         $qp = Search::Xapian::QueryParser->new;
 279         $qp->set_default_op(OP_AND());
 280         $qp->set_database($xdb);
 281         $qp->set_stemmer($self->stemmer);
 282         $qp->set_stemming_strategy(STEM_SOME());
 283         $qp->set_max_wildcard_expansion(100);
 284         $qp->add_valuerangeprocessor(
 285                 Search::Xapian::NumberValueRangeProcessor->new(YYYYMMDD, 'd:'));
 286         $qp->add_valuerangeprocessor(
 287                 Search::Xapian::NumberValueRangeProcessor->new(DT, 'dt:'));
 288
 289         while (my ($name, $prefix) = each %bool_pfx_external) {
 290                 $qp->add_boolean_prefix($name, $_) foreach split(/ /, $prefix);
 291         }
 292
 293         # we do not actually create AltId objects,
 294         # just parse the spec to avoid the extra DB handles for now.
 295         if (my $altid = $self->{altid}) {
 296                 my $user_pfx = $self->{-user_pfx} ||= [];
 297                 for (@$altid) {
 298                         # $_ = 'serial:gmane:/path/to/gmane.msgmap.sqlite3'
 299                         /\Aserial:(\w+):/ or next;
 300                         my $pfx = $1;
 301                         push @$user_pfx, "$pfx:", <<EOF;
 302 alternate serial number  e.g. $pfx:12345 (boolean)
 303 EOF
 304                         # gmane => XGMANE
 305                         $qp->add_boolean_prefix($pfx, 'X'.uc($pfx));
 306                 }
 307                 chomp @$user_pfx;
 308         }
 309
 310         while (my ($name, $prefix) = each %prob_prefix) {
 311                 $qp->add_prefix($name, $_) foreach split(/ /, $prefix);
 312         }
 313
 314         $self->{query_parser} = $qp;
 315 }
 316
 317 sub lookup_article {
 318         my ($self, $num) = @_;
 319         $self->{over_ro}->get_art($num);
 320 }
 321
 322 sub help {
 323         my ($self) = @_;
 324         $self->qp; # parse altids
 325         my @ret = @HELP;
 326         if (my $user_pfx = $self->{-user_pfx}) {
 327                 push @ret, @$user_pfx;
 328         }
 329         \@ret;
 330 }
 331
 332 1;