lib/PublicInbox/Search.pm

   1 # Copyright (C) 2015 all contributors <meta@public-inbox.org>
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 # based on notmuch, but with no concept of folders, files or flags
   4 #
   5 # Read-only search interface for use by the web and NNTP interfaces
   6 package PublicInbox::Search;
   7 use strict;
   8 use warnings;
   9
  10 # values for searching
  11 use constant TS => 0; # timestamp
  12 use constant NUM => 1; # NNTP article number
  13 use constant BYTES => 2; # :bytes as defined in RFC 3977
  14 use constant LINES => 3; # :lines as defined in RFC 3977
  15 use constant YYYYMMDD => 4; # for searching in the WWW UI
  16
  17 use Search::Xapian qw/:standard/;
  18 use PublicInbox::SearchMsg;
  19 use Email::MIME;
  20 use PublicInbox::MID qw/mid_clean id_compress/;
  21
  22 # This is English-only, everything else is non-standard and may be confused as
  23 # a prefix common in patch emails
  24 our $REPLY_RE = qr/^re:\s+/i;
  25 our $LANG = 'english';
  26
  27 use constant {
  28         # SCHEMA_VERSION history
  29         # 0 - initial
  30         # 1 - subject_path is lower-cased
  31         # 2 - subject_path is id_compress in the index, only
  32         # 3 - message-ID is compressed if it includes '%' (hack!)
  33         # 4 - change "Re: " normalization, avoid circular Reference ghosts
  34         # 5 - subject_path drops trailing '.'
  35         # 6 - preserve References: order in document data
  36         # 7 - remove references and inreplyto terms
  37         # 8 - remove redundant/unneeded document data
  38         # 9 - disable Message-ID compression (SHA-1)
  39         # 10 - optimize doc for NNTP overviews
  40         # 11 - merge threads when vivifying ghosts
  41         # 12 - change YYYYMMDD value column to numeric
  42         SCHEMA_VERSION => 12,
  43
  44         # n.b. FLAG_PURE_NOT is expensive not suitable for a public website
  45         # as it could become a denial-of-service vector
  46         QP_FLAGS => FLAG_PHRASE|FLAG_BOOLEAN|FLAG_LOVEHATE|FLAG_WILDCARD,
  47 };
  48
  49 # setup prefixes
  50 my %bool_pfx_internal = (
  51         type => 'T', # "mail" or "ghost"
  52         thread => 'G', # newsGroup (or similar entity - e.g. a web forum name)
  53 );
  54
  55 my %bool_pfx_external = (
  56         # do we still need these? probably not..
  57         path => 'XPATH',
  58         mid => 'Q', # uniQue id (Message-ID)
  59 );
  60
  61 my %prob_prefix = (
  62         # for mairix compatibility
  63         s => 'S',
  64         m => 'XMID', # 'mid:' (bool) is exact, 'm:' (prob) can do partial
  65         f => 'A',
  66         t => 'XTO',
  67         tc => 'XTO XCC',
  68         c => 'XCC',
  69         tcf => 'XTO XCC A',
  70         a => 'XTO XCC A',
  71         b => 'XNQ XQUOT',
  72         bs => 'XNQ XQUOT S',
  73         n => 'XFN',
  74
  75         q => 'XQUOT',
  76         nq => 'XNQ',
  77
  78         # default:
  79         '' => 'XMID S A XNQ XQUOT XFN',
  80 );
  81
  82 # not documenting m: and mid: for now, the using the URLs works w/o Xapian
  83 our @HELP = (
  84         's:' => 'match within Subject  e.g. s:"a quick brown fox"',
  85         'd:' => <<EOF,
  86 date range as YYYYMMDD  e.g. d:19931002..20101002
  87 Open-ended ranges such as d:19931002.. and d:..20101002
  88 are also supported
  89 EOF
  90         'b:' => 'match within message body, including text attachments',
  91         'nq:' => 'match non-quoted text within message body',
  92         'quot:' => 'match quoted text within message body',
  93         'n:' => 'match filename of attachment(s)',
  94         't:' => 'match within the To header',
  95         'c:' => 'match within the Cc header',
  96         'f:' => 'match within the From header',
  97         'a:' => 'match within the To, Cc, and From headers',
  98         'tc:' => 'match within the To and Cc headers',
  99         'bs:' => 'match within the Subject and body',
 100 );
 101 chomp @HELP;
 102 # TODO:
 103 # df (filenames from diff)
 104 # da (diff a/ removed lines)
 105 # db (diff b/ added lines)
 106
 107 my %all_pfx = (%bool_pfx_internal, %bool_pfx_external, %prob_prefix);
 108
 109 sub xpfx { $all_pfx{$_[0]} }
 110
 111 our %PFX2TERM_RMAP;
 112 my %meta_pfx = (mid => 1, thread => 1, path => 1);
 113 while (my ($k, $v) = each %all_pfx) {
 114         $PFX2TERM_RMAP{$v} = $k if $meta_pfx{$k};
 115 }
 116
 117 my $mail_query = Search::Xapian::Query->new(xpfx('type') . 'mail');
 118
 119 sub xdir {
 120         my (undef, $git_dir) = @_;
 121         "$git_dir/public-inbox/xapian" . SCHEMA_VERSION;
 122 }
 123
 124 sub new {
 125         my ($class, $git_dir, $altid) = @_;
 126         my $dir = $class->xdir($git_dir);
 127         my $db = Search::Xapian::Database->new($dir);
 128         bless { xdb => $db, git_dir => $git_dir, altid => $altid }, $class;
 129 }
 130
 131 sub reopen { $_[0]->{xdb}->reopen }
 132
 133 # read-only
 134 sub query {
 135         my ($self, $query_string, $opts) = @_;
 136         my $query;
 137
 138         $opts ||= {};
 139         unless ($query_string eq '') {
 140                 $query = $self->qp->parse_query($query_string, QP_FLAGS);
 141                 $opts->{relevance} = 1 unless exists $opts->{relevance};
 142         }
 143
 144         _do_enquire($self, $query, $opts);
 145 }
 146
 147 sub get_thread {
 148         my ($self, $mid, $opts) = @_;
 149         my $smsg = eval { $self->lookup_message($mid) };
 150
 151         return { total => 0, msgs => [] } unless $smsg;
 152         my $qtid = Search::Xapian::Query->new(xpfx('thread').$smsg->thread_id);
 153         my $path = $smsg->path;
 154         if (defined $path && $path ne '') {
 155                 my $path = id_compress($smsg->path);
 156                 my $qsub = Search::Xapian::Query->new(xpfx('path').$path);
 157                 $qtid = Search::Xapian::Query->new(OP_OR, $qtid, $qsub);
 158         }
 159         $opts ||= {};
 160         $opts->{limit} ||= 1000;
 161         _do_enquire($self, $qtid, $opts);
 162 }
 163
 164 sub _do_enquire {
 165         my ($self, $query, $opts) = @_;
 166         my $ret;
 167         for (1..10) {
 168                 eval { $ret = _enquire_once($self, $query, $opts) };
 169                 return $ret unless $@;
 170                 # Exception: The revision being read has been discarded -
 171                 # you should call Xapian::Database::reopen()
 172                 if (index($@, 'Xapian::Database::reopen') >= 0) {
 173                         reopen($self);
 174                 } else {
 175                         die $@;
 176                 }
 177         }
 178 }
 179
 180 sub _enquire_once {
 181         my ($self, $query, $opts) = @_;
 182         my $enquire = $self->enquire;
 183         if (defined $query) {
 184                 $query = Search::Xapian::Query->new(OP_AND,$query,$mail_query);
 185         } else {
 186                 $query = $mail_query;
 187         }
 188         $enquire->set_query($query);
 189         $opts ||= {};
 190         my $desc = !$opts->{asc};
 191         if ($opts->{relevance}) {
 192                 $enquire->set_sort_by_relevance_then_value(TS, $desc);
 193         } elsif ($opts->{num}) {
 194                 $enquire->set_sort_by_value(NUM, 0);
 195         } else {
 196                 $enquire->set_sort_by_value_then_relevance(TS, $desc);
 197         }
 198         my $offset = $opts->{offset} || 0;
 199         my $limit = $opts->{limit} || 50;
 200         my $mset = $enquire->get_mset($offset, $limit);
 201         return $mset if $opts->{mset};
 202         my @msgs = map {
 203                 PublicInbox::SearchMsg->load_doc($_->get_document);
 204         } $mset->items;
 205
 206         { total => $mset->get_matches_estimated, msgs => \@msgs }
 207 }
 208
 209 # read-write
 210 sub stemmer { Search::Xapian::Stem->new($LANG) }
 211
 212 # read-only
 213 sub qp {
 214         my ($self) = @_;
 215
 216         my $qp = $self->{query_parser};
 217         return $qp if $qp;
 218
 219         # new parser
 220         $qp = Search::Xapian::QueryParser->new;
 221         $qp->set_default_op(OP_AND);
 222         $qp->set_database($self->{xdb});
 223         $qp->set_stemmer($self->stemmer);
 224         $qp->set_stemming_strategy(STEM_SOME);
 225         $qp->add_valuerangeprocessor(
 226                 Search::Xapian::NumberValueRangeProcessor->new(YYYYMMDD, 'd:'));
 227
 228         while (my ($name, $prefix) = each %bool_pfx_external) {
 229                 $qp->add_boolean_prefix($name, $prefix);
 230         }
 231
 232         # we do not actually create AltId objects,
 233         # just parse the spec to avoid the extra DB handles for now.
 234         if (my $altid = $self->{altid}) {
 235                 my $user_pfx = $self->{-user_pfx} ||= [];
 236                 for (@$altid) {
 237                         # $_ = 'serial:gmane:/path/to/gmane.msgmap.sqlite3'
 238                         /\Aserial:(\w+):/ or next;
 239                         my $pfx = $1;
 240                         push @$user_pfx, "$pfx:", <<EOF;
 241 alternate serial number  e.g. $pfx:12345 (boolean)
 242 EOF
 243                         # gmane => XGMANE
 244                         $qp->add_boolean_prefix($pfx, 'X'.uc($pfx));
 245                 }
 246                 chomp @$user_pfx;
 247         }
 248
 249         while (my ($name, $prefix) = each %prob_prefix) {
 250                 $qp->add_prefix($name, $_) foreach split(/ /, $prefix);
 251         }
 252
 253         $self->{query_parser} = $qp;
 254 }
 255
 256 sub num_range_processor {
 257         $_[0]->{nrp} ||= Search::Xapian::NumberValueRangeProcessor->new(NUM);
 258 }
 259
 260 # only used for NNTP server
 261 sub query_xover {
 262         my ($self, $beg, $end, $offset) = @_;
 263         my $qp = Search::Xapian::QueryParser->new;
 264         $qp->set_database($self->{xdb});
 265         $qp->add_valuerangeprocessor($self->num_range_processor);
 266         my $query = $qp->parse_query("$beg..$end", QP_FLAGS);
 267
 268         _do_enquire($self, $query, {num => 1, limit => 200, offset => $offset});
 269 }
 270
 271 sub lookup_message {
 272         my ($self, $mid) = @_;
 273         $mid = mid_clean($mid);
 274
 275         my $doc_id = $self->find_unique_doc_id('mid', $mid);
 276         my $smsg;
 277         if (defined $doc_id) {
 278                 # raises on error:
 279                 my $doc = $self->{xdb}->get_document($doc_id);
 280                 $smsg = PublicInbox::SearchMsg->wrap($doc, $mid);
 281                 $smsg->doc_id($doc_id);
 282         }
 283         $smsg;
 284 }
 285
 286 sub lookup_mail { # no ghosts!
 287         my ($self, $mid) = @_;
 288         my $smsg = lookup_message($self, $mid) or return;
 289         PublicInbox::SearchMsg->load_doc($smsg->{doc});
 290 }
 291
 292 sub find_unique_doc_id {
 293         my ($self, $term, $value) = @_;
 294
 295         my ($begin, $end) = $self->find_doc_ids($term, $value);
 296
 297         return undef if $begin->equal($end); # not found
 298
 299         my $rv = $begin->get_docid;
 300
 301         # sanity check
 302         $begin->inc;
 303         $begin->equal($end) or die "Term '$term:$value' is not unique\n";
 304         $rv;
 305 }
 306
 307 # returns begin and end PostingIterator
 308 sub find_doc_ids {
 309         my ($self, $term, $value) = @_;
 310
 311         $self->find_doc_ids_for_term(xpfx($term) . $value);
 312 }
 313
 314 # returns begin and end PostingIterator
 315 sub find_doc_ids_for_term {
 316         my ($self, $term) = @_;
 317         my $db = $self->{xdb};
 318
 319         ($db->postlist_begin($term), $db->postlist_end($term));
 320 }
 321
 322 # normalize subjects so they are suitable as pathnames for URLs
 323 sub subject_path {
 324         my $subj = pop;
 325         $subj = subject_normalized($subj);
 326         $subj =~ s![^a-zA-Z0-9_\.~/\-]+!_!g;
 327         lc($subj);
 328 }
 329
 330 sub subject_normalized {
 331         my $subj = pop;
 332         $subj =~ s/\A\s+//s; # no leading space
 333         $subj =~ s/\s+\z//s; # no trailing space
 334         $subj =~ s/\s+/ /gs; # no redundant spaces
 335         $subj =~ s/\.+\z//; # no trailing '.'
 336         $subj =~ s/$REPLY_RE//igo; # remove reply prefix
 337         $subj;
 338 }
 339
 340 # for doc data
 341 sub subject_summary {
 342         my $subj = pop;
 343         my $max = 68;
 344         if (length($subj) > $max) {
 345                 my @subj = split(/\s+/, $subj);
 346                 $subj = '';
 347                 my $l;
 348
 349                 while ($l = shift @subj) {
 350                         my $new = $subj . $l . ' ';
 351                         last if length($new) >= $max;
 352                         $subj = $new;
 353                 }
 354                 if ($subj ne '') {
 355                         my $r = scalar @subj ? ' ...' : '';
 356                         $subj =~ s/ \z/$r/s;
 357                 } else {
 358                         # subject has one REALLY long word, and NOT spam? wtf
 359                         @subj = ($l =~ /\A(.{1,72})/);
 360                         $subj = $subj[0] . ' ...';
 361                 }
 362         }
 363         $subj;
 364 }
 365
 366 sub enquire {
 367         my ($self) = @_;
 368         $self->{enquire} ||= Search::Xapian::Enquire->new($self->{xdb});
 369 }
 370
 371 sub help {
 372         my ($self) = @_;
 373         $self->qp; # parse altids
 374         my @ret = @HELP;
 375         if (my $user_pfx = $self->{-user_pfx}) {
 376                 push @ret, @$user_pfx;
 377         }
 378         \@ret;
 379 }
 380
 381 1;