lib/PublicInbox/Search.pm

   1 # Copyright (C) 2015-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 # based on notmuch, but with no concept of folders, files or flags
   4 #
   5 # Read-only search interface for use by the web and NNTP interfaces
   6 package PublicInbox::Search;
   7 use strict;
   8 use warnings;
   9
  10 # values for searching
  11 use constant TS => 0;  # Received: header in Unix time
  12 use constant YYYYMMDD => 1; # Date: header for searching in the WWW UI
  13 use constant DT => 2; # Date: YYYYMMDDHHMMSS
  14
  15 use PublicInbox::Smsg;
  16 use PublicInbox::Over;
  17 my $QP_FLAGS;
  18 our %X = map { $_ => 0 } qw(BoolWeight Database Enquire
  19                         NumberValueRangeProcessor QueryParser Stem);
  20 our $Xap; # 'Search::Xapian' or 'Xapian'
  21 my $ENQ_ASCENDING;
  22
  23 sub load_xapian () {
  24         return 1 if defined $Xap;
  25         for my $x (qw(Search::Xapian Xapian)) {
  26                 eval "require $x";
  27                 next if $@;
  28
  29                 $x->import(qw(:standard));
  30                 $Xap = $x;
  31                 $X{$_} = $Xap.'::'.$_ for (keys %X);
  32
  33                 # ENQ_ASCENDING doesn't seem exported by SWIG Xapian.pm,
  34                 # so lets hope this part of the ABI is stable because it's
  35                 # just an integer:
  36                 $ENQ_ASCENDING = $x eq 'Xapian' ?
  37                                 1 : Search::Xapian::ENQ_ASCENDING();
  38
  39                 # for Smsg:
  40                 *PublicInbox::Smsg::sortable_unserialise =
  41                                                 $Xap.'::sortable_unserialise';
  42                 # n.b. FLAG_PURE_NOT is expensive not suitable for a public
  43                 # website as it could become a denial-of-service vector
  44                 # FLAG_PHRASE also seems to cause performance problems chert
  45                 # (and probably earlier Xapian DBs).  glass seems fine...
  46                 # TODO: make this an option, maybe?
  47                 # or make indexlevel=medium as default
  48                 $QP_FLAGS = FLAG_PHRASE() | FLAG_BOOLEAN() | FLAG_LOVEHATE() |
  49                                 FLAG_WILDCARD();
  50                 return 1;
  51         }
  52         undef;
  53 }
  54
  55 # This is English-only, everything else is non-standard and may be confused as
  56 # a prefix common in patch emails
  57 our $LANG = 'english';
  58
  59 use constant {
  60         # SCHEMA_VERSION history
  61         # 0 - initial
  62         # 1 - subject_path is lower-cased
  63         # 2 - subject_path is id_compress in the index, only
  64         # 3 - message-ID is compressed if it includes '%' (hack!)
  65         # 4 - change "Re: " normalization, avoid circular Reference ghosts
  66         # 5 - subject_path drops trailing '.'
  67         # 6 - preserve References: order in document data
  68         # 7 - remove references and inreplyto terms
  69         # 8 - remove redundant/unneeded document data
  70         # 9 - disable Message-ID compression (SHA-1)
  71         # 10 - optimize doc for NNTP overviews
  72         # 11 - merge threads when vivifying ghosts
  73         # 12 - change YYYYMMDD value column to numeric
  74         # 13 - fix threading for empty References/In-Reply-To
  75         #      (commit 83425ef12e4b65cdcecd11ddcb38175d4a91d5a0)
  76         # 14 - fix ghost root vivification
  77         # 15 - see public-inbox-v2-format(5)
  78         #      further bumps likely unnecessary, we'll suggest in-place
  79         #      "--reindex" use for further fixes and tweaks
  80         #
  81         #      public-inbox v1.5.0 adds (still SCHEMA_VERSION=15):
  82         #      * "lid:" and "l:" for List-Id searches
  83         SCHEMA_VERSION => 15,
  84 };
  85
  86 # note: the non-X term prefix allocations are shared with
  87 # Xapian omega, see xapian-applications/omega/docs/termprefixes.rst
  88 my %bool_pfx_external = (
  89         mid => 'Q', # Message-ID (full/exact), this is mostly uniQue
  90         lid => 'G', # newsGroup (or similar entity), just inside <>
  91         dfpre => 'XDFPRE',
  92         dfpost => 'XDFPOST',
  93         dfblob => 'XDFPRE XDFPOST',
  94 );
  95
  96 my $non_quoted_body = 'XNQ XDFN XDFA XDFB XDFHH XDFCTX XDFPRE XDFPOST';
  97 my %prob_prefix = (
  98         # for mairix compatibility
  99         s => 'S',
 100         m => 'XM', # 'mid:' (bool) is exact, 'm:' (prob) can do partial
 101         l => 'XL', # 'lid:' (bool) is exact, 'l:' (prob) can do partial
 102         f => 'A',
 103         t => 'XTO',
 104         tc => 'XTO XCC',
 105         c => 'XCC',
 106         tcf => 'XTO XCC A',
 107         a => 'XTO XCC A',
 108         b => $non_quoted_body . ' XQUOT',
 109         bs => $non_quoted_body . ' XQUOT S',
 110         n => 'XFN',
 111
 112         q => 'XQUOT',
 113         nq => $non_quoted_body,
 114         dfn => 'XDFN',
 115         dfa => 'XDFA',
 116         dfb => 'XDFB',
 117         dfhh => 'XDFHH',
 118         dfctx => 'XDFCTX',
 119
 120         # default:
 121         '' => 'XM S A XQUOT XFN ' . $non_quoted_body,
 122 );
 123
 124 # not documenting m: and mid: for now, the using the URLs works w/o Xapian
 125 our @HELP = (
 126         's:' => 'match within Subject  e.g. s:"a quick brown fox"',
 127         'd:' => <<EOF,
 128 date range as YYYYMMDD  e.g. d:19931002..20101002
 129 Open-ended ranges such as d:19931002.. and d:..20101002
 130 are also supported
 131 EOF
 132         'dt:' => <<EOF,
 133 date-time range as YYYYMMDDhhmmss (e.g. dt:19931002011000..19931002011200)
 134 EOF
 135         'b:' => 'match within message body, including text attachments',
 136         'nq:' => 'match non-quoted text within message body',
 137         'q:' => 'match quoted text within message body',
 138         'n:' => 'match filename of attachment(s)',
 139         't:' => 'match within the To header',
 140         'c:' => 'match within the Cc header',
 141         'f:' => 'match within the From header',
 142         'a:' => 'match within the To, Cc, and From headers',
 143         'tc:' => 'match within the To and Cc headers',
 144         'lid:' => 'exact contents of the List-Id',
 145         'l:' => 'partial match contents of the List-Id header',
 146         'bs:' => 'match within the Subject and body',
 147         'dfn:' => 'match filename from diff',
 148         'dfa:' => 'match diff removed (-) lines',
 149         'dfb:' => 'match diff added (+) lines',
 150         'dfhh:' => 'match diff hunk header context (usually a function name)',
 151         'dfctx:' => 'match diff context lines',
 152         'dfpre:' => 'match pre-image git blob ID',
 153         'dfpost:' => 'match post-image git blob ID',
 154         'dfblob:' => 'match either pre or post-image git blob ID',
 155 );
 156 chomp @HELP;
 157
 158 sub xdir ($;$) {
 159         my ($self, $rdonly) = @_;
 160         if ($self->{ibx_ver} == 1) {
 161                 "$self->{inboxdir}/public-inbox/xapian" . SCHEMA_VERSION;
 162         } else {
 163                 my $dir = "$self->{inboxdir}/xap" . SCHEMA_VERSION;
 164                 return $dir if $rdonly;
 165
 166                 my $shard = $self->{shard};
 167                 defined $shard or die "shard not given";
 168                 $dir .= "/$shard";
 169         }
 170 }
 171
 172 sub _xdb ($) {
 173         my ($self) = @_;
 174         my $dir = xdir($self, 1);
 175         my ($xdb, $slow_phrase);
 176         my $qpf = \($self->{qp_flags} ||= $QP_FLAGS);
 177         if ($self->{ibx_ver} >= 2) {
 178                 foreach my $shard (<$dir/*>) {
 179                         -d $shard && $shard =~ m!/[0-9]+\z! or next;
 180                         my $sub = $X{Database}->new($shard);
 181                         if ($xdb) {
 182                                 $xdb->add_database($sub);
 183                         } else {
 184                                 $xdb = $sub;
 185                         }
 186                         $slow_phrase ||= -f "$shard/iamchert";
 187                 }
 188         } else {
 189                 $slow_phrase = -f "$dir/iamchert";
 190                 $xdb = $X{Database}->new($dir);
 191         }
 192         $$qpf |= FLAG_PHRASE() unless $slow_phrase;
 193         $xdb;
 194 }
 195
 196 sub xdb ($) {
 197         my ($self) = @_;
 198         $self->{xdb} ||= do {
 199                 load_xapian();
 200                 _xdb($self);
 201         };
 202 }
 203
 204 sub new {
 205         my ($class, $ibx) = @_;
 206         ref $ibx or die "BUG: expected PublicInbox::Inbox object: $ibx";
 207         my $self = bless {
 208                 inboxdir => $ibx->{inboxdir},
 209                 altid => $ibx->{altid},
 210                 ibx_ver => $ibx->version,
 211         }, $class;
 212         my $dir = xdir($self, 1);
 213         $self->{over_ro} = PublicInbox::Over->new("$dir/over.sqlite3");
 214         $self;
 215 }
 216
 217 sub reopen {
 218         my ($self) = @_;
 219         if (my $xdb = $self->{xdb}) {
 220                 $xdb->reopen;
 221         }
 222         $self; # make chaining easier
 223 }
 224
 225 # read-only
 226 sub query {
 227         my ($self, $query_string, $opts) = @_;
 228         $opts ||= {};
 229         if ($query_string eq '' && !$opts->{mset}) {
 230                 $self->{over_ro}->recent($opts);
 231         } else {
 232                 my $qp = qp($self);
 233                 my $qp_flags = $self->{qp_flags};
 234                 my $query = $qp->parse_query($query_string, $qp_flags);
 235                 $opts->{relevance} = 1 unless exists $opts->{relevance};
 236                 _do_enquire($self, $query, $opts);
 237         }
 238 }
 239
 240 sub retry_reopen {
 241         my ($self, $cb, $arg) = @_;
 242         for my $i (1..10) {
 243                 if (wantarray) {
 244                         my @ret;
 245                         eval { @ret = $cb->($arg) };
 246                         return @ret unless $@;
 247                 } else {
 248                         my $ret;
 249                         eval { $ret = $cb->($arg) };
 250                         return $ret unless $@;
 251                 }
 252                 # Exception: The revision being read has been discarded -
 253                 # you should call Xapian::Database::reopen()
 254                 if (ref($@) =~ /\bDatabaseModifiedError\b/) {
 255                         warn "reopen try #$i on $@\n";
 256                         reopen($self);
 257                 } else {
 258                         # let caller decide how to spew, because ExtMsg queries
 259                         # get wonky and trigger:
 260                         # "something terrible happened at .../Xapian/Enquire.pm"
 261                         die;
 262                 }
 263         }
 264         die "Too many Xapian database modifications in progress\n";
 265 }
 266
 267 sub _do_enquire {
 268         my ($self, $query, $opts) = @_;
 269         retry_reopen($self, \&_enquire_once, [ $self, $query, $opts ]);
 270 }
 271
 272 sub _enquire_once { # retry_reopen callback
 273         my ($self, $query, $opts) = @{$_[0]};
 274         my $xdb = xdb($self);
 275         my $enquire = $X{Enquire}->new($xdb);
 276         $enquire->set_query($query);
 277         $opts ||= {};
 278         my $desc = !$opts->{asc};
 279         if (($opts->{mset} || 0) == 2) {
 280                 $enquire->set_docid_order($ENQ_ASCENDING);
 281                 $enquire->set_weighting_scheme($X{BoolWeight}->new);
 282         } elsif ($opts->{relevance}) {
 283                 $enquire->set_sort_by_relevance_then_value(TS, $desc);
 284         } else {
 285                 $enquire->set_sort_by_value_then_relevance(TS, $desc);
 286         }
 287         my $offset = $opts->{offset} || 0;
 288         my $limit = $opts->{limit} || 50;
 289         my $mset = $enquire->get_mset($offset, $limit);
 290         return $mset if $opts->{mset};
 291         my @msgs = map { PublicInbox::Smsg::from_mitem($_) } $mset->items;
 292         return \@msgs unless wantarray;
 293
 294         ($mset->get_matches_estimated, \@msgs)
 295 }
 296
 297 # read-write
 298 sub stemmer { $X{Stem}->new($LANG) }
 299
 300 # read-only
 301 sub qp {
 302         my ($self) = @_;
 303
 304         my $qp = $self->{query_parser};
 305         return $qp if $qp;
 306         my $xdb = xdb($self);
 307         # new parser
 308         $qp = $X{QueryParser}->new;
 309         $qp->set_default_op(OP_AND());
 310         $qp->set_database($xdb);
 311         $qp->set_stemmer($self->stemmer);
 312         $qp->set_stemming_strategy(STEM_SOME());
 313         $qp->set_max_wildcard_expansion(100);
 314         my $nvrp = $X{NumberValueRangeProcessor};
 315         $qp->add_valuerangeprocessor($nvrp->new(YYYYMMDD, 'd:'));
 316         $qp->add_valuerangeprocessor($nvrp->new(DT, 'dt:'));
 317
 318         while (my ($name, $prefix) = each %bool_pfx_external) {
 319                 $qp->add_boolean_prefix($name, $_) foreach split(/ /, $prefix);
 320         }
 321
 322         # we do not actually create AltId objects,
 323         # just parse the spec to avoid the extra DB handles for now.
 324         if (my $altid = $self->{altid}) {
 325                 my $user_pfx = $self->{-user_pfx} = [];
 326                 for (@$altid) {
 327                         # $_ = 'serial:gmane:/path/to/gmane.msgmap.sqlite3'
 328                         # note: Xapian supports multibyte UTF-8, /^[0-9]+$/,
 329                         # and '_' with prefixes matching \w+
 330                         /\Aserial:(\w+):/ or next;
 331                         my $pfx = $1;
 332                         push @$user_pfx, "$pfx:", <<EOF;
 333 alternate serial number  e.g. $pfx:12345 (boolean)
 334 EOF
 335                         # gmane => XGMANE
 336                         $qp->add_boolean_prefix($pfx, 'X'.uc($pfx));
 337                 }
 338                 chomp @$user_pfx;
 339         }
 340
 341         while (my ($name, $prefix) = each %prob_prefix) {
 342                 $qp->add_prefix($name, $_) foreach split(/ /, $prefix);
 343         }
 344
 345         $self->{query_parser} = $qp;
 346 }
 347
 348 sub help {
 349         my ($self) = @_;
 350         $self->qp; # parse altids
 351         my @ret = @HELP;
 352         if (my $user_pfx = $self->{-user_pfx}) {
 353                 push @ret, @$user_pfx;
 354         }
 355         \@ret;
 356 }
 357
 358 1;