lib/PublicInbox/Search.pm

   1 # Copyright (C) 2015-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 # based on notmuch, but with no concept of folders, files or flags
   4 #
   5 # Read-only search interface for use by the web and NNTP interfaces
   6 package PublicInbox::Search;
   7 use strict;
   8 use parent qw(Exporter);
   9 our @EXPORT_OK = qw(retry_reopen);
  10 use List::Util qw(max);
  11
  12 # values for searching, changing the numeric value breaks
  13 # compatibility with old indices (so don't change them it)
  14 use constant {
  15         TS => 0, # Received: header in Unix time (IMAP INTERNALDATE)
  16         YYYYMMDD => 1, # Date: header for searching in the WWW UI
  17         DT => 2, # Date: YYYYMMDDHHMMSS
  18
  19         # added for public-inbox 1.6.0+
  20         BYTES => 3, # IMAP RFC822.SIZE
  21         UID => 4, # IMAP UID == NNTP article number == Xapian docid
  22         THREADID => 5, # RFC 8474, RFC 8621
  23
  24         # TODO
  25         # REPLYCNT => ?, # IMAP ANSWERED
  26
  27         # SCHEMA_VERSION history
  28         # 0 - initial
  29         # 1 - subject_path is lower-cased
  30         # 2 - subject_path is id_compress in the index, only
  31         # 3 - message-ID is compressed if it includes '%' (hack!)
  32         # 4 - change "Re: " normalization, avoid circular Reference ghosts
  33         # 5 - subject_path drops trailing '.'
  34         # 6 - preserve References: order in document data
  35         # 7 - remove references and inreplyto terms
  36         # 8 - remove redundant/unneeded document data
  37         # 9 - disable Message-ID compression (SHA-1)
  38         # 10 - optimize doc for NNTP overviews
  39         # 11 - merge threads when vivifying ghosts
  40         # 12 - change YYYYMMDD value column to numeric
  41         # 13 - fix threading for empty References/In-Reply-To
  42         #      (commit 83425ef12e4b65cdcecd11ddcb38175d4a91d5a0)
  43         # 14 - fix ghost root vivification
  44         # 15 - see public-inbox-v2-format(5)
  45         #      further bumps likely unnecessary, we'll suggest in-place
  46         #      "--reindex" use for further fixes and tweaks:
  47         #
  48         #      public-inbox v1.5.0 adds (still SCHEMA_VERSION=15):
  49         #      * "lid:" and "l:" for List-Id searches
  50         #
  51         #      v1.6.0 adds BYTES, UID and THREADID values
  52         SCHEMA_VERSION => 15,
  53 };
  54
  55 use PublicInbox::Smsg;
  56 use PublicInbox::Over;
  57 our $QP_FLAGS;
  58 our %X = map { $_ => 0 } qw(BoolWeight Database Enquire QueryParser Stem Query);
  59 our $Xap; # 'Search::Xapian' or 'Xapian'
  60 our $NVRP; # '$Xap::'.('NumberValueRangeProcessor' or 'NumberRangeProcessor')
  61 our $ENQ_ASCENDING;
  62
  63 sub load_xapian () {
  64         return 1 if defined $Xap;
  65         # n.b. PI_XAPIAN is intended for development use only.  We still
  66         # favor Search::Xapian since that's what's available in current
  67         # Debian stable (10.x) and derived distros.
  68         for my $x (($ENV{PI_XAPIAN} // 'Search::Xapian'), 'Xapian') {
  69                 eval "require $x";
  70                 next if $@;
  71
  72                 $x->import(qw(:standard));
  73                 $Xap = $x;
  74
  75                 # `version_string' was added in Xapian 1.1
  76                 my $xver = eval('v'.eval($x.'::version_string()')) //
  77                                 eval('v'.eval($x.'::xapian_version_string()'));
  78
  79                 # NumberRangeProcessor was added in Xapian 1.3.6,
  80                 # NumberValueRangeProcessor was removed for 1.5.0+,
  81                 # favor the older /Value/ variant since that's what our
  82                 # (currently) preferred Search::Xapian supports
  83                 $NVRP = $x.'::'.($x eq 'Xapian' && $xver ge v1.5 ?
  84                         'NumberRangeProcessor' : 'NumberValueRangeProcessor');
  85                 $X{$_} = $Xap.'::'.$_ for (keys %X);
  86
  87                 # ENQ_ASCENDING doesn't seem exported by SWIG Xapian.pm,
  88                 # so lets hope this part of the ABI is stable because it's
  89                 # just an integer:
  90                 $ENQ_ASCENDING = $x eq 'Xapian' ?
  91                                 1 : Search::Xapian::ENQ_ASCENDING();
  92
  93                 # n.b. FLAG_PURE_NOT is expensive not suitable for a public
  94                 # website as it could become a denial-of-service vector
  95                 # FLAG_PHRASE also seems to cause performance problems chert
  96                 # (and probably earlier Xapian DBs).  glass seems fine...
  97                 # TODO: make this an option, maybe?
  98                 # or make indexlevel=medium as default
  99                 $QP_FLAGS = FLAG_PHRASE() | FLAG_BOOLEAN() | FLAG_LOVEHATE() |
 100                                 FLAG_WILDCARD();
 101                 return 1;
 102         }
 103         undef;
 104 }
 105
 106 # This is English-only, everything else is non-standard and may be confused as
 107 # a prefix common in patch emails
 108 our $LANG = 'english';
 109
 110 # note: the non-X term prefix allocations are shared with
 111 # Xapian omega, see xapian-applications/omega/docs/termprefixes.rst
 112 my %bool_pfx_external = (
 113         mid => 'Q', # Message-ID (full/exact), this is mostly uniQue
 114         lid => 'G', # newsGroup (or similar entity), just inside <>
 115         dfpre => 'XDFPRE',
 116         dfpost => 'XDFPOST',
 117         dfblob => 'XDFPRE XDFPOST',
 118 );
 119
 120 my $non_quoted_body = 'XNQ XDFN XDFA XDFB XDFHH XDFCTX XDFPRE XDFPOST';
 121 my %prob_prefix = (
 122         # for mairix compatibility
 123         s => 'S',
 124         m => 'XM', # 'mid:' (bool) is exact, 'm:' (prob) can do partial
 125         l => 'XL', # 'lid:' (bool) is exact, 'l:' (prob) can do partial
 126         f => 'A',
 127         t => 'XTO',
 128         tc => 'XTO XCC',
 129         c => 'XCC',
 130         tcf => 'XTO XCC A',
 131         a => 'XTO XCC A',
 132         b => $non_quoted_body . ' XQUOT',
 133         bs => $non_quoted_body . ' XQUOT S',
 134         n => 'XFN',
 135
 136         q => 'XQUOT',
 137         nq => $non_quoted_body,
 138         dfn => 'XDFN',
 139         dfa => 'XDFA',
 140         dfb => 'XDFB',
 141         dfhh => 'XDFHH',
 142         dfctx => 'XDFCTX',
 143
 144         # default:
 145         '' => 'XM S A XQUOT XFN ' . $non_quoted_body,
 146 );
 147
 148 # not documenting m: and mid: for now, the using the URLs works w/o Xapian
 149 # not documenting lid: for now, either, it is probably redundant with l:,
 150 # especially since we don't offer boolean searches for To/Cc/From
 151 # headers, either
 152 our @HELP = (
 153         's:' => 'match within Subject  e.g. s:"a quick brown fox"',
 154         'd:' => <<EOF,
 155 date range as YYYYMMDD  e.g. d:19931002..20101002
 156 Open-ended ranges such as d:19931002.. and d:..20101002
 157 are also supported
 158 EOF
 159         'dt:' => <<EOF,
 160 date-time range as YYYYMMDDhhmmss (e.g. dt:19931002011000..19931002011200)
 161 EOF
 162         'b:' => 'match within message body, including text attachments',
 163         'nq:' => 'match non-quoted text within message body',
 164         'q:' => 'match quoted text within message body',
 165         'n:' => 'match filename of attachment(s)',
 166         't:' => 'match within the To header',
 167         'c:' => 'match within the Cc header',
 168         'f:' => 'match within the From header',
 169         'a:' => 'match within the To, Cc, and From headers',
 170         'tc:' => 'match within the To and Cc headers',
 171         'l:' => 'match contents of the List-Id header',
 172         'bs:' => 'match within the Subject and body',
 173         'dfn:' => 'match filename from diff',
 174         'dfa:' => 'match diff removed (-) lines',
 175         'dfb:' => 'match diff added (+) lines',
 176         'dfhh:' => 'match diff hunk header context (usually a function name)',
 177         'dfctx:' => 'match diff context lines',
 178         'dfpre:' => 'match pre-image git blob ID',
 179         'dfpost:' => 'match post-image git blob ID',
 180         'dfblob:' => 'match either pre or post-image git blob ID',
 181 );
 182 chomp @HELP;
 183
 184 sub xdir ($;$) {
 185         my ($self, $rdonly) = @_;
 186         if ($rdonly || !defined($self->{shard})) {
 187                 $self->{xpfx};
 188         } else { # v2 only:
 189                 "$self->{xpfx}/$self->{shard}";
 190         }
 191 }
 192
 193 sub xdb_sharded {
 194         my ($self) = @_;
 195         opendir(my $dh, $self->{xpfx}) or return; # not initialized yet
 196
 197         # We need numeric sorting so shard[0] is first for reading
 198         # Xapian metadata, if needed
 199         my $last = max(grep(/\A[0-9]+\z/, readdir($dh)));
 200         return if !defined($last);
 201         my (@xdb, $slow_phrase);
 202         for (0..$last) {
 203                 my $shard_dir = "$self->{xpfx}/$_";
 204                 if (-d $shard_dir && -r _) {
 205                         push @xdb, $X{Database}->new($shard_dir);
 206                         $slow_phrase ||= -f "$shard_dir/iamchert";
 207                 } else { # gaps from missing epochs throw off mdocid()
 208                         warn "E: $shard_dir missing or unreadable\n";
 209                         return;
 210                 }
 211         }
 212         $self->{qp_flags} |= FLAG_PHRASE() if !$slow_phrase;
 213         $self->{nshard} = scalar(@xdb);
 214         my $xdb = shift @xdb;
 215         $xdb->add_database($_) for @xdb;
 216         $xdb;
 217 }
 218
 219 sub _xdb {
 220         my ($self) = @_;
 221         my $dir = xdir($self, 1);
 222         $self->{qp_flags} //= $QP_FLAGS;
 223         if ($self->{ibx_ver} >= 2) {
 224                 xdb_sharded($self);
 225         } else {
 226                 $self->{qp_flags} |= FLAG_PHRASE() if !-f "$dir/iamchert";
 227                 $X{Database}->new($dir);
 228         }
 229 }
 230
 231 # v2 Xapian docids don't conflict, so they're identical to
 232 # NNTP article numbers and IMAP UIDs.
 233 # https://trac.xapian.org/wiki/FAQ/MultiDatabaseDocumentID
 234 sub mdocid {
 235         my ($nshard, $mitem) = @_;
 236         my $docid = $mitem->get_docid;
 237         int(($docid - 1) / $nshard) + 1;
 238 }
 239
 240 sub mset_to_artnums {
 241         my ($self, $mset) = @_;
 242         my $nshard = $self->{nshard} // 1;
 243         [ map { mdocid($nshard, $_) } $mset->items ];
 244 }
 245
 246 sub xdb ($) {
 247         my ($self) = @_;
 248         $self->{xdb} //= do {
 249                 load_xapian();
 250                 $self->_xdb;
 251         };
 252 }
 253
 254 sub xpfx_init ($) {
 255         my ($self) = @_;
 256         if ($self->{ibx_ver} == 1) {
 257                 $self->{xpfx} .= '/public-inbox/xapian' . SCHEMA_VERSION;
 258         } else {
 259                 $self->{xpfx} .= '/xap'.SCHEMA_VERSION;
 260         }
 261 }
 262
 263 sub new {
 264         my ($class, $ibx) = @_;
 265         ref $ibx or die "BUG: expected PublicInbox::Inbox object: $ibx";
 266         my $self = bless {
 267                 xpfx => $ibx->{inboxdir}, # for xpfx_init
 268                 altid => $ibx->{altid},
 269                 ibx_ver => $ibx->version,
 270         }, $class;
 271         xpfx_init($self);
 272         $self;
 273 }
 274
 275 sub reopen {
 276         my ($self) = @_;
 277         if (my $xdb = $self->{xdb}) {
 278                 $xdb->reopen;
 279         }
 280         $self; # make chaining easier
 281 }
 282
 283 # read-only
 284 sub mset {
 285         my ($self, $query_string, $opts) = @_;
 286         $opts ||= {};
 287         my $qp = $self->{qp} //= qparse_new($self);
 288         my $query = $qp->parse_query($query_string, $self->{qp_flags});
 289         $opts->{relevance} = 1 unless exists $opts->{relevance};
 290         _do_enquire($self, $query, $opts);
 291 }
 292
 293 sub retry_reopen {
 294         my ($self, $cb, @arg) = @_;
 295         for my $i (1..10) {
 296                 if (wantarray) {
 297                         my @ret;
 298                         eval { @ret = $cb->($self, @arg) };
 299                         return @ret unless $@;
 300                 } else {
 301                         my $ret;
 302                         eval { $ret = $cb->($self, @arg) };
 303                         return $ret unless $@;
 304                 }
 305                 # Exception: The revision being read has been discarded -
 306                 # you should call Xapian::Database::reopen()
 307                 if (ref($@) =~ /\bDatabaseModifiedError\b/) {
 308                         warn "reopen try #$i on $@\n";
 309                         reopen($self);
 310                 } else {
 311                         # let caller decide how to spew, because ExtMsg queries
 312                         # get wonky and trigger:
 313                         # "something terrible happened at .../Xapian/Enquire.pm"
 314                         die;
 315                 }
 316         }
 317         die "Too many Xapian database modifications in progress\n";
 318 }
 319
 320 sub _do_enquire {
 321         my ($self, $query, $opts) = @_;
 322         retry_reopen($self, \&_enquire_once, $query, $opts);
 323 }
 324
 325 # returns true if all docs have the THREADID value
 326 sub has_threadid ($) {
 327         my ($self) = @_;
 328         (xdb($self)->get_metadata('has_threadid') // '') eq '1';
 329 }
 330
 331 sub _enquire_once { # retry_reopen callback
 332         my ($self, $query, $opts) = @_;
 333         my $xdb = xdb($self);
 334         if (defined(my $eidx_key = $opts->{eidx_key})) {
 335                 $query = $X{Query}->new(OP_FILTER(), $query, 'O'.$eidx_key);
 336         }
 337         my $enquire = $X{Enquire}->new($xdb);
 338         $enquire->set_query($query);
 339         $opts ||= {};
 340         my $desc = !$opts->{asc};
 341         if (($opts->{mset} || 0) == 2) { # mset == 2: ORDER BY docid/UID
 342                 $enquire->set_docid_order($ENQ_ASCENDING);
 343                 $enquire->set_weighting_scheme($X{BoolWeight}->new);
 344         } elsif ($opts->{relevance}) {
 345                 $enquire->set_sort_by_relevance_then_value(TS, $desc);
 346         } else {
 347                 $enquire->set_sort_by_value_then_relevance(TS, $desc);
 348         }
 349
 350         # `mairix -t / --threads' or JMAP collapseThreads
 351         if ($opts->{thread} && has_threadid($self)) {
 352                 $enquire->set_collapse_key(THREADID);
 353         }
 354         $enquire->get_mset($opts->{offset} || 0, $opts->{limit} || 50);
 355 }
 356
 357 sub mset_to_smsg {
 358         my ($self, $ibx, $mset) = @_;
 359         my $nshard = $self->{nshard} // 1;
 360         my $i = 0;
 361         my %order = map { mdocid($nshard, $_) => ++$i } $mset->items;
 362         my @msgs = sort {
 363                 $order{$a->{num}} <=> $order{$b->{num}}
 364         } @{$ibx->over->get_all(keys %order)};
 365         wantarray ? ($mset->get_matches_estimated, \@msgs) : \@msgs;
 366 }
 367
 368 # read-write
 369 sub stemmer { $X{Stem}->new($LANG) }
 370
 371 # read-only
 372 sub qparse_new ($) {
 373         my ($self) = @_;
 374
 375         my $xdb = xdb($self);
 376         my $qp = $X{QueryParser}->new;
 377         $qp->set_default_op(OP_AND());
 378         $qp->set_database($xdb);
 379         $qp->set_stemmer(stemmer($self));
 380         $qp->set_stemming_strategy(STEM_SOME());
 381         my $cb = $qp->can('set_max_wildcard_expansion') //
 382                 $qp->can('set_max_expansion'); # Xapian 1.5.0+
 383         $cb->($qp, 100);
 384         $cb = $qp->can('add_valuerangeprocessor') //
 385                 $qp->can('add_rangeprocessor'); # Xapian 1.5.0+
 386         $cb->($qp, $NVRP->new(YYYYMMDD, 'd:'));
 387         $cb->($qp, $NVRP->new(DT, 'dt:'));
 388
 389         # for IMAP, undocumented for WWW and may be split off go away
 390         $cb->($qp, $NVRP->new(BYTES, 'bytes:'));
 391         $cb->($qp, $NVRP->new(TS, 'ts:'));
 392         $cb->($qp, $NVRP->new(UID, 'uid:'));
 393
 394         while (my ($name, $prefix) = each %bool_pfx_external) {
 395                 $qp->add_boolean_prefix($name, $_) foreach split(/ /, $prefix);
 396         }
 397
 398         # we do not actually create AltId objects,
 399         # just parse the spec to avoid the extra DB handles for now.
 400         if (my $altid = $self->{altid}) {
 401                 my $user_pfx = $self->{-user_pfx} = [];
 402                 for (@$altid) {
 403                         # $_ = 'serial:gmane:/path/to/gmane.msgmap.sqlite3'
 404                         # note: Xapian supports multibyte UTF-8, /^[0-9]+$/,
 405                         # and '_' with prefixes matching \w+
 406                         /\Aserial:(\w+):/ or next;
 407                         my $pfx = $1;
 408                         push @$user_pfx, "$pfx:", <<EOF;
 409 alternate serial number  e.g. $pfx:12345 (boolean)
 410 EOF
 411                         # gmane => XGMANE
 412                         $qp->add_boolean_prefix($pfx, 'X'.uc($pfx));
 413                 }
 414                 chomp @$user_pfx;
 415         }
 416
 417         while (my ($name, $prefix) = each %prob_prefix) {
 418                 $qp->add_prefix($name, $_) foreach split(/ /, $prefix);
 419         }
 420         $qp;
 421 }
 422
 423 sub help {
 424         my ($self) = @_;
 425         $self->{qp} //= qparse_new($self); # parse altids
 426         my @ret = @HELP;
 427         if (my $user_pfx = $self->{-user_pfx}) {
 428                 push @ret, @$user_pfx;
 429         }
 430         \@ret;
 431 }
 432
 433 1;