lib/PublicInbox/Search.pm

   1 # Copyright (C) 2015 all contributors <meta@public-inbox.org>
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 # based on notmuch, but with no concept of folders, files or flags
   4 #
   5 # Read-only search interface for use by the web and NNTP interfaces
   6 package PublicInbox::Search;
   7 use strict;
   8 use warnings;
   9
  10 # values for searching
  11 use constant TS => 0; # timestamp
  12 use constant NUM => 1; # NNTP article number
  13 use constant BYTES => 2; # :bytes as defined in RFC 3977
  14 use constant LINES => 3; # :lines as defined in RFC 3977
  15
  16 use Search::Xapian qw/:standard/;
  17 use PublicInbox::SearchMsg;
  18 use Email::MIME;
  19 use PublicInbox::MID qw/mid_clean id_compress/;
  20
  21 # This is English-only, everything else is non-standard and may be confused as
  22 # a prefix common in patch emails
  23 our $REPLY_RE = qr/^re:\s+/i;
  24 our $LANG = 'english';
  25
  26 use constant {
  27         # SCHEMA_VERSION history
  28         # 0 - initial
  29         # 1 - subject_path is lower-cased
  30         # 2 - subject_path is id_compress in the index, only
  31         # 3 - message-ID is compressed if it includes '%' (hack!)
  32         # 4 - change "Re: " normalization, avoid circular Reference ghosts
  33         # 5 - subject_path drops trailing '.'
  34         # 6 - preserve References: order in document data
  35         # 7 - remove references and inreplyto terms
  36         # 8 - remove redundant/unneeded document data
  37         # 9 - disable Message-ID compression (SHA-1)
  38         # 10 - optimize doc for NNTP overviews
  39         SCHEMA_VERSION => 10,
  40
  41         # n.b. FLAG_PURE_NOT is expensive not suitable for a public website
  42         # as it could become a denial-of-service vector
  43         QP_FLAGS => FLAG_PHRASE|FLAG_BOOLEAN|FLAG_LOVEHATE|FLAG_WILDCARD,
  44 };
  45
  46 # setup prefixes
  47 my %bool_pfx_internal = (
  48         type => 'T', # "mail" or "ghost"
  49         thread => 'G', # newsGroup (or similar entity - e.g. a web forum name)
  50 );
  51
  52 my %bool_pfx_external = (
  53         path => 'XPATH',
  54         mid => 'Q', # uniQue id (Message-ID)
  55 );
  56
  57 my %prob_prefix = (
  58         subject => 'S',
  59         s => 'S', # for mairix compatibility
  60         m => 'Q', # 'mid' is exact, 'm' can do partial
  61 );
  62
  63 my %all_pfx = (%bool_pfx_internal, %bool_pfx_external, %prob_prefix);
  64
  65 sub xpfx { $all_pfx{$_[0]} }
  66
  67 our %PFX2TERM_RMAP;
  68 my %meta_pfx = (mid => 1, thread => 1, path => 1);
  69 while (my ($k, $v) = each %all_pfx) {
  70         $PFX2TERM_RMAP{$v} = $k if $meta_pfx{$k};
  71 }
  72
  73 my $mail_query = Search::Xapian::Query->new(xpfx('type') . 'mail');
  74
  75 sub xdir {
  76         my (undef, $git_dir) = @_;
  77         "$git_dir/public-inbox/xapian" . SCHEMA_VERSION;
  78 }
  79
  80 sub new {
  81         my ($class, $git_dir) = @_;
  82         my $dir = $class->xdir($git_dir);
  83         my $db = Search::Xapian::Database->new($dir);
  84         bless { xdb => $db, git_dir => $git_dir }, $class;
  85 }
  86
  87 sub reopen { $_[0]->{xdb}->reopen }
  88
  89 # read-only
  90 sub query {
  91         my ($self, $query_string, $opts) = @_;
  92         my $query;
  93
  94         $opts ||= {};
  95         unless ($query_string eq '') {
  96                 $query = $self->qp->parse_query($query_string, QP_FLAGS);
  97                 $opts->{relevance} = 1 unless exists $opts->{relevance};
  98         }
  99
 100         $self->do_enquire($query, $opts);
 101 }
 102
 103 sub get_thread {
 104         my ($self, $mid, $opts) = @_;
 105         my $smsg = eval { $self->lookup_message($mid) };
 106
 107         return { total => 0, msgs => [] } unless $smsg;
 108         my $qtid = Search::Xapian::Query->new(xpfx('thread').$smsg->thread_id);
 109         my $path = id_compress($smsg->path);
 110         my $qsub = Search::Xapian::Query->new(xpfx('path').$path);
 111         my $query = Search::Xapian::Query->new(OP_OR, $qtid, $qsub);
 112         $opts ||= {};
 113         $opts->{limit} ||= 1000;
 114         $self->do_enquire($query, $opts);
 115 }
 116
 117 sub do_enquire {
 118         my ($self, $query, $opts) = @_;
 119         my $enquire = $self->enquire;
 120         if (defined $query) {
 121                 $query = Search::Xapian::Query->new(OP_AND,$query,$mail_query);
 122         } else {
 123                 $query = $mail_query;
 124         }
 125         $enquire->set_query($query);
 126         $opts ||= {};
 127         my $desc = !$opts->{asc};
 128         if ($opts->{relevance}) {
 129                 $enquire->set_sort_by_relevance_then_value(TS, $desc);
 130         } else {
 131                 $enquire->set_sort_by_value_then_relevance(TS, $desc);
 132         }
 133         my $offset = $opts->{offset} || 0;
 134         my $limit = $opts->{limit} || 50;
 135         my $mset = $enquire->get_mset($offset, $limit);
 136         return $mset if $opts->{mset};
 137         my @msgs = map {
 138                 PublicInbox::SearchMsg->load_doc($_->get_document);
 139         } $mset->items;
 140
 141         { total => $mset->get_matches_estimated, msgs => \@msgs }
 142 }
 143
 144 # read-write
 145 sub stemmer { Search::Xapian::Stem->new($LANG) }
 146
 147 # read-only
 148 sub qp {
 149         my ($self) = @_;
 150
 151         my $qp = $self->{query_parser};
 152         return $qp if $qp;
 153
 154         # new parser
 155         $qp = Search::Xapian::QueryParser->new;
 156         $qp->set_default_op(OP_AND);
 157         $qp->set_database($self->{xdb});
 158         $qp->set_stemmer($self->stemmer);
 159         $qp->set_stemming_strategy(STEM_SOME);
 160         $qp->add_valuerangeprocessor($self->ts_range_processor);
 161         $qp->add_valuerangeprocessor($self->date_range_processor);
 162
 163         while (my ($name, $prefix) = each %bool_pfx_external) {
 164                 $qp->add_boolean_prefix($name, $prefix);
 165         }
 166
 167         while (my ($name, $prefix) = each %prob_prefix) {
 168                 $qp->add_prefix($name, $prefix);
 169         }
 170
 171         $self->{query_parser} = $qp;
 172 }
 173
 174 sub ts_range_processor {
 175         $_[0]->{tsrp} ||= Search::Xapian::NumberValueRangeProcessor->new(TS);
 176 }
 177
 178 sub date_range_processor {
 179         $_[0]->{drp} ||= Search::Xapian::DateValueRangeProcessor->new(TS);
 180 }
 181
 182 sub num_range_processor {
 183         $_[0]->{nrp} ||= Search::Xapian::NumberValueRangeProcessor->new(NUM);
 184 }
 185
 186 # only used for NNTP server
 187 sub query_xover {
 188         my ($self, $beg, $end, $offset) = @_;
 189         my $enquire = $self->enquire;
 190         my $qp = Search::Xapian::QueryParser->new;
 191         $qp->set_database($self->{xdb});
 192         $qp->add_valuerangeprocessor($self->num_range_processor);
 193         my $query = $qp->parse_query("$beg..$end", QP_FLAGS);
 194         $query = Search::Xapian::Query->new(OP_AND, $mail_query, $query);
 195         $enquire->set_query($query);
 196         $enquire->set_sort_by_value(NUM, 0);
 197         my $limit = 200;
 198         my $mset = $enquire->get_mset($offset, $limit);
 199         my @msgs = map {
 200                 PublicInbox::SearchMsg->load_doc($_->get_document);
 201         } $mset->items;
 202
 203         { total => $mset->get_matches_estimated, msgs => \@msgs }
 204 }
 205
 206 sub lookup_message {
 207         my ($self, $mid) = @_;
 208         $mid = mid_clean($mid);
 209
 210         my $doc_id = $self->find_unique_doc_id('mid', $mid);
 211         my $smsg;
 212         if (defined $doc_id) {
 213                 # raises on error:
 214                 my $doc = $self->{xdb}->get_document($doc_id);
 215                 $smsg = PublicInbox::SearchMsg->wrap($doc, $mid);
 216                 $smsg->doc_id($doc_id);
 217         }
 218         $smsg;
 219 }
 220
 221 sub find_unique_doc_id {
 222         my ($self, $term, $value) = @_;
 223
 224         my ($begin, $end) = $self->find_doc_ids($term, $value);
 225
 226         return undef if $begin->equal($end); # not found
 227
 228         my $rv = $begin->get_docid;
 229
 230         # sanity check
 231         $begin->inc;
 232         $begin->equal($end) or die "Term '$term:$value' is not unique\n";
 233         $rv;
 234 }
 235
 236 # returns begin and end PostingIterator
 237 sub find_doc_ids {
 238         my ($self, $term, $value) = @_;
 239
 240         $self->find_doc_ids_for_term(xpfx($term) . $value);
 241 }
 242
 243 # returns begin and end PostingIterator
 244 sub find_doc_ids_for_term {
 245         my ($self, $term) = @_;
 246         my $db = $self->{xdb};
 247
 248         ($db->postlist_begin($term), $db->postlist_end($term));
 249 }
 250
 251 # normalize subjects so they are suitable as pathnames for URLs
 252 sub subject_path {
 253         my $subj = pop;
 254         $subj = subject_normalized($subj);
 255         $subj =~ s![^a-zA-Z0-9_\.~/\-]+!_!g;
 256         lc($subj);
 257 }
 258
 259 sub subject_normalized {
 260         my $subj = pop;
 261         $subj =~ s/\A\s+//s; # no leading space
 262         $subj =~ s/\s+\z//s; # no trailing space
 263         $subj =~ s/\s+/ /gs; # no redundant spaces
 264         $subj =~ s/\.+\z//; # no trailing '.'
 265         $subj =~ s/$REPLY_RE//igo; # remove reply prefix
 266         $subj;
 267 }
 268
 269 # for doc data
 270 sub subject_summary {
 271         my $subj = pop;
 272         my $max = 68;
 273         if (length($subj) > $max) {
 274                 my @subj = split(/\s+/, $subj);
 275                 $subj = '';
 276                 my $l;
 277
 278                 while ($l = shift @subj) {
 279                         my $new = $subj . $l . ' ';
 280                         last if length($new) >= $max;
 281                         $subj = $new;
 282                 }
 283                 if ($subj ne '') {
 284                         my $r = scalar @subj ? ' ...' : '';
 285                         $subj =~ s/ \z/$r/s;
 286                 } else {
 287                         # subject has one REALLY long word, and NOT spam? wtf
 288                         @subj = ($l =~ /\A(.{1,72})/);
 289                         $subj = $subj[0] . ' ...';
 290                 }
 291         }
 292         $subj;
 293 }
 294
 295 sub enquire {
 296         my ($self) = @_;
 297         $self->{enquire} ||= Search::Xapian::Enquire->new($self->{xdb});
 298 }
 299
 300 1;