lib/PublicInbox/Search.pm

   1 # Copyright (C) 2015-2021 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 # based on notmuch, but with no concept of folders, files or flags
   4 #
   5 # Read-only search interface for use by the web and NNTP interfaces
   6 package PublicInbox::Search;
   7 use strict;
   8 use parent qw(Exporter);
   9 our @EXPORT_OK = qw(retry_reopen int_val get_pct xap_terms);
  10 use List::Util qw(max);
  11 use POSIX qw(strftime);
  12
  13 # values for searching, changing the numeric value breaks
  14 # compatibility with old indices (so don't change them it)
  15 use constant {
  16         TS => 0, # Received: in Unix time (IMAP INTERNALDATE, JMAP receivedAt)
  17         YYYYMMDD => 1, # Date: header for searching in the WWW UI
  18         DT => 2, # Date: YYYYMMDDHHMMSS (IMAP SENT*, JMAP sentAt)
  19
  20         # added for public-inbox 1.6.0+
  21         BYTES => 3, # IMAP RFC822.SIZE
  22         UID => 4, # IMAP UID == NNTP article number == Xapian docid
  23         THREADID => 5, # RFC 8474, RFC 8621
  24
  25         # TODO
  26         # REPLYCNT => ?, # IMAP ANSWERED
  27
  28         # SCHEMA_VERSION history
  29         # 0 - initial
  30         # 1 - subject_path is lower-cased
  31         # 2 - subject_path is id_compress in the index, only
  32         # 3 - message-ID is compressed if it includes '%' (hack!)
  33         # 4 - change "Re: " normalization, avoid circular Reference ghosts
  34         # 5 - subject_path drops trailing '.'
  35         # 6 - preserve References: order in document data
  36         # 7 - remove references and inreplyto terms
  37         # 8 - remove redundant/unneeded document data
  38         # 9 - disable Message-ID compression (SHA-1)
  39         # 10 - optimize doc for NNTP overviews
  40         # 11 - merge threads when vivifying ghosts
  41         # 12 - change YYYYMMDD value column to numeric
  42         # 13 - fix threading for empty References/In-Reply-To
  43         #      (commit 83425ef12e4b65cdcecd11ddcb38175d4a91d5a0)
  44         # 14 - fix ghost root vivification
  45         # 15 - see public-inbox-v2-format(5)
  46         #      further bumps likely unnecessary, we'll suggest in-place
  47         #      "--reindex" use for further fixes and tweaks:
  48         #
  49         #      public-inbox v1.5.0 adds (still SCHEMA_VERSION=15):
  50         #      * "lid:" and "l:" for List-Id searches
  51         #
  52         #      v1.6.0 adds BYTES, UID and THREADID values
  53         SCHEMA_VERSION => 15,
  54 };
  55
  56 use PublicInbox::Smsg;
  57 use PublicInbox::Over;
  58 our $QP_FLAGS;
  59 our %X = map { $_ => 0 } qw(BoolWeight Database Enquire QueryParser Stem Query);
  60 our $Xap; # 'Search::Xapian' or 'Xapian'
  61 our $NVRP; # '$Xap::'.('NumberValueRangeProcessor' or 'NumberRangeProcessor')
  62
  63 # ENQ_DESCENDING and ENQ_ASCENDING weren't in SWIG Xapian.pm prior to 1.4.16,
  64 # let's hope the ABI is stable
  65 our $ENQ_DESCENDING = 0;
  66 our $ENQ_ASCENDING = 1;
  67
  68 sub load_xapian () {
  69         return 1 if defined $Xap;
  70         # n.b. PI_XAPIAN is intended for development use only.  We still
  71         # favor Search::Xapian since that's what's available in current
  72         # Debian stable (10.x) and derived distros.
  73         for my $x (($ENV{PI_XAPIAN} // 'Search::Xapian'), 'Xapian') {
  74                 eval "require $x";
  75                 next if $@;
  76
  77                 $x->import(qw(:standard));
  78                 $Xap = $x;
  79
  80                 # `version_string' was added in Xapian 1.1
  81                 my $xver = eval('v'.eval($x.'::version_string()')) //
  82                                 eval('v'.eval($x.'::xapian_version_string()'));
  83
  84                 # NumberRangeProcessor was added in Xapian 1.3.6,
  85                 # NumberValueRangeProcessor was removed for 1.5.0+,
  86                 # favor the older /Value/ variant since that's what our
  87                 # (currently) preferred Search::Xapian supports
  88                 $NVRP = $x.'::'.($x eq 'Xapian' && $xver ge v1.5 ?
  89                         'NumberRangeProcessor' : 'NumberValueRangeProcessor');
  90                 $X{$_} = $Xap.'::'.$_ for (keys %X);
  91
  92                 *sortable_serialise = $x.'::sortable_serialise';
  93                 *sortable_unserialise = $x.'::sortable_unserialise';
  94                 # n.b. FLAG_PURE_NOT is expensive not suitable for a public
  95                 # website as it could become a denial-of-service vector
  96                 # FLAG_PHRASE also seems to cause performance problems chert
  97                 # (and probably earlier Xapian DBs).  glass seems fine...
  98                 # TODO: make this an option, maybe?
  99                 # or make indexlevel=medium as default
 100                 $QP_FLAGS = FLAG_PHRASE() | FLAG_BOOLEAN() | FLAG_LOVEHATE() |
 101                                 FLAG_WILDCARD();
 102                 return 1;
 103         }
 104         undef;
 105 }
 106
 107 # This is English-only, everything else is non-standard and may be confused as
 108 # a prefix common in patch emails
 109 our $LANG = 'english';
 110
 111 # note: the non-X term prefix allocations are shared with
 112 # Xapian omega, see xapian-applications/omega/docs/termprefixes.rst
 113 my %bool_pfx_external = (
 114         mid => 'Q', # Message-ID (full/exact), this is mostly uniQue
 115         lid => 'G', # newsGroup (or similar entity), just inside <>
 116         dfpre => 'XDFPRE',
 117         dfpost => 'XDFPOST',
 118         dfblob => 'XDFPRE XDFPOST',
 119 );
 120
 121 my $non_quoted_body = 'XNQ XDFN XDFA XDFB XDFHH XDFCTX XDFPRE XDFPOST';
 122 my %prob_prefix = (
 123         # for mairix compatibility
 124         s => 'S',
 125         m => 'XM', # 'mid:' (bool) is exact, 'm:' (prob) can do partial
 126         l => 'XL', # 'lid:' (bool) is exact, 'l:' (prob) can do partial
 127         f => 'A',
 128         t => 'XTO',
 129         tc => 'XTO XCC',
 130         c => 'XCC',
 131         tcf => 'XTO XCC A',
 132         a => 'XTO XCC A',
 133         b => $non_quoted_body . ' XQUOT',
 134         bs => $non_quoted_body . ' XQUOT S',
 135         n => 'XFN',
 136
 137         q => 'XQUOT',
 138         nq => $non_quoted_body,
 139         dfn => 'XDFN',
 140         dfa => 'XDFA',
 141         dfb => 'XDFB',
 142         dfhh => 'XDFHH',
 143         dfctx => 'XDFCTX',
 144
 145         # default:
 146         '' => 'XM S A XQUOT XFN ' . $non_quoted_body,
 147 );
 148
 149 # not documenting m: and mid: for now, the using the URLs works w/o Xapian
 150 # not documenting lid: for now, either, it is probably redundant with l:,
 151 # especially since we don't offer boolean searches for To/Cc/From
 152 # headers, either
 153 our @HELP = (
 154         's:' => 'match within Subject  e.g. s:"a quick brown fox"',
 155         'd:' => <<EOF,
 156 date range as YYYYMMDD  e.g. d:19931002..20101002
 157 Open-ended ranges such as d:19931002.. and d:..20101002
 158 are also supported
 159 EOF
 160         'dt:' => <<EOF,
 161 date-time range as YYYYMMDDhhmmss (e.g. dt:19931002011000..19931002011200)
 162 EOF
 163         'b:' => 'match within message body, including text attachments',
 164         'nq:' => 'match non-quoted text within message body',
 165         'q:' => 'match quoted text within message body',
 166         'n:' => 'match filename of attachment(s)',
 167         't:' => 'match within the To header',
 168         'c:' => 'match within the Cc header',
 169         'f:' => 'match within the From header',
 170         'a:' => 'match within the To, Cc, and From headers',
 171         'tc:' => 'match within the To and Cc headers',
 172         'l:' => 'match contents of the List-Id header',
 173         'bs:' => 'match within the Subject and body',
 174         'dfn:' => 'match filename from diff',
 175         'dfa:' => 'match diff removed (-) lines',
 176         'dfb:' => 'match diff added (+) lines',
 177         'dfhh:' => 'match diff hunk header context (usually a function name)',
 178         'dfctx:' => 'match diff context lines',
 179         'dfpre:' => 'match pre-image git blob ID',
 180         'dfpost:' => 'match post-image git blob ID',
 181         'dfblob:' => 'match either pre or post-image git blob ID',
 182 );
 183 chomp @HELP;
 184
 185 sub xdir ($;$) {
 186         my ($self, $rdonly) = @_;
 187         if ($rdonly || !defined($self->{shard})) {
 188                 $self->{xpfx};
 189         } else { # v2 only:
 190                 "$self->{xpfx}/$self->{shard}";
 191         }
 192 }
 193
 194 # returns all shards as separate Xapian::Database objects w/o combining
 195 sub xdb_shards_flat ($) {
 196         my ($self) = @_;
 197         my $xpfx = $self->{xpfx};
 198         my (@xdb, $slow_phrase);
 199         load_xapian();
 200         $self->{qp_flags} //= $QP_FLAGS;
 201         if ($xpfx =~ m/xapian${\SCHEMA_VERSION}\z/) {
 202                 @xdb = ($X{Database}->new($xpfx));
 203                 $self->{qp_flags} |= FLAG_PHRASE() if !-f "$xpfx/iamchert";
 204         } else {
 205                 opendir(my $dh, $xpfx) or return (); # not initialized yet
 206                 # We need numeric sorting so shard[0] is first for reading
 207                 # Xapian metadata, if needed
 208                 my $last = max(grep(/\A[0-9]+\z/, readdir($dh))) // return ();
 209                 for (0..$last) {
 210                         my $shard_dir = "$self->{xpfx}/$_";
 211                         push @xdb, $X{Database}->new($shard_dir);
 212                         $slow_phrase ||= -f "$shard_dir/iamchert";
 213                 }
 214                 $self->{qp_flags} |= FLAG_PHRASE() if !$slow_phrase;
 215         }
 216         @xdb;
 217 }
 218
 219 # v2 Xapian docids don't conflict, so they're identical to
 220 # NNTP article numbers and IMAP UIDs.
 221 # https://trac.xapian.org/wiki/FAQ/MultiDatabaseDocumentID
 222 sub mdocid {
 223         my ($nshard, $mitem) = @_;
 224         my $docid = $mitem->get_docid;
 225         int(($docid - 1) / $nshard) + 1;
 226 }
 227
 228 sub mset_to_artnums {
 229         my ($self, $mset) = @_;
 230         my $nshard = $self->{nshard};
 231         [ map { mdocid($nshard, $_) } $mset->items ];
 232 }
 233
 234 sub xdb ($) {
 235         my ($self) = @_;
 236         $self->{xdb} //= do {
 237                 my @xdb = $self->xdb_shards_flat or return;
 238                 $self->{nshard} = scalar(@xdb);
 239                 my $xdb = shift @xdb;
 240                 $xdb->add_database($_) for @xdb;
 241                 $xdb;
 242         };
 243 }
 244
 245 sub new {
 246         my ($class, $ibx) = @_;
 247         ref $ibx or die "BUG: expected PublicInbox::Inbox object: $ibx";
 248         my $xap = $ibx->version > 1 ? 'xap' : 'public-inbox/xapian';
 249         bless {
 250                 xpfx => "$ibx->{inboxdir}/$xap" . SCHEMA_VERSION,
 251                 altid => $ibx->{altid},
 252         }, $class;
 253 }
 254
 255 sub reopen {
 256         my ($self) = @_;
 257         if (my $xdb = $self->{xdb}) {
 258                 $xdb->reopen;
 259         }
 260         $self; # make chaining easier
 261 }
 262
 263 # Convert git "approxidate" ranges to something usable with our
 264 # Xapian indices.  At the moment, Xapian only offers a C++-only API
 265 # and neither the SWIG nor XS bindings allow us to use custom code
 266 # to parse dates (and libgit2 doesn't expose git__date_parse, either,
 267 # so we're running git-rev-parse(1)).
 268 # This replaces things we need to send to $git->date_parse with
 269 # "\0".$strftime_format.['+'|$idx]."\0" placeholders
 270 sub date_parse_prepare {
 271         my ($to_parse, $pfx, $range) = @_;
 272         # are we inside a parenthesized statement?
 273         my $end = $range =~ s/([\)\s]*)\z// ? $1 : '';
 274         my @r = split(/\.\./, $range, 2);
 275
 276         # expand "d:20101002" => "d:20101002..20101003" and like
 277         # n.b. git doesn't do YYYYMMDD w/o '-', it needs YYYY-MM-DD
 278         if ($pfx eq 'd') {
 279                 if (!defined($r[1])) {
 280                         if ($r[0] =~ /\A([0-9]{4})([0-9]{2})([0-9]{2})\z/) {
 281                                 push @$to_parse, "$1-$2-$3";
 282                                 # we could've handled as-is, but we need
 283                                 # to parse anyways for "d+" below
 284                         } else {
 285                                 push @$to_parse, $r[0];
 286                         }
 287                         $r[0] = "\0%Y%m%d$#$to_parse\0";
 288                         $r[1] = "\0%Y%m%d+\0";
 289                 } else {
 290                         for my $x (@r) {
 291                                 next if $x eq '' || $x =~ /\A[0-9]{8}\z/;
 292                                 push @$to_parse, $x;
 293                                 $x = "\0%Y%m%d$#$to_parse\0";
 294                         }
 295                 }
 296         } elsif ($pfx eq 'dt') {
 297                 if (!defined($r[1])) { # git needs gaps and not /\d{14}/
 298                         if ($r[0] =~ /\A([0-9]{4})([0-9]{2})([0-9]{2})
 299                                         ([0-9]{2})([0-9]{2})([0-9]{2})\z/x) {
 300                                 push @$to_parse, "$1-$2-$3 $4:$5:$6";
 301                         } else {
 302                                 push @$to_parse, $r[0];
 303                         }
 304                         $r[0] = "\0%Y%m%d%H%M%S$#$to_parse\0";
 305                         $r[1] = "\0%Y%m%d%H%M%S+\0";
 306                 } else {
 307                         for my $x (@r) {
 308                                 next if $x eq '' || $x =~ /\A[0-9]{14}\z/;
 309                                 push @$to_parse, $x;
 310                                 $x = "\0%Y%m%d%H%M%S$#$to_parse\0";
 311                         }
 312                 }
 313         } else { # "rt", let git interpret "YYYY", deal with Y10K later :P
 314                 for my $x (@r) {
 315                         next if $x eq '' || $x =~ /\A[0-9]{5,}\z/;
 316                         push @$to_parse, $x;
 317                         $x = "\0%s$#$to_parse\0";
 318                 }
 319                 $r[1] //= "\0%s+\0";
 320         }
 321         "$pfx:".join('..', @r).$end;
 322 }
 323
 324 sub date_parse_finalize {
 325         my ($git, $to_parse) = @_;
 326         # git-rev-parse can handle any number of args up to system
 327         # limits (around (4096*32) bytes on Linux).
 328         my @r = $git->date_parse(@$to_parse);
 329         my $i;
 330         $_[2] =~ s/\0(%[%YmdHMSs]+)([0-9\+]+)\0/strftime($1,
 331                 gmtime($2 eq '+' ? ($r[$i]+86400) : $r[$i=$2+0]))/sge;
 332 }
 333
 334 # n.b. argv never has NUL, though we'll need to filter it out
 335 # if this $argv isn't from a command execution
 336 sub query_argv_to_string {
 337         my (undef, $git, $argv) = @_;
 338         my $to_parse;
 339         my $tmp = join(' ', map {;
 340                 if (s!\b(d|rt|dt):(\S+)\z!date_parse_prepare(
 341                                                 $to_parse //= [], $1, $2)!sge) {
 342                         $_;
 343                 } elsif (/\s/) {
 344                         s/(.*?)\b(\w+:)// ? qq{$1$2"$_"} : qq{"$_"};
 345                 } else {
 346                         $_
 347                 }
 348         } @$argv);
 349         date_parse_finalize($git, $to_parse, $tmp) if $to_parse;
 350         $tmp
 351 }
 352
 353 # this is for the WWW "q=" query parameter and "lei q --stdin"
 354 # it can't do d:"5 days ago", but it will do d:5.days.ago
 355 sub query_approxidate {
 356         my (undef, $git) = @_; # $_[2] = $query_string (modified in-place)
 357         my $DQ = qq<"\x{201c}\x{201d}>; # Xapian can use curly quotes
 358         $_[2] =~ tr/\x00/ /; # Xapian doesn't do NUL, we use it as a placeholder
 359         my ($terms, $phrase, $to_parse);
 360         $_[2] =~ s{([^$DQ]*)([$DQ][^$DQ]*[$DQ])?}{
 361                 ($terms, $phrase) = ($1, $2);
 362                 $terms =~ s!\b(d|rt|dt):(\S+)!
 363                         date_parse_prepare($to_parse //= [], $1, $2)!sge;
 364                 $terms.($phrase // '');
 365                 }sge;
 366         date_parse_finalize($git, $to_parse, $_[2]) if $to_parse;
 367 }
 368
 369 # read-only
 370 sub mset {
 371         my ($self, $query_string, $opts) = @_;
 372         $opts ||= {};
 373         my $qp = $self->{qp} //= qparse_new($self);
 374         my $query = $qp->parse_query($query_string, $self->{qp_flags});
 375         _do_enquire($self, $query, $opts);
 376 }
 377
 378 sub retry_reopen {
 379         my ($self, $cb, @arg) = @_;
 380         for my $i (1..10) {
 381                 if (wantarray) {
 382                         my @ret;
 383                         eval { @ret = $cb->($self, @arg) };
 384                         return @ret unless $@;
 385                 } else {
 386                         my $ret;
 387                         eval { $ret = $cb->($self, @arg) };
 388                         return $ret unless $@;
 389                 }
 390                 # Exception: The revision being read has been discarded -
 391                 # you should call Xapian::Database::reopen()
 392                 if (ref($@) =~ /\bDatabaseModifiedError\b/) {
 393                         warn "reopen try #$i on $@\n";
 394                         reopen($self);
 395                 } else {
 396                         # let caller decide how to spew, because ExtMsg queries
 397                         # get wonky and trigger:
 398                         # "something terrible happened at .../Xapian/Enquire.pm"
 399                         die;
 400                 }
 401         }
 402         die "Too many Xapian database modifications in progress\n";
 403 }
 404
 405 sub _do_enquire {
 406         my ($self, $query, $opts) = @_;
 407         retry_reopen($self, \&_enquire_once, $query, $opts);
 408 }
 409
 410 # returns true if all docs have the THREADID value
 411 sub has_threadid ($) {
 412         my ($self) = @_;
 413         (xdb($self)->get_metadata('has_threadid') // '') eq '1';
 414 }
 415
 416 sub _enquire_once { # retry_reopen callback
 417         my ($self, $query, $opts) = @_;
 418         my $xdb = xdb($self);
 419         if (defined(my $eidx_key = $opts->{eidx_key})) {
 420                 $query = $X{Query}->new(OP_FILTER(), $query, 'O'.$eidx_key);
 421         }
 422         if (defined(my $uid_range = $opts->{uid_range})) {
 423                 my $range = $X{Query}->new(OP_VALUE_RANGE(), UID,
 424                                         sortable_serialise($uid_range->[0]),
 425                                         sortable_serialise($uid_range->[1]));
 426                 $query = $X{Query}->new(OP_FILTER(), $query, $range);
 427         }
 428         my $enquire = $X{Enquire}->new($xdb);
 429         $enquire->set_query($query);
 430         $opts ||= {};
 431         my $rel = $opts->{relevance} // 0;
 432         if ($rel == -2) { # ORDER BY docid/UID (highest first)
 433                 $enquire->set_weighting_scheme($X{BoolWeight}->new);
 434                 $enquire->set_docid_order($ENQ_DESCENDING);
 435         } elsif ($rel == -1) { # ORDER BY docid/UID (lowest first)
 436                 $enquire->set_weighting_scheme($X{BoolWeight}->new);
 437                 $enquire->set_docid_order($ENQ_ASCENDING);
 438         } elsif ($rel == 0) {
 439                 $enquire->set_sort_by_value_then_relevance(TS, !$opts->{asc});
 440         } else { # rel > 0
 441                 $enquire->set_sort_by_relevance_then_value(TS, !$opts->{asc});
 442         }
 443
 444         # `mairix -t / --threads' or JMAP collapseThreads
 445         if ($opts->{threads} && has_threadid($self)) {
 446                 $enquire->set_collapse_key(THREADID);
 447         }
 448         $enquire->get_mset($opts->{offset} || 0, $opts->{limit} || 50);
 449 }
 450
 451 sub mset_to_smsg {
 452         my ($self, $ibx, $mset) = @_;
 453         my $nshard = $self->{nshard};
 454         my $i = 0;
 455         my %order = map { mdocid($nshard, $_) => ++$i } $mset->items;
 456         my @msgs = sort {
 457                 $order{$a->{num}} <=> $order{$b->{num}}
 458         } @{$ibx->over->get_all(keys %order)};
 459         wantarray ? ($mset->get_matches_estimated, \@msgs) : \@msgs;
 460 }
 461
 462 # read-write
 463 sub stemmer { $X{Stem}->new($LANG) }
 464
 465 # read-only
 466 sub qparse_new ($) {
 467         my ($self) = @_;
 468
 469         my $xdb = xdb($self);
 470         my $qp = $X{QueryParser}->new;
 471         $qp->set_default_op(OP_AND());
 472         $qp->set_database($xdb);
 473         $qp->set_stemmer(stemmer($self));
 474         $qp->set_stemming_strategy(STEM_SOME());
 475         my $cb = $qp->can('set_max_wildcard_expansion') //
 476                 $qp->can('set_max_expansion'); # Xapian 1.5.0+
 477         $cb->($qp, 100);
 478         $cb = $qp->can('add_valuerangeprocessor') //
 479                 $qp->can('add_rangeprocessor'); # Xapian 1.5.0+
 480         $cb->($qp, $NVRP->new(YYYYMMDD, 'd:'));
 481         $cb->($qp, $NVRP->new(DT, 'dt:'));
 482
 483         # for IMAP, undocumented for WWW and may be split off go away
 484         $cb->($qp, $NVRP->new(BYTES, 'z:'));
 485         $cb->($qp, $NVRP->new(TS, 'rt:'));
 486         $cb->($qp, $NVRP->new(UID, 'uid:'));
 487
 488         while (my ($name, $prefix) = each %bool_pfx_external) {
 489                 $qp->add_boolean_prefix($name, $_) foreach split(/ /, $prefix);
 490         }
 491
 492         # we do not actually create AltId objects,
 493         # just parse the spec to avoid the extra DB handles for now.
 494         if (my $altid = $self->{altid}) {
 495                 my $user_pfx = $self->{-user_pfx} = [];
 496                 for (@$altid) {
 497                         # $_ = 'serial:gmane:/path/to/gmane.msgmap.sqlite3'
 498                         # note: Xapian supports multibyte UTF-8, /^[0-9]+$/,
 499                         # and '_' with prefixes matching \w+
 500                         /\Aserial:(\w+):/ or next;
 501                         my $pfx = $1;
 502                         push @$user_pfx, "$pfx:", <<EOF;
 503 alternate serial number  e.g. $pfx:12345 (boolean)
 504 EOF
 505                         # gmane => XGMANE
 506                         $qp->add_boolean_prefix($pfx, 'X'.uc($pfx));
 507                 }
 508                 chomp @$user_pfx;
 509         }
 510
 511         while (my ($name, $prefix) = each %prob_prefix) {
 512                 $qp->add_prefix($name, $_) foreach split(/ /, $prefix);
 513         }
 514         $qp;
 515 }
 516
 517 sub help {
 518         my ($self) = @_;
 519         $self->{qp} //= qparse_new($self); # parse altids
 520         my @ret = @HELP;
 521         if (my $user_pfx = $self->{-user_pfx}) {
 522                 push @ret, @$user_pfx;
 523         }
 524         \@ret;
 525 }
 526
 527 sub int_val ($$) {
 528         my ($doc, $col) = @_;
 529         my $val = $doc->get_value($col) or return; # undefined is '' in Xapian
 530         sortable_unserialise($val) + 0; # PV => IV conversion
 531 }
 532
 533 sub get_pct ($) { # mset item
 534         # Capped at "99%" since "100%" takes an extra column in the
 535         # thread skeleton view.  <xapian/mset.h> says the value isn't
 536         # very meaningful, anyways.
 537         my $n = $_[0]->get_percent;
 538         $n > 99 ? 99 : $n;
 539 }
 540
 541 sub xap_terms ($$;@) {
 542         my ($pfx, $xdb_or_doc, @docid) = @_; # @docid may be empty ()
 543         my %ret;
 544         eval {
 545                 my $end = $xdb_or_doc->termlist_end(@docid);
 546                 my $cur = $xdb_or_doc->termlist_begin(@docid);
 547                 for (; $cur != $end; $cur++) {
 548                         $cur->skip_to($pfx);
 549                         last if $cur == $end;
 550                         my $tn = $cur->get_termname;
 551                         if (index($tn, $pfx) == 0) {
 552                                 $ret{substr($tn, length($pfx))} = undef;
 553                         }
 554                 }
 555         };
 556         \%ret;
 557 }
 558
 559 1;