lib/PublicInbox/Search.pm

   1 # Copyright (C) 2015-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 # based on notmuch, but with no concept of folders, files or flags
   4 #
   5 # Read-only search interface for use by the web and NNTP interfaces
   6 package PublicInbox::Search;
   7 use strict;
   8 use parent qw(Exporter);
   9 our @EXPORT_OK = qw(retry_reopen);
  10 use List::Util qw(max);
  11
  12 # values for searching, changing the numeric value breaks
  13 # compatibility with old indices (so don't change them it)
  14 use constant {
  15         TS => 0, # Received: header in Unix time (IMAP INTERNALDATE)
  16         YYYYMMDD => 1, # Date: header for searching in the WWW UI
  17         DT => 2, # Date: YYYYMMDDHHMMSS
  18
  19         # added for public-inbox 1.6.0+
  20         BYTES => 3, # IMAP RFC822.SIZE
  21         UID => 4, # IMAP UID == NNTP article number == Xapian docid
  22         THREADID => 5, # RFC 8474, RFC 8621
  23
  24         # TODO
  25         # REPLYCNT => ?, # IMAP ANSWERED
  26
  27         # SCHEMA_VERSION history
  28         # 0 - initial
  29         # 1 - subject_path is lower-cased
  30         # 2 - subject_path is id_compress in the index, only
  31         # 3 - message-ID is compressed if it includes '%' (hack!)
  32         # 4 - change "Re: " normalization, avoid circular Reference ghosts
  33         # 5 - subject_path drops trailing '.'
  34         # 6 - preserve References: order in document data
  35         # 7 - remove references and inreplyto terms
  36         # 8 - remove redundant/unneeded document data
  37         # 9 - disable Message-ID compression (SHA-1)
  38         # 10 - optimize doc for NNTP overviews
  39         # 11 - merge threads when vivifying ghosts
  40         # 12 - change YYYYMMDD value column to numeric
  41         # 13 - fix threading for empty References/In-Reply-To
  42         #      (commit 83425ef12e4b65cdcecd11ddcb38175d4a91d5a0)
  43         # 14 - fix ghost root vivification
  44         # 15 - see public-inbox-v2-format(5)
  45         #      further bumps likely unnecessary, we'll suggest in-place
  46         #      "--reindex" use for further fixes and tweaks:
  47         #
  48         #      public-inbox v1.5.0 adds (still SCHEMA_VERSION=15):
  49         #      * "lid:" and "l:" for List-Id searches
  50         #
  51         #      v1.6.0 adds BYTES, UID and THREADID values
  52         SCHEMA_VERSION => 15,
  53 };
  54
  55 use PublicInbox::Smsg;
  56 use PublicInbox::Over;
  57 our $QP_FLAGS;
  58 our %X = map { $_ => 0 } qw(BoolWeight Database Enquire QueryParser Stem Query);
  59 our $Xap; # 'Search::Xapian' or 'Xapian'
  60 our $NVRP; # '$Xap::'.('NumberValueRangeProcessor' or 'NumberRangeProcessor')
  61 our $ENQ_ASCENDING;
  62
  63 sub load_xapian () {
  64         return 1 if defined $Xap;
  65         # n.b. PI_XAPIAN is intended for development use only.  We still
  66         # favor Search::Xapian since that's what's available in current
  67         # Debian stable (10.x) and derived distros.
  68         for my $x (($ENV{PI_XAPIAN} // 'Search::Xapian'), 'Xapian') {
  69                 eval "require $x";
  70                 next if $@;
  71
  72                 $x->import(qw(:standard));
  73                 $Xap = $x;
  74
  75                 # `version_string' was added in Xapian 1.1
  76                 my $xver = eval('v'.eval($x.'::version_string()')) //
  77                                 eval('v'.eval($x.'::xapian_version_string()'));
  78
  79                 # NumberRangeProcessor was added in Xapian 1.3.6,
  80                 # NumberValueRangeProcessor was removed for 1.5.0+,
  81                 # favor the older /Value/ variant since that's what our
  82                 # (currently) preferred Search::Xapian supports
  83                 $NVRP = $x.'::'.($x eq 'Xapian' && $xver ge v1.5 ?
  84                         'NumberRangeProcessor' : 'NumberValueRangeProcessor');
  85                 $X{$_} = $Xap.'::'.$_ for (keys %X);
  86
  87                 # ENQ_ASCENDING doesn't seem exported by SWIG Xapian.pm,
  88                 # so lets hope this part of the ABI is stable because it's
  89                 # just an integer:
  90                 $ENQ_ASCENDING = $x eq 'Xapian' ?
  91                                 1 : Search::Xapian::ENQ_ASCENDING();
  92
  93                 *sortable_serialise = $x.'::sortable_serialise';
  94                 # n.b. FLAG_PURE_NOT is expensive not suitable for a public
  95                 # website as it could become a denial-of-service vector
  96                 # FLAG_PHRASE also seems to cause performance problems chert
  97                 # (and probably earlier Xapian DBs).  glass seems fine...
  98                 # TODO: make this an option, maybe?
  99                 # or make indexlevel=medium as default
 100                 $QP_FLAGS = FLAG_PHRASE() | FLAG_BOOLEAN() | FLAG_LOVEHATE() |
 101                                 FLAG_WILDCARD();
 102                 return 1;
 103         }
 104         undef;
 105 }
 106
 107 # This is English-only, everything else is non-standard and may be confused as
 108 # a prefix common in patch emails
 109 our $LANG = 'english';
 110
 111 # note: the non-X term prefix allocations are shared with
 112 # Xapian omega, see xapian-applications/omega/docs/termprefixes.rst
 113 my %bool_pfx_external = (
 114         mid => 'Q', # Message-ID (full/exact), this is mostly uniQue
 115         lid => 'G', # newsGroup (or similar entity), just inside <>
 116         dfpre => 'XDFPRE',
 117         dfpost => 'XDFPOST',
 118         dfblob => 'XDFPRE XDFPOST',
 119 );
 120
 121 my $non_quoted_body = 'XNQ XDFN XDFA XDFB XDFHH XDFCTX XDFPRE XDFPOST';
 122 my %prob_prefix = (
 123         # for mairix compatibility
 124         s => 'S',
 125         m => 'XM', # 'mid:' (bool) is exact, 'm:' (prob) can do partial
 126         l => 'XL', # 'lid:' (bool) is exact, 'l:' (prob) can do partial
 127         f => 'A',
 128         t => 'XTO',
 129         tc => 'XTO XCC',
 130         c => 'XCC',
 131         tcf => 'XTO XCC A',
 132         a => 'XTO XCC A',
 133         b => $non_quoted_body . ' XQUOT',
 134         bs => $non_quoted_body . ' XQUOT S',
 135         n => 'XFN',
 136
 137         q => 'XQUOT',
 138         nq => $non_quoted_body,
 139         dfn => 'XDFN',
 140         dfa => 'XDFA',
 141         dfb => 'XDFB',
 142         dfhh => 'XDFHH',
 143         dfctx => 'XDFCTX',
 144
 145         # default:
 146         '' => 'XM S A XQUOT XFN ' . $non_quoted_body,
 147 );
 148
 149 # not documenting m: and mid: for now, the using the URLs works w/o Xapian
 150 # not documenting lid: for now, either, it is probably redundant with l:,
 151 # especially since we don't offer boolean searches for To/Cc/From
 152 # headers, either
 153 our @HELP = (
 154         's:' => 'match within Subject  e.g. s:"a quick brown fox"',
 155         'd:' => <<EOF,
 156 date range as YYYYMMDD  e.g. d:19931002..20101002
 157 Open-ended ranges such as d:19931002.. and d:..20101002
 158 are also supported
 159 EOF
 160         'dt:' => <<EOF,
 161 date-time range as YYYYMMDDhhmmss (e.g. dt:19931002011000..19931002011200)
 162 EOF
 163         'b:' => 'match within message body, including text attachments',
 164         'nq:' => 'match non-quoted text within message body',
 165         'q:' => 'match quoted text within message body',
 166         'n:' => 'match filename of attachment(s)',
 167         't:' => 'match within the To header',
 168         'c:' => 'match within the Cc header',
 169         'f:' => 'match within the From header',
 170         'a:' => 'match within the To, Cc, and From headers',
 171         'tc:' => 'match within the To and Cc headers',
 172         'l:' => 'match contents of the List-Id header',
 173         'bs:' => 'match within the Subject and body',
 174         'dfn:' => 'match filename from diff',
 175         'dfa:' => 'match diff removed (-) lines',
 176         'dfb:' => 'match diff added (+) lines',
 177         'dfhh:' => 'match diff hunk header context (usually a function name)',
 178         'dfctx:' => 'match diff context lines',
 179         'dfpre:' => 'match pre-image git blob ID',
 180         'dfpost:' => 'match post-image git blob ID',
 181         'dfblob:' => 'match either pre or post-image git blob ID',
 182 );
 183 chomp @HELP;
 184
 185 sub xdir ($;$) {
 186         my ($self, $rdonly) = @_;
 187         if ($rdonly || !defined($self->{shard})) {
 188                 $self->{xpfx};
 189         } else { # v2 only:
 190                 "$self->{xpfx}/$self->{shard}";
 191         }
 192 }
 193
 194 sub xdb_sharded {
 195         my ($self) = @_;
 196         opendir(my $dh, $self->{xpfx}) or return; # not initialized yet
 197
 198         # We need numeric sorting so shard[0] is first for reading
 199         # Xapian metadata, if needed
 200         my $last = max(grep(/\A[0-9]+\z/, readdir($dh)));
 201         return if !defined($last);
 202         my (@xdb, $slow_phrase);
 203         for (0..$last) {
 204                 my $shard_dir = "$self->{xpfx}/$_";
 205                 if (-d $shard_dir && -r _) {
 206                         push @xdb, $X{Database}->new($shard_dir);
 207                         $slow_phrase ||= -f "$shard_dir/iamchert";
 208                 } else { # gaps from missing epochs throw off mdocid()
 209                         warn "E: $shard_dir missing or unreadable\n";
 210                         return;
 211                 }
 212         }
 213         $self->{qp_flags} |= FLAG_PHRASE() if !$slow_phrase;
 214         $self->{nshard} = scalar(@xdb);
 215         my $xdb = shift @xdb;
 216         $xdb->add_database($_) for @xdb;
 217         $xdb;
 218 }
 219
 220 sub _xdb {
 221         my ($self) = @_;
 222         my $dir = xdir($self, 1);
 223         $self->{qp_flags} //= $QP_FLAGS;
 224         if ($self->{ibx_ver} >= 2) {
 225                 xdb_sharded($self);
 226         } else {
 227                 $self->{qp_flags} |= FLAG_PHRASE() if !-f "$dir/iamchert";
 228                 $X{Database}->new($dir);
 229         }
 230 }
 231
 232 # v2 Xapian docids don't conflict, so they're identical to
 233 # NNTP article numbers and IMAP UIDs.
 234 # https://trac.xapian.org/wiki/FAQ/MultiDatabaseDocumentID
 235 sub mdocid {
 236         my ($nshard, $mitem) = @_;
 237         my $docid = $mitem->get_docid;
 238         int(($docid - 1) / $nshard) + 1;
 239 }
 240
 241 sub mset_to_artnums {
 242         my ($self, $mset) = @_;
 243         my $nshard = $self->{nshard} // 1;
 244         [ map { mdocid($nshard, $_) } $mset->items ];
 245 }
 246
 247 sub xdb ($) {
 248         my ($self) = @_;
 249         $self->{xdb} //= do {
 250                 load_xapian();
 251                 $self->_xdb;
 252         };
 253 }
 254
 255 sub xpfx_init ($) {
 256         my ($self) = @_;
 257         if ($self->{ibx_ver} == 1) {
 258                 $self->{xpfx} .= '/public-inbox/xapian' . SCHEMA_VERSION;
 259         } else {
 260                 $self->{xpfx} .= '/xap'.SCHEMA_VERSION;
 261         }
 262 }
 263
 264 sub new {
 265         my ($class, $ibx) = @_;
 266         ref $ibx or die "BUG: expected PublicInbox::Inbox object: $ibx";
 267         my $self = bless {
 268                 xpfx => $ibx->{inboxdir}, # for xpfx_init
 269                 altid => $ibx->{altid},
 270                 ibx_ver => $ibx->version,
 271         }, $class;
 272         xpfx_init($self);
 273         $self;
 274 }
 275
 276 sub reopen {
 277         my ($self) = @_;
 278         if (my $xdb = $self->{xdb}) {
 279                 $xdb->reopen;
 280         }
 281         $self; # make chaining easier
 282 }
 283
 284 # read-only
 285 sub mset {
 286         my ($self, $query_string, $opts) = @_;
 287         $opts ||= {};
 288         my $qp = $self->{qp} //= qparse_new($self);
 289         my $query = $qp->parse_query($query_string, $self->{qp_flags});
 290         $opts->{relevance} = 1 unless exists $opts->{relevance};
 291         _do_enquire($self, $query, $opts);
 292 }
 293
 294 sub retry_reopen {
 295         my ($self, $cb, @arg) = @_;
 296         for my $i (1..10) {
 297                 if (wantarray) {
 298                         my @ret;
 299                         eval { @ret = $cb->($self, @arg) };
 300                         return @ret unless $@;
 301                 } else {
 302                         my $ret;
 303                         eval { $ret = $cb->($self, @arg) };
 304                         return $ret unless $@;
 305                 }
 306                 # Exception: The revision being read has been discarded -
 307                 # you should call Xapian::Database::reopen()
 308                 if (ref($@) =~ /\bDatabaseModifiedError\b/) {
 309                         warn "reopen try #$i on $@\n";
 310                         reopen($self);
 311                 } else {
 312                         # let caller decide how to spew, because ExtMsg queries
 313                         # get wonky and trigger:
 314                         # "something terrible happened at .../Xapian/Enquire.pm"
 315                         die;
 316                 }
 317         }
 318         die "Too many Xapian database modifications in progress\n";
 319 }
 320
 321 sub _do_enquire {
 322         my ($self, $query, $opts) = @_;
 323         retry_reopen($self, \&_enquire_once, $query, $opts);
 324 }
 325
 326 # returns true if all docs have the THREADID value
 327 sub has_threadid ($) {
 328         my ($self) = @_;
 329         (xdb($self)->get_metadata('has_threadid') // '') eq '1';
 330 }
 331
 332 sub _enquire_once { # retry_reopen callback
 333         my ($self, $query, $opts) = @_;
 334         my $xdb = xdb($self);
 335         if (defined(my $eidx_key = $opts->{eidx_key})) {
 336                 $query = $X{Query}->new(OP_FILTER(), $query, 'O'.$eidx_key);
 337         }
 338         if (defined(my $uid_range = $opts->{uid_range})) {
 339                 my $range = $X{Query}->new(OP_VALUE_RANGE(), UID,
 340                                         sortable_serialise($uid_range->[0]),
 341                                         sortable_serialise($uid_range->[1]));
 342                 $query = $X{Query}->new(OP_FILTER(), $query, $range);
 343         }
 344         my $enquire = $X{Enquire}->new($xdb);
 345         $enquire->set_query($query);
 346         $opts ||= {};
 347         my $desc = !$opts->{asc};
 348         if (($opts->{mset} || 0) == 2) { # mset == 2: ORDER BY docid/UID
 349                 $enquire->set_docid_order($ENQ_ASCENDING);
 350                 $enquire->set_weighting_scheme($X{BoolWeight}->new);
 351         } elsif ($opts->{relevance}) {
 352                 $enquire->set_sort_by_relevance_then_value(TS, $desc);
 353         } else {
 354                 $enquire->set_sort_by_value_then_relevance(TS, $desc);
 355         }
 356
 357         # `mairix -t / --threads' or JMAP collapseThreads
 358         if ($opts->{thread} && has_threadid($self)) {
 359                 $enquire->set_collapse_key(THREADID);
 360         }
 361         $enquire->get_mset($opts->{offset} || 0, $opts->{limit} || 50);
 362 }
 363
 364 sub mset_to_smsg {
 365         my ($self, $ibx, $mset) = @_;
 366         my $nshard = $self->{nshard} // 1;
 367         my $i = 0;
 368         my %order = map { mdocid($nshard, $_) => ++$i } $mset->items;
 369         my @msgs = sort {
 370                 $order{$a->{num}} <=> $order{$b->{num}}
 371         } @{$ibx->over->get_all(keys %order)};
 372         wantarray ? ($mset->get_matches_estimated, \@msgs) : \@msgs;
 373 }
 374
 375 # read-write
 376 sub stemmer { $X{Stem}->new($LANG) }
 377
 378 # read-only
 379 sub qparse_new ($) {
 380         my ($self) = @_;
 381
 382         my $xdb = xdb($self);
 383         my $qp = $X{QueryParser}->new;
 384         $qp->set_default_op(OP_AND());
 385         $qp->set_database($xdb);
 386         $qp->set_stemmer(stemmer($self));
 387         $qp->set_stemming_strategy(STEM_SOME());
 388         my $cb = $qp->can('set_max_wildcard_expansion') //
 389                 $qp->can('set_max_expansion'); # Xapian 1.5.0+
 390         $cb->($qp, 100);
 391         $cb = $qp->can('add_valuerangeprocessor') //
 392                 $qp->can('add_rangeprocessor'); # Xapian 1.5.0+
 393         $cb->($qp, $NVRP->new(YYYYMMDD, 'd:'));
 394         $cb->($qp, $NVRP->new(DT, 'dt:'));
 395
 396         # for IMAP, undocumented for WWW and may be split off go away
 397         $cb->($qp, $NVRP->new(BYTES, 'bytes:'));
 398         $cb->($qp, $NVRP->new(TS, 'ts:'));
 399         $cb->($qp, $NVRP->new(UID, 'uid:'));
 400
 401         while (my ($name, $prefix) = each %bool_pfx_external) {
 402                 $qp->add_boolean_prefix($name, $_) foreach split(/ /, $prefix);
 403         }
 404
 405         # we do not actually create AltId objects,
 406         # just parse the spec to avoid the extra DB handles for now.
 407         if (my $altid = $self->{altid}) {
 408                 my $user_pfx = $self->{-user_pfx} = [];
 409                 for (@$altid) {
 410                         # $_ = 'serial:gmane:/path/to/gmane.msgmap.sqlite3'
 411                         # note: Xapian supports multibyte UTF-8, /^[0-9]+$/,
 412                         # and '_' with prefixes matching \w+
 413                         /\Aserial:(\w+):/ or next;
 414                         my $pfx = $1;
 415                         push @$user_pfx, "$pfx:", <<EOF;
 416 alternate serial number  e.g. $pfx:12345 (boolean)
 417 EOF
 418                         # gmane => XGMANE
 419                         $qp->add_boolean_prefix($pfx, 'X'.uc($pfx));
 420                 }
 421                 chomp @$user_pfx;
 422         }
 423
 424         while (my ($name, $prefix) = each %prob_prefix) {
 425                 $qp->add_prefix($name, $_) foreach split(/ /, $prefix);
 426         }
 427         $qp;
 428 }
 429
 430 sub help {
 431         my ($self) = @_;
 432         $self->{qp} //= qparse_new($self); # parse altids
 433         my @ret = @HELP;
 434         if (my $user_pfx = $self->{-user_pfx}) {
 435                 push @ret, @$user_pfx;
 436         }
 437         \@ret;
 438 }
 439
 440 1;