lib/PublicInbox/Search.pm

   1 # Copyright (C) 2015-2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 # based on notmuch, but with no concept of folders, files or flags
   4 #
   5 # Read-only search interface for use by the web and NNTP interfaces
   6 package PublicInbox::Search;
   7 use strict;
   8 use warnings;
   9
  10 # values for searching
  11 use constant TS => 0;  # Received: header in Unix time
  12 use constant YYYYMMDD => 1; # for searching in the WWW UI
  13
  14 use Search::Xapian qw/:standard/;
  15 use PublicInbox::SearchMsg;
  16 use PublicInbox::MIME;
  17 use PublicInbox::MID qw/id_compress/;
  18 use PublicInbox::Over;
  19
  20 # This is English-only, everything else is non-standard and may be confused as
  21 # a prefix common in patch emails
  22 our $REPLY_RE = qr/^re:\s+/i;
  23 our $LANG = 'english';
  24
  25 use constant {
  26         # SCHEMA_VERSION history
  27         # 0 - initial
  28         # 1 - subject_path is lower-cased
  29         # 2 - subject_path is id_compress in the index, only
  30         # 3 - message-ID is compressed if it includes '%' (hack!)
  31         # 4 - change "Re: " normalization, avoid circular Reference ghosts
  32         # 5 - subject_path drops trailing '.'
  33         # 6 - preserve References: order in document data
  34         # 7 - remove references and inreplyto terms
  35         # 8 - remove redundant/unneeded document data
  36         # 9 - disable Message-ID compression (SHA-1)
  37         # 10 - optimize doc for NNTP overviews
  38         # 11 - merge threads when vivifying ghosts
  39         # 12 - change YYYYMMDD value column to numeric
  40         # 13 - fix threading for empty References/In-Reply-To
  41         #      (commit 83425ef12e4b65cdcecd11ddcb38175d4a91d5a0)
  42         # 14 - fix ghost root vivification
  43         SCHEMA_VERSION => 15,
  44
  45         # n.b. FLAG_PURE_NOT is expensive not suitable for a public website
  46         # as it could become a denial-of-service vector
  47         QP_FLAGS => FLAG_PHRASE|FLAG_BOOLEAN|FLAG_LOVEHATE|FLAG_WILDCARD,
  48 };
  49
  50 my %bool_pfx_external = (
  51         mid => 'Q', # Message-ID (full/exact), this is mostly uniQue
  52 );
  53
  54 my $non_quoted_body = 'XNQ XDFN XDFA XDFB XDFHH XDFCTX XDFPRE XDFPOST';
  55 my %prob_prefix = (
  56         # for mairix compatibility
  57         s => 'S',
  58         m => 'XM', # 'mid:' (bool) is exact, 'm:' (prob) can do partial
  59         f => 'A',
  60         t => 'XTO',
  61         tc => 'XTO XCC',
  62         c => 'XCC',
  63         tcf => 'XTO XCC A',
  64         a => 'XTO XCC A',
  65         b => $non_quoted_body . ' XQUOT',
  66         bs => $non_quoted_body . ' XQUOT S',
  67         n => 'XFN',
  68
  69         q => 'XQUOT',
  70         nq => $non_quoted_body,
  71         dfn => 'XDFN',
  72         dfa => 'XDFA',
  73         dfb => 'XDFB',
  74         dfhh => 'XDFHH',
  75         dfctx => 'XDFCTX',
  76         dfpre => 'XDFPRE',
  77         dfpost => 'XDFPOST',
  78         dfblob => 'XDFPRE XDFPOST',
  79
  80         # default:
  81         '' => 'XM S A XQUOT XFN ' . $non_quoted_body,
  82 );
  83
  84 # not documenting m: and mid: for now, the using the URLs works w/o Xapian
  85 our @HELP = (
  86         's:' => 'match within Subject  e.g. s:"a quick brown fox"',
  87         'd:' => <<EOF,
  88 date range as YYYYMMDD  e.g. d:19931002..20101002
  89 Open-ended ranges such as d:19931002.. and d:..20101002
  90 are also supported
  91 EOF
  92         'b:' => 'match within message body, including text attachments',
  93         'nq:' => 'match non-quoted text within message body',
  94         'q:' => 'match quoted text within message body',
  95         'n:' => 'match filename of attachment(s)',
  96         't:' => 'match within the To header',
  97         'c:' => 'match within the Cc header',
  98         'f:' => 'match within the From header',
  99         'a:' => 'match within the To, Cc, and From headers',
 100         'tc:' => 'match within the To and Cc headers',
 101         'bs:' => 'match within the Subject and body',
 102         'dfn:' => 'match filename from diff',
 103         'dfa:' => 'match diff removed (-) lines',
 104         'dfb:' => 'match diff added (+) lines',
 105         'dfhh:' => 'match diff hunk header context (usually a function name)',
 106         'dfctx:' => 'match diff context lines',
 107         'dfpre:' => 'match pre-image git blob ID',
 108         'dfpost:' => 'match post-image git blob ID',
 109         'dfblob:' => 'match either pre or post-image git blob ID',
 110 );
 111 chomp @HELP;
 112
 113 sub xdir {
 114         my ($self) = @_;
 115         if ($self->{version} == 1) {
 116                 "$self->{mainrepo}/public-inbox/xapian" . SCHEMA_VERSION;
 117         } else {
 118                 my $dir = "$self->{mainrepo}/xap" . SCHEMA_VERSION;
 119                 my $part = $self->{partition};
 120                 defined $part or die "partition not given";
 121                 $dir .= "/$part";
 122         }
 123 }
 124
 125 sub new {
 126         my ($class, $mainrepo, $altid) = @_;
 127         my $version = 1;
 128         my $ibx = $mainrepo;
 129         if (ref $ibx) {
 130                 $version = $ibx->{version} || 1;
 131                 $mainrepo = $ibx->{mainrepo};
 132         }
 133         my $self = bless {
 134                 mainrepo => $mainrepo,
 135                 altid => $altid,
 136                 version => $version,
 137         }, $class;
 138         my $dir;
 139         if ($version >= 2) {
 140                 $dir = "$self->{mainrepo}/xap" . SCHEMA_VERSION;
 141                 my $xdb;
 142                 my $parts = 0;
 143                 foreach my $part (<$dir/*>) {
 144                         -d $part && $part =~ m!/\d+\z! or next;
 145                         $parts++;
 146                         my $sub = Search::Xapian::Database->new($part);
 147                         if ($xdb) {
 148                                 $xdb->add_database($sub);
 149                         } else {
 150                                 $xdb = $sub;
 151                         }
 152                 }
 153                 $self->{xdb} = $xdb;
 154         } else {
 155                 $dir = $self->xdir;
 156                 $self->{xdb} = Search::Xapian::Database->new($dir);
 157         }
 158         $self->{over_ro} = PublicInbox::Over->new("$dir/over.sqlite3");
 159         $self;
 160 }
 161
 162 sub reopen {
 163         my ($self) = @_;
 164         $self->{xdb}->reopen;
 165         $self; # make chaining easier
 166 }
 167
 168 # read-only
 169 sub query {
 170         my ($self, $query_string, $opts) = @_;
 171         $opts ||= {};
 172         if ($query_string eq '' && !$opts->{mset}) {
 173                 $self->{over_ro}->recent($opts);
 174         } else {
 175                 my $query = $self->qp->parse_query($query_string, QP_FLAGS);
 176                 $opts->{relevance} = 1 unless exists $opts->{relevance};
 177                 _do_enquire($self, $query, $opts);
 178         }
 179 }
 180
 181 sub get_thread {
 182         my ($self, $mid, $opts) = @_;
 183         $self->{over_ro}->get_thread($mid, $opts);
 184 }
 185
 186 sub retry_reopen {
 187         my ($self, $cb) = @_;
 188         for my $i (1..10) {
 189                 if (wantarray) {
 190                         my @ret;
 191                         eval { @ret = $cb->() };
 192                         return @ret unless $@;
 193                 } else {
 194                         my $ret;
 195                         eval { $ret = $cb->() };
 196                         return $ret unless $@;
 197                 }
 198                 # Exception: The revision being read has been discarded -
 199                 # you should call Xapian::Database::reopen()
 200                 if (ref($@) eq 'Search::Xapian::DatabaseModifiedError') {
 201                         warn "reopen try #$i on $@\n";
 202                         reopen($self);
 203                 } else {
 204                         warn "ref: ", ref($@), "\n";
 205                         die;
 206                 }
 207         }
 208         die "Too many Xapian database modifications in progress\n";
 209 }
 210
 211 sub _do_enquire {
 212         my ($self, $query, $opts) = @_;
 213         retry_reopen($self, sub { _enquire_once($self, $query, $opts) });
 214 }
 215
 216 sub _enquire_once {
 217         my ($self, $query, $opts) = @_;
 218         my $enquire = enquire($self);
 219         $query = Search::Xapian::Query->new(OP_AND,$query);
 220         $enquire->set_query($query);
 221         $opts ||= {};
 222         my $desc = !$opts->{asc};
 223         if ($opts->{relevance}) {
 224                 $enquire->set_sort_by_relevance_then_value(TS, $desc);
 225         } else {
 226                 $enquire->set_sort_by_value_then_relevance(TS, $desc);
 227         }
 228         my $offset = $opts->{offset} || 0;
 229         my $limit = $opts->{limit} || 50;
 230         my $mset = $enquire->get_mset($offset, $limit);
 231         return $mset if $opts->{mset};
 232         my @msgs = map {
 233                 PublicInbox::SearchMsg->load_doc($_->get_document);
 234         } $mset->items;
 235         return \@msgs unless wantarray;
 236
 237         ($mset->get_matches_estimated, \@msgs)
 238 }
 239
 240 # read-write
 241 sub stemmer { Search::Xapian::Stem->new($LANG) }
 242
 243 # read-only
 244 sub qp {
 245         my ($self) = @_;
 246
 247         my $qp = $self->{query_parser};
 248         return $qp if $qp;
 249
 250         # new parser
 251         $qp = Search::Xapian::QueryParser->new;
 252         $qp->set_default_op(OP_AND);
 253         $qp->set_database($self->{xdb});
 254         $qp->set_stemmer($self->stemmer);
 255         $qp->set_stemming_strategy(STEM_SOME);
 256         $qp->add_valuerangeprocessor(
 257                 Search::Xapian::NumberValueRangeProcessor->new(YYYYMMDD, 'd:'));
 258
 259         while (my ($name, $prefix) = each %bool_pfx_external) {
 260                 $qp->add_boolean_prefix($name, $prefix);
 261         }
 262
 263         # we do not actually create AltId objects,
 264         # just parse the spec to avoid the extra DB handles for now.
 265         if (my $altid = $self->{altid}) {
 266                 my $user_pfx = $self->{-user_pfx} ||= [];
 267                 for (@$altid) {
 268                         # $_ = 'serial:gmane:/path/to/gmane.msgmap.sqlite3'
 269                         /\Aserial:(\w+):/ or next;
 270                         my $pfx = $1;
 271                         push @$user_pfx, "$pfx:", <<EOF;
 272 alternate serial number  e.g. $pfx:12345 (boolean)
 273 EOF
 274                         # gmane => XGMANE
 275                         $qp->add_boolean_prefix($pfx, 'X'.uc($pfx));
 276                 }
 277                 chomp @$user_pfx;
 278         }
 279
 280         while (my ($name, $prefix) = each %prob_prefix) {
 281                 $qp->add_prefix($name, $_) foreach split(/ /, $prefix);
 282         }
 283
 284         $self->{query_parser} = $qp;
 285 }
 286
 287 # only used for NNTP server
 288 sub query_xover {
 289         my ($self, $beg, $end, $offset) = @_;
 290         $self->{over_ro}->query_xover($beg, $end, $offset);
 291 }
 292
 293 sub query_ts {
 294         my ($self, $ts, $prev) = @_;
 295         $self->{over_ro}->query_ts($ts, $prev);
 296 }
 297
 298 sub first_smsg_by_mid {
 299         my ($self, $mid) = @_;
 300         my $smsg;
 301         retry_reopen($self, sub {
 302                 each_smsg_by_mid($self, $mid, sub { $smsg = $_[0]; undef });
 303         });
 304         $smsg;
 305 }
 306
 307 sub lookup_article {
 308         my ($self, $num) = @_;
 309         my $term = 'XNUM'.$num;
 310         my $db = $self->{xdb};
 311         retry_reopen($self, sub {
 312                 my $head = $db->postlist_begin($term);
 313                 my $tail = $db->postlist_end($term);
 314                 return if $head->equal($tail);
 315                 my $doc_id = $head->get_docid;
 316                 return unless defined $doc_id;
 317                 $head->inc;
 318                 if ($head->nequal($tail)) {
 319                         warn "article #$num is not unique\n";
 320                 }
 321                 # raises on error:
 322                 my $doc = $db->get_document($doc_id);
 323                 my $smsg = PublicInbox::SearchMsg->wrap($doc);
 324                 $smsg->{doc_id} = $doc_id;
 325                 $smsg->load_expand;
 326         });
 327 }
 328
 329 sub each_smsg_by_mid {
 330         my ($self, $mid, $cb) = @_;
 331         # XXX retry_reopen isn't necessary for V2Writable, but the PSGI
 332         # interface will need it...
 333         my $db = $self->{xdb};
 334         my $term = 'Q' . $mid;
 335         my $head = $db->postlist_begin($term);
 336         my $tail = $db->postlist_end($term);
 337         if ($head == $tail) {
 338                 $db->reopen;
 339                 $head = $db->postlist_begin($term);
 340                 $tail = $db->postlist_end($term);
 341         }
 342         return ($head, $tail, $db) if wantarray;
 343         for (; $head->nequal($tail); $head->inc) {
 344                 my $doc_id = $head->get_docid;
 345                 my $doc = $db->get_document($doc_id);
 346                 my $smsg = PublicInbox::SearchMsg->wrap($doc, $mid);
 347                 $smsg->{doc_id} = $doc_id;
 348                 $cb->($smsg) or return;
 349         }
 350 }
 351
 352 # normalize subjects so they are suitable as pathnames for URLs
 353 # XXX: consider for removal
 354 sub subject_path {
 355         my $subj = pop;
 356         $subj = subject_normalized($subj);
 357         $subj =~ s![^a-zA-Z0-9_\.~/\-]+!_!g;
 358         lc($subj);
 359 }
 360
 361 sub subject_normalized {
 362         my $subj = pop;
 363         $subj =~ s/\A\s+//s; # no leading space
 364         $subj =~ s/\s+\z//s; # no trailing space
 365         $subj =~ s/\s+/ /gs; # no redundant spaces
 366         $subj =~ s/\.+\z//; # no trailing '.'
 367         $subj =~ s/$REPLY_RE//igo; # remove reply prefix
 368         $subj;
 369 }
 370
 371 sub enquire {
 372         my ($self) = @_;
 373         $self->{enquire} ||= Search::Xapian::Enquire->new($self->{xdb});
 374 }
 375
 376 sub help {
 377         my ($self) = @_;
 378         $self->qp; # parse altids
 379         my @ret = @HELP;
 380         if (my $user_pfx = $self->{-user_pfx}) {
 381                 push @ret, @$user_pfx;
 382         }
 383         \@ret;
 384 }
 385
 386 1;