lib/PublicInbox/Search.pm

   1 # Copyright (C) 2015, all contributors <meta@public-inbox.org>
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 # based on notmuch, but with no concept of folders, files or flags
   4 package PublicInbox::Search;
   5 use strict;
   6 use warnings;
   7 use PublicInbox::SearchMsg;
   8 use base qw/Exporter/;
   9 use Digest::SHA qw//;
  10 use Search::Xapian qw/:standard/;
  11 require PublicInbox::View;
  12 use Date::Parse qw/str2time/;
  13 use POSIX qw//;
  14 use Email::MIME;
  15
  16 our @EXPORT = qw/xpfx mid_compressed/;
  17
  18 use constant {
  19         TS => 0,
  20         SHA1HEX_LEN => 40,
  21         SCHEMA_VERSION => 0,
  22         LANG => 'english',
  23         QP_FLAGS => FLAG_PHRASE|FLAG_BOOLEAN|FLAG_LOVEHATE|FLAG_WILDCARD,
  24 };
  25
  26 use constant MID_MAX => SHA1HEX_LEN;
  27
  28 # setup prefixes
  29 my %bool_pfx_internal = (
  30         type => 'T', # "mail" or "ghost"
  31         mid => 'Q', # uniQue id (Message-ID or mid_compressed)
  32 );
  33
  34 my %bool_pfx_external = (
  35         path => 'XPATH',
  36         thread => 'G', # newsGroup (or similar entity - e.g. a web forum name)
  37         references => 'XREFS',
  38         inreplyto => 'XIRT',
  39 );
  40
  41 my %prob_prefix = (
  42         subject => 'S',
  43 );
  44
  45 my %all_pfx = (%bool_pfx_internal, %bool_pfx_external, %prob_prefix);
  46
  47 sub xpfx { $all_pfx{$_[0]} }
  48
  49 our %PFX2TERM_RMAP;
  50 while (my ($k, $v) = each %all_pfx) {
  51         next if $prob_prefix{$k};
  52         $PFX2TERM_RMAP{$v} = $k;
  53 }
  54
  55 my $mail_query = Search::Xapian::Query->new(xpfx('type') . 'mail');
  56
  57 # this is idempotent
  58 sub mid_compressed {
  59         my ($mid) = @_;
  60         return $mid if (length($mid) <= MID_MAX);
  61         Digest::SHA::sha1_hex($mid);
  62 }
  63
  64 sub new {
  65         my ($class, $git_dir, $writable) = @_;
  66         # allow concurrent versions for easier rollback:
  67         my $dir = "$git_dir/public-inbox/xapian" . SCHEMA_VERSION;
  68         my $db;
  69
  70         if ($writable) { # not used by the WWW interface
  71                 require Search::Xapian::WritableDatabase;
  72                 require File::Path;
  73                 File::Path::mkpath($dir);
  74                 $db = Search::Xapian::WritableDatabase->new($dir,
  75                                         Search::Xapian::DB_CREATE_OR_OPEN);
  76         } else {
  77                 $db = Search::Xapian::Database->new($dir);
  78         }
  79         bless { xdb => $db, git_dir => $git_dir }, $class;
  80 }
  81
  82 sub reopen { $_[0]->{xdb}->reopen }
  83
  84 sub add_message {
  85         my ($self, $mime) = @_; # mime = Email::MIME object
  86         my $db = $self->{xdb};
  87
  88         my $doc_id;
  89         my $mid = clean_mid($mime->header('Message-ID'));
  90         $mid = mid_compressed($mid);
  91         my $was_ghost = 0;
  92         my $ct_msg = $mime->header('Content-Type') || 'text/plain';
  93         my $enc_msg = PublicInbox::View::enc_for($ct_msg);
  94
  95         $db->begin_transaction;
  96         eval {
  97                 my $smsg = $self->lookup_message($mid);
  98                 my $doc;
  99
 100                 if ($smsg) {
 101                         $smsg->ensure_metadata;
 102                         # convert a ghost to a regular message
 103                         # it will also clobber any existing regular message
 104                         $smsg->mime($mime);
 105                         $doc = $smsg->{doc};
 106
 107                         my $type = xpfx('type');
 108                         eval {
 109                                 $doc->remove_term($type . 'ghost');
 110                                 $was_ghost = 1;
 111                         };
 112
 113                         # probably does not exist:
 114                         eval { $doc->remove_term($type . 'mail') };
 115                         $doc->add_term($type . 'mail');
 116                 }  else {
 117                         $smsg = PublicInbox::SearchMsg->new($mime);
 118                         $doc = $smsg->{doc};
 119                         $doc->add_term(xpfx('mid') . $mid);
 120                 }
 121
 122                 my $subj = $mime->header('Subject');
 123                 $subj = '' unless defined $subj;
 124
 125                 if (length $subj) {
 126                         $doc->add_term(xpfx('subject') . $subj);
 127
 128                         my $path = subject_path($subj);
 129                         $doc->add_term(xpfx('path') . $path);
 130                 }
 131
 132                 my $from = $mime->header('From') || '';
 133                 my @from;
 134
 135                 if ($from) {
 136                         @from = Email::Address->parse($from);
 137                         $from = $from[0]->name;
 138                 }
 139
 140                 my $ts = eval { str2time($mime->header('Date')) } || 0;
 141                 my $date = POSIX::strftime('%Y-%m-%d %H:%M', gmtime($ts));
 142                 $ts = Search::Xapian::sortable_serialise($ts);
 143                 $doc->add_value(PublicInbox::Search::TS, $ts);
 144
 145                 # this is what we show in index results:
 146                 $subj =~ tr/\n/ /;
 147                 $from =~ tr/\n/ /;
 148                 $doc->set_data("$mid\n$subj\n$from\n$date");
 149
 150                 my $tg = $self->term_generator;
 151
 152                 $tg->set_document($doc);
 153                 $tg->index_text($subj, 1, 'S') if $subj;
 154                 $tg->increase_termpos;
 155                 $tg->index_text($subj) if $subj;
 156                 $tg->increase_termpos;
 157
 158                 if (@from) {
 159                         $tg->index_text($from[0]->format);
 160                         $tg->increase_termpos;
 161                 }
 162
 163                 $mime->walk_parts(sub {
 164                         my ($part) = @_;
 165                         return if $part->subparts; # walk_parts already recurses
 166                         my $ct = $part->content_type || $ct_msg;
 167
 168                         # account for filter bugs...
 169                         $ct =~ m!\btext/plain\b!i or return;
 170
 171                         my $enc = PublicInbox::View::enc_for($ct, $enc_msg);
 172                         my (@orig, @quot);
 173                         foreach my $l (split(/\n/, $enc->decode($part->body))) {
 174                                 if ($l =~ /^\s*>/) {
 175                                         push @quot, $l;
 176                                 } else {
 177                                         push @orig, $l;
 178                                 }
 179                         }
 180                         if (@quot) {
 181                                 $tg->index_text(join("\n", @quot), 0);
 182                                 $tg->increase_termpos;
 183                         }
 184                         if (@orig) {
 185                                 $tg->index_text(join("\n", @orig));
 186                                 $tg->increase_termpos;
 187                         }
 188                 });
 189
 190                 if ($was_ghost) {
 191                         $doc_id = $smsg->doc_id;
 192                         $self->link_message($smsg, 0);
 193                         $db->replace_document($doc_id, $doc);
 194                 } else {
 195                         $self->link_message($smsg, 0);
 196                         $doc_id = $db->add_document($doc);
 197                 }
 198         };
 199
 200         if ($@) {
 201                 warn "failed to index message <$mid>: $@\n";
 202                 $db->cancel_transaction;
 203         } else {
 204                 $db->commit_transaction;
 205         }
 206         $doc_id;
 207 }
 208
 209 # returns deleted doc_id on success, undef on missing
 210 sub remove_message {
 211         my ($self, $mid) = @_;
 212         my $db = $self->{xdb};
 213         my $doc_id;
 214         $mid = clean_mid($mid);
 215         $mid = mid_compressed($mid);
 216
 217         $db->begin_transaction;
 218         eval {
 219                 $doc_id = $self->find_unique_doc_id('mid', $mid);
 220                 $db->delete_document($doc_id) if defined $doc_id;
 221         };
 222
 223         if ($@) {
 224                 warn "failed to remove message <$mid>: $@\n";
 225                 $db->cancel_transaction;
 226         } else {
 227                 $db->commit_transaction;
 228         }
 229         $doc_id;
 230 }
 231
 232 # read-only
 233 sub query {
 234         my ($self, $query_string, $opts) = @_;
 235         my $query = $self->qp->parse_query($query_string, QP_FLAGS);
 236
 237         $query = Search::Xapian::Query->new(OP_AND, $mail_query, $query);
 238         $self->do_enquire($query, $opts);
 239 }
 240
 241 # given a message ID, get replies to a message
 242 sub get_replies {
 243         my ($self, $mid, $opts) = @_;
 244         $mid = clean_mid($mid);
 245         $mid = mid_compressed($mid);
 246         my $qp = $self->qp;
 247         my $irt = $qp->parse_query("inreplyto:$mid", 0);
 248         my $ref = $qp->parse_query("references:$mid", 0);
 249         my $query = Search::Xapian::Query->new(OP_OR, $irt, $ref);
 250
 251         $self->do_enquire($query);
 252 }
 253
 254 sub get_thread {
 255         my ($self, $mid, $opts) = @_;
 256         my $smsg = eval { $self->lookup_message($mid) };
 257
 258         return { count => 0, msgs => [] } unless $smsg;
 259         my $qp = $self->qp;
 260         my $qtid = $qp->parse_query('thread:'.$smsg->thread_id);
 261         my $qsub = $qp->parse_query('path:'.$smsg->path);
 262         my $query = Search::Xapian::Query->new(OP_OR, $qtid, $qsub);
 263         $self->do_enquire($query);
 264 }
 265
 266 # private subs below
 267
 268 sub do_enquire {
 269         my ($self, $query, $opts) = @_;
 270         my $enquire = $self->enquire;
 271
 272         $enquire->set_query($query);
 273         $enquire->set_sort_by_relevance_then_value(TS, 0);
 274         $opts ||= {};
 275         my $offset = $opts->{offset} || 0;
 276         my $limit = $opts->{limit} || 50;
 277         my $mset = $enquire->get_mset($offset, $limit);
 278         my @msgs = map { $_->get_document->get_data } $mset->items;
 279
 280         { count => $mset->get_matches_estimated, msgs => \@msgs }
 281 }
 282
 283 # read-write
 284 sub stemmer { Search::Xapian::Stem->new(LANG) }
 285
 286 # read-only
 287 sub qp {
 288         my ($self) = @_;
 289
 290         my $qp = $self->{query_parser};
 291         return $qp if $qp;
 292
 293         # new parser
 294         $qp = Search::Xapian::QueryParser->new;
 295         $qp->set_default_op(OP_AND);
 296         $qp->set_database($self->{xdb});
 297         $qp->set_stemmer($self->stemmer);
 298         $qp->set_stemming_strategy(STEM_SOME);
 299         $qp->add_valuerangeprocessor($self->ts_range_processor);
 300         $qp->add_valuerangeprocessor($self->date_range_processor);
 301
 302         while (my ($name, $prefix) = each %bool_pfx_external) {
 303                 $qp->add_boolean_prefix($name, $prefix);
 304         }
 305
 306         while (my ($name, $prefix) = each %prob_prefix) {
 307                 $qp->add_prefix($name, $prefix);
 308         }
 309
 310         $self->{query_parser} = $qp;
 311 }
 312
 313 sub term_generator { # write-only
 314         my ($self) = @_;
 315
 316         my $tg = $self->{term_generator};
 317         return $tg if $tg;
 318
 319         $tg = Search::Xapian::TermGenerator->new;
 320         $tg->set_stemmer($self->stemmer);
 321
 322         $self->{term_generator} = $tg;
 323 }
 324
 325 sub next_doc_id { $_[0]->{xdb}->get_lastdocid + 1 }
 326
 327 # increments last_thread_id counter
 328 # returns a 64-bit integer represented as a hex string
 329 sub next_thread_id {
 330         my ($self) = @_;
 331         my $db = $self->{xdb};
 332         my $last_thread_id = int($db->get_metadata('last_thread_id') || 0);
 333
 334         $db->set_metadata('last_thread_id', ++$last_thread_id);
 335
 336         $last_thread_id;
 337 }
 338
 339 sub ts_range_processor {
 340         $_[0]->{tsrp} ||= Search::Xapian::NumberValueRangeProcessor->new(TS);
 341 }
 342
 343 sub date_range_processor {
 344         $_[0]->{drp} ||= Search::Xapian::DateValueRangeProcessor->new(TS);
 345 }
 346
 347 sub clean_mid {
 348         my ($mid) = @_;
 349         defined($mid) or die "no Message-ID";
 350         # MDA->precheck did more checking for us
 351         $mid =~ s/\A\s*<?//;
 352         $mid =~ s/>?\s*\z//;
 353         $mid;
 354 }
 355
 356 sub link_message {
 357         my ($self, $smsg, $is_ghost) = @_;
 358
 359         if ($is_ghost) {
 360                 $smsg->ensure_metadata;
 361         } else {
 362                 $self->link_message_to_parents($smsg);
 363         }
 364 }
 365
 366 sub link_message_to_parents {
 367         my ($self, $smsg) = @_;
 368         my $doc = $smsg->{doc};
 369         my $mid = mid_compressed($smsg->mid);
 370         my $mime = $smsg->mime;
 371         my $refs = $mime->header('References');
 372         my @refs = $refs ? ($refs =~ /<([^>]+)>/g) : ();
 373         my $irt = $mime->header('In-Reply-To');
 374         if ($irt) {
 375                 if ($irt =~ /<([^>]+)>/) {
 376                         $irt = $1;
 377                 }
 378                 push @refs, $irt;
 379         }
 380
 381         my $tid;
 382         if (@refs) {
 383                 @refs = map { mid_compressed($_) } @refs;
 384                 my %uniq;
 385                 @refs = grep { !$uniq{$_}++ } @refs; # uniq
 386
 387                 $doc->add_term(xpfx('inreplyto') . $refs[-1]);
 388
 389                 my $ref_pfx = xpfx('references');
 390
 391                 # first ref *should* be the thread root,
 392                 # but we can never trust clients to do the right thing
 393                 my $ref = shift @refs;
 394                 $doc->add_term($ref_pfx . $ref);
 395                 $tid = $self->_resolve_mid_to_tid($ref);
 396
 397                 # the rest of the refs should point to this tid:
 398                 foreach $ref (@refs) {
 399                         $doc->add_term($ref_pfx . $ref);
 400                         my $ptid = $self->_resolve_mid_to_tid($ref);
 401                         if ($tid ne $ptid) {
 402                                 $self->merge_threads($tid, $ptid);
 403                         }
 404                 }
 405         } else {
 406                 $tid = $self->next_thread_id;
 407         }
 408         $doc->add_term(xpfx('thread') . $tid);
 409 }
 410
 411 sub lookup_message {
 412         my ($self, $mid) = @_;
 413         $mid = clean_mid($mid);
 414         $mid = mid_compressed($mid);
 415
 416         my $doc_id = $self->find_unique_doc_id('mid', $mid);
 417         my $smsg;
 418         if (defined $doc_id) {
 419                 # raises on error:
 420                 my $doc = $self->{xdb}->get_document($doc_id);
 421                 $smsg = PublicInbox::SearchMsg->wrap($doc, $mid);
 422                 $smsg->doc_id($doc_id);
 423         }
 424         $smsg;
 425 }
 426
 427 sub find_unique_doc_id {
 428         my ($self, $term, $value) = @_;
 429
 430         my ($begin, $end) = $self->find_doc_ids($term, $value);
 431
 432         return undef if $begin->equal($end); # not found
 433
 434         my $rv = $begin->get_docid;
 435
 436         # sanity check
 437         $begin->inc;
 438         $begin->equal($end) or die "Term '$term:$value' is not unique\n";
 439         $rv;
 440 }
 441
 442 # returns begin and end PostingIterator
 443 sub find_doc_ids {
 444         my ($self, $term, $value) = @_;
 445
 446         $self->find_doc_ids_for_term(xpfx($term) . $value);
 447 }
 448
 449 # returns begin and end PostingIterator
 450 sub find_doc_ids_for_term {
 451         my ($self, $term) = @_;
 452         my $db = $self->{xdb};
 453
 454         ($db->postlist_begin($term), $db->postlist_end($term));
 455 }
 456
 457 # this will create a ghost as necessary
 458 sub _resolve_mid_to_tid {
 459         my ($self, $mid) = @_;
 460
 461         my $smsg = $self->lookup_message($mid) || $self->create_ghost($mid);
 462         $smsg->thread_id;
 463 }
 464
 465 sub create_ghost {
 466         my ($self, $mid, $tid) = @_;
 467
 468         $mid = mid_compressed($mid);
 469         $tid = $self->next_thread_id unless defined $tid;
 470
 471         my $doc = Search::Xapian::Document->new;
 472         $doc->add_term(xpfx('mid') . $mid);
 473         $doc->add_term(xpfx('thread') . $tid);
 474         $doc->add_term(xpfx('type') . 'ghost');
 475
 476         my $smsg = PublicInbox::SearchMsg->wrap($doc, $mid);
 477         $self->link_message($smsg, 1);
 478         $self->{xdb}->add_document($doc);
 479
 480         $smsg;
 481 }
 482
 483 sub merge_threads {
 484         my ($self, $winner_tid, $loser_tid) = @_;
 485         my ($head, $tail) = $self->find_doc_ids('thread', $loser_tid);
 486         my $thread_pfx = xpfx('thread');
 487         my $db = $self->{xdb};
 488
 489         for (; $head != $tail; $head->inc) {
 490                 my $docid = $head->get_docid;
 491                 my $doc = $db->get_document($docid);
 492                 $doc->remove_term($thread_pfx . $loser_tid);
 493                 $doc->add_term($thread_pfx . $winner_tid);
 494                 $db->replace_document($docid, $doc);
 495         }
 496 }
 497
 498 # normalize subjects so they are suitable as pathnames for URLs
 499 sub subject_path {
 500         my ($subj) = @_;
 501
 502         $subj =~ s/\A\s+//;
 503         $subj =~ s/\s+\z//;
 504         $subj =~ s/^(?:re|aw):\s*//i; # remove reply prefix (aw: German)
 505         $subj =~ s![^a-zA-Z0-9_\.~/\-]+!_!g;
 506         $subj;
 507 }
 508
 509 sub do_cat_mail {
 510         my ($git, $blob) = @_;
 511         my $mime = eval {
 512                 my $str = $git->cat_file($blob);
 513                 Email::MIME->new($str);
 514         };
 515         $@ ? undef : $mime;
 516 }
 517
 518 sub index_blob {
 519         my ($self, $git, $blob) = @_;
 520         my $mime = do_cat_mail($git, $blob) or return;
 521         eval { $self->add_message($mime) };
 522         warn "W: index_blob $blob: $@\n" if $@;
 523 }
 524
 525 sub unindex_blob {
 526         my ($self, $git, $blob) = @_;
 527         my $mime = do_cat_mail($git, $blob) or return;
 528         my $mid = $mime->header('Message-ID');
 529         eval { $self->remove_message($mid) } if defined $mid;
 530         warn "W: unindex_blob $blob: $@\n" if $@;
 531 }
 532
 533 sub enquire {
 534         my ($self) = @_;
 535         $self->{enquire} ||= Search::Xapian::Enquire->new($self->{xdb});
 536 }
 537
 538 # indexes all unindexed messages
 539 sub index_sync {
 540         my ($self, $git) = @_;
 541         my $db = $self->{xdb};
 542         my $latest = $db->get_metadata('last_commit');
 543         my $range = length $latest ? "$latest..HEAD" : 'HEAD';
 544         $latest = undef;
 545
 546         my $hex = '[a-f0-9]';
 547         my $h40 = $hex .'{40}';
 548         my $addmsg = qr!^:000000 100644 \S+ ($h40) A\t${hex}{2}/${hex}{38}$!;
 549         my $delmsg = qr!^:100644 000000 ($h40) \S+ D\t${hex}{2}/${hex}{38}$!;
 550
 551         # get indexed messages
 552         my @cmd = ('git', "--git-dir=$git->{git_dir}", "log",
 553                     qw/--reverse --no-notes --no-color --raw -r --no-abbrev/,
 554                     $range);
 555
 556         my $pid = open(my $log, '-|', @cmd) or
 557                 die('open` '.join(' ', @cmd) . " pipe failed: $!\n");
 558         my $last;
 559         while (my $line = <$log>) {
 560                 if ($line =~ /$addmsg/o) {
 561                         $self->index_blob($git, $1);
 562                 } elsif ($line =~ /$delmsg/o) {
 563                         $self->unindex_blob($git, $1);
 564                 } elsif ($line =~ /^commit ($h40)/o) {
 565                         my $commit = $1;
 566                         if (defined $latest) {
 567                                 $db->set_metadata('last_commit', $latest)
 568                         }
 569                         $latest = $commit;
 570                 }
 571         }
 572         close $log;
 573         $db->set_metadata('last_commit', $latest) if defined $latest;
 574 }
 575
 576 1;