lib/PublicInbox/Search.pm

   1 # Copyright (C) 2015-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 # based on notmuch, but with no concept of folders, files or flags
   4 #
   5 # Read-only search interface for use by the web and NNTP interfaces
   6 package PublicInbox::Search;
   7 use strict;
   8 use parent qw(Exporter);
   9 our @EXPORT_OK = qw(retry_reopen int_val);
  10 use List::Util qw(max);
  11
  12 # values for searching, changing the numeric value breaks
  13 # compatibility with old indices (so don't change them it)
  14 use constant {
  15         TS => 0, # Received: header in Unix time (IMAP INTERNALDATE)
  16         YYYYMMDD => 1, # Date: header for searching in the WWW UI
  17         DT => 2, # Date: YYYYMMDDHHMMSS
  18
  19         # added for public-inbox 1.6.0+
  20         BYTES => 3, # IMAP RFC822.SIZE
  21         UID => 4, # IMAP UID == NNTP article number == Xapian docid
  22         THREADID => 5, # RFC 8474, RFC 8621
  23
  24         # TODO
  25         # REPLYCNT => ?, # IMAP ANSWERED
  26
  27         # SCHEMA_VERSION history
  28         # 0 - initial
  29         # 1 - subject_path is lower-cased
  30         # 2 - subject_path is id_compress in the index, only
  31         # 3 - message-ID is compressed if it includes '%' (hack!)
  32         # 4 - change "Re: " normalization, avoid circular Reference ghosts
  33         # 5 - subject_path drops trailing '.'
  34         # 6 - preserve References: order in document data
  35         # 7 - remove references and inreplyto terms
  36         # 8 - remove redundant/unneeded document data
  37         # 9 - disable Message-ID compression (SHA-1)
  38         # 10 - optimize doc for NNTP overviews
  39         # 11 - merge threads when vivifying ghosts
  40         # 12 - change YYYYMMDD value column to numeric
  41         # 13 - fix threading for empty References/In-Reply-To
  42         #      (commit 83425ef12e4b65cdcecd11ddcb38175d4a91d5a0)
  43         # 14 - fix ghost root vivification
  44         # 15 - see public-inbox-v2-format(5)
  45         #      further bumps likely unnecessary, we'll suggest in-place
  46         #      "--reindex" use for further fixes and tweaks:
  47         #
  48         #      public-inbox v1.5.0 adds (still SCHEMA_VERSION=15):
  49         #      * "lid:" and "l:" for List-Id searches
  50         #
  51         #      v1.6.0 adds BYTES, UID and THREADID values
  52         SCHEMA_VERSION => 15,
  53 };
  54
  55 use PublicInbox::Smsg;
  56 use PublicInbox::Over;
  57 our $QP_FLAGS;
  58 our %X = map { $_ => 0 } qw(BoolWeight Database Enquire QueryParser Stem Query);
  59 our $Xap; # 'Search::Xapian' or 'Xapian'
  60 our $NVRP; # '$Xap::'.('NumberValueRangeProcessor' or 'NumberRangeProcessor')
  61
  62 # ENQ_DESCENDING and ENQ_ASCENDING weren't in SWIG Xapian.pm prior to 1.4.16,
  63 # let's hope the ABI is stable
  64 our $ENQ_DESCENDING = 0;
  65 our $ENQ_ASCENDING = 1;
  66
  67 sub load_xapian () {
  68         return 1 if defined $Xap;
  69         # n.b. PI_XAPIAN is intended for development use only.  We still
  70         # favor Search::Xapian since that's what's available in current
  71         # Debian stable (10.x) and derived distros.
  72         for my $x (($ENV{PI_XAPIAN} // 'Search::Xapian'), 'Xapian') {
  73                 eval "require $x";
  74                 next if $@;
  75
  76                 $x->import(qw(:standard));
  77                 $Xap = $x;
  78
  79                 # `version_string' was added in Xapian 1.1
  80                 my $xver = eval('v'.eval($x.'::version_string()')) //
  81                                 eval('v'.eval($x.'::xapian_version_string()'));
  82
  83                 # NumberRangeProcessor was added in Xapian 1.3.6,
  84                 # NumberValueRangeProcessor was removed for 1.5.0+,
  85                 # favor the older /Value/ variant since that's what our
  86                 # (currently) preferred Search::Xapian supports
  87                 $NVRP = $x.'::'.($x eq 'Xapian' && $xver ge v1.5 ?
  88                         'NumberRangeProcessor' : 'NumberValueRangeProcessor');
  89                 $X{$_} = $Xap.'::'.$_ for (keys %X);
  90
  91                 *sortable_serialise = $x.'::sortable_serialise';
  92                 *sortable_unserialise = $x.'::sortable_unserialise';
  93                 # n.b. FLAG_PURE_NOT is expensive not suitable for a public
  94                 # website as it could become a denial-of-service vector
  95                 # FLAG_PHRASE also seems to cause performance problems chert
  96                 # (and probably earlier Xapian DBs).  glass seems fine...
  97                 # TODO: make this an option, maybe?
  98                 # or make indexlevel=medium as default
  99                 $QP_FLAGS = FLAG_PHRASE() | FLAG_BOOLEAN() | FLAG_LOVEHATE() |
 100                                 FLAG_WILDCARD();
 101                 return 1;
 102         }
 103         undef;
 104 }
 105
 106 # This is English-only, everything else is non-standard and may be confused as
 107 # a prefix common in patch emails
 108 our $LANG = 'english';
 109
 110 # note: the non-X term prefix allocations are shared with
 111 # Xapian omega, see xapian-applications/omega/docs/termprefixes.rst
 112 my %bool_pfx_external = (
 113         mid => 'Q', # Message-ID (full/exact), this is mostly uniQue
 114         lid => 'G', # newsGroup (or similar entity), just inside <>
 115         dfpre => 'XDFPRE',
 116         dfpost => 'XDFPOST',
 117         dfblob => 'XDFPRE XDFPOST',
 118 );
 119
 120 my $non_quoted_body = 'XNQ XDFN XDFA XDFB XDFHH XDFCTX XDFPRE XDFPOST';
 121 my %prob_prefix = (
 122         # for mairix compatibility
 123         s => 'S',
 124         m => 'XM', # 'mid:' (bool) is exact, 'm:' (prob) can do partial
 125         l => 'XL', # 'lid:' (bool) is exact, 'l:' (prob) can do partial
 126         f => 'A',
 127         t => 'XTO',
 128         tc => 'XTO XCC',
 129         c => 'XCC',
 130         tcf => 'XTO XCC A',
 131         a => 'XTO XCC A',
 132         b => $non_quoted_body . ' XQUOT',
 133         bs => $non_quoted_body . ' XQUOT S',
 134         n => 'XFN',
 135
 136         q => 'XQUOT',
 137         nq => $non_quoted_body,
 138         dfn => 'XDFN',
 139         dfa => 'XDFA',
 140         dfb => 'XDFB',
 141         dfhh => 'XDFHH',
 142         dfctx => 'XDFCTX',
 143
 144         # default:
 145         '' => 'XM S A XQUOT XFN ' . $non_quoted_body,
 146 );
 147
 148 # not documenting m: and mid: for now, the using the URLs works w/o Xapian
 149 # not documenting lid: for now, either, it is probably redundant with l:,
 150 # especially since we don't offer boolean searches for To/Cc/From
 151 # headers, either
 152 our @HELP = (
 153         's:' => 'match within Subject  e.g. s:"a quick brown fox"',
 154         'd:' => <<EOF,
 155 date range as YYYYMMDD  e.g. d:19931002..20101002
 156 Open-ended ranges such as d:19931002.. and d:..20101002
 157 are also supported
 158 EOF
 159         'dt:' => <<EOF,
 160 date-time range as YYYYMMDDhhmmss (e.g. dt:19931002011000..19931002011200)
 161 EOF
 162         'b:' => 'match within message body, including text attachments',
 163         'nq:' => 'match non-quoted text within message body',
 164         'q:' => 'match quoted text within message body',
 165         'n:' => 'match filename of attachment(s)',
 166         't:' => 'match within the To header',
 167         'c:' => 'match within the Cc header',
 168         'f:' => 'match within the From header',
 169         'a:' => 'match within the To, Cc, and From headers',
 170         'tc:' => 'match within the To and Cc headers',
 171         'l:' => 'match contents of the List-Id header',
 172         'bs:' => 'match within the Subject and body',
 173         'dfn:' => 'match filename from diff',
 174         'dfa:' => 'match diff removed (-) lines',
 175         'dfb:' => 'match diff added (+) lines',
 176         'dfhh:' => 'match diff hunk header context (usually a function name)',
 177         'dfctx:' => 'match diff context lines',
 178         'dfpre:' => 'match pre-image git blob ID',
 179         'dfpost:' => 'match post-image git blob ID',
 180         'dfblob:' => 'match either pre or post-image git blob ID',
 181 );
 182 chomp @HELP;
 183
 184 sub xdir ($;$) {
 185         my ($self, $rdonly) = @_;
 186         if ($rdonly || !defined($self->{shard})) {
 187                 $self->{xpfx};
 188         } else { # v2 only:
 189                 "$self->{xpfx}/$self->{shard}";
 190         }
 191 }
 192
 193 # returns all shards as separate Xapian::Database objects w/o combining
 194 sub xdb_shards_flat ($) {
 195         my ($self) = @_;
 196         my $xpfx = $self->{xpfx};
 197         my (@xdb, $slow_phrase);
 198         load_xapian();
 199         if ($xpfx =~ m/xapian${\SCHEMA_VERSION}\z/) {
 200                 @xdb = ($X{Database}->new($xpfx));
 201                 $self->{qp_flags} |= FLAG_PHRASE() if !-f "$xpfx/iamchert";
 202         } else {
 203                 opendir(my $dh, $xpfx) or return (); # not initialized yet
 204                 # We need numeric sorting so shard[0] is first for reading
 205                 # Xapian metadata, if needed
 206                 my $last = max(grep(/\A[0-9]+\z/, readdir($dh))) // return ();
 207                 for (0..$last) {
 208                         my $shard_dir = "$self->{xpfx}/$_";
 209                         push @xdb, $X{Database}->new($shard_dir);
 210                         $slow_phrase ||= -f "$shard_dir/iamchert";
 211                 }
 212                 $self->{qp_flags} |= FLAG_PHRASE() if !$slow_phrase;
 213         }
 214         @xdb;
 215 }
 216
 217 # v2 Xapian docids don't conflict, so they're identical to
 218 # NNTP article numbers and IMAP UIDs.
 219 # https://trac.xapian.org/wiki/FAQ/MultiDatabaseDocumentID
 220 sub mdocid {
 221         my ($nshard, $mitem) = @_;
 222         my $docid = $mitem->get_docid;
 223         int(($docid - 1) / $nshard) + 1;
 224 }
 225
 226 sub mset_to_artnums {
 227         my ($self, $mset) = @_;
 228         my $nshard = $self->{nshard};
 229         [ map { mdocid($nshard, $_) } $mset->items ];
 230 }
 231
 232 sub xdb ($) {
 233         my ($self) = @_;
 234         $self->{xdb} //= do {
 235                 $self->{qp_flags} //= $QP_FLAGS;
 236                 my @xdb = $self->xdb_shards_flat or return;
 237                 $self->{nshard} = scalar(@xdb);
 238                 my $xdb = shift @xdb;
 239                 $xdb->add_database($_) for @xdb;
 240                 $xdb;
 241         };
 242 }
 243
 244 sub new {
 245         my ($class, $ibx) = @_;
 246         ref $ibx or die "BUG: expected PublicInbox::Inbox object: $ibx";
 247         my $xap = $ibx->version > 1 ? 'xap' : 'public-inbox/xapian';
 248         bless {
 249                 xpfx => "$ibx->{inboxdir}/$xap" . SCHEMA_VERSION,
 250                 altid => $ibx->{altid},
 251         }, $class;
 252 }
 253
 254 sub reopen {
 255         my ($self) = @_;
 256         if (my $xdb = $self->{xdb}) {
 257                 $xdb->reopen;
 258         }
 259         $self; # make chaining easier
 260 }
 261
 262 # read-only
 263 sub mset {
 264         my ($self, $query_string, $opts) = @_;
 265         $opts ||= {};
 266         my $qp = $self->{qp} //= qparse_new($self);
 267         my $query = $qp->parse_query($query_string, $self->{qp_flags});
 268         _do_enquire($self, $query, $opts);
 269 }
 270
 271 sub retry_reopen {
 272         my ($self, $cb, @arg) = @_;
 273         for my $i (1..10) {
 274                 if (wantarray) {
 275                         my @ret;
 276                         eval { @ret = $cb->($self, @arg) };
 277                         return @ret unless $@;
 278                 } else {
 279                         my $ret;
 280                         eval { $ret = $cb->($self, @arg) };
 281                         return $ret unless $@;
 282                 }
 283                 # Exception: The revision being read has been discarded -
 284                 # you should call Xapian::Database::reopen()
 285                 if (ref($@) =~ /\bDatabaseModifiedError\b/) {
 286                         warn "reopen try #$i on $@\n";
 287                         reopen($self);
 288                 } else {
 289                         # let caller decide how to spew, because ExtMsg queries
 290                         # get wonky and trigger:
 291                         # "something terrible happened at .../Xapian/Enquire.pm"
 292                         die;
 293                 }
 294         }
 295         die "Too many Xapian database modifications in progress\n";
 296 }
 297
 298 sub _do_enquire {
 299         my ($self, $query, $opts) = @_;
 300         retry_reopen($self, \&_enquire_once, $query, $opts);
 301 }
 302
 303 # returns true if all docs have the THREADID value
 304 sub has_threadid ($) {
 305         my ($self) = @_;
 306         (xdb($self)->get_metadata('has_threadid') // '') eq '1';
 307 }
 308
 309 sub _enquire_once { # retry_reopen callback
 310         my ($self, $query, $opts) = @_;
 311         my $xdb = xdb($self);
 312         if (defined(my $eidx_key = $opts->{eidx_key})) {
 313                 $query = $X{Query}->new(OP_FILTER(), $query, 'O'.$eidx_key);
 314         }
 315         if (defined(my $uid_range = $opts->{uid_range})) {
 316                 my $range = $X{Query}->new(OP_VALUE_RANGE(), UID,
 317                                         sortable_serialise($uid_range->[0]),
 318                                         sortable_serialise($uid_range->[1]));
 319                 $query = $X{Query}->new(OP_FILTER(), $query, $range);
 320         }
 321         my $enquire = $X{Enquire}->new($xdb);
 322         $enquire->set_query($query);
 323         $opts ||= {};
 324         my $desc = !$opts->{asc};
 325         my $rel = $opts->{relevance} // 0;
 326         if ($rel == -1) { # ORDER BY docid/UID
 327                 $enquire->set_weighting_scheme($X{BoolWeight}->new);
 328                 $enquire->set_docid_order($ENQ_ASCENDING);
 329         } elsif ($rel == 0) {
 330                 $enquire->set_sort_by_value_then_relevance(TS, $desc);
 331         } elsif ($rel == -2) {
 332                 $enquire->set_weighting_scheme($X{BoolWeight}->new);
 333                 $enquire->set_docid_order($ENQ_DESCENDING);
 334         } else { # rel > 0
 335                 $enquire->set_sort_by_relevance_then_value(TS, $desc);
 336         }
 337
 338         # `mairix -t / --threads' or JMAP collapseThreads
 339         if ($opts->{thread} && has_threadid($self)) {
 340                 $enquire->set_collapse_key(THREADID);
 341         }
 342         $enquire->get_mset($opts->{offset} || 0, $opts->{limit} || 50);
 343 }
 344
 345 sub mset_to_smsg {
 346         my ($self, $ibx, $mset) = @_;
 347         my $nshard = $self->{nshard};
 348         my $i = 0;
 349         my %order = map { mdocid($nshard, $_) => ++$i } $mset->items;
 350         my @msgs = sort {
 351                 $order{$a->{num}} <=> $order{$b->{num}}
 352         } @{$ibx->over->get_all(keys %order)};
 353         wantarray ? ($mset->get_matches_estimated, \@msgs) : \@msgs;
 354 }
 355
 356 # read-write
 357 sub stemmer { $X{Stem}->new($LANG) }
 358
 359 # read-only
 360 sub qparse_new ($) {
 361         my ($self) = @_;
 362
 363         my $xdb = xdb($self);
 364         my $qp = $X{QueryParser}->new;
 365         $qp->set_default_op(OP_AND());
 366         $qp->set_database($xdb);
 367         $qp->set_stemmer(stemmer($self));
 368         $qp->set_stemming_strategy(STEM_SOME());
 369         my $cb = $qp->can('set_max_wildcard_expansion') //
 370                 $qp->can('set_max_expansion'); # Xapian 1.5.0+
 371         $cb->($qp, 100);
 372         $cb = $qp->can('add_valuerangeprocessor') //
 373                 $qp->can('add_rangeprocessor'); # Xapian 1.5.0+
 374         $cb->($qp, $NVRP->new(YYYYMMDD, 'd:'));
 375         $cb->($qp, $NVRP->new(DT, 'dt:'));
 376
 377         # for IMAP, undocumented for WWW and may be split off go away
 378         $cb->($qp, $NVRP->new(BYTES, 'bytes:'));
 379         $cb->($qp, $NVRP->new(TS, 'ts:'));
 380         $cb->($qp, $NVRP->new(UID, 'uid:'));
 381
 382         while (my ($name, $prefix) = each %bool_pfx_external) {
 383                 $qp->add_boolean_prefix($name, $_) foreach split(/ /, $prefix);
 384         }
 385
 386         # we do not actually create AltId objects,
 387         # just parse the spec to avoid the extra DB handles for now.
 388         if (my $altid = $self->{altid}) {
 389                 my $user_pfx = $self->{-user_pfx} = [];
 390                 for (@$altid) {
 391                         # $_ = 'serial:gmane:/path/to/gmane.msgmap.sqlite3'
 392                         # note: Xapian supports multibyte UTF-8, /^[0-9]+$/,
 393                         # and '_' with prefixes matching \w+
 394                         /\Aserial:(\w+):/ or next;
 395                         my $pfx = $1;
 396                         push @$user_pfx, "$pfx:", <<EOF;
 397 alternate serial number  e.g. $pfx:12345 (boolean)
 398 EOF
 399                         # gmane => XGMANE
 400                         $qp->add_boolean_prefix($pfx, 'X'.uc($pfx));
 401                 }
 402                 chomp @$user_pfx;
 403         }
 404
 405         while (my ($name, $prefix) = each %prob_prefix) {
 406                 $qp->add_prefix($name, $_) foreach split(/ /, $prefix);
 407         }
 408         $qp;
 409 }
 410
 411 sub help {
 412         my ($self) = @_;
 413         $self->{qp} //= qparse_new($self); # parse altids
 414         my @ret = @HELP;
 415         if (my $user_pfx = $self->{-user_pfx}) {
 416                 push @ret, @$user_pfx;
 417         }
 418         \@ret;
 419 }
 420
 421 sub int_val ($$) {
 422         my ($doc, $col) = @_;
 423         my $val = $doc->get_value($col) or return; # undefined is '' in Xapian
 424         sortable_unserialise($val) + 0; # PV => IV conversion
 425 }
 426
 427 1;