lib/PublicInbox/Search.pm

   1 # Copyright (C) 2015-2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 # based on notmuch, but with no concept of folders, files or flags
   4 #
   5 # Read-only search interface for use by the web and NNTP interfaces
   6 package PublicInbox::Search;
   7 use strict;
   8 use warnings;
   9
  10 # values for searching
  11 use constant DS => 0; # Date: header in Unix time
  12 use constant NUM => 1; # NNTP article number
  13 use constant BYTES => 2; # :bytes as defined in RFC 3977
  14 use constant LINES => 3; # :lines as defined in RFC 3977
  15 use constant TS => 4;  # Received: header in Unix time
  16 use constant YYYYMMDD => 5; # for searching in the WWW UI
  17
  18 use Search::Xapian qw/:standard/;
  19 use PublicInbox::SearchMsg;
  20 use PublicInbox::MIME;
  21 use PublicInbox::MID qw/id_compress/;
  22
  23 # This is English-only, everything else is non-standard and may be confused as
  24 # a prefix common in patch emails
  25 our $REPLY_RE = qr/^re:\s+/i;
  26 our $LANG = 'english';
  27
  28 use constant {
  29         # SCHEMA_VERSION history
  30         # 0 - initial
  31         # 1 - subject_path is lower-cased
  32         # 2 - subject_path is id_compress in the index, only
  33         # 3 - message-ID is compressed if it includes '%' (hack!)
  34         # 4 - change "Re: " normalization, avoid circular Reference ghosts
  35         # 5 - subject_path drops trailing '.'
  36         # 6 - preserve References: order in document data
  37         # 7 - remove references and inreplyto terms
  38         # 8 - remove redundant/unneeded document data
  39         # 9 - disable Message-ID compression (SHA-1)
  40         # 10 - optimize doc for NNTP overviews
  41         # 11 - merge threads when vivifying ghosts
  42         # 12 - change YYYYMMDD value column to numeric
  43         # 13 - fix threading for empty References/In-Reply-To
  44         #      (commit 83425ef12e4b65cdcecd11ddcb38175d4a91d5a0)
  45         # 14 - fix ghost root vivification
  46         SCHEMA_VERSION => 14,
  47
  48         # n.b. FLAG_PURE_NOT is expensive not suitable for a public website
  49         # as it could become a denial-of-service vector
  50         QP_FLAGS => FLAG_PHRASE|FLAG_BOOLEAN|FLAG_LOVEHATE|FLAG_WILDCARD,
  51 };
  52
  53 # setup prefixes
  54 my %bool_pfx_internal = (
  55         type => 'T', # "mail" or "ghost"
  56         thread => 'G', # newsGroup (or similar entity - e.g. a web forum name)
  57 );
  58
  59 my %bool_pfx_external = (
  60         mid => 'Q', # Message-ID (full/exact), this is mostly uniQue
  61 );
  62
  63 my $non_quoted_body = 'XNQ XDFN XDFA XDFB XDFHH XDFCTX XDFPRE XDFPOST';
  64 my %prob_prefix = (
  65         # for mairix compatibility
  66         s => 'S',
  67         m => 'XM', # 'mid:' (bool) is exact, 'm:' (prob) can do partial
  68         f => 'A',
  69         t => 'XTO',
  70         tc => 'XTO XCC',
  71         c => 'XCC',
  72         tcf => 'XTO XCC A',
  73         a => 'XTO XCC A',
  74         b => $non_quoted_body . ' XQUOT',
  75         bs => $non_quoted_body . ' XQUOT S',
  76         n => 'XFN',
  77
  78         q => 'XQUOT',
  79         nq => $non_quoted_body,
  80         dfn => 'XDFN',
  81         dfa => 'XDFA',
  82         dfb => 'XDFB',
  83         dfhh => 'XDFHH',
  84         dfctx => 'XDFCTX',
  85         dfpre => 'XDFPRE',
  86         dfpost => 'XDFPOST',
  87         dfblob => 'XDFPRE XDFPOST',
  88
  89         # default:
  90         '' => 'XM S A XQUOT XFN ' . $non_quoted_body,
  91 );
  92
  93 # not documenting m: and mid: for now, the using the URLs works w/o Xapian
  94 our @HELP = (
  95         's:' => 'match within Subject  e.g. s:"a quick brown fox"',
  96         'd:' => <<EOF,
  97 date range as YYYYMMDD  e.g. d:19931002..20101002
  98 Open-ended ranges such as d:19931002.. and d:..20101002
  99 are also supported
 100 EOF
 101         'b:' => 'match within message body, including text attachments',
 102         'nq:' => 'match non-quoted text within message body',
 103         'q:' => 'match quoted text within message body',
 104         'n:' => 'match filename of attachment(s)',
 105         't:' => 'match within the To header',
 106         'c:' => 'match within the Cc header',
 107         'f:' => 'match within the From header',
 108         'a:' => 'match within the To, Cc, and From headers',
 109         'tc:' => 'match within the To and Cc headers',
 110         'bs:' => 'match within the Subject and body',
 111         'dfn:' => 'match filename from diff',
 112         'dfa:' => 'match diff removed (-) lines',
 113         'dfb:' => 'match diff added (+) lines',
 114         'dfhh:' => 'match diff hunk header context (usually a function name)',
 115         'dfctx:' => 'match diff context lines',
 116         'dfpre:' => 'match pre-image git blob ID',
 117         'dfpost:' => 'match post-image git blob ID',
 118         'dfblob:' => 'match either pre or post-image git blob ID',
 119 );
 120 chomp @HELP;
 121
 122 my $mail_query = Search::Xapian::Query->new('T' . 'mail');
 123
 124 sub xdir {
 125         my ($self) = @_;
 126         if ($self->{version} == 1) {
 127                 "$self->{mainrepo}/public-inbox/xapian" . SCHEMA_VERSION;
 128         } else {
 129                 my $dir = "$self->{mainrepo}/xap" . SCHEMA_VERSION;
 130                 my $part = $self->{partition};
 131                 defined $part or die "partition not given";
 132                 $dir .= "/$part";
 133         }
 134 }
 135
 136 sub new {
 137         my ($class, $mainrepo, $altid) = @_;
 138         my $version = 1;
 139         my $ibx = $mainrepo;
 140         if (ref $ibx) {
 141                 $version = $ibx->{version} || 1;
 142                 $mainrepo = $ibx->{mainrepo};
 143         }
 144         my $self = bless {
 145                 mainrepo => $mainrepo,
 146                 altid => $altid,
 147                 version => $version,
 148         }, $class;
 149         if ($version >= 2) {
 150                 my $dir = "$self->{mainrepo}/xap" . SCHEMA_VERSION;
 151                 my $xdb;
 152                 my $parts = 0;
 153                 foreach my $part (<$dir/*>) {
 154                         -d $part && $part =~ m!/\d+\z! or next;
 155                         $parts++;
 156                         my $sub = Search::Xapian::Database->new($part);
 157                         if ($xdb) {
 158                                 $xdb->add_database($sub);
 159                         } else {
 160                                 $xdb = $sub;
 161                         }
 162                 }
 163                 $self->{xdb} = $xdb;
 164                 $self->{skel} = Search::Xapian::Database->new("$dir/skel");
 165         } else {
 166                 $self->{xdb} = Search::Xapian::Database->new($self->xdir);
 167         }
 168         $self;
 169 }
 170
 171 sub reopen {
 172         my ($self) = @_;
 173         $self->{xdb}->reopen;
 174         if (my $skel = $self->{skel}) {
 175                 $skel->reopen;
 176         }
 177         $self; # make chaining easier
 178 }
 179
 180 # read-only
 181 sub query {
 182         my ($self, $query_string, $opts) = @_;
 183         my $query;
 184
 185         $opts ||= {};
 186         unless ($query_string eq '') {
 187                 $query = $self->qp->parse_query($query_string, QP_FLAGS);
 188                 $opts->{relevance} = 1 unless exists $opts->{relevance};
 189         }
 190
 191         _do_enquire($self, $query, $opts);
 192 }
 193
 194 sub get_thread {
 195         my ($self, $mid, $opts) = @_;
 196         my $smsg = first_smsg_by_mid($self, $mid) or
 197                         return { total => 0, msgs => [] };
 198         my $qtid = Search::Xapian::Query->new('G' . $smsg->thread_id);
 199         my $path = $smsg->path;
 200         if (defined $path && $path ne '') {
 201                 my $path = id_compress($smsg->path);
 202                 my $qsub = Search::Xapian::Query->new('XPATH' . $path);
 203                 $qtid = Search::Xapian::Query->new(OP_OR, $qtid, $qsub);
 204         }
 205         $opts ||= {};
 206         $opts->{limit} ||= 1000;
 207
 208         # always sort threads by timestamp, this makes life easier
 209         # for the threading algorithm (in SearchThread.pm)
 210         $opts->{asc} = 1;
 211         $opts->{enquire} = enquire_skel($self);
 212         _do_enquire($self, $qtid, $opts);
 213 }
 214
 215 sub retry_reopen {
 216         my ($self, $cb) = @_;
 217         my $ret;
 218         for (1..10) {
 219                 eval { $ret = $cb->() };
 220                 return $ret unless $@;
 221                 # Exception: The revision being read has been discarded -
 222                 # you should call Xapian::Database::reopen()
 223                 if (ref($@) eq 'Search::Xapian::DatabaseModifiedError') {
 224                         reopen($self);
 225                 } else {
 226                         warn "ref: ", ref($@), "\n";
 227                         die;
 228                 }
 229         }
 230 }
 231
 232 sub _do_enquire {
 233         my ($self, $query, $opts) = @_;
 234         retry_reopen($self, sub { _enquire_once($self, $query, $opts) });
 235 }
 236
 237 sub _enquire_once {
 238         my ($self, $query, $opts) = @_;
 239         my $enquire = $opts->{enquire} || enquire($self);
 240         if (defined $query) {
 241                 $query = Search::Xapian::Query->new(OP_AND,$query,$mail_query);
 242         } else {
 243                 $query = $mail_query;
 244         }
 245         $enquire->set_query($query);
 246         $opts ||= {};
 247         my $desc = !$opts->{asc};
 248         if ($opts->{relevance}) {
 249                 $enquire->set_sort_by_relevance_then_value(TS, $desc);
 250         } elsif ($opts->{num}) {
 251                 $enquire->set_sort_by_value(NUM, 0);
 252         } else {
 253                 $enquire->set_sort_by_value_then_relevance(TS, $desc);
 254         }
 255         my $offset = $opts->{offset} || 0;
 256         my $limit = $opts->{limit} || 50;
 257         my $mset = $enquire->get_mset($offset, $limit);
 258         return $mset if $opts->{mset};
 259         my @msgs = map {
 260                 PublicInbox::SearchMsg->load_doc($_->get_document);
 261         } $mset->items;
 262
 263         { total => $mset->get_matches_estimated, msgs => \@msgs }
 264 }
 265
 266 # read-write
 267 sub stemmer { Search::Xapian::Stem->new($LANG) }
 268
 269 # read-only
 270 sub qp {
 271         my ($self) = @_;
 272
 273         my $qp = $self->{query_parser};
 274         return $qp if $qp;
 275
 276         # new parser
 277         $qp = Search::Xapian::QueryParser->new;
 278         $qp->set_default_op(OP_AND);
 279         $qp->set_database($self->{xdb});
 280         $qp->set_stemmer($self->stemmer);
 281         $qp->set_stemming_strategy(STEM_SOME);
 282         $qp->add_valuerangeprocessor(
 283                 Search::Xapian::NumberValueRangeProcessor->new(YYYYMMDD, 'd:'));
 284
 285         while (my ($name, $prefix) = each %bool_pfx_external) {
 286                 $qp->add_boolean_prefix($name, $prefix);
 287         }
 288
 289         # we do not actually create AltId objects,
 290         # just parse the spec to avoid the extra DB handles for now.
 291         if (my $altid = $self->{altid}) {
 292                 my $user_pfx = $self->{-user_pfx} ||= [];
 293                 for (@$altid) {
 294                         # $_ = 'serial:gmane:/path/to/gmane.msgmap.sqlite3'
 295                         /\Aserial:(\w+):/ or next;
 296                         my $pfx = $1;
 297                         push @$user_pfx, "$pfx:", <<EOF;
 298 alternate serial number  e.g. $pfx:12345 (boolean)
 299 EOF
 300                         # gmane => XGMANE
 301                         $qp->add_boolean_prefix($pfx, 'X'.uc($pfx));
 302                 }
 303                 chomp @$user_pfx;
 304         }
 305
 306         while (my ($name, $prefix) = each %prob_prefix) {
 307                 $qp->add_prefix($name, $_) foreach split(/ /, $prefix);
 308         }
 309
 310         $self->{query_parser} = $qp;
 311 }
 312
 313 sub num_range_processor {
 314         $_[0]->{nrp} ||= Search::Xapian::NumberValueRangeProcessor->new(NUM);
 315 }
 316
 317 # only used for NNTP server
 318 sub query_xover {
 319         my ($self, $beg, $end, $offset) = @_;
 320         my $qp = Search::Xapian::QueryParser->new;
 321         $qp->set_database($self->{skel} || $self->{xdb});
 322         $qp->add_valuerangeprocessor($self->num_range_processor);
 323         my $query = $qp->parse_query("$beg..$end", QP_FLAGS);
 324
 325         my $opts = {
 326                 enquire => enquire_skel($self),
 327                 num => 1,
 328                 limit => 200,
 329                 offset => $offset,
 330         };
 331         _do_enquire($self, $query, $opts);
 332 }
 333
 334 sub query_ts {
 335         my ($self, $ts, $opts) = @_;
 336         my $qp = $self->{qp_ts} ||= eval {
 337                 my $q = Search::Xapian::QueryParser->new;
 338                 $q->set_database($self->{skel} || $self->{xdb});
 339                 $q->add_valuerangeprocessor(
 340                         Search::Xapian::NumberValueRangeProcessor->new(TS));
 341                 $q
 342         };
 343         my $query = $qp->parse_query($ts, QP_FLAGS);
 344         $opts->{enquire} = enquire_skel($self);
 345         _do_enquire($self, $query, $opts);
 346 }
 347
 348 sub first_smsg_by_mid {
 349         my ($self, $mid) = @_;
 350         my $smsg;
 351         each_smsg_by_mid($self, $mid, sub { $smsg = $_[0]; undef });
 352         $smsg;
 353 }
 354
 355 sub lookup_article {
 356         my ($self, $num) = @_;
 357         my $term = 'XNUM'.$num;
 358         my $smsg;
 359         eval {
 360                 retry_reopen($self, sub {
 361                         my $db = $self->{skel} || $self->{xdb};
 362                         my $head = $db->postlist_begin($term);
 363                         my $tail = $db->postlist_end($term);
 364                         return if $head->equal($tail);
 365                         my $doc_id = $head->get_docid;
 366                         return unless defined $doc_id;
 367                         $head->inc;
 368                         if ($head->nequal($tail)) {
 369                                 my $loc= $self->{mainrepo} .
 370                                         ($self->{skel} ? 'skel' : 'xdb');
 371                                 warn "article #$num is not unique in $loc\n";
 372                         }
 373                         # raises on error:
 374                         my $doc = $db->get_document($doc_id);
 375                         $smsg = PublicInbox::SearchMsg->wrap($doc);
 376                         $smsg->load_expand;
 377                         $smsg->{doc_id} = $doc_id;
 378                 });
 379         };
 380         $smsg;
 381 }
 382
 383 sub each_smsg_by_mid {
 384         my ($self, $mid, $cb) = @_;
 385         # XXX retry_reopen isn't necessary for V2Writable, but the PSGI
 386         # interface will need it...
 387         my $db = $self->{skel} || $self->{xdb};
 388         my $term = 'Q' . $mid;
 389         my $head = $db->postlist_begin($term);
 390         my $tail = $db->postlist_end($term);
 391         if ($head == $tail) {
 392                 $db->reopen;
 393                 $head = $db->postlist_begin($term);
 394                 $tail = $db->postlist_end($term);
 395         }
 396         return ($head, $tail, $db) if wantarray;
 397         for (; $head->nequal($tail); $head->inc) {
 398                 my $doc_id = $head->get_docid;
 399                 my $doc = $db->get_document($doc_id);
 400                 my $smsg = PublicInbox::SearchMsg->wrap($doc, $mid);
 401                 $smsg->{doc_id} = $doc_id;
 402                 $cb->($smsg) or return;
 403         }
 404 }
 405
 406 # normalize subjects so they are suitable as pathnames for URLs
 407 # XXX: consider for removal
 408 sub subject_path {
 409         my $subj = pop;
 410         $subj = subject_normalized($subj);
 411         $subj =~ s![^a-zA-Z0-9_\.~/\-]+!_!g;
 412         lc($subj);
 413 }
 414
 415 sub subject_normalized {
 416         my $subj = pop;
 417         $subj =~ s/\A\s+//s; # no leading space
 418         $subj =~ s/\s+\z//s; # no trailing space
 419         $subj =~ s/\s+/ /gs; # no redundant spaces
 420         $subj =~ s/\.+\z//; # no trailing '.'
 421         $subj =~ s/$REPLY_RE//igo; # remove reply prefix
 422         $subj;
 423 }
 424
 425 sub enquire {
 426         my ($self) = @_;
 427         $self->{enquire} ||= Search::Xapian::Enquire->new($self->{xdb});
 428 }
 429
 430 sub enquire_skel {
 431         my ($self) = @_;
 432         if (my $skel = $self->{skel}) {
 433                 $self->{enquire_skel} ||= Search::Xapian::Enquire->new($skel);
 434         } else {
 435                 enquire($self);
 436         }
 437 }
 438
 439 sub help {
 440         my ($self) = @_;
 441         $self->qp; # parse altids
 442         my @ret = @HELP;
 443         if (my $user_pfx = $self->{-user_pfx}) {
 444                 push @ret, @$user_pfx;
 445         }
 446         \@ret;
 447 }
 448
 449 1;