lib/PublicInbox/Search.pm

   1 # Copyright (C) 2015 all contributors <meta@public-inbox.org>
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 # based on notmuch, but with no concept of folders, files or flags
   4 #
   5 # Read-only search interface for use by the web and NNTP interfaces
   6 package PublicInbox::Search;
   7 use strict;
   8 use warnings;
   9
  10 # values for searching
  11 use constant TS => 0; # timestamp
  12 use constant NUM => 1; # NNTP article number
  13 use constant BYTES => 2; # :bytes as defined in RFC 3977
  14 use constant LINES => 3; # :lines as defined in RFC 3977
  15 use constant YYYYMMDD => 4; # for searching in the WWW UI
  16
  17 use Search::Xapian qw/:standard/;
  18 use PublicInbox::SearchMsg;
  19 use Email::MIME;
  20 use PublicInbox::MID qw/mid_clean id_compress/;
  21
  22 # This is English-only, everything else is non-standard and may be confused as
  23 # a prefix common in patch emails
  24 our $REPLY_RE = qr/^re:\s+/i;
  25 our $LANG = 'english';
  26
  27 use constant {
  28         # SCHEMA_VERSION history
  29         # 0 - initial
  30         # 1 - subject_path is lower-cased
  31         # 2 - subject_path is id_compress in the index, only
  32         # 3 - message-ID is compressed if it includes '%' (hack!)
  33         # 4 - change "Re: " normalization, avoid circular Reference ghosts
  34         # 5 - subject_path drops trailing '.'
  35         # 6 - preserve References: order in document data
  36         # 7 - remove references and inreplyto terms
  37         # 8 - remove redundant/unneeded document data
  38         # 9 - disable Message-ID compression (SHA-1)
  39         # 10 - optimize doc for NNTP overviews
  40         # 11 - merge threads when vivifying ghosts
  41         # 12 - change YYYYMMDD value column to numeric
  42         SCHEMA_VERSION => 12,
  43
  44         # n.b. FLAG_PURE_NOT is expensive not suitable for a public website
  45         # as it could become a denial-of-service vector
  46         QP_FLAGS => FLAG_PHRASE|FLAG_BOOLEAN|FLAG_LOVEHATE|FLAG_WILDCARD,
  47 };
  48
  49 # setup prefixes
  50 my %bool_pfx_internal = (
  51         type => 'T', # "mail" or "ghost"
  52         thread => 'G', # newsGroup (or similar entity - e.g. a web forum name)
  53 );
  54
  55 my %bool_pfx_external = (
  56         # do we still need these? probably not..
  57         path => 'XPATH',
  58         mid => 'Q', # uniQue id (Message-ID)
  59 );
  60
  61 my %prob_prefix = (
  62         # for mairix compatibility
  63         s => 'S',
  64         m => 'XMID', # 'mid:' (bool) is exact, 'm:' (prob) can do partial
  65         f => 'A',
  66         t => 'XTO',
  67         tc => 'XTO XCC',
  68         c => 'XCC',
  69         tcf => 'XTO XCC A',
  70         b => 'XNQ XQUOT',
  71         bs => 'XNQ XQUOT S',
  72         n => 'XFN',
  73
  74         # n.b.: leaving out "a:" alias for "tcf:" even though
  75         # mairix supports it.  It is only mentioned in passing in mairix(1)
  76         # and the extra two letters are not significantly longer.
  77         q => 'XQUOT',
  78         nq => 'XNQ',
  79
  80         # default:
  81         '' => 'XMID S A XNQ XQUOT XFN',
  82 );
  83
  84 # not documenting m: and mid: for now, the using the URLs works w/o Xapian
  85 our @HELP = (
  86         's:' => <<EOF,
  87 match within Subject only  e.g. s:"a quick brown fox"
  88 This is a probabilistic search with support for stemming
  89 and wildcards '*'
  90 EOF
  91         'd:' => <<EOF,
  92 date range as YYYYMMDD  e.g. d:19931002..20101002
  93 Open-ended ranges such as d:19931002.. and d:..20101002
  94 are also supported.
  95 EOF
  96 );
  97 # TODO: (from mairix, some of these are maybe)
  98 # b (body), f (From:), c (Cc:), n (attachment), t (To:)
  99 # tc (To:+Cc:), bs (body + Subject), tcf (To: +Cc: +From:)
 100 #
 101 # Non-mairix:
 102 # df (filenames from diff)
 103 # nq (non-quoted body)
 104 # da (diff a/ removed lines)
 105 # db (diff b/ added lines)
 106
 107 my %all_pfx = (%bool_pfx_internal, %bool_pfx_external, %prob_prefix);
 108
 109 sub xpfx { $all_pfx{$_[0]} }
 110
 111 our %PFX2TERM_RMAP;
 112 my %meta_pfx = (mid => 1, thread => 1, path => 1);
 113 while (my ($k, $v) = each %all_pfx) {
 114         $PFX2TERM_RMAP{$v} = $k if $meta_pfx{$k};
 115 }
 116
 117 my $mail_query = Search::Xapian::Query->new(xpfx('type') . 'mail');
 118
 119 sub xdir {
 120         my (undef, $git_dir) = @_;
 121         "$git_dir/public-inbox/xapian" . SCHEMA_VERSION;
 122 }
 123
 124 sub new {
 125         my ($class, $git_dir, $altid) = @_;
 126         my $dir = $class->xdir($git_dir);
 127         my $db = Search::Xapian::Database->new($dir);
 128         bless { xdb => $db, git_dir => $git_dir, altid => $altid }, $class;
 129 }
 130
 131 sub reopen { $_[0]->{xdb}->reopen }
 132
 133 # read-only
 134 sub query {
 135         my ($self, $query_string, $opts) = @_;
 136         my $query;
 137
 138         $opts ||= {};
 139         unless ($query_string eq '') {
 140                 $query = $self->qp->parse_query($query_string, QP_FLAGS);
 141                 $opts->{relevance} = 1 unless exists $opts->{relevance};
 142         }
 143
 144         _do_enquire($self, $query, $opts);
 145 }
 146
 147 sub get_thread {
 148         my ($self, $mid, $opts) = @_;
 149         my $smsg = eval { $self->lookup_message($mid) };
 150
 151         return { total => 0, msgs => [] } unless $smsg;
 152         my $qtid = Search::Xapian::Query->new(xpfx('thread').$smsg->thread_id);
 153         my $path = $smsg->path;
 154         if (defined $path && $path ne '') {
 155                 my $path = id_compress($smsg->path);
 156                 my $qsub = Search::Xapian::Query->new(xpfx('path').$path);
 157                 $qtid = Search::Xapian::Query->new(OP_OR, $qtid, $qsub);
 158         }
 159         $opts ||= {};
 160         $opts->{limit} ||= 1000;
 161         _do_enquire($self, $qtid, $opts);
 162 }
 163
 164 sub _do_enquire {
 165         my ($self, $query, $opts) = @_;
 166         my $ret;
 167         for (1..10) {
 168                 eval { $ret = _enquire_once($self, $query, $opts) };
 169                 return $ret unless $@;
 170                 # Exception: The revision being read has been discarded -
 171                 # you should call Xapian::Database::reopen()
 172                 if (index($@, 'Xapian::Database::reopen') >= 0) {
 173                         reopen($self);
 174                 } else {
 175                         die $@;
 176                 }
 177         }
 178 }
 179
 180 sub _enquire_once {
 181         my ($self, $query, $opts) = @_;
 182         my $enquire = $self->enquire;
 183         if (defined $query) {
 184                 $query = Search::Xapian::Query->new(OP_AND,$query,$mail_query);
 185         } else {
 186                 $query = $mail_query;
 187         }
 188         $enquire->set_query($query);
 189         $opts ||= {};
 190         my $desc = !$opts->{asc};
 191         if ($opts->{relevance}) {
 192                 $enquire->set_sort_by_relevance_then_value(TS, $desc);
 193         } elsif ($opts->{num}) {
 194                 $enquire->set_sort_by_value(NUM, 0);
 195         } else {
 196                 $enquire->set_sort_by_value_then_relevance(TS, $desc);
 197         }
 198         my $offset = $opts->{offset} || 0;
 199         my $limit = $opts->{limit} || 50;
 200         my $mset = $enquire->get_mset($offset, $limit);
 201         return $mset if $opts->{mset};
 202         my @msgs = map {
 203                 PublicInbox::SearchMsg->load_doc($_->get_document);
 204         } $mset->items;
 205
 206         { total => $mset->get_matches_estimated, msgs => \@msgs }
 207 }
 208
 209 # read-write
 210 sub stemmer { Search::Xapian::Stem->new($LANG) }
 211
 212 # read-only
 213 sub qp {
 214         my ($self) = @_;
 215
 216         my $qp = $self->{query_parser};
 217         return $qp if $qp;
 218
 219         # new parser
 220         $qp = Search::Xapian::QueryParser->new;
 221         $qp->set_default_op(OP_AND);
 222         $qp->set_database($self->{xdb});
 223         $qp->set_stemmer($self->stemmer);
 224         $qp->set_stemming_strategy(STEM_SOME);
 225         $qp->add_valuerangeprocessor(
 226                 Search::Xapian::NumberValueRangeProcessor->new(YYYYMMDD, 'd:'));
 227
 228         while (my ($name, $prefix) = each %bool_pfx_external) {
 229                 $qp->add_boolean_prefix($name, $prefix);
 230         }
 231
 232         # we do not actually create AltId objects,
 233         # just parse the spec to avoid the extra DB handles for now.
 234         if (my $altid = $self->{altid}) {
 235                 my $user_pfx = $self->{-user_pfx} ||= [];
 236                 for (@$altid) {
 237                         # $_ = 'serial:gmane:/path/to/gmane.msgmap.sqlite3'
 238                         /\Aserial:(\w+):/ or next;
 239                         my $pfx = $1;
 240                         push @$user_pfx, "$pfx:", <<EOF;
 241 alternate serial number  e.g. $pfx:12345
 242 EOF
 243                         # gmane => XGMANE
 244                         $qp->add_boolean_prefix($pfx, 'X'.uc($pfx));
 245                 }
 246         }
 247
 248         while (my ($name, $prefix) = each %prob_prefix) {
 249                 $qp->add_prefix($name, $_) foreach split(/ /, $prefix);
 250         }
 251
 252         $self->{query_parser} = $qp;
 253 }
 254
 255 sub num_range_processor {
 256         $_[0]->{nrp} ||= Search::Xapian::NumberValueRangeProcessor->new(NUM);
 257 }
 258
 259 # only used for NNTP server
 260 sub query_xover {
 261         my ($self, $beg, $end, $offset) = @_;
 262         my $qp = Search::Xapian::QueryParser->new;
 263         $qp->set_database($self->{xdb});
 264         $qp->add_valuerangeprocessor($self->num_range_processor);
 265         my $query = $qp->parse_query("$beg..$end", QP_FLAGS);
 266
 267         _do_enquire($self, $query, {num => 1, limit => 200, offset => $offset});
 268 }
 269
 270 sub lookup_message {
 271         my ($self, $mid) = @_;
 272         $mid = mid_clean($mid);
 273
 274         my $doc_id = $self->find_unique_doc_id('mid', $mid);
 275         my $smsg;
 276         if (defined $doc_id) {
 277                 # raises on error:
 278                 my $doc = $self->{xdb}->get_document($doc_id);
 279                 $smsg = PublicInbox::SearchMsg->wrap($doc, $mid);
 280                 $smsg->doc_id($doc_id);
 281         }
 282         $smsg;
 283 }
 284
 285 sub lookup_mail { # no ghosts!
 286         my ($self, $mid) = @_;
 287         my $smsg = lookup_message($self, $mid) or return;
 288         PublicInbox::SearchMsg->load_doc($smsg->{doc});
 289 }
 290
 291 sub find_unique_doc_id {
 292         my ($self, $term, $value) = @_;
 293
 294         my ($begin, $end) = $self->find_doc_ids($term, $value);
 295
 296         return undef if $begin->equal($end); # not found
 297
 298         my $rv = $begin->get_docid;
 299
 300         # sanity check
 301         $begin->inc;
 302         $begin->equal($end) or die "Term '$term:$value' is not unique\n";
 303         $rv;
 304 }
 305
 306 # returns begin and end PostingIterator
 307 sub find_doc_ids {
 308         my ($self, $term, $value) = @_;
 309
 310         $self->find_doc_ids_for_term(xpfx($term) . $value);
 311 }
 312
 313 # returns begin and end PostingIterator
 314 sub find_doc_ids_for_term {
 315         my ($self, $term) = @_;
 316         my $db = $self->{xdb};
 317
 318         ($db->postlist_begin($term), $db->postlist_end($term));
 319 }
 320
 321 # normalize subjects so they are suitable as pathnames for URLs
 322 sub subject_path {
 323         my $subj = pop;
 324         $subj = subject_normalized($subj);
 325         $subj =~ s![^a-zA-Z0-9_\.~/\-]+!_!g;
 326         lc($subj);
 327 }
 328
 329 sub subject_normalized {
 330         my $subj = pop;
 331         $subj =~ s/\A\s+//s; # no leading space
 332         $subj =~ s/\s+\z//s; # no trailing space
 333         $subj =~ s/\s+/ /gs; # no redundant spaces
 334         $subj =~ s/\.+\z//; # no trailing '.'
 335         $subj =~ s/$REPLY_RE//igo; # remove reply prefix
 336         $subj;
 337 }
 338
 339 # for doc data
 340 sub subject_summary {
 341         my $subj = pop;
 342         my $max = 68;
 343         if (length($subj) > $max) {
 344                 my @subj = split(/\s+/, $subj);
 345                 $subj = '';
 346                 my $l;
 347
 348                 while ($l = shift @subj) {
 349                         my $new = $subj . $l . ' ';
 350                         last if length($new) >= $max;
 351                         $subj = $new;
 352                 }
 353                 if ($subj ne '') {
 354                         my $r = scalar @subj ? ' ...' : '';
 355                         $subj =~ s/ \z/$r/s;
 356                 } else {
 357                         # subject has one REALLY long word, and NOT spam? wtf
 358                         @subj = ($l =~ /\A(.{1,72})/);
 359                         $subj = $subj[0] . ' ...';
 360                 }
 361         }
 362         $subj;
 363 }
 364
 365 sub enquire {
 366         my ($self) = @_;
 367         $self->{enquire} ||= Search::Xapian::Enquire->new($self->{xdb});
 368 }
 369
 370 sub help {
 371         my ($self) = @_;
 372         $self->qp; # parse altids
 373         my @ret = @HELP;
 374         if (my $user_pfx = $self->{-user_pfx}) {
 375                 push @ret, @$user_pfx;
 376         }
 377         \@ret;
 378 }
 379
 380 1;