lib/PublicInbox/Search.pm

   1 # Copyright (C) 2015, all contributors <meta@public-inbox.org>
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 # based on notmuch, but with no concept of folders, files or flags
   4 package PublicInbox::Search;
   5 use strict;
   6 use warnings;
   7 use PublicInbox::SearchMsg;
   8 use Search::Xapian qw/:standard/;
   9 require PublicInbox::View;
  10 use Email::MIME;
  11 use PublicInbox::MID qw/mid_clean mid_compressed/;
  12
  13 # This is English-only, everything else is non-standard and may be confused as
  14 # a prefix common in patch emails
  15 our $REPLY_RE = qr/^re:\s+/i;
  16 our $LANG = 'english';
  17
  18 use constant {
  19         TS => 0,
  20         # SCHEMA_VERSION history
  21         # 0 - initial
  22         # 1 - subject_path is lower-cased
  23         # 2 - subject_path is mid_compressed in the index, only
  24         # 3 - message-ID is compressed if it includes '%' (hack!)
  25         # 4 - change "Re: " normalization, avoid circular Reference ghosts
  26         SCHEMA_VERSION => 4,
  27         QP_FLAGS => FLAG_PHRASE|FLAG_BOOLEAN|FLAG_LOVEHATE|FLAG_WILDCARD,
  28 };
  29
  30 # setup prefixes
  31 my %bool_pfx_internal = (
  32         type => 'T', # "mail" or "ghost"
  33         mid => 'Q', # uniQue id (Message-ID or mid_compressed)
  34 );
  35
  36 my %bool_pfx_external = (
  37         path => 'XPATH',
  38         thread => 'G', # newsGroup (or similar entity - e.g. a web forum name)
  39         references => 'XREFS',
  40         inreplyto => 'XIRT',
  41 );
  42
  43 my %prob_prefix = (
  44         subject => 'S',
  45 );
  46
  47 my %all_pfx = (%bool_pfx_internal, %bool_pfx_external, %prob_prefix);
  48
  49 sub xpfx { $all_pfx{$_[0]} }
  50
  51 our %PFX2TERM_RMAP;
  52 while (my ($k, $v) = each %all_pfx) {
  53         next if $prob_prefix{$k};
  54         $PFX2TERM_RMAP{$v} = $k;
  55 }
  56
  57 my $mail_query = Search::Xapian::Query->new(xpfx('type') . 'mail');
  58
  59 sub new {
  60         my ($class, $git_dir, $writable) = @_;
  61         # allow concurrent versions for easier rollback:
  62         my $dir = "$git_dir/public-inbox/xapian" . SCHEMA_VERSION;
  63         my $db;
  64
  65         if ($writable) { # not used by the WWW interface
  66                 require Search::Xapian::WritableDatabase;
  67                 my $flag = Search::Xapian::DB_OPEN;
  68                 if ($writable == 1) {
  69                         require File::Path;
  70                         File::Path::mkpath($dir);
  71                         $flag = Search::Xapian::DB_CREATE_OR_OPEN;
  72                 }
  73                 $db = Search::Xapian::WritableDatabase->new($dir, $flag);
  74         } else {
  75                 $db = Search::Xapian::Database->new($dir);
  76         }
  77         bless { xdb => $db, git_dir => $git_dir }, $class;
  78 }
  79
  80 sub reopen { $_[0]->{xdb}->reopen }
  81
  82 sub add_message {
  83         my ($self, $mime) = @_; # mime = Email::MIME object
  84         my $db = $self->{xdb};
  85
  86         my $doc_id;
  87         my $mid_orig = mid_clean($mime->header_obj->header_raw('Message-ID'));
  88         my $mid = mid_compressed($mid_orig);
  89         my $was_ghost = 0;
  90         my $ct_msg = $mime->header('Content-Type') || 'text/plain';
  91         my $enc_msg = PublicInbox::View::enc_for($ct_msg);
  92
  93         eval {
  94                 my $smsg = $self->lookup_message($mid);
  95                 my $doc;
  96
  97                 if ($smsg) {
  98                         $smsg->ensure_metadata;
  99                         # convert a ghost to a regular message
 100                         # it will also clobber any existing regular message
 101                         $smsg->mime($mime);
 102                         $doc = $smsg->{doc};
 103
 104                         my $type = xpfx('type');
 105                         eval {
 106                                 $doc->remove_term($type . 'ghost');
 107                                 $was_ghost = 1;
 108                         };
 109
 110                         # probably does not exist:
 111                         eval { $doc->remove_term($type . 'mail') };
 112                         $doc->add_term($type . 'mail');
 113                 }  else {
 114                         $smsg = PublicInbox::SearchMsg->new($mime);
 115                         $doc = $smsg->{doc};
 116                         $doc->add_term(xpfx('mid') . $mid);
 117                 }
 118
 119                 my $subj = $smsg->subject;
 120
 121                 if (length $subj) {
 122                         $doc->add_term(xpfx('subject') . $subj);
 123
 124                         my $path = subject_path($subj);
 125                         $doc->add_term(xpfx('path') . mid_compressed($path));
 126                 }
 127
 128                 my $from = $smsg->from_name;
 129                 my $date = $smsg->date;
 130                 my $ts = Search::Xapian::sortable_serialise($smsg->ts);
 131                 $doc->add_value(PublicInbox::Search::TS, $ts);
 132
 133                 $doc->set_data($smsg->to_doc_data);
 134
 135                 my $tg = $self->term_generator;
 136
 137                 $tg->set_document($doc);
 138                 $tg->index_text($subj, 1, 'S') if $subj;
 139                 $tg->increase_termpos;
 140                 $tg->index_text($subj) if $subj;
 141                 $tg->increase_termpos;
 142
 143                 $tg->index_text($smsg->from->format);
 144                 $tg->increase_termpos;
 145
 146                 $mime->walk_parts(sub {
 147                         my ($part) = @_;
 148                         return if $part->subparts; # walk_parts already recurses
 149                         my $ct = $part->content_type || $ct_msg;
 150
 151                         # account for filter bugs...
 152                         $ct =~ m!\btext/plain\b!i or return;
 153
 154                         my $enc = PublicInbox::View::enc_for($ct, $enc_msg);
 155                         my (@orig, @quot);
 156                         foreach my $l (split(/\n/, $enc->decode($part->body))) {
 157                                 if ($l =~ /^\s*>/) {
 158                                         push @quot, $l;
 159                                 } else {
 160                                         push @orig, $l;
 161                                 }
 162                         }
 163                         if (@quot) {
 164                                 $tg->index_text(join("\n", @quot), 0);
 165                                 $tg->increase_termpos;
 166                         }
 167                         if (@orig) {
 168                                 $tg->index_text(join("\n", @orig));
 169                                 $tg->increase_termpos;
 170                         }
 171                 });
 172
 173                 if ($was_ghost) {
 174                         $doc_id = $smsg->doc_id;
 175                         $self->link_message($smsg, 0);
 176                         $db->replace_document($doc_id, $doc);
 177                 } else {
 178                         $self->link_message($smsg, 0);
 179                         $doc_id = $db->add_document($doc);
 180                 }
 181         };
 182
 183         if ($@) {
 184                 warn "failed to index message <$mid_orig>: $@\n";
 185                 return undef;
 186         }
 187         $doc_id;
 188 }
 189
 190 # returns deleted doc_id on success, undef on missing
 191 sub remove_message {
 192         my ($self, $mid_orig) = @_;
 193         my $db = $self->{xdb};
 194         my $doc_id;
 195         $mid_orig = mid_clean($mid_orig);
 196         my $mid = mid_compressed($mid_orig);
 197
 198         eval {
 199                 $doc_id = $self->find_unique_doc_id('mid', $mid);
 200                 $db->delete_document($doc_id) if defined $doc_id;
 201         };
 202
 203         if ($@) {
 204                 warn "failed to remove message <$mid_orig>: $@\n";
 205                 return undef;
 206         }
 207         $doc_id;
 208 }
 209
 210 # read-only
 211 sub query {
 212         my ($self, $query_string, $opts) = @_;
 213         my $query = $self->qp->parse_query($query_string, QP_FLAGS);
 214
 215         $query = Search::Xapian::Query->new(OP_AND, $mail_query, $query);
 216         $self->do_enquire($query, $opts);
 217 }
 218
 219 sub get_subject_path {
 220         my ($self, $path, $opts) = @_;
 221         my $query = $self->qp->parse_query("path:".mid_compressed($path), 0);
 222         $self->do_enquire($query);
 223 }
 224
 225 # given a message ID, get followups to a message
 226 sub get_followups {
 227         my ($self, $mid, $opts) = @_;
 228         $mid = mid_clean($mid);
 229         $mid = mid_compressed($mid);
 230         my $qp = $self->qp;
 231         my $irt = $qp->parse_query("inreplyto:$mid", 0);
 232         my $ref = $qp->parse_query("references:$mid", 0);
 233         my $query = Search::Xapian::Query->new(OP_OR, $irt, $ref);
 234
 235         $self->do_enquire($query);
 236 }
 237
 238 sub get_thread {
 239         my ($self, $mid, $opts) = @_;
 240         my $smsg = eval { $self->lookup_message($mid) };
 241
 242         return { count => 0, msgs => [] } unless $smsg;
 243         my $qp = $self->qp;
 244         my $qtid = $qp->parse_query('thread:'.$smsg->thread_id);
 245         my $qsub = $qp->parse_query('path:'.mid_compressed($smsg->path));
 246         my $query = Search::Xapian::Query->new(OP_OR, $qtid, $qsub);
 247         $self->do_enquire($query);
 248 }
 249
 250 # private subs below
 251
 252 sub do_enquire {
 253         my ($self, $query, $opts) = @_;
 254         my $enquire = $self->enquire;
 255
 256         $enquire->set_query($query);
 257         $enquire->set_sort_by_relevance_then_value(TS, 0);
 258         $opts ||= {};
 259         my $offset = $opts->{offset} || 0;
 260         my $limit = $opts->{limit} || 50;
 261         my $mset = $enquire->get_mset($offset, $limit);
 262         my @msgs = map {
 263                 PublicInbox::SearchMsg->load_doc($_->get_document);
 264         } $mset->items;
 265
 266         { count => $mset->get_matches_estimated, msgs => \@msgs }
 267 }
 268
 269 # read-write
 270 sub stemmer { Search::Xapian::Stem->new($LANG) }
 271
 272 # read-only
 273 sub qp {
 274         my ($self) = @_;
 275
 276         my $qp = $self->{query_parser};
 277         return $qp if $qp;
 278
 279         # new parser
 280         $qp = Search::Xapian::QueryParser->new;
 281         $qp->set_default_op(OP_AND);
 282         $qp->set_database($self->{xdb});
 283         $qp->set_stemmer($self->stemmer);
 284         $qp->set_stemming_strategy(STEM_SOME);
 285         $qp->add_valuerangeprocessor($self->ts_range_processor);
 286         $qp->add_valuerangeprocessor($self->date_range_processor);
 287
 288         while (my ($name, $prefix) = each %bool_pfx_external) {
 289                 $qp->add_boolean_prefix($name, $prefix);
 290         }
 291
 292         while (my ($name, $prefix) = each %prob_prefix) {
 293                 $qp->add_prefix($name, $prefix);
 294         }
 295
 296         $self->{query_parser} = $qp;
 297 }
 298
 299 sub term_generator { # write-only
 300         my ($self) = @_;
 301
 302         my $tg = $self->{term_generator};
 303         return $tg if $tg;
 304
 305         $tg = Search::Xapian::TermGenerator->new;
 306         $tg->set_stemmer($self->stemmer);
 307
 308         $self->{term_generator} = $tg;
 309 }
 310
 311 sub next_doc_id { $_[0]->{xdb}->get_lastdocid + 1 }
 312
 313 # increments last_thread_id counter
 314 # returns a 64-bit integer represented as a hex string
 315 sub next_thread_id {
 316         my ($self) = @_;
 317         my $db = $self->{xdb};
 318         my $last_thread_id = int($db->get_metadata('last_thread_id') || 0);
 319
 320         $db->set_metadata('last_thread_id', ++$last_thread_id);
 321
 322         $last_thread_id;
 323 }
 324
 325 sub ts_range_processor {
 326         $_[0]->{tsrp} ||= Search::Xapian::NumberValueRangeProcessor->new(TS);
 327 }
 328
 329 sub date_range_processor {
 330         $_[0]->{drp} ||= Search::Xapian::DateValueRangeProcessor->new(TS);
 331 }
 332
 333 sub link_message {
 334         my ($self, $smsg, $is_ghost) = @_;
 335
 336         if ($is_ghost) {
 337                 $smsg->ensure_metadata;
 338         } else {
 339                 $self->link_message_to_parents($smsg);
 340         }
 341 }
 342
 343 sub link_message_to_parents {
 344         my ($self, $smsg) = @_;
 345         my $doc = $smsg->{doc};
 346         my $mid = mid_compressed($smsg->mid);
 347         my $mime = $smsg->mime;
 348         my $refs = $mime->header_obj->header_raw('References');
 349         my @refs = $refs ? ($refs =~ /<([^>]+)>/g) : ();
 350         my $irt = $mime->header_obj->header_raw('In-Reply-To');
 351         if ($irt) {
 352                 if ($irt =~ /<([^>]+)>/) {
 353                         $irt = $1;
 354                 }
 355
 356                 # maybe some crazies will try to make a circular reference:
 357                 if ($irt eq $mid) {
 358                         $irt = undef;
 359                 } else {
 360                         push @refs, $irt;
 361                 }
 362         }
 363
 364         my $tid;
 365         if (@refs) {
 366                 my @crefs = map { mid_compressed($_) } @refs;
 367                 my %uniq = ($mid => 1);
 368
 369                 # prevent circular references via References: here:
 370                 @refs = ();
 371                 foreach my $ref (@crefs) {
 372                         next if $uniq{$ref};
 373                         $uniq{$ref} = 1;
 374                         push @refs, $ref;
 375                 }
 376                 $irt = undef if (defined $irt && !$uniq{$irt});
 377         }
 378         if (@refs) {
 379                 if (defined $irt) {
 380                         $doc->add_term(xpfx('inreplyto') . $irt);
 381                 }
 382
 383                 my $ref_pfx = xpfx('references');
 384
 385                 # first ref *should* be the thread root,
 386                 # but we can never trust clients to do the right thing
 387                 my $ref = shift @refs;
 388                 $doc->add_term($ref_pfx . $ref);
 389                 $tid = $self->_resolve_mid_to_tid($ref);
 390
 391                 # the rest of the refs should point to this tid:
 392                 foreach $ref (@refs) {
 393                         $doc->add_term($ref_pfx . $ref);
 394                         my $ptid = $self->_resolve_mid_to_tid($ref);
 395                         if ($tid ne $ptid) {
 396                                 $self->merge_threads($tid, $ptid);
 397                         }
 398                 }
 399         } else {
 400                 $tid = $self->next_thread_id;
 401         }
 402         $doc->add_term(xpfx('thread') . $tid);
 403 }
 404
 405 sub lookup_message {
 406         my ($self, $mid) = @_;
 407         $mid = mid_clean($mid);
 408         $mid = mid_compressed($mid);
 409
 410         my $doc_id = $self->find_unique_doc_id('mid', $mid);
 411         my $smsg;
 412         if (defined $doc_id) {
 413                 # raises on error:
 414                 my $doc = $self->{xdb}->get_document($doc_id);
 415                 $smsg = PublicInbox::SearchMsg->wrap($doc, $mid);
 416                 $smsg->doc_id($doc_id);
 417         }
 418         $smsg;
 419 }
 420
 421 sub find_unique_doc_id {
 422         my ($self, $term, $value) = @_;
 423
 424         my ($begin, $end) = $self->find_doc_ids($term, $value);
 425
 426         return undef if $begin->equal($end); # not found
 427
 428         my $rv = $begin->get_docid;
 429
 430         # sanity check
 431         $begin->inc;
 432         $begin->equal($end) or die "Term '$term:$value' is not unique\n";
 433         $rv;
 434 }
 435
 436 # returns begin and end PostingIterator
 437 sub find_doc_ids {
 438         my ($self, $term, $value) = @_;
 439
 440         $self->find_doc_ids_for_term(xpfx($term) . $value);
 441 }
 442
 443 # returns begin and end PostingIterator
 444 sub find_doc_ids_for_term {
 445         my ($self, $term) = @_;
 446         my $db = $self->{xdb};
 447
 448         ($db->postlist_begin($term), $db->postlist_end($term));
 449 }
 450
 451 # this will create a ghost as necessary
 452 sub _resolve_mid_to_tid {
 453         my ($self, $mid) = @_;
 454
 455         my $smsg = $self->lookup_message($mid) || $self->create_ghost($mid);
 456         $smsg->thread_id;
 457 }
 458
 459 sub create_ghost {
 460         my ($self, $mid, $tid) = @_;
 461
 462         $mid = mid_compressed($mid);
 463         $tid = $self->next_thread_id unless defined $tid;
 464
 465         my $doc = Search::Xapian::Document->new;
 466         $doc->add_term(xpfx('mid') . $mid);
 467         $doc->add_term(xpfx('thread') . $tid);
 468         $doc->add_term(xpfx('type') . 'ghost');
 469
 470         my $smsg = PublicInbox::SearchMsg->wrap($doc, $mid);
 471         $self->link_message($smsg, 1);
 472         $self->{xdb}->add_document($doc);
 473
 474         $smsg;
 475 }
 476
 477 sub merge_threads {
 478         my ($self, $winner_tid, $loser_tid) = @_;
 479         my ($head, $tail) = $self->find_doc_ids('thread', $loser_tid);
 480         my $thread_pfx = xpfx('thread');
 481         my $db = $self->{xdb};
 482
 483         for (; $head != $tail; $head->inc) {
 484                 my $docid = $head->get_docid;
 485                 my $doc = $db->get_document($docid);
 486                 $doc->remove_term($thread_pfx . $loser_tid);
 487                 $doc->add_term($thread_pfx . $winner_tid);
 488                 $db->replace_document($docid, $doc);
 489         }
 490 }
 491
 492 # normalize subjects so they are suitable as pathnames for URLs
 493 sub subject_path {
 494         my $subj = pop;
 495
 496         $subj =~ s/\A\s+//;
 497         $subj =~ s/\s+\z//;
 498         $subj =~ s/$REPLY_RE//igo; # remove reply prefix
 499         $subj =~ s![^a-zA-Z0-9_\.~/\-]+!_!g;
 500         lc($subj);
 501 }
 502
 503 sub do_cat_mail {
 504         my ($git, $blob) = @_;
 505         my $mime = eval {
 506                 my $str = $git->cat_file($blob);
 507                 Email::MIME->new($str);
 508         };
 509         $@ ? undef : $mime;
 510 }
 511
 512 sub index_blob {
 513         my ($self, $git, $blob) = @_;
 514         my $mime = do_cat_mail($git, $blob) or return;
 515         eval { $self->add_message($mime) };
 516         warn "W: index_blob $blob: $@\n" if $@;
 517 }
 518
 519 sub unindex_blob {
 520         my ($self, $git, $blob) = @_;
 521         my $mime = do_cat_mail($git, $blob) or return;
 522         my $mid = $mime->header_obj->header_raw('Message-ID');
 523         eval { $self->remove_message($mid) } if defined $mid;
 524         warn "W: unindex_blob $blob: $@\n" if $@;
 525 }
 526
 527 sub enquire {
 528         my ($self) = @_;
 529         $self->{enquire} ||= Search::Xapian::Enquire->new($self->{xdb});
 530 }
 531
 532 # indexes all unindexed messages
 533 sub index_sync {
 534         my ($self) = @_;
 535         require PublicInbox::GitCatFile;
 536         my $db = $self->{xdb};
 537         my $hex = '[a-f0-9]';
 538         my $h40 = $hex .'{40}';
 539         my $addmsg = qr!^:000000 100644 \S+ ($h40) A\t${hex}{2}/${hex}{38}$!;
 540         my $delmsg = qr!^:100644 000000 ($h40) \S+ D\t${hex}{2}/${hex}{38}$!;
 541
 542         $db->begin_transaction;
 543         eval {
 544                 my $git = PublicInbox::GitCatFile->new($self->{git_dir});
 545
 546                 my $latest = $db->get_metadata('last_commit');
 547                 my $range = length $latest ? "$latest..HEAD" : 'HEAD';
 548                 $latest = undef;
 549
 550                 # get indexed messages
 551                 my @cmd = ('git', "--git-dir=$self->{git_dir}", "log",
 552                             qw/--reverse --no-notes --no-color --raw -r
 553                                --no-abbrev/, $range);
 554                 my $pid = open(my $log, '-|', @cmd) or
 555                         die('open` '.join(' ', @cmd) . " pipe failed: $!\n");
 556
 557                 while (my $line = <$log>) {
 558                         if ($line =~ /$addmsg/o) {
 559                                 $self->index_blob($git, $1);
 560                         } elsif ($line =~ /$delmsg/o) {
 561                                 $self->unindex_blob($git, $1);
 562                         } elsif ($line =~ /^commit ($h40)/o) {
 563                                 $latest = $1;
 564                         }
 565                 }
 566                 close $log;
 567                 $db->set_metadata('last_commit', $latest) if defined $latest;
 568         };
 569         if ($@) {
 570                 warn "indexing failed: $@\n";
 571                 $db->cancel_transaction;
 572         } else {
 573                 $db->commit_transaction;
 574         }
 575 }
 576
 577 1;