lib/PublicInbox/Search.pm

   1 # Copyright (C) 2015, all contributors <meta@public-inbox.org>
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 # based on notmuch, but with no concept of folders, files or flags
   4 package PublicInbox::Search;
   5 use strict;
   6 use warnings;
   7 use constant TS => 0;
   8 use Search::Xapian qw/:standard/;
   9 use PublicInbox::SearchMsg;
  10 use Email::MIME;
  11 use PublicInbox::MID qw/mid_clean mid_compress/;
  12
  13 # This is English-only, everything else is non-standard and may be confused as
  14 # a prefix common in patch emails
  15 our $REPLY_RE = qr/^re:\s+/i;
  16 our $LANG = 'english';
  17
  18 use constant {
  19         # SCHEMA_VERSION history
  20         # 0 - initial
  21         # 1 - subject_path is lower-cased
  22         # 2 - subject_path is mid_compress in the index, only
  23         # 3 - message-ID is compressed if it includes '%' (hack!)
  24         # 4 - change "Re: " normalization, avoid circular Reference ghosts
  25         # 5 - subject_path drops trailing '.'
  26         # 6 - preserve References: order in document data
  27         # 7 - remove references and inreplyto terms
  28         # 8 - remove redundant/unneeded document data
  29         # 9 - disable Message-ID compression
  30         SCHEMA_VERSION => 9,
  31         QP_FLAGS => FLAG_PHRASE|FLAG_BOOLEAN|FLAG_LOVEHATE|FLAG_WILDCARD,
  32 };
  33
  34 # setup prefixes
  35 my %bool_pfx_internal = (
  36         type => 'T', # "mail" or "ghost"
  37         mid => 'Q', # uniQue id (Message-ID)
  38 );
  39
  40 my %bool_pfx_external = (
  41         path => 'XPATH',
  42         thread => 'G', # newsGroup (or similar entity - e.g. a web forum name)
  43 );
  44
  45 my %prob_prefix = (
  46         subject => 'S',
  47 );
  48
  49 my %all_pfx = (%bool_pfx_internal, %bool_pfx_external, %prob_prefix);
  50
  51 sub xpfx { $all_pfx{$_[0]} }
  52
  53 our %PFX2TERM_RMAP;
  54 my %meta_pfx = (mid => 1, thread => 1, path => 1);
  55 while (my ($k, $v) = each %all_pfx) {
  56         $PFX2TERM_RMAP{$v} = $k if $meta_pfx{$k};
  57 }
  58
  59 my $mail_query = Search::Xapian::Query->new(xpfx('type') . 'mail');
  60
  61 sub xdir {
  62         my (undef, $git_dir) = @_;
  63         "$git_dir/public-inbox/xapian" . SCHEMA_VERSION;
  64 }
  65
  66 sub new {
  67         my ($class, $git_dir) = @_;
  68         my $dir = $class->xdir($git_dir);
  69         my $db = Search::Xapian::Database->new($dir);
  70         bless { xdb => $db, git_dir => $git_dir }, $class;
  71 }
  72
  73 sub reopen { $_[0]->{xdb}->reopen }
  74
  75 # read-only
  76 sub query {
  77         my ($self, $query_string, $opts) = @_;
  78         my $query;
  79
  80         $opts ||= {};
  81         unless ($query_string eq '') {
  82                 $query = $self->qp->parse_query($query_string, QP_FLAGS);
  83                 $opts->{relevance} = 1 unless exists $opts->{relevance};
  84         }
  85
  86         $self->do_enquire($query, $opts);
  87 }
  88
  89 sub get_subject_path {
  90         my ($self, $path, $opts) = @_;
  91         my $query = $self->qp->parse_query("path:".mid_compress($path), 0);
  92         $self->do_enquire($query, $opts);
  93 }
  94
  95 sub get_thread {
  96         my ($self, $mid, $opts) = @_;
  97         my $smsg = eval { $self->lookup_message($mid) };
  98
  99         return { total => 0, msgs => [] } unless $smsg;
 100         my $qp = $self->qp;
 101         my $qtid = $qp->parse_query('thread:'.$smsg->thread_id, 0);
 102         my $qsub = $qp->parse_query('path:'.mid_compress($smsg->path), 0);
 103         my $query = Search::Xapian::Query->new(OP_OR, $qtid, $qsub);
 104         $self->do_enquire($query, $opts);
 105 }
 106
 107 # private subs below
 108
 109 sub do_enquire {
 110         my ($self, $query, $opts) = @_;
 111         my $enquire = $self->enquire;
 112         if (defined $query) {
 113                 $query = Search::Xapian::Query->new(OP_AND,$query,$mail_query);
 114         } else {
 115                 $query = $mail_query;
 116         }
 117         $enquire->set_query($query);
 118         if ($opts->{relevance}) {
 119                 $enquire->set_sort_by_relevance_then_value(TS, 1);
 120         } else {
 121                 $enquire->set_sort_by_value(TS, 1);
 122         }
 123         $opts ||= {};
 124         my $offset = $opts->{offset} || 0;
 125         my $limit = $opts->{limit} || 50;
 126         my $mset = $enquire->get_mset($offset, $limit);
 127         return $mset if $opts->{mset};
 128         my @msgs = map {
 129                 PublicInbox::SearchMsg->load_doc($_->get_document);
 130         } $mset->items;
 131
 132         { total => $mset->get_matches_estimated, msgs => \@msgs }
 133 }
 134
 135 # read-write
 136 sub stemmer { Search::Xapian::Stem->new($LANG) }
 137
 138 # read-only
 139 sub qp {
 140         my ($self) = @_;
 141
 142         my $qp = $self->{query_parser};
 143         return $qp if $qp;
 144
 145         # new parser
 146         $qp = Search::Xapian::QueryParser->new;
 147         $qp->set_default_op(OP_AND);
 148         $qp->set_database($self->{xdb});
 149         $qp->set_stemmer($self->stemmer);
 150         $qp->set_stemming_strategy(STEM_SOME);
 151         $qp->add_valuerangeprocessor($self->ts_range_processor);
 152         $qp->add_valuerangeprocessor($self->date_range_processor);
 153
 154         while (my ($name, $prefix) = each %bool_pfx_external) {
 155                 $qp->add_boolean_prefix($name, $prefix);
 156         }
 157
 158         while (my ($name, $prefix) = each %prob_prefix) {
 159                 $qp->add_prefix($name, $prefix);
 160         }
 161
 162         $self->{query_parser} = $qp;
 163 }
 164
 165 sub ts_range_processor {
 166         $_[0]->{tsrp} ||= Search::Xapian::NumberValueRangeProcessor->new(TS);
 167 }
 168
 169 sub date_range_processor {
 170         $_[0]->{drp} ||= Search::Xapian::DateValueRangeProcessor->new(TS);
 171 }
 172
 173 sub lookup_message {
 174         my ($self, $mid) = @_;
 175         $mid = mid_clean($mid);
 176
 177         my $doc_id = $self->find_unique_doc_id('mid', $mid);
 178         my $smsg;
 179         if (defined $doc_id) {
 180                 # raises on error:
 181                 my $doc = $self->{xdb}->get_document($doc_id);
 182                 $smsg = PublicInbox::SearchMsg->wrap($doc, $mid);
 183                 $smsg->doc_id($doc_id);
 184         }
 185         $smsg;
 186 }
 187
 188 sub find_unique_doc_id {
 189         my ($self, $term, $value) = @_;
 190
 191         my ($begin, $end) = $self->find_doc_ids($term, $value);
 192
 193         return undef if $begin->equal($end); # not found
 194
 195         my $rv = $begin->get_docid;
 196
 197         # sanity check
 198         $begin->inc;
 199         $begin->equal($end) or die "Term '$term:$value' is not unique\n";
 200         $rv;
 201 }
 202
 203 # returns begin and end PostingIterator
 204 sub find_doc_ids {
 205         my ($self, $term, $value) = @_;
 206
 207         $self->find_doc_ids_for_term(xpfx($term) . $value);
 208 }
 209
 210 # returns begin and end PostingIterator
 211 sub find_doc_ids_for_term {
 212         my ($self, $term) = @_;
 213         my $db = $self->{xdb};
 214
 215         ($db->postlist_begin($term), $db->postlist_end($term));
 216 }
 217
 218 # normalize subjects so they are suitable as pathnames for URLs
 219 sub subject_path {
 220         my $subj = pop;
 221         $subj = subject_normalized($subj);
 222         $subj =~ s![^a-zA-Z0-9_\.~/\-]+!_!g;
 223         lc($subj);
 224 }
 225
 226 sub subject_normalized {
 227         my $subj = pop;
 228         $subj =~ s/\A\s+//s; # no leading space
 229         $subj =~ s/\s+\z//s; # no trailing space
 230         $subj =~ s/\s+/ /gs; # no redundant spaces
 231         $subj =~ s/\.+\z//; # no trailing '.'
 232         $subj =~ s/$REPLY_RE//igo; # remove reply prefix
 233         $subj;
 234 }
 235
 236 # for doc data
 237 sub subject_summary {
 238         my $subj = pop;
 239         my $max = 68;
 240         if (length($subj) > $max) {
 241                 my @subj = split(/\s+/, $subj);
 242                 $subj = '';
 243                 my $l;
 244
 245                 while ($l = shift @subj) {
 246                         my $new = $subj . $l . ' ';
 247                         last if length($new) >= $max;
 248                         $subj = $new;
 249                 }
 250                 if ($subj ne '') {
 251                         my $r = scalar @subj ? ' ...' : '';
 252                         $subj =~ s/ \z/$r/s;
 253                 } else {
 254                         # subject has one REALLY long word, and NOT spam? wtf
 255                         @subj = ($l =~ /\A(.{1,72})/);
 256                         $subj = $subj[0] . ' ...';
 257                 }
 258         }
 259         $subj;
 260 }
 261
 262 sub enquire {
 263         my ($self) = @_;
 264         $self->{enquire} ||= Search::Xapian::Enquire->new($self->{xdb});
 265 }
 266
 267 1;