lib/PublicInbox/Search.pm

   1 # Copyright (C) all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 # based on notmuch, but with no concept of folders, files or flags
   4 #
   5 # Read-only search interface for use by the web and NNTP interfaces
   6 package PublicInbox::Search;
   7 use strict;
   8 use v5.10.1;
   9 use parent qw(Exporter);
  10 our @EXPORT_OK = qw(retry_reopen int_val get_pct xap_terms);
  11 use List::Util qw(max);
  12 use POSIX qw(strftime);
  13 use Carp ();
  14
  15 # values for searching, changing the numeric value breaks
  16 # compatibility with old indices (so don't change them it)
  17 use constant {
  18         TS => 0, # Received: in Unix time (IMAP INTERNALDATE, JMAP receivedAt)
  19         YYYYMMDD => 1, # redundant with DT below
  20         DT => 2, # Date: YYYYMMDDHHMMSS (IMAP SENT*, JMAP sentAt)
  21
  22         # added for public-inbox 1.6.0+
  23         BYTES => 3, # IMAP RFC822.SIZE
  24         UID => 4, # IMAP UID == NNTP article number == Xapian docid
  25         THREADID => 5, # RFC 8474, RFC 8621
  26
  27         # TODO
  28         # REPLYCNT => ?, # IMAP ANSWERED
  29
  30         # SCHEMA_VERSION history
  31         # 0 - initial
  32         # 1 - subject_path is lower-cased
  33         # 2 - subject_path is id_compress in the index, only
  34         # 3 - message-ID is compressed if it includes '%' (hack!)
  35         # 4 - change "Re: " normalization, avoid circular Reference ghosts
  36         # 5 - subject_path drops trailing '.'
  37         # 6 - preserve References: order in document data
  38         # 7 - remove references and inreplyto terms
  39         # 8 - remove redundant/unneeded document data
  40         # 9 - disable Message-ID compression (SHA-1)
  41         # 10 - optimize doc for NNTP overviews
  42         # 11 - merge threads when vivifying ghosts
  43         # 12 - change YYYYMMDD value column to numeric
  44         # 13 - fix threading for empty References/In-Reply-To
  45         #      (commit 83425ef12e4b65cdcecd11ddcb38175d4a91d5a0)
  46         # 14 - fix ghost root vivification
  47         # 15 - see public-inbox-v2-format(5)
  48         #      further bumps likely unnecessary, we'll suggest in-place
  49         #      "--reindex" use for further fixes and tweaks:
  50         #
  51         #      public-inbox v1.5.0 adds (still SCHEMA_VERSION=15):
  52         #      * "lid:" and "l:" for List-Id searches
  53         #
  54         #      v1.6.0 adds BYTES, UID and THREADID values
  55         SCHEMA_VERSION => 15,
  56 };
  57
  58 use PublicInbox::Smsg;
  59 use PublicInbox::Over;
  60 our $QP_FLAGS;
  61 our %X = map { $_ => 0 } qw(BoolWeight Database Enquire QueryParser Stem Query);
  62 our $Xap; # 'Search::Xapian' or 'Xapian'
  63 our $NVRP; # '$Xap::'.('NumberValueRangeProcessor' or 'NumberRangeProcessor')
  64
  65 # ENQ_DESCENDING and ENQ_ASCENDING weren't in SWIG Xapian.pm prior to 1.4.16,
  66 # let's hope the ABI is stable
  67 our $ENQ_DESCENDING = 0;
  68 our $ENQ_ASCENDING = 1;
  69
  70 sub load_xapian () {
  71         return 1 if defined $Xap;
  72         # n.b. PI_XAPIAN is intended for development use only.  We still
  73         # favor Search::Xapian since that's what's available in current
  74         # Debian stable (10.x) and derived distros.
  75         for my $x (($ENV{PI_XAPIAN} // 'Search::Xapian'), 'Xapian') {
  76                 eval "require $x";
  77                 next if $@;
  78
  79                 $x->import(qw(:standard));
  80                 $Xap = $x;
  81
  82                 # `version_string' was added in Xapian 1.1
  83                 my $xver = eval('v'.eval($x.'::version_string()')) //
  84                                 eval('v'.eval($x.'::xapian_version_string()'));
  85
  86                 # NumberRangeProcessor was added in Xapian 1.3.6,
  87                 # NumberValueRangeProcessor was removed for 1.5.0+,
  88                 # favor the older /Value/ variant since that's what our
  89                 # (currently) preferred Search::Xapian supports
  90                 $NVRP = $x.'::'.($x eq 'Xapian' && $xver ge v1.5 ?
  91                         'NumberRangeProcessor' : 'NumberValueRangeProcessor');
  92                 $X{$_} = $Xap.'::'.$_ for (keys %X);
  93
  94                 *sortable_serialise = $x.'::sortable_serialise';
  95                 *sortable_unserialise = $x.'::sortable_unserialise';
  96                 # n.b. FLAG_PURE_NOT is expensive not suitable for a public
  97                 # website as it could become a denial-of-service vector
  98                 # FLAG_PHRASE also seems to cause performance problems chert
  99                 # (and probably earlier Xapian DBs).  glass seems fine...
 100                 # TODO: make this an option, maybe?
 101                 # or make indexlevel=medium as default
 102                 $QP_FLAGS = FLAG_PHRASE() | FLAG_BOOLEAN() | FLAG_LOVEHATE() |
 103                                 FLAG_WILDCARD();
 104                 return 1;
 105         }
 106         undef;
 107 }
 108
 109 # This is English-only, everything else is non-standard and may be confused as
 110 # a prefix common in patch emails
 111 our $LANG = 'english';
 112
 113 # note: the non-X term prefix allocations are shared with
 114 # Xapian omega, see xapian-applications/omega/docs/termprefixes.rst
 115 my %bool_pfx_external = (
 116         mid => 'Q', # Message-ID (full/exact), this is mostly uniQue
 117         lid => 'G', # newsGroup (or similar entity), just inside <>
 118         dfpre => 'XDFPRE',
 119         dfpost => 'XDFPOST',
 120         dfblob => 'XDFPRE XDFPOST',
 121         patchid => 'XDFID',
 122 );
 123
 124 my $non_quoted_body = 'XNQ XDFN XDFA XDFB XDFHH XDFCTX XDFPRE XDFPOST XDFID';
 125 my %prob_prefix = (
 126         # for mairix compatibility
 127         s => 'S',
 128         m => 'XM', # 'mid:' (bool) is exact, 'm:' (prob) can do partial
 129         l => 'XL', # 'lid:' (bool) is exact, 'l:' (prob) can do partial
 130         f => 'A',
 131         t => 'XTO',
 132         tc => 'XTO XCC',
 133         c => 'XCC',
 134         tcf => 'XTO XCC A',
 135         a => 'XTO XCC A',
 136         b => $non_quoted_body . ' XQUOT',
 137         bs => $non_quoted_body . ' XQUOT S',
 138         n => 'XFN',
 139
 140         q => 'XQUOT',
 141         nq => $non_quoted_body,
 142         dfn => 'XDFN',
 143         dfa => 'XDFA',
 144         dfb => 'XDFB',
 145         dfhh => 'XDFHH',
 146         dfctx => 'XDFCTX',
 147
 148         # default:
 149         '' => 'XM S A XQUOT XFN ' . $non_quoted_body,
 150 );
 151
 152 # not documenting m: and mid: for now, the using the URLs works w/o Xapian
 153 # not documenting lid: for now, either, it is probably redundant with l:,
 154 # especially since we don't offer boolean searches for To/Cc/From
 155 # headers, either
 156 our @HELP = (
 157         's:' => 'match within Subject  e.g. s:"a quick brown fox"',
 158         'd:' => <<EOF,
 159 match date-time range, git "approxidate" formats supported
 160 Open-ended ranges such as `d:last.week..' and
 161 `d:..2.days.ago' are supported
 162 EOF
 163         'b:' => 'match within message body, including text attachments',
 164         'nq:' => 'match non-quoted text within message body',
 165         'q:' => 'match quoted text within message body',
 166         'n:' => 'match filename of attachment(s)',
 167         't:' => 'match within the To header',
 168         'c:' => 'match within the Cc header',
 169         'f:' => 'match within the From header',
 170         'a:' => 'match within the To, Cc, and From headers',
 171         'tc:' => 'match within the To and Cc headers',
 172         'l:' => 'match contents of the List-Id header',
 173         'bs:' => 'match within the Subject and body',
 174         'dfn:' => 'match filename from diff',
 175         'dfa:' => 'match diff removed (-) lines',
 176         'dfb:' => 'match diff added (+) lines',
 177         'dfhh:' => 'match diff hunk header context (usually a function name)',
 178         'dfctx:' => 'match diff context lines',
 179         'dfpre:' => 'match pre-image git blob ID',
 180         'dfpost:' => 'match post-image git blob ID',
 181         'dfblob:' => 'match either pre or post-image git blob ID',
 182         'rt:' => <<EOF,
 183 match received time, like `d:' if sender's clock was correct
 184 EOF
 185 );
 186 chomp @HELP;
 187
 188 sub xdir ($;$) {
 189         my ($self, $rdonly) = @_;
 190         if ($rdonly || !defined($self->{shard})) {
 191                 $self->{xpfx};
 192         } else { # v2 + extindex only:
 193                 "$self->{xpfx}/$self->{shard}";
 194         }
 195 }
 196
 197 # returns all shards as separate Xapian::Database objects w/o combining
 198 sub xdb_shards_flat ($) {
 199         my ($self) = @_;
 200         my $xpfx = $self->{xpfx};
 201         my (@xdb, $slow_phrase);
 202         load_xapian();
 203         $self->{qp_flags} //= $QP_FLAGS;
 204         if ($xpfx =~ m!/xapian[0-9]+\z!) {
 205                 @xdb = ($X{Database}->new($xpfx));
 206                 $self->{qp_flags} |= FLAG_PHRASE() if !-f "$xpfx/iamchert";
 207         } else {
 208                 opendir(my $dh, $xpfx) or return (); # not initialized yet
 209                 # We need numeric sorting so shard[0] is first for reading
 210                 # Xapian metadata, if needed
 211                 my $last = max(grep(/\A[0-9]+\z/, readdir($dh))) // return ();
 212                 for (0..$last) {
 213                         my $shard_dir = "$self->{xpfx}/$_";
 214                         push @xdb, $X{Database}->new($shard_dir);
 215                         $slow_phrase ||= -f "$shard_dir/iamchert";
 216                 }
 217                 $self->{qp_flags} |= FLAG_PHRASE() if !$slow_phrase;
 218         }
 219         @xdb;
 220 }
 221
 222 # v2 Xapian docids don't conflict, so they're identical to
 223 # NNTP article numbers and IMAP UIDs.
 224 # https://trac.xapian.org/wiki/FAQ/MultiDatabaseDocumentID
 225 sub mdocid {
 226         my ($nshard, $mitem) = @_;
 227         my $docid = $mitem->get_docid;
 228         int(($docid - 1) / $nshard) + 1;
 229 }
 230
 231 sub mset_to_artnums {
 232         my ($self, $mset) = @_;
 233         my $nshard = $self->{nshard};
 234         [ map { mdocid($nshard, $_) } $mset->items ];
 235 }
 236
 237 sub xdb ($) {
 238         my ($self) = @_;
 239         $self->{xdb} // do {
 240                 my @xdb = $self->xdb_shards_flat or return;
 241                 $self->{nshard} = scalar(@xdb);
 242                 my $xdb = shift @xdb;
 243                 $xdb->add_database($_) for @xdb;
 244                 $self->{xdb} = $xdb;
 245         };
 246 }
 247
 248 sub new {
 249         my ($class, $ibx) = @_;
 250         ref $ibx or die "BUG: expected PublicInbox::Inbox object: $ibx";
 251         my $xap = $ibx->version > 1 ? 'xap' : 'public-inbox/xapian';
 252         my $xpfx = "$ibx->{inboxdir}/$xap".SCHEMA_VERSION;
 253         my $self = bless { xpfx => $xpfx }, $class;
 254         $self->{altid} = $ibx->{altid} if defined($ibx->{altid});
 255         $self;
 256 }
 257
 258 sub reopen {
 259         my ($self) = @_;
 260         if (my $xdb = $self->{xdb}) {
 261                 $xdb->reopen;
 262         }
 263         $self; # make chaining easier
 264 }
 265
 266 # Convert git "approxidate" ranges to something usable with our
 267 # Xapian indices.  At the moment, Xapian only offers a C++-only API
 268 # and neither the SWIG nor XS bindings allow us to use custom code
 269 # to parse dates (and libgit2 doesn't expose git__date_parse, either,
 270 # so we're running git-rev-parse(1)).
 271 # This replaces things we need to send to $git->date_parse with
 272 # "\0".$strftime_format.['+'|$idx]."\0" placeholders
 273 sub date_parse_prepare {
 274         my ($to_parse, $pfx, $range) = @_;
 275         # are we inside a parenthesized statement?
 276         my $end = $range =~ s/([\)\s]*)\z// ? $1 : '';
 277         my @r = split(/\.\./, $range, 2);
 278
 279         # expand "d:20101002" => "d:20101002..20101003" and like
 280         # n.b. git doesn't do YYYYMMDD w/o '-', it needs YYYY-MM-DD
 281         # We upgrade "d:" to "dt:" to iff using approxidate
 282         if ($pfx eq 'd') {
 283                 my $fmt = "\0%Y%m%d";
 284                 if (!defined($r[1])) {
 285                         if ($r[0] =~ /\A([0-9]{4})([0-9]{2})([0-9]{2})\z/) {
 286                                 push @$to_parse, "$1-$2-$3";
 287                                 # we could've handled as-is, but we need
 288                                 # to parse anyways for "d+" below
 289                         } else {
 290                                 push @$to_parse, $r[0];
 291                                 if ($r[0] !~ /\A[0-9]{4}-[0-9]{2}-[0-9]{2}\z/) {
 292                                         $pfx = 'dt';
 293                                         $fmt = "\0%Y%m%d%H%M%S";
 294                                 }
 295                         }
 296                         $r[0] = "$fmt+$#$to_parse\0";
 297                         $r[1] = "$fmt+\0";
 298                 } else {
 299                         for my $x (@r) {
 300                                 next if $x eq '' || $x =~ /\A[0-9]{8}\z/;
 301                                 push @$to_parse, $x;
 302                                 if ($x !~ /\A[0-9]{4}-[0-9]{2}-[0-9]{2}\z/) {
 303                                         $pfx = 'dt';
 304                                 }
 305                                 $x = "$fmt$#$to_parse\0";
 306                         }
 307                         if ($pfx eq 'dt') {
 308                                 for (@r) {
 309                                         s/\0%Y%m%d/\0%Y%m%d%H%M%S/;
 310                                         s/\A([0-9]{8})\z/${1}000000/;
 311                                 }
 312                         }
 313                 }
 314         } elsif ($pfx eq 'dt') {
 315                 if (!defined($r[1])) { # git needs gaps and not /\d{14}/
 316                         if ($r[0] =~ /\A([0-9]{4})([0-9]{2})([0-9]{2})
 317                                         ([0-9]{2})([0-9]{2})([0-9]{2})\z/x) {
 318                                 push @$to_parse, "$1-$2-$3 $4:$5:$6";
 319                         } else {
 320                                 push @$to_parse, $r[0];
 321                         }
 322                         $r[0] = "\0%Y%m%d%H%M%S$#$to_parse\0";
 323                         $r[1] = "\0%Y%m%d%H%M%S+\0";
 324                 } else {
 325                         for my $x (@r) {
 326                                 next if $x eq '' || $x =~ /\A[0-9]{14}\z/;
 327                                 push @$to_parse, $x;
 328                                 $x = "\0%Y%m%d%H%M%S$#$to_parse\0";
 329                         }
 330                 }
 331         } else { # "rt", let git interpret "YYYY", deal with Y10K later :P
 332                 for my $x (@r) {
 333                         next if $x eq '' || $x =~ /\A[0-9]{5,}\z/;
 334                         push @$to_parse, $x;
 335                         $x = "\0%s$#$to_parse\0";
 336                 }
 337                 $r[1] //= "\0%s+\0"; # add 1 day
 338         }
 339         "$pfx:".join('..', @r).$end;
 340 }
 341
 342 sub date_parse_finalize {
 343         my ($git, $to_parse) = @_;
 344         # git-rev-parse can handle any number of args up to system
 345         # limits (around (4096*32) bytes on Linux).
 346         my @r = $git->date_parse(@$to_parse);
 347         # n.b. git respects TZ, times stored in SQLite/Xapian are always UTC,
 348         # and gmtime doesn't seem to do the right thing when TZ!=UTC
 349         my ($i, $t);
 350         $_[2] =~ s/\0(%[%YmdHMSs]+)([0-9\+]+)\0/
 351                 $t = $2 eq '+' ? ($r[$i]+86400) : $r[$i=$2+0];
 352                 $1 eq '%s' ? $t : strftime($1, gmtime($t))/sge;
 353 }
 354
 355 # n.b. argv never has NUL, though we'll need to filter it out
 356 # if this $argv isn't from a command execution
 357 sub query_argv_to_string {
 358         my (undef, $git, $argv) = @_;
 359         my $to_parse;
 360         my $tmp = join(' ', map {;
 361                 if (s!\b(d|rt|dt):(\S+)\z!date_parse_prepare(
 362                                                 $to_parse //= [], $1, $2)!sge) {
 363                         $_;
 364                 } elsif (/\s/) {
 365                         s/(.*?)\b(\w+:)// ? qq{$1$2"$_"} : qq{"$_"};
 366                 } else {
 367                         $_
 368                 }
 369         } @$argv);
 370         date_parse_finalize($git, $to_parse, $tmp) if $to_parse;
 371         $tmp
 372 }
 373
 374 # this is for the WWW "q=" query parameter and "lei q --stdin"
 375 # it can't do d:"5 days ago", but it will do d:5.days.ago
 376 sub query_approxidate {
 377         my (undef, $git) = @_; # $_[2] = $query_string (modified in-place)
 378         my $DQ = qq<"\x{201c}\x{201d}>; # Xapian can use curly quotes
 379         $_[2] =~ tr/\x00/ /; # Xapian doesn't do NUL, we use it as a placeholder
 380         my ($terms, $phrase, $to_parse);
 381         $_[2] =~ s{([^$DQ]*)([$DQ][^$DQ]*[$DQ])?}{
 382                 ($terms, $phrase) = ($1, $2);
 383                 $terms =~ s!\b(d|rt|dt):(\S+)!
 384                         date_parse_prepare($to_parse //= [], $1, $2)!sge;
 385                 $terms.($phrase // '');
 386                 }sge;
 387         date_parse_finalize($git, $to_parse, $_[2]) if $to_parse;
 388 }
 389
 390 # read-only
 391 sub mset {
 392         my ($self, $query_string, $opts) = @_;
 393         $opts ||= {};
 394         my $qp = $self->{qp} //= $self->qparse_new;
 395         my $query = $qp->parse_query($query_string, $self->{qp_flags});
 396         _do_enquire($self, $query, $opts);
 397 }
 398
 399 sub retry_reopen {
 400         my ($self, $cb, @arg) = @_;
 401         for my $i (1..10) {
 402                 if (wantarray) {
 403                         my @ret = eval { $cb->($self, @arg) };
 404                         return @ret unless $@;
 405                 } else {
 406                         my $ret = eval { $cb->($self, @arg) };
 407                         return $ret unless $@;
 408                 }
 409                 # Exception: The revision being read has been discarded -
 410                 # you should call Xapian::Database::reopen()
 411                 if (ref($@) =~ /\bDatabaseModifiedError\b/) {
 412                         reopen($self);
 413                 } else {
 414                         # let caller decide how to spew, because ExtMsg queries
 415                         # get wonky and trigger:
 416                         # "something terrible happened at .../Xapian/Enquire.pm"
 417                         Carp::croak($@);
 418                 }
 419         }
 420         Carp::croak("Too many Xapian database modifications in progress\n");
 421 }
 422
 423 sub _do_enquire {
 424         my ($self, $query, $opts) = @_;
 425         retry_reopen($self, \&_enquire_once, $query, $opts);
 426 }
 427
 428 # returns true if all docs have the THREADID value
 429 sub has_threadid ($) {
 430         my ($self) = @_;
 431         (xdb($self)->get_metadata('has_threadid') // '') eq '1';
 432 }
 433
 434 sub _enquire_once { # retry_reopen callback
 435         my ($self, $query, $opts) = @_;
 436         my $xdb = xdb($self);
 437         if (defined(my $eidx_key = $opts->{eidx_key})) {
 438                 $query = $X{Query}->new(OP_FILTER(), $query, 'O'.$eidx_key);
 439         }
 440         if (defined(my $uid_range = $opts->{uid_range})) {
 441                 my $range = $X{Query}->new(OP_VALUE_RANGE(), UID,
 442                                         sortable_serialise($uid_range->[0]),
 443                                         sortable_serialise($uid_range->[1]));
 444                 $query = $X{Query}->new(OP_FILTER(), $query, $range);
 445         }
 446         my $enquire = $X{Enquire}->new($xdb);
 447         $enquire->set_query($query);
 448         $opts ||= {};
 449         my $rel = $opts->{relevance} // 0;
 450         if ($rel == -2) { # ORDER BY docid/UID (highest first)
 451                 $enquire->set_weighting_scheme($X{BoolWeight}->new);
 452                 $enquire->set_docid_order($ENQ_DESCENDING);
 453         } elsif ($rel == -1) { # ORDER BY docid/UID (lowest first)
 454                 $enquire->set_weighting_scheme($X{BoolWeight}->new);
 455                 $enquire->set_docid_order($ENQ_ASCENDING);
 456         } elsif ($rel == 0) {
 457                 $enquire->set_sort_by_value_then_relevance(TS, !$opts->{asc});
 458         } else { # rel > 0
 459                 $enquire->set_sort_by_relevance_then_value(TS, !$opts->{asc});
 460         }
 461
 462         # `mairix -t / --threads' or JMAP collapseThreads
 463         if ($opts->{threads} && has_threadid($self)) {
 464                 $enquire->set_collapse_key(THREADID);
 465         }
 466         $enquire->get_mset($opts->{offset} || 0, $opts->{limit} || 50);
 467 }
 468
 469 sub mset_to_smsg {
 470         my ($self, $ibx, $mset) = @_;
 471         my $nshard = $self->{nshard};
 472         my $i = 0;
 473         my %order = map { mdocid($nshard, $_) => ++$i } $mset->items;
 474         my @msgs = sort {
 475                 $order{$a->{num}} <=> $order{$b->{num}}
 476         } @{$ibx->over->get_all(keys %order)};
 477         wantarray ? ($mset->get_matches_estimated, \@msgs) : \@msgs;
 478 }
 479
 480 # read-write
 481 sub stemmer { $X{Stem}->new($LANG) }
 482
 483 # read-only
 484 sub qparse_new {
 485         my ($self) = @_;
 486
 487         my $xdb = xdb($self);
 488         my $qp = $X{QueryParser}->new;
 489         $qp->set_default_op(OP_AND());
 490         $qp->set_database($xdb);
 491         $qp->set_stemmer(stemmer($self));
 492         $qp->set_stemming_strategy(STEM_SOME());
 493         my $cb = $qp->can('set_max_wildcard_expansion') //
 494                 $qp->can('set_max_expansion'); # Xapian 1.5.0+
 495         $cb->($qp, 100);
 496         $cb = $qp->can('add_valuerangeprocessor') //
 497                 $qp->can('add_rangeprocessor'); # Xapian 1.5.0+
 498         $cb->($qp, $NVRP->new(YYYYMMDD, 'd:'));
 499         $cb->($qp, $NVRP->new(DT, 'dt:'));
 500
 501         # for IMAP, undocumented for WWW and may be split off go away
 502         $cb->($qp, $NVRP->new(BYTES, 'z:'));
 503         $cb->($qp, $NVRP->new(TS, 'rt:'));
 504         $cb->($qp, $NVRP->new(UID, 'uid:'));
 505
 506         while (my ($name, $prefix) = each %bool_pfx_external) {
 507                 $qp->add_boolean_prefix($name, $_) foreach split(/ /, $prefix);
 508         }
 509
 510         # we do not actually create AltId objects,
 511         # just parse the spec to avoid the extra DB handles for now.
 512         if (my $altid = $self->{altid}) {
 513                 my $user_pfx = $self->{-user_pfx} = [];
 514                 for (@$altid) {
 515                         # $_ = 'serial:gmane:/path/to/gmane.msgmap.sqlite3'
 516                         # note: Xapian supports multibyte UTF-8, /^[0-9]+$/,
 517                         # and '_' with prefixes matching \w+
 518                         /\Aserial:(\w+):/ or next;
 519                         my $pfx = $1;
 520                         push @$user_pfx, "$pfx:", <<EOF;
 521 alternate serial number  e.g. $pfx:12345 (boolean)
 522 EOF
 523                         # gmane => XGMANE
 524                         $qp->add_boolean_prefix($pfx, 'X'.uc($pfx));
 525                 }
 526                 chomp @$user_pfx;
 527         }
 528
 529         while (my ($name, $prefix) = each %prob_prefix) {
 530                 $qp->add_prefix($name, $_) foreach split(/ /, $prefix);
 531         }
 532         $qp;
 533 }
 534
 535 sub help {
 536         my ($self) = @_;
 537         $self->{qp} //= $self->qparse_new; # parse altids
 538         my @ret = @HELP;
 539         if (my $user_pfx = $self->{-user_pfx}) {
 540                 push @ret, @$user_pfx;
 541         }
 542         \@ret;
 543 }
 544
 545 sub int_val ($$) {
 546         my ($doc, $col) = @_;
 547         my $val = $doc->get_value($col) or return; # undefined is '' in Xapian
 548         sortable_unserialise($val) + 0; # PV => IV conversion
 549 }
 550
 551 sub get_pct ($) { # mset item
 552         # Capped at "99%" since "100%" takes an extra column in the
 553         # thread skeleton view.  <xapian/mset.h> says the value isn't
 554         # very meaningful, anyways.
 555         my $n = $_[0]->get_percent;
 556         $n > 99 ? 99 : $n;
 557 }
 558
 559 sub xap_terms ($$;@) {
 560         my ($pfx, $xdb_or_doc, @docid) = @_; # @docid may be empty ()
 561         my %ret;
 562         my $end = $xdb_or_doc->termlist_end(@docid);
 563         my $cur = $xdb_or_doc->termlist_begin(@docid);
 564         for (; $cur != $end; $cur++) {
 565                 $cur->skip_to($pfx);
 566                 last if $cur == $end;
 567                 my $tn = $cur->get_termname;
 568                 $ret{substr($tn, length($pfx))} = undef if !index($tn, $pfx);
 569         }
 570         wantarray ? sort(keys(%ret)) : \%ret;
 571 }
 572
 573 # get combined docid from over.num:
 574 # (not generic Xapian, only works with our sharding scheme)
 575 sub num2docid ($$) {
 576         my ($self, $num) = @_;
 577         my $nshard = $self->{nshard};
 578         ($num - 1) * $nshard + $num % $nshard + 1;
 579 }
 580
 581 1;