lib/PublicInbox/Search.pm

   1 # Copyright (C) 2015, all contributors <meta@public-inbox.org>
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 # based on notmuch, but with no concept of folders, files or flags
   4 package PublicInbox::Search;
   5 use strict;
   6 use warnings;
   7 use PublicInbox::SearchMsg;
   8 use Search::Xapian qw/:standard/;
   9 require PublicInbox::View;
  10 use Email::MIME;
  11 use PublicInbox::MID qw/mid_clean mid_compressed/;
  12
  13 use constant {
  14         TS => 0,
  15         # SCHEMA_VERSION history
  16         # 0 - initial
  17         # 1 - subject_path is lower-cased
  18         # 2 - subject_path is mid_compressed in the index, only
  19         # 3 - message-ID is compressed if it includes '%' (hack!)
  20         SCHEMA_VERSION => 3,
  21         LANG => 'english',
  22         QP_FLAGS => FLAG_PHRASE|FLAG_BOOLEAN|FLAG_LOVEHATE|FLAG_WILDCARD,
  23 };
  24
  25 # setup prefixes
  26 my %bool_pfx_internal = (
  27         type => 'T', # "mail" or "ghost"
  28         mid => 'Q', # uniQue id (Message-ID or mid_compressed)
  29 );
  30
  31 my %bool_pfx_external = (
  32         path => 'XPATH',
  33         thread => 'G', # newsGroup (or similar entity - e.g. a web forum name)
  34         references => 'XREFS',
  35         inreplyto => 'XIRT',
  36 );
  37
  38 my %prob_prefix = (
  39         subject => 'S',
  40 );
  41
  42 my %all_pfx = (%bool_pfx_internal, %bool_pfx_external, %prob_prefix);
  43
  44 sub xpfx { $all_pfx{$_[0]} }
  45
  46 our %PFX2TERM_RMAP;
  47 while (my ($k, $v) = each %all_pfx) {
  48         next if $prob_prefix{$k};
  49         $PFX2TERM_RMAP{$v} = $k;
  50 }
  51
  52 my $mail_query = Search::Xapian::Query->new(xpfx('type') . 'mail');
  53
  54 sub new {
  55         my ($class, $git_dir, $writable) = @_;
  56         # allow concurrent versions for easier rollback:
  57         my $dir = "$git_dir/public-inbox/xapian" . SCHEMA_VERSION;
  58         my $db;
  59
  60         if ($writable) { # not used by the WWW interface
  61                 require Search::Xapian::WritableDatabase;
  62                 require File::Path;
  63                 File::Path::mkpath($dir);
  64                 $db = Search::Xapian::WritableDatabase->new($dir,
  65                                         Search::Xapian::DB_CREATE_OR_OPEN);
  66         } else {
  67                 $db = Search::Xapian::Database->new($dir);
  68         }
  69         bless { xdb => $db, git_dir => $git_dir }, $class;
  70 }
  71
  72 sub reopen { $_[0]->{xdb}->reopen }
  73
  74 sub add_message {
  75         my ($self, $mime) = @_; # mime = Email::MIME object
  76         my $db = $self->{xdb};
  77
  78         my $doc_id;
  79         my $mid = mid_clean($mime->header_obj->header_raw('Message-ID'));
  80         $mid = mid_compressed($mid);
  81         my $was_ghost = 0;
  82         my $ct_msg = $mime->header('Content-Type') || 'text/plain';
  83         my $enc_msg = PublicInbox::View::enc_for($ct_msg);
  84
  85         $db->begin_transaction;
  86         eval {
  87                 my $smsg = $self->lookup_message($mid);
  88                 my $doc;
  89
  90                 if ($smsg) {
  91                         $smsg->ensure_metadata;
  92                         # convert a ghost to a regular message
  93                         # it will also clobber any existing regular message
  94                         $smsg->mime($mime);
  95                         $doc = $smsg->{doc};
  96
  97                         my $type = xpfx('type');
  98                         eval {
  99                                 $doc->remove_term($type . 'ghost');
 100                                 $was_ghost = 1;
 101                         };
 102
 103                         # probably does not exist:
 104                         eval { $doc->remove_term($type . 'mail') };
 105                         $doc->add_term($type . 'mail');
 106                 }  else {
 107                         $smsg = PublicInbox::SearchMsg->new($mime);
 108                         $doc = $smsg->{doc};
 109                         $doc->add_term(xpfx('mid') . $mid);
 110                 }
 111
 112                 my $subj = $smsg->subject;
 113
 114                 if (length $subj) {
 115                         $doc->add_term(xpfx('subject') . $subj);
 116
 117                         my $path = subject_path($subj);
 118                         $doc->add_term(xpfx('path') . mid_compressed($path));
 119                 }
 120
 121                 my $from = $smsg->from_name;
 122                 my $date = $smsg->date;
 123                 my $ts = Search::Xapian::sortable_serialise($smsg->ts);
 124                 $doc->add_value(PublicInbox::Search::TS, $ts);
 125
 126                 $doc->set_data($smsg->to_doc_data);
 127
 128                 my $tg = $self->term_generator;
 129
 130                 $tg->set_document($doc);
 131                 $tg->index_text($subj, 1, 'S') if $subj;
 132                 $tg->increase_termpos;
 133                 $tg->index_text($subj) if $subj;
 134                 $tg->increase_termpos;
 135
 136                 $tg->index_text($smsg->from->format);
 137                 $tg->increase_termpos;
 138
 139                 $mime->walk_parts(sub {
 140                         my ($part) = @_;
 141                         return if $part->subparts; # walk_parts already recurses
 142                         my $ct = $part->content_type || $ct_msg;
 143
 144                         # account for filter bugs...
 145                         $ct =~ m!\btext/plain\b!i or return;
 146
 147                         my $enc = PublicInbox::View::enc_for($ct, $enc_msg);
 148                         my (@orig, @quot);
 149                         foreach my $l (split(/\n/, $enc->decode($part->body))) {
 150                                 if ($l =~ /^\s*>/) {
 151                                         push @quot, $l;
 152                                 } else {
 153                                         push @orig, $l;
 154                                 }
 155                         }
 156                         if (@quot) {
 157                                 $tg->index_text(join("\n", @quot), 0);
 158                                 $tg->increase_termpos;
 159                         }
 160                         if (@orig) {
 161                                 $tg->index_text(join("\n", @orig));
 162                                 $tg->increase_termpos;
 163                         }
 164                 });
 165
 166                 if ($was_ghost) {
 167                         $doc_id = $smsg->doc_id;
 168                         $self->link_message($smsg, 0);
 169                         $db->replace_document($doc_id, $doc);
 170                 } else {
 171                         $self->link_message($smsg, 0);
 172                         $doc_id = $db->add_document($doc);
 173                 }
 174         };
 175
 176         if ($@) {
 177                 warn "failed to index message <$mid>: $@\n";
 178                 $db->cancel_transaction;
 179         } else {
 180                 $db->commit_transaction;
 181         }
 182         $doc_id;
 183 }
 184
 185 # returns deleted doc_id on success, undef on missing
 186 sub remove_message {
 187         my ($self, $mid) = @_;
 188         my $db = $self->{xdb};
 189         my $doc_id;
 190         $mid = mid_clean($mid);
 191         $mid = mid_compressed($mid);
 192
 193         $db->begin_transaction;
 194         eval {
 195                 $doc_id = $self->find_unique_doc_id('mid', $mid);
 196                 $db->delete_document($doc_id) if defined $doc_id;
 197         };
 198
 199         if ($@) {
 200                 warn "failed to remove message <$mid>: $@\n";
 201                 $db->cancel_transaction;
 202         } else {
 203                 $db->commit_transaction;
 204         }
 205         $doc_id;
 206 }
 207
 208 # read-only
 209 sub query {
 210         my ($self, $query_string, $opts) = @_;
 211         my $query = $self->qp->parse_query($query_string, QP_FLAGS);
 212
 213         $query = Search::Xapian::Query->new(OP_AND, $mail_query, $query);
 214         $self->do_enquire($query, $opts);
 215 }
 216
 217 sub get_subject_path {
 218         my ($self, $path, $opts) = @_;
 219         my $query = $self->qp->parse_query("path:".mid_compressed($path), 0);
 220         $self->do_enquire($query);
 221 }
 222
 223 # given a message ID, get followups to a message
 224 sub get_followups {
 225         my ($self, $mid, $opts) = @_;
 226         $mid = mid_clean($mid);
 227         $mid = mid_compressed($mid);
 228         my $qp = $self->qp;
 229         my $irt = $qp->parse_query("inreplyto:$mid", 0);
 230         my $ref = $qp->parse_query("references:$mid", 0);
 231         my $query = Search::Xapian::Query->new(OP_OR, $irt, $ref);
 232
 233         $self->do_enquire($query);
 234 }
 235
 236 sub get_thread {
 237         my ($self, $mid, $opts) = @_;
 238         my $smsg = eval { $self->lookup_message($mid) };
 239
 240         return { count => 0, msgs => [] } unless $smsg;
 241         my $qp = $self->qp;
 242         my $qtid = $qp->parse_query('thread:'.$smsg->thread_id);
 243         my $qsub = $qp->parse_query('path:'.mid_compressed($smsg->path));
 244         my $query = Search::Xapian::Query->new(OP_OR, $qtid, $qsub);
 245         $self->do_enquire($query);
 246 }
 247
 248 # private subs below
 249
 250 sub do_enquire {
 251         my ($self, $query, $opts) = @_;
 252         my $enquire = $self->enquire;
 253
 254         $enquire->set_query($query);
 255         $enquire->set_sort_by_relevance_then_value(TS, 0);
 256         $opts ||= {};
 257         my $offset = $opts->{offset} || 0;
 258         my $limit = $opts->{limit} || 50;
 259         my $mset = $enquire->get_mset($offset, $limit);
 260         my @msgs = map {
 261                 PublicInbox::SearchMsg->load_doc($_->get_document);
 262         } $mset->items;
 263
 264         { count => $mset->get_matches_estimated, msgs => \@msgs }
 265 }
 266
 267 # read-write
 268 sub stemmer { Search::Xapian::Stem->new(LANG) }
 269
 270 # read-only
 271 sub qp {
 272         my ($self) = @_;
 273
 274         my $qp = $self->{query_parser};
 275         return $qp if $qp;
 276
 277         # new parser
 278         $qp = Search::Xapian::QueryParser->new;
 279         $qp->set_default_op(OP_AND);
 280         $qp->set_database($self->{xdb});
 281         $qp->set_stemmer($self->stemmer);
 282         $qp->set_stemming_strategy(STEM_SOME);
 283         $qp->add_valuerangeprocessor($self->ts_range_processor);
 284         $qp->add_valuerangeprocessor($self->date_range_processor);
 285
 286         while (my ($name, $prefix) = each %bool_pfx_external) {
 287                 $qp->add_boolean_prefix($name, $prefix);
 288         }
 289
 290         while (my ($name, $prefix) = each %prob_prefix) {
 291                 $qp->add_prefix($name, $prefix);
 292         }
 293
 294         $self->{query_parser} = $qp;
 295 }
 296
 297 sub term_generator { # write-only
 298         my ($self) = @_;
 299
 300         my $tg = $self->{term_generator};
 301         return $tg if $tg;
 302
 303         $tg = Search::Xapian::TermGenerator->new;
 304         $tg->set_stemmer($self->stemmer);
 305
 306         $self->{term_generator} = $tg;
 307 }
 308
 309 sub next_doc_id { $_[0]->{xdb}->get_lastdocid + 1 }
 310
 311 # increments last_thread_id counter
 312 # returns a 64-bit integer represented as a hex string
 313 sub next_thread_id {
 314         my ($self) = @_;
 315         my $db = $self->{xdb};
 316         my $last_thread_id = int($db->get_metadata('last_thread_id') || 0);
 317
 318         $db->set_metadata('last_thread_id', ++$last_thread_id);
 319
 320         $last_thread_id;
 321 }
 322
 323 sub ts_range_processor {
 324         $_[0]->{tsrp} ||= Search::Xapian::NumberValueRangeProcessor->new(TS);
 325 }
 326
 327 sub date_range_processor {
 328         $_[0]->{drp} ||= Search::Xapian::DateValueRangeProcessor->new(TS);
 329 }
 330
 331 sub link_message {
 332         my ($self, $smsg, $is_ghost) = @_;
 333
 334         if ($is_ghost) {
 335                 $smsg->ensure_metadata;
 336         } else {
 337                 $self->link_message_to_parents($smsg);
 338         }
 339 }
 340
 341 sub link_message_to_parents {
 342         my ($self, $smsg) = @_;
 343         my $doc = $smsg->{doc};
 344         my $mid = mid_compressed($smsg->mid);
 345         my $mime = $smsg->mime;
 346         my $refs = $mime->header_obj->header_raw('References');
 347         my @refs = $refs ? ($refs =~ /<([^>]+)>/g) : ();
 348         my $irt = $mime->header_obj->header_raw('In-Reply-To');
 349         if ($irt) {
 350                 if ($irt =~ /<([^>]+)>/) {
 351                         $irt = $1;
 352                 }
 353                 push @refs, $irt;
 354         }
 355
 356         my $tid;
 357         if (@refs) {
 358                 @refs = map { mid_compressed($_) } @refs;
 359                 my %uniq;
 360                 @refs = grep { !$uniq{$_}++ } @refs; # uniq
 361
 362                 $doc->add_term(xpfx('inreplyto') . $refs[-1]);
 363
 364                 my $ref_pfx = xpfx('references');
 365
 366                 # first ref *should* be the thread root,
 367                 # but we can never trust clients to do the right thing
 368                 my $ref = shift @refs;
 369                 $doc->add_term($ref_pfx . $ref);
 370                 $tid = $self->_resolve_mid_to_tid($ref);
 371
 372                 # the rest of the refs should point to this tid:
 373                 foreach $ref (@refs) {
 374                         $doc->add_term($ref_pfx . $ref);
 375                         my $ptid = $self->_resolve_mid_to_tid($ref);
 376                         if ($tid ne $ptid) {
 377                                 $self->merge_threads($tid, $ptid);
 378                         }
 379                 }
 380         } else {
 381                 $tid = $self->next_thread_id;
 382         }
 383         $doc->add_term(xpfx('thread') . $tid);
 384 }
 385
 386 sub lookup_message {
 387         my ($self, $mid) = @_;
 388         $mid = mid_clean($mid);
 389         $mid = mid_compressed($mid);
 390
 391         my $doc_id = $self->find_unique_doc_id('mid', $mid);
 392         my $smsg;
 393         if (defined $doc_id) {
 394                 # raises on error:
 395                 my $doc = $self->{xdb}->get_document($doc_id);
 396                 $smsg = PublicInbox::SearchMsg->wrap($doc, $mid);
 397                 $smsg->doc_id($doc_id);
 398         }
 399         $smsg;
 400 }
 401
 402 sub find_unique_doc_id {
 403         my ($self, $term, $value) = @_;
 404
 405         my ($begin, $end) = $self->find_doc_ids($term, $value);
 406
 407         return undef if $begin->equal($end); # not found
 408
 409         my $rv = $begin->get_docid;
 410
 411         # sanity check
 412         $begin->inc;
 413         $begin->equal($end) or die "Term '$term:$value' is not unique\n";
 414         $rv;
 415 }
 416
 417 # returns begin and end PostingIterator
 418 sub find_doc_ids {
 419         my ($self, $term, $value) = @_;
 420
 421         $self->find_doc_ids_for_term(xpfx($term) . $value);
 422 }
 423
 424 # returns begin and end PostingIterator
 425 sub find_doc_ids_for_term {
 426         my ($self, $term) = @_;
 427         my $db = $self->{xdb};
 428
 429         ($db->postlist_begin($term), $db->postlist_end($term));
 430 }
 431
 432 # this will create a ghost as necessary
 433 sub _resolve_mid_to_tid {
 434         my ($self, $mid) = @_;
 435
 436         my $smsg = $self->lookup_message($mid) || $self->create_ghost($mid);
 437         $smsg->thread_id;
 438 }
 439
 440 sub create_ghost {
 441         my ($self, $mid, $tid) = @_;
 442
 443         $mid = mid_compressed($mid);
 444         $tid = $self->next_thread_id unless defined $tid;
 445
 446         my $doc = Search::Xapian::Document->new;
 447         $doc->add_term(xpfx('mid') . $mid);
 448         $doc->add_term(xpfx('thread') . $tid);
 449         $doc->add_term(xpfx('type') . 'ghost');
 450
 451         my $smsg = PublicInbox::SearchMsg->wrap($doc, $mid);
 452         $self->link_message($smsg, 1);
 453         $self->{xdb}->add_document($doc);
 454
 455         $smsg;
 456 }
 457
 458 sub merge_threads {
 459         my ($self, $winner_tid, $loser_tid) = @_;
 460         my ($head, $tail) = $self->find_doc_ids('thread', $loser_tid);
 461         my $thread_pfx = xpfx('thread');
 462         my $db = $self->{xdb};
 463
 464         for (; $head != $tail; $head->inc) {
 465                 my $docid = $head->get_docid;
 466                 my $doc = $db->get_document($docid);
 467                 $doc->remove_term($thread_pfx . $loser_tid);
 468                 $doc->add_term($thread_pfx . $winner_tid);
 469                 $db->replace_document($docid, $doc);
 470         }
 471 }
 472
 473 # normalize subjects so they are suitable as pathnames for URLs
 474 sub subject_path {
 475         my $subj = pop;
 476
 477         $subj =~ s/\A\s+//;
 478         $subj =~ s/\s+\z//;
 479         $subj =~ s/^(?:re|aw):\s*//i; # remove reply prefix (aw: German)
 480         $subj =~ s![^a-zA-Z0-9_\.~/\-]+!_!g;
 481         lc($subj);
 482 }
 483
 484 sub do_cat_mail {
 485         my ($git, $blob) = @_;
 486         my $mime = eval {
 487                 my $str = $git->cat_file($blob);
 488                 Email::MIME->new($str);
 489         };
 490         $@ ? undef : $mime;
 491 }
 492
 493 sub index_blob {
 494         my ($self, $git, $blob) = @_;
 495         my $mime = do_cat_mail($git, $blob) or return;
 496         eval { $self->add_message($mime) };
 497         warn "W: index_blob $blob: $@\n" if $@;
 498 }
 499
 500 sub unindex_blob {
 501         my ($self, $git, $blob) = @_;
 502         my $mime = do_cat_mail($git, $blob) or return;
 503         my $mid = $mime->header_obj->header_raw('Message-ID');
 504         eval { $self->remove_message($mid) } if defined $mid;
 505         warn "W: unindex_blob $blob: $@\n" if $@;
 506 }
 507
 508 sub enquire {
 509         my ($self) = @_;
 510         $self->{enquire} ||= Search::Xapian::Enquire->new($self->{xdb});
 511 }
 512
 513 # indexes all unindexed messages
 514 sub index_sync {
 515         my ($self, $git) = @_;
 516         my $db = $self->{xdb};
 517         my $latest = $db->get_metadata('last_commit');
 518         my $range = length $latest ? "$latest..HEAD" : 'HEAD';
 519         $latest = undef;
 520
 521         my $hex = '[a-f0-9]';
 522         my $h40 = $hex .'{40}';
 523         my $addmsg = qr!^:000000 100644 \S+ ($h40) A\t${hex}{2}/${hex}{38}$!;
 524         my $delmsg = qr!^:100644 000000 ($h40) \S+ D\t${hex}{2}/${hex}{38}$!;
 525
 526         # get indexed messages
 527         my @cmd = ('git', "--git-dir=$git->{git_dir}", "log",
 528                     qw/--reverse --no-notes --no-color --raw -r --no-abbrev/,
 529                     $range);
 530
 531         my $pid = open(my $log, '-|', @cmd) or
 532                 die('open` '.join(' ', @cmd) . " pipe failed: $!\n");
 533         my $last;
 534         while (my $line = <$log>) {
 535                 if ($line =~ /$addmsg/o) {
 536                         $self->index_blob($git, $1);
 537                 } elsif ($line =~ /$delmsg/o) {
 538                         $self->unindex_blob($git, $1);
 539                 } elsif ($line =~ /^commit ($h40)/o) {
 540                         my $commit = $1;
 541                         if (defined $latest) {
 542                                 $db->set_metadata('last_commit', $latest)
 543                         }
 544                         $latest = $commit;
 545                 }
 546         }
 547         close $log;
 548         $db->set_metadata('last_commit', $latest) if defined $latest;
 549 }
 550
 551 1;