lib/PublicInbox/Search.pm

   1 # Copyright (C) 2015, all contributors <meta@public-inbox.org>
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 # based on notmuch, but with no concept of folders, files or flags
   4 package PublicInbox::Search;
   5 use strict;
   6 use warnings;
   7 use PublicInbox::SearchMsg;
   8 use Search::Xapian qw/:standard/;
   9 require PublicInbox::View;
  10 use Email::MIME;
  11 use PublicInbox::MID qw/mid_clean mid_compressed/;
  12
  13 use constant {
  14         TS => 0,
  15         # SCHEMA_VERSION history
  16         # 0 - initial
  17         # 1 - subject_path is lower-cased
  18         SCHEMA_VERSION => 1,
  19         LANG => 'english',
  20         QP_FLAGS => FLAG_PHRASE|FLAG_BOOLEAN|FLAG_LOVEHATE|FLAG_WILDCARD,
  21 };
  22
  23 # setup prefixes
  24 my %bool_pfx_internal = (
  25         type => 'T', # "mail" or "ghost"
  26         mid => 'Q', # uniQue id (Message-ID or mid_compressed)
  27 );
  28
  29 my %bool_pfx_external = (
  30         path => 'XPATH',
  31         thread => 'G', # newsGroup (or similar entity - e.g. a web forum name)
  32         references => 'XREFS',
  33         inreplyto => 'XIRT',
  34 );
  35
  36 my %prob_prefix = (
  37         subject => 'S',
  38 );
  39
  40 my %all_pfx = (%bool_pfx_internal, %bool_pfx_external, %prob_prefix);
  41
  42 sub xpfx { $all_pfx{$_[0]} }
  43
  44 our %PFX2TERM_RMAP;
  45 while (my ($k, $v) = each %all_pfx) {
  46         next if $prob_prefix{$k};
  47         $PFX2TERM_RMAP{$v} = $k;
  48 }
  49
  50 my $mail_query = Search::Xapian::Query->new(xpfx('type') . 'mail');
  51
  52 sub new {
  53         my ($class, $git_dir, $writable) = @_;
  54         # allow concurrent versions for easier rollback:
  55         my $dir = "$git_dir/public-inbox/xapian" . SCHEMA_VERSION;
  56         my $db;
  57
  58         if ($writable) { # not used by the WWW interface
  59                 require Search::Xapian::WritableDatabase;
  60                 require File::Path;
  61                 File::Path::mkpath($dir);
  62                 $db = Search::Xapian::WritableDatabase->new($dir,
  63                                         Search::Xapian::DB_CREATE_OR_OPEN);
  64         } else {
  65                 $db = Search::Xapian::Database->new($dir);
  66         }
  67         bless { xdb => $db, git_dir => $git_dir }, $class;
  68 }
  69
  70 sub reopen { $_[0]->{xdb}->reopen }
  71
  72 sub add_message {
  73         my ($self, $mime) = @_; # mime = Email::MIME object
  74         my $db = $self->{xdb};
  75
  76         my $doc_id;
  77         my $mid = mid_clean($mime->header_obj->header_raw('Message-ID'));
  78         $mid = mid_compressed($mid);
  79         my $was_ghost = 0;
  80         my $ct_msg = $mime->header('Content-Type') || 'text/plain';
  81         my $enc_msg = PublicInbox::View::enc_for($ct_msg);
  82
  83         $db->begin_transaction;
  84         eval {
  85                 my $smsg = $self->lookup_message($mid);
  86                 my $doc;
  87
  88                 if ($smsg) {
  89                         $smsg->ensure_metadata;
  90                         # convert a ghost to a regular message
  91                         # it will also clobber any existing regular message
  92                         $smsg->mime($mime);
  93                         $doc = $smsg->{doc};
  94
  95                         my $type = xpfx('type');
  96                         eval {
  97                                 $doc->remove_term($type . 'ghost');
  98                                 $was_ghost = 1;
  99                         };
 100
 101                         # probably does not exist:
 102                         eval { $doc->remove_term($type . 'mail') };
 103                         $doc->add_term($type . 'mail');
 104                 }  else {
 105                         $smsg = PublicInbox::SearchMsg->new($mime);
 106                         $doc = $smsg->{doc};
 107                         $doc->add_term(xpfx('mid') . $mid);
 108                 }
 109
 110                 my $subj = $smsg->subject;
 111
 112                 if (length $subj) {
 113                         $doc->add_term(xpfx('subject') . $subj);
 114
 115                         my $path = subject_path($subj);
 116                         $doc->add_term(xpfx('path') . $path);
 117                 }
 118
 119                 my $from = $smsg->from_name;
 120                 my $date = $smsg->date;
 121                 my $ts = Search::Xapian::sortable_serialise($smsg->ts);
 122                 $doc->add_value(PublicInbox::Search::TS, $ts);
 123
 124                 $doc->set_data($smsg->to_doc_data);
 125
 126                 my $tg = $self->term_generator;
 127
 128                 $tg->set_document($doc);
 129                 $tg->index_text($subj, 1, 'S') if $subj;
 130                 $tg->increase_termpos;
 131                 $tg->index_text($subj) if $subj;
 132                 $tg->increase_termpos;
 133
 134                 $tg->index_text($smsg->from->format);
 135                 $tg->increase_termpos;
 136
 137                 $mime->walk_parts(sub {
 138                         my ($part) = @_;
 139                         return if $part->subparts; # walk_parts already recurses
 140                         my $ct = $part->content_type || $ct_msg;
 141
 142                         # account for filter bugs...
 143                         $ct =~ m!\btext/plain\b!i or return;
 144
 145                         my $enc = PublicInbox::View::enc_for($ct, $enc_msg);
 146                         my (@orig, @quot);
 147                         foreach my $l (split(/\n/, $enc->decode($part->body))) {
 148                                 if ($l =~ /^\s*>/) {
 149                                         push @quot, $l;
 150                                 } else {
 151                                         push @orig, $l;
 152                                 }
 153                         }
 154                         if (@quot) {
 155                                 $tg->index_text(join("\n", @quot), 0);
 156                                 $tg->increase_termpos;
 157                         }
 158                         if (@orig) {
 159                                 $tg->index_text(join("\n", @orig));
 160                                 $tg->increase_termpos;
 161                         }
 162                 });
 163
 164                 if ($was_ghost) {
 165                         $doc_id = $smsg->doc_id;
 166                         $self->link_message($smsg, 0);
 167                         $db->replace_document($doc_id, $doc);
 168                 } else {
 169                         $self->link_message($smsg, 0);
 170                         $doc_id = $db->add_document($doc);
 171                 }
 172         };
 173
 174         if ($@) {
 175                 warn "failed to index message <$mid>: $@\n";
 176                 $db->cancel_transaction;
 177         } else {
 178                 $db->commit_transaction;
 179         }
 180         $doc_id;
 181 }
 182
 183 # returns deleted doc_id on success, undef on missing
 184 sub remove_message {
 185         my ($self, $mid) = @_;
 186         my $db = $self->{xdb};
 187         my $doc_id;
 188         $mid = mid_clean($mid);
 189         $mid = mid_compressed($mid);
 190
 191         $db->begin_transaction;
 192         eval {
 193                 $doc_id = $self->find_unique_doc_id('mid', $mid);
 194                 $db->delete_document($doc_id) if defined $doc_id;
 195         };
 196
 197         if ($@) {
 198                 warn "failed to remove message <$mid>: $@\n";
 199                 $db->cancel_transaction;
 200         } else {
 201                 $db->commit_transaction;
 202         }
 203         $doc_id;
 204 }
 205
 206 # read-only
 207 sub query {
 208         my ($self, $query_string, $opts) = @_;
 209         my $query = $self->qp->parse_query($query_string, QP_FLAGS);
 210
 211         $query = Search::Xapian::Query->new(OP_AND, $mail_query, $query);
 212         $self->do_enquire($query, $opts);
 213 }
 214
 215 sub get_subject_path {
 216         my ($self, $path, $opts) = @_;
 217         my $query = $self->qp->parse_query("path:$path", 0);
 218         $self->do_enquire($query);
 219 }
 220
 221 # given a message ID, get followups to a message
 222 sub get_followups {
 223         my ($self, $mid, $opts) = @_;
 224         $mid = mid_clean($mid);
 225         $mid = mid_compressed($mid);
 226         my $qp = $self->qp;
 227         my $irt = $qp->parse_query("inreplyto:$mid", 0);
 228         my $ref = $qp->parse_query("references:$mid", 0);
 229         my $query = Search::Xapian::Query->new(OP_OR, $irt, $ref);
 230
 231         $self->do_enquire($query);
 232 }
 233
 234 sub get_thread {
 235         my ($self, $mid, $opts) = @_;
 236         my $smsg = eval { $self->lookup_message($mid) };
 237
 238         return { count => 0, msgs => [] } unless $smsg;
 239         my $qp = $self->qp;
 240         my $qtid = $qp->parse_query('thread:'.$smsg->thread_id);
 241         my $qsub = $qp->parse_query('path:'.$smsg->path);
 242         my $query = Search::Xapian::Query->new(OP_OR, $qtid, $qsub);
 243         $self->do_enquire($query);
 244 }
 245
 246 # private subs below
 247
 248 sub do_enquire {
 249         my ($self, $query, $opts) = @_;
 250         my $enquire = $self->enquire;
 251
 252         $enquire->set_query($query);
 253         $enquire->set_sort_by_relevance_then_value(TS, 0);
 254         $opts ||= {};
 255         my $offset = $opts->{offset} || 0;
 256         my $limit = $opts->{limit} || 50;
 257         my $mset = $enquire->get_mset($offset, $limit);
 258         my @msgs = map {
 259                 PublicInbox::SearchMsg->load_doc($_->get_document);
 260         } $mset->items;
 261
 262         { count => $mset->get_matches_estimated, msgs => \@msgs }
 263 }
 264
 265 # read-write
 266 sub stemmer { Search::Xapian::Stem->new(LANG) }
 267
 268 # read-only
 269 sub qp {
 270         my ($self) = @_;
 271
 272         my $qp = $self->{query_parser};
 273         return $qp if $qp;
 274
 275         # new parser
 276         $qp = Search::Xapian::QueryParser->new;
 277         $qp->set_default_op(OP_AND);
 278         $qp->set_database($self->{xdb});
 279         $qp->set_stemmer($self->stemmer);
 280         $qp->set_stemming_strategy(STEM_SOME);
 281         $qp->add_valuerangeprocessor($self->ts_range_processor);
 282         $qp->add_valuerangeprocessor($self->date_range_processor);
 283
 284         while (my ($name, $prefix) = each %bool_pfx_external) {
 285                 $qp->add_boolean_prefix($name, $prefix);
 286         }
 287
 288         while (my ($name, $prefix) = each %prob_prefix) {
 289                 $qp->add_prefix($name, $prefix);
 290         }
 291
 292         $self->{query_parser} = $qp;
 293 }
 294
 295 sub term_generator { # write-only
 296         my ($self) = @_;
 297
 298         my $tg = $self->{term_generator};
 299         return $tg if $tg;
 300
 301         $tg = Search::Xapian::TermGenerator->new;
 302         $tg->set_stemmer($self->stemmer);
 303
 304         $self->{term_generator} = $tg;
 305 }
 306
 307 sub next_doc_id { $_[0]->{xdb}->get_lastdocid + 1 }
 308
 309 # increments last_thread_id counter
 310 # returns a 64-bit integer represented as a hex string
 311 sub next_thread_id {
 312         my ($self) = @_;
 313         my $db = $self->{xdb};
 314         my $last_thread_id = int($db->get_metadata('last_thread_id') || 0);
 315
 316         $db->set_metadata('last_thread_id', ++$last_thread_id);
 317
 318         $last_thread_id;
 319 }
 320
 321 sub ts_range_processor {
 322         $_[0]->{tsrp} ||= Search::Xapian::NumberValueRangeProcessor->new(TS);
 323 }
 324
 325 sub date_range_processor {
 326         $_[0]->{drp} ||= Search::Xapian::DateValueRangeProcessor->new(TS);
 327 }
 328
 329 sub link_message {
 330         my ($self, $smsg, $is_ghost) = @_;
 331
 332         if ($is_ghost) {
 333                 $smsg->ensure_metadata;
 334         } else {
 335                 $self->link_message_to_parents($smsg);
 336         }
 337 }
 338
 339 sub link_message_to_parents {
 340         my ($self, $smsg) = @_;
 341         my $doc = $smsg->{doc};
 342         my $mid = mid_compressed($smsg->mid);
 343         my $mime = $smsg->mime;
 344         my $refs = $mime->header_obj->header_raw('References');
 345         my @refs = $refs ? ($refs =~ /<([^>]+)>/g) : ();
 346         my $irt = $mime->header_obj->header_raw('In-Reply-To');
 347         if ($irt) {
 348                 if ($irt =~ /<([^>]+)>/) {
 349                         $irt = $1;
 350                 }
 351                 push @refs, $irt;
 352         }
 353
 354         my $tid;
 355         if (@refs) {
 356                 @refs = map { mid_compressed($_) } @refs;
 357                 my %uniq;
 358                 @refs = grep { !$uniq{$_}++ } @refs; # uniq
 359
 360                 $doc->add_term(xpfx('inreplyto') . $refs[-1]);
 361
 362                 my $ref_pfx = xpfx('references');
 363
 364                 # first ref *should* be the thread root,
 365                 # but we can never trust clients to do the right thing
 366                 my $ref = shift @refs;
 367                 $doc->add_term($ref_pfx . $ref);
 368                 $tid = $self->_resolve_mid_to_tid($ref);
 369
 370                 # the rest of the refs should point to this tid:
 371                 foreach $ref (@refs) {
 372                         $doc->add_term($ref_pfx . $ref);
 373                         my $ptid = $self->_resolve_mid_to_tid($ref);
 374                         if ($tid ne $ptid) {
 375                                 $self->merge_threads($tid, $ptid);
 376                         }
 377                 }
 378         } else {
 379                 $tid = $self->next_thread_id;
 380         }
 381         $doc->add_term(xpfx('thread') . $tid);
 382 }
 383
 384 sub lookup_message {
 385         my ($self, $mid) = @_;
 386         $mid = mid_clean($mid);
 387         $mid = mid_compressed($mid);
 388
 389         my $doc_id = $self->find_unique_doc_id('mid', $mid);
 390         my $smsg;
 391         if (defined $doc_id) {
 392                 # raises on error:
 393                 my $doc = $self->{xdb}->get_document($doc_id);
 394                 $smsg = PublicInbox::SearchMsg->wrap($doc, $mid);
 395                 $smsg->doc_id($doc_id);
 396         }
 397         $smsg;
 398 }
 399
 400 sub find_unique_doc_id {
 401         my ($self, $term, $value) = @_;
 402
 403         my ($begin, $end) = $self->find_doc_ids($term, $value);
 404
 405         return undef if $begin->equal($end); # not found
 406
 407         my $rv = $begin->get_docid;
 408
 409         # sanity check
 410         $begin->inc;
 411         $begin->equal($end) or die "Term '$term:$value' is not unique\n";
 412         $rv;
 413 }
 414
 415 # returns begin and end PostingIterator
 416 sub find_doc_ids {
 417         my ($self, $term, $value) = @_;
 418
 419         $self->find_doc_ids_for_term(xpfx($term) . $value);
 420 }
 421
 422 # returns begin and end PostingIterator
 423 sub find_doc_ids_for_term {
 424         my ($self, $term) = @_;
 425         my $db = $self->{xdb};
 426
 427         ($db->postlist_begin($term), $db->postlist_end($term));
 428 }
 429
 430 # this will create a ghost as necessary
 431 sub _resolve_mid_to_tid {
 432         my ($self, $mid) = @_;
 433
 434         my $smsg = $self->lookup_message($mid) || $self->create_ghost($mid);
 435         $smsg->thread_id;
 436 }
 437
 438 sub create_ghost {
 439         my ($self, $mid, $tid) = @_;
 440
 441         $mid = mid_compressed($mid);
 442         $tid = $self->next_thread_id unless defined $tid;
 443
 444         my $doc = Search::Xapian::Document->new;
 445         $doc->add_term(xpfx('mid') . $mid);
 446         $doc->add_term(xpfx('thread') . $tid);
 447         $doc->add_term(xpfx('type') . 'ghost');
 448
 449         my $smsg = PublicInbox::SearchMsg->wrap($doc, $mid);
 450         $self->link_message($smsg, 1);
 451         $self->{xdb}->add_document($doc);
 452
 453         $smsg;
 454 }
 455
 456 sub merge_threads {
 457         my ($self, $winner_tid, $loser_tid) = @_;
 458         my ($head, $tail) = $self->find_doc_ids('thread', $loser_tid);
 459         my $thread_pfx = xpfx('thread');
 460         my $db = $self->{xdb};
 461
 462         for (; $head != $tail; $head->inc) {
 463                 my $docid = $head->get_docid;
 464                 my $doc = $db->get_document($docid);
 465                 $doc->remove_term($thread_pfx . $loser_tid);
 466                 $doc->add_term($thread_pfx . $winner_tid);
 467                 $db->replace_document($docid, $doc);
 468         }
 469 }
 470
 471 # normalize subjects so they are suitable as pathnames for URLs
 472 sub subject_path {
 473         my $subj = pop;
 474
 475         $subj =~ s/\A\s+//;
 476         $subj =~ s/\s+\z//;
 477         $subj =~ s/^(?:re|aw):\s*//i; # remove reply prefix (aw: German)
 478         $subj =~ s![^a-zA-Z0-9_\.~/\-]+!_!g;
 479         lc($subj);
 480 }
 481
 482 sub do_cat_mail {
 483         my ($git, $blob) = @_;
 484         my $mime = eval {
 485                 my $str = $git->cat_file($blob);
 486                 Email::MIME->new($str);
 487         };
 488         $@ ? undef : $mime;
 489 }
 490
 491 sub index_blob {
 492         my ($self, $git, $blob) = @_;
 493         my $mime = do_cat_mail($git, $blob) or return;
 494         eval { $self->add_message($mime) };
 495         warn "W: index_blob $blob: $@\n" if $@;
 496 }
 497
 498 sub unindex_blob {
 499         my ($self, $git, $blob) = @_;
 500         my $mime = do_cat_mail($git, $blob) or return;
 501         my $mid = $mime->header_obj->header_raw('Message-ID');
 502         eval { $self->remove_message($mid) } if defined $mid;
 503         warn "W: unindex_blob $blob: $@\n" if $@;
 504 }
 505
 506 sub enquire {
 507         my ($self) = @_;
 508         $self->{enquire} ||= Search::Xapian::Enquire->new($self->{xdb});
 509 }
 510
 511 # indexes all unindexed messages
 512 sub index_sync {
 513         my ($self, $git) = @_;
 514         my $db = $self->{xdb};
 515         my $latest = $db->get_metadata('last_commit');
 516         my $range = length $latest ? "$latest..HEAD" : 'HEAD';
 517         $latest = undef;
 518
 519         my $hex = '[a-f0-9]';
 520         my $h40 = $hex .'{40}';
 521         my $addmsg = qr!^:000000 100644 \S+ ($h40) A\t${hex}{2}/${hex}{38}$!;
 522         my $delmsg = qr!^:100644 000000 ($h40) \S+ D\t${hex}{2}/${hex}{38}$!;
 523
 524         # get indexed messages
 525         my @cmd = ('git', "--git-dir=$git->{git_dir}", "log",
 526                     qw/--reverse --no-notes --no-color --raw -r --no-abbrev/,
 527                     $range);
 528
 529         my $pid = open(my $log, '-|', @cmd) or
 530                 die('open` '.join(' ', @cmd) . " pipe failed: $!\n");
 531         my $last;
 532         while (my $line = <$log>) {
 533                 if ($line =~ /$addmsg/o) {
 534                         $self->index_blob($git, $1);
 535                 } elsif ($line =~ /$delmsg/o) {
 536                         $self->unindex_blob($git, $1);
 537                 } elsif ($line =~ /^commit ($h40)/o) {
 538                         my $commit = $1;
 539                         if (defined $latest) {
 540                                 $db->set_metadata('last_commit', $latest)
 541                         }
 542                         $latest = $commit;
 543                 }
 544         }
 545         close $log;
 546         $db->set_metadata('last_commit', $latest) if defined $latest;
 547 }
 548
 549 1;