lib/PublicInbox/Search.pm

   1 # Copyright (C) 2015, all contributors <meta@public-inbox.org>
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 # based on notmuch, but with no concept of folders, files or flags
   4 package PublicInbox::Search;
   5 use strict;
   6 use warnings;
   7 use PublicInbox::SearchMsg;
   8 use base qw/Exporter/;
   9 use Digest::SHA qw//;
  10 use Search::Xapian qw/:standard/;
  11 require PublicInbox::View;
  12 use Date::Parse qw/str2time/;
  13 use POSIX qw//;
  14 use Email::MIME;
  15
  16 our @EXPORT = qw/xpfx mid_compressed/;
  17
  18 use constant {
  19         TS => 0,
  20         SHA1HEX_LEN => 40,
  21         SCHEMA_VERSION => 0,
  22         LANG => 'english',
  23         QP_FLAGS => FLAG_PHRASE|FLAG_BOOLEAN|FLAG_LOVEHATE|FLAG_WILDCARD,
  24 };
  25
  26 use constant MID_MAX => SHA1HEX_LEN;
  27
  28 # setup prefixes
  29 my %bool_pfx_internal = (
  30         type => 'T', # "mail" or "ghost"
  31         mid => 'Q', # uniQue id (Message-ID or mid_compressed)
  32 );
  33
  34 my %bool_pfx_external = (
  35         path => 'XPATH',
  36         thread => 'G', # newsGroup (or similar entity - e.g. a web forum name)
  37         references => 'XREFS',
  38         inreplyto => 'XIRT',
  39 );
  40
  41 my %prob_prefix = (
  42         subject => 'S',
  43 );
  44
  45 my %all_pfx = (%bool_pfx_internal, %bool_pfx_external, %prob_prefix);
  46
  47 sub xpfx { $all_pfx{$_[0]} }
  48
  49 our %PFX2TERM_RMAP;
  50 while (my ($k, $v) = each %all_pfx) {
  51         next if $prob_prefix{$k};
  52         $PFX2TERM_RMAP{$v} = $k;
  53 }
  54
  55 my $mail_query = Search::Xapian::Query->new(xpfx('type') . 'mail');
  56
  57 # this is idempotent
  58 sub mid_compressed {
  59         my ($mid) = @_;
  60         return $mid if (length($mid) <= MID_MAX);
  61         Digest::SHA::sha1_hex($mid);
  62 }
  63
  64 sub new {
  65         my ($class, $git_dir, $writable) = @_;
  66         # allow concurrent versions for easier rollback:
  67         my $dir = "$git_dir/public-inbox/xapian" . SCHEMA_VERSION;
  68         my $db;
  69
  70         if ($writable) { # not used by the WWW interface
  71                 require Search::Xapian::WritableDatabase;
  72                 require File::Path;
  73                 File::Path::mkpath($dir);
  74                 $db = Search::Xapian::WritableDatabase->new($dir,
  75                                         Search::Xapian::DB_CREATE_OR_OPEN);
  76         } else {
  77                 $db = Search::Xapian::Database->new($dir);
  78         }
  79         bless { xdb => $db, git_dir => $git_dir }, $class;
  80 }
  81
  82 sub reopen { $_[0]->{xdb}->reopen }
  83
  84 sub add_message {
  85         my ($self, $mime) = @_; # mime = Email::MIME object
  86         my $db = $self->{xdb};
  87
  88         my $doc_id;
  89         my $mid = clean_mid($mime->header('Message-ID'));
  90         $mid = mid_compressed($mid);
  91         my $was_ghost = 0;
  92         my $ct_msg = $mime->header('Content-Type') || 'text/plain';
  93         my $enc_msg = PublicInbox::View::enc_for($ct_msg);
  94
  95         $db->begin_transaction;
  96         eval {
  97                 my $smsg = $self->lookup_message($mid);
  98                 my $doc;
  99
 100                 if ($smsg) {
 101                         $smsg->ensure_metadata;
 102                         # convert a ghost to a regular message
 103                         # it will also clobber any existing regular message
 104                         $smsg->mime($mime);
 105                         $doc = $smsg->{doc};
 106
 107                         my $type = xpfx('type');
 108                         eval {
 109                                 $doc->remove_term($type . 'ghost');
 110                                 $was_ghost = 1;
 111                         };
 112
 113                         # probably does not exist:
 114                         eval { $doc->remove_term($type . 'mail') };
 115                         $doc->add_term($type . 'mail');
 116                 }  else {
 117                         $smsg = PublicInbox::SearchMsg->new($mime);
 118                         $doc = $smsg->{doc};
 119                         $doc->add_term(xpfx('mid') . $mid);
 120                 }
 121
 122                 my $subj = $mime->header('Subject');
 123                 $subj = '' unless defined $subj;
 124
 125                 if (length $subj) {
 126                         $doc->add_term(xpfx('subject') . $subj);
 127
 128                         my $path = subject_path($subj);
 129                         $doc->add_term(xpfx('path') . $path);
 130                 }
 131
 132                 my $from = $mime->header('From') || '';
 133                 my @from;
 134
 135                 if ($from) {
 136                         @from = Email::Address->parse($from);
 137                         $from = $from[0]->name;
 138                 }
 139
 140                 my $ts = eval { str2time($mime->header('Date')) } || 0;
 141                 my $date = POSIX::strftime('%Y-%m-%d %H:%M', gmtime($ts));
 142                 $ts = Search::Xapian::sortable_serialise($ts);
 143                 $doc->add_value(PublicInbox::Search::TS, $ts);
 144
 145                 # this is what we show in index results:
 146                 $subj =~ tr/\n/ /;
 147                 $from =~ tr/\n/ /;
 148                 $doc->set_data("$mid\n$subj\n$from\n$date");
 149
 150                 my $tg = $self->term_generator;
 151
 152                 $tg->set_document($doc);
 153                 $tg->index_text($subj, 1, 'S') if $subj;
 154                 $tg->increase_termpos;
 155                 $tg->index_text($subj) if $subj;
 156                 $tg->increase_termpos;
 157
 158                 if (@from) {
 159                         $tg->index_text($from[0]->format);
 160                         $tg->increase_termpos;
 161                 }
 162
 163                 $mime->walk_parts(sub {
 164                         my ($part) = @_;
 165                         return if $part->subparts; # walk_parts already recurses
 166                         my $ct = $part->content_type || $ct_msg;
 167
 168                         # account for filter bugs...
 169                         $ct =~ m!\btext/plain\b!i or return;
 170
 171                         my $enc = PublicInbox::View::enc_for($ct, $enc_msg);
 172                         my (@orig, @quot);
 173                         foreach my $l (split(/\n/, $enc->decode($part->body))) {
 174                                 if ($l =~ /^\s*>/) {
 175                                         push @quot, $l;
 176                                 } else {
 177                                         push @orig, $l;
 178                                 }
 179                         }
 180                         if (@quot) {
 181                                 $tg->index_text(join("\n", @quot), 0);
 182                                 $tg->increase_termpos;
 183                         }
 184                         if (@orig) {
 185                                 $tg->index_text(join("\n", @orig));
 186                                 $tg->increase_termpos;
 187                         }
 188                 });
 189
 190                 if ($was_ghost) {
 191                         $doc_id = $smsg->doc_id;
 192                         $self->link_message($smsg, 0);
 193                         $db->replace_document($doc_id, $doc);
 194                 } else {
 195                         $self->link_message($smsg, 0);
 196                         $doc_id = $db->add_document($doc);
 197                 }
 198         };
 199
 200         if ($@) {
 201                 warn "failed to index message <$mid>: $@\n";
 202                 $db->cancel_transaction;
 203         } else {
 204                 $db->commit_transaction;
 205         }
 206         $doc_id;
 207 }
 208
 209 # returns deleted doc_id on success, undef on missing
 210 sub remove_message {
 211         my ($self, $mid) = @_;
 212         my $db = $self->{xdb};
 213         my $doc_id;
 214         $mid = clean_mid($mid);
 215         $mid = mid_compressed($mid);
 216
 217         $db->begin_transaction;
 218         eval {
 219                 $doc_id = $self->find_unique_doc_id('mid', $mid);
 220                 $db->delete_document($doc_id) if defined $doc_id;
 221         };
 222
 223         if ($@) {
 224                 warn "failed to remove message <$mid>: $@\n";
 225                 $db->cancel_transaction;
 226         } else {
 227                 $db->commit_transaction;
 228         }
 229         $db->commit;
 230         $doc_id;
 231 }
 232
 233 # read-only
 234 sub query {
 235         my ($self, $query_string, $opts) = @_;
 236         my $query = $self->qp->parse_query($query_string, QP_FLAGS);
 237
 238         $query = Search::Xapian::Query->new(OP_AND, $mail_query, $query);
 239         $self->do_enquire($query, $opts);
 240 }
 241
 242 # given a message ID, get replies to a message
 243 sub get_replies {
 244         my ($self, $mid, $opts) = @_;
 245         $mid = clean_mid($mid);
 246         $mid = mid_compressed($mid);
 247         my $qp = $self->qp;
 248         my $irt = $qp->parse_query("inreplyto:$mid", 0);
 249         my $ref = $qp->parse_query("references:$mid", 0);
 250         my $query = Search::Xapian::Query->new(OP_OR, $irt, $ref);
 251
 252         $self->do_enquire($query);
 253 }
 254
 255 sub get_thread {
 256         my ($self, $mid, $opts) = @_;
 257         my $smsg = eval { $self->lookup_message($mid) };
 258
 259         return { count => 0, msgs => [] } unless $smsg;
 260         my $qp = $self->qp;
 261         my $qtid = $qp->parse_query('thread:'.$smsg->thread_id);
 262         my $qsub = $qp->parse_query('path:'.$smsg->path);
 263         my $query = Search::Xapian::Query->new(OP_OR, $qtid, $qsub);
 264         $self->do_enquire($query);
 265 }
 266
 267 # private subs below
 268
 269 sub do_enquire {
 270         my ($self, $query, $opts) = @_;
 271         my $enquire = $self->enquire;
 272
 273         $enquire->set_query($query);
 274         $enquire->set_sort_by_relevance_then_value(TS, 0);
 275         $opts ||= {};
 276         my $offset = $opts->{offset} || 0;
 277         my $limit = $opts->{limit} || 50;
 278         my $mset = $enquire->get_mset($offset, $limit);
 279         my @msgs = map { $_->get_document->get_data } $mset->items;
 280
 281         { count => $mset->get_matches_estimated, msgs => \@msgs }
 282 }
 283
 284 # read-write
 285 sub stemmer { Search::Xapian::Stem->new(LANG) }
 286
 287 # read-only
 288 sub qp {
 289         my ($self) = @_;
 290
 291         my $qp = $self->{query_parser};
 292         return $qp if $qp;
 293
 294         # new parser
 295         $qp = Search::Xapian::QueryParser->new;
 296         $qp->set_default_op(OP_AND);
 297         $qp->set_database($self->{xdb});
 298         $qp->set_stemmer($self->stemmer);
 299         $qp->set_stemming_strategy(STEM_SOME);
 300         $qp->add_valuerangeprocessor($self->ts_range_processor);
 301         $qp->add_valuerangeprocessor($self->date_range_processor);
 302
 303         while (my ($name, $prefix) = each %bool_pfx_external) {
 304                 $qp->add_boolean_prefix($name, $prefix);
 305         }
 306
 307         while (my ($name, $prefix) = each %prob_prefix) {
 308                 $qp->add_prefix($name, $prefix);
 309         }
 310
 311         $self->{query_parser} = $qp;
 312 }
 313
 314 sub term_generator { # write-only
 315         my ($self) = @_;
 316
 317         my $tg = $self->{term_generator};
 318         return $tg if $tg;
 319
 320         $tg = Search::Xapian::TermGenerator->new;
 321         $tg->set_stemmer($self->stemmer);
 322
 323         $self->{term_generator} = $tg;
 324 }
 325
 326 sub next_doc_id { $_[0]->{xdb}->get_lastdocid + 1 }
 327
 328 # increments last_thread_id counter
 329 # returns a 64-bit integer represented as a hex string
 330 sub next_thread_id {
 331         my ($self) = @_;
 332         my $db = $self->{xdb};
 333         my $last_thread_id = int($db->get_metadata('last_thread_id') || 0);
 334
 335         $db->set_metadata('last_thread_id', ++$last_thread_id);
 336
 337         $last_thread_id;
 338 }
 339
 340 sub ts_range_processor {
 341         $_[0]->{tsrp} ||= Search::Xapian::NumberValueRangeProcessor->new(TS);
 342 }
 343
 344 sub date_range_processor {
 345         $_[0]->{drp} ||= Search::Xapian::DateValueRangeProcessor->new(TS);
 346 }
 347
 348 sub clean_mid {
 349         my ($mid) = @_;
 350         defined($mid) or die "no Message-ID";
 351         # MDA->precheck did more checking for us
 352         $mid =~ s/\A\s*<?//;
 353         $mid =~ s/>?\s*\z//;
 354         $mid;
 355 }
 356
 357 sub link_message {
 358         my ($self, $smsg, $is_ghost) = @_;
 359
 360         if ($is_ghost) {
 361                 $smsg->ensure_metadata;
 362         } else {
 363                 $self->link_message_to_parents($smsg);
 364         }
 365 }
 366
 367 sub link_message_to_parents {
 368         my ($self, $smsg) = @_;
 369         my $doc = $smsg->{doc};
 370         my $mid = mid_compressed($smsg->mid);
 371         my $mime = $smsg->mime;
 372         my $refs = $mime->header('References');
 373         my @refs = $refs ? ($refs =~ /<([^>]+)>/g) : ();
 374         my $irt = $mime->header('In-Reply-To');
 375         if ($irt) {
 376                 if ($irt =~ /<([^>]+)>/) {
 377                         $irt = $1;
 378                 }
 379                 push @refs, $irt;
 380         }
 381
 382         my $tid;
 383         if (@refs) {
 384                 @refs = map { mid_compressed($_) } @refs;
 385                 my %uniq;
 386                 @refs = grep { !$uniq{$_}++ } @refs; # uniq
 387
 388                 $doc->add_term(xpfx('inreplyto') . $refs[-1]);
 389
 390                 my $ref_pfx = xpfx('references');
 391
 392                 # first ref *should* be the thread root,
 393                 # but we can never trust clients to do the right thing
 394                 my $ref = shift @refs;
 395                 $doc->add_term($ref_pfx . $ref);
 396                 $tid = $self->_resolve_mid_to_tid($ref);
 397
 398                 # the rest of the refs should point to this tid:
 399                 foreach $ref (@refs) {
 400                         $doc->add_term($ref_pfx . $ref);
 401                         my $ptid = $self->_resolve_mid_to_tid($ref);
 402                         if ($tid ne $ptid) {
 403                                 $self->merge_threads($tid, $ptid);
 404                         }
 405                 }
 406         } else {
 407                 $tid = $self->next_thread_id;
 408         }
 409         $doc->add_term(xpfx('thread') . $tid);
 410 }
 411
 412 sub lookup_message {
 413         my ($self, $mid) = @_;
 414         $mid = clean_mid($mid);
 415         $mid = mid_compressed($mid);
 416
 417         my $doc_id = $self->find_unique_doc_id('mid', $mid);
 418         my $smsg;
 419         if (defined $doc_id) {
 420                 # raises on error:
 421                 my $doc = $self->{xdb}->get_document($doc_id);
 422                 $smsg = PublicInbox::SearchMsg->wrap($doc, $mid);
 423                 $smsg->doc_id($doc_id);
 424         }
 425         $smsg;
 426 }
 427
 428 sub find_unique_doc_id {
 429         my ($self, $term, $value) = @_;
 430
 431         my ($begin, $end) = $self->find_doc_ids($term, $value);
 432
 433         return undef if $begin->equal($end); # not found
 434
 435         my $rv = $begin->get_docid;
 436
 437         # sanity check
 438         $begin->inc;
 439         $begin->equal($end) or die "Term '$term:$value' is not unique\n";
 440         $rv;
 441 }
 442
 443 # returns begin and end PostingIterator
 444 sub find_doc_ids {
 445         my ($self, $term, $value) = @_;
 446
 447         $self->find_doc_ids_for_term(xpfx($term) . $value);
 448 }
 449
 450 # returns begin and end PostingIterator
 451 sub find_doc_ids_for_term {
 452         my ($self, $term) = @_;
 453         my $db = $self->{xdb};
 454
 455         ($db->postlist_begin($term), $db->postlist_end($term));
 456 }
 457
 458 # this will create a ghost as necessary
 459 sub _resolve_mid_to_tid {
 460         my ($self, $mid) = @_;
 461
 462         my $smsg = $self->lookup_message($mid) || $self->create_ghost($mid);
 463         $smsg->thread_id;
 464 }
 465
 466 sub create_ghost {
 467         my ($self, $mid, $tid) = @_;
 468
 469         $mid = mid_compressed($mid);
 470         $tid = $self->next_thread_id unless defined $tid;
 471
 472         my $doc = Search::Xapian::Document->new;
 473         $doc->add_term(xpfx('mid') . $mid);
 474         $doc->add_term(xpfx('thread') . $tid);
 475         $doc->add_term(xpfx('type') . 'ghost');
 476
 477         my $smsg = PublicInbox::SearchMsg->wrap($doc, $mid);
 478         $self->link_message($smsg, 1);
 479         $self->{xdb}->add_document($doc);
 480
 481         $smsg;
 482 }
 483
 484 sub merge_threads {
 485         my ($self, $winner_tid, $loser_tid) = @_;
 486         my ($head, $tail) = $self->find_doc_ids('thread', $loser_tid);
 487         my $thread_pfx = xpfx('thread');
 488         my $db = $self->{xdb};
 489
 490         for (; $head != $tail; $head->inc) {
 491                 my $docid = $head->get_docid;
 492                 my $doc = $db->get_document($docid);
 493                 $doc->remove_term($thread_pfx . $loser_tid);
 494                 $doc->add_term($thread_pfx . $winner_tid);
 495                 $db->replace_document($docid, $doc);
 496         }
 497 }
 498
 499 # normalize subjects so they are suitable as pathnames for URLs
 500 sub subject_path {
 501         my ($subj) = @_;
 502
 503         $subj =~ s/\A\s+//;
 504         $subj =~ s/\s+\z//;
 505         $subj =~ s/^(?:re|aw):\s*//i; # remove reply prefix (aw: German)
 506         $subj =~ s![^a-zA-Z0-9_\.~/\-]+!_!g;
 507         $subj;
 508 }
 509
 510 sub do_cat_mail {
 511         my ($git, $blob) = @_;
 512         my $mime = eval {
 513                 my $str = $git->cat_file($blob);
 514                 Email::MIME->new($str);
 515         };
 516         $@ ? undef : $mime;
 517 }
 518
 519 sub index_blob {
 520         my ($self, $git, $blob) = @_;
 521         my $mime = do_cat_mail($git, $blob) or return;
 522         eval { $self->add_message($mime) };
 523         warn "W: index_blob $blob: $@\n" if $@;
 524 }
 525
 526 sub unindex_blob {
 527         my ($self, $git, $blob) = @_;
 528         my $mime = do_cat_mail($git, $blob) or return;
 529         my $mid = $mime->header('Message-ID');
 530         eval { $self->remove_message($mid) } if defined $mid;
 531         warn "W: unindex_blob $blob: $@\n" if $@;
 532 }
 533
 534 sub enquire {
 535         my ($self) = @_;
 536         $self->{enquire} ||= Search::Xapian::Enquire->new($self->{xdb});
 537 }
 538
 539 1;