lib/PublicInbox/Search.pm

   1 # Copyright (C) 2015-2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 # based on notmuch, but with no concept of folders, files or flags
   4 #
   5 # Read-only search interface for use by the web and NNTP interfaces
   6 package PublicInbox::Search;
   7 use strict;
   8 use warnings;
   9
  10 # values for searching
  11 use constant TS => 0; # timestamp
  12 use constant NUM => 1; # NNTP article number
  13 use constant BYTES => 2; # :bytes as defined in RFC 3977
  14 use constant LINES => 3; # :lines as defined in RFC 3977
  15 use constant YYYYMMDD => 4; # for searching in the WWW UI
  16
  17 use Search::Xapian qw/:standard/;
  18 use PublicInbox::SearchMsg;
  19 use PublicInbox::MIME;
  20 use PublicInbox::MID qw/mid_clean id_compress/;
  21
  22 # This is English-only, everything else is non-standard and may be confused as
  23 # a prefix common in patch emails
  24 our $REPLY_RE = qr/^re:\s+/i;
  25 our $LANG = 'english';
  26
  27 use constant {
  28         # SCHEMA_VERSION history
  29         # 0 - initial
  30         # 1 - subject_path is lower-cased
  31         # 2 - subject_path is id_compress in the index, only
  32         # 3 - message-ID is compressed if it includes '%' (hack!)
  33         # 4 - change "Re: " normalization, avoid circular Reference ghosts
  34         # 5 - subject_path drops trailing '.'
  35         # 6 - preserve References: order in document data
  36         # 7 - remove references and inreplyto terms
  37         # 8 - remove redundant/unneeded document data
  38         # 9 - disable Message-ID compression (SHA-1)
  39         # 10 - optimize doc for NNTP overviews
  40         # 11 - merge threads when vivifying ghosts
  41         # 12 - change YYYYMMDD value column to numeric
  42         # 13 - fix threading for empty References/In-Reply-To
  43         #      (commit 83425ef12e4b65cdcecd11ddcb38175d4a91d5a0)
  44         # 14 - fix ghost root vivification
  45         SCHEMA_VERSION => 14,
  46
  47         # n.b. FLAG_PURE_NOT is expensive not suitable for a public website
  48         # as it could become a denial-of-service vector
  49         QP_FLAGS => FLAG_PHRASE|FLAG_BOOLEAN|FLAG_LOVEHATE|FLAG_WILDCARD,
  50 };
  51
  52 # setup prefixes
  53 my %bool_pfx_internal = (
  54         type => 'T', # "mail" or "ghost"
  55         thread => 'G', # newsGroup (or similar entity - e.g. a web forum name)
  56 );
  57
  58 my %bool_pfx_external = (
  59         mid => 'Q', # Message-ID (full/exact), this is mostly uniQue
  60 );
  61
  62 my $non_quoted_body = 'XNQ XDFN XDFA XDFB XDFHH XDFCTX XDFPRE XDFPOST';
  63 my %prob_prefix = (
  64         # for mairix compatibility
  65         s => 'S',
  66         m => 'XM', # 'mid:' (bool) is exact, 'm:' (prob) can do partial
  67         f => 'A',
  68         t => 'XTO',
  69         tc => 'XTO XCC',
  70         c => 'XCC',
  71         tcf => 'XTO XCC A',
  72         a => 'XTO XCC A',
  73         b => $non_quoted_body . ' XQUOT',
  74         bs => $non_quoted_body . ' XQUOT S',
  75         n => 'XFN',
  76
  77         q => 'XQUOT',
  78         nq => $non_quoted_body,
  79         dfn => 'XDFN',
  80         dfa => 'XDFA',
  81         dfb => 'XDFB',
  82         dfhh => 'XDFHH',
  83         dfctx => 'XDFCTX',
  84         dfpre => 'XDFPRE',
  85         dfpost => 'XDFPOST',
  86         dfblob => 'XDFPRE XDFPOST',
  87
  88         # default:
  89         '' => 'XM S A XQUOT XFN ' . $non_quoted_body,
  90 );
  91
  92 # not documenting m: and mid: for now, the using the URLs works w/o Xapian
  93 our @HELP = (
  94         's:' => 'match within Subject  e.g. s:"a quick brown fox"',
  95         'd:' => <<EOF,
  96 date range as YYYYMMDD  e.g. d:19931002..20101002
  97 Open-ended ranges such as d:19931002.. and d:..20101002
  98 are also supported
  99 EOF
 100         'b:' => 'match within message body, including text attachments',
 101         'nq:' => 'match non-quoted text within message body',
 102         'q:' => 'match quoted text within message body',
 103         'n:' => 'match filename of attachment(s)',
 104         't:' => 'match within the To header',
 105         'c:' => 'match within the Cc header',
 106         'f:' => 'match within the From header',
 107         'a:' => 'match within the To, Cc, and From headers',
 108         'tc:' => 'match within the To and Cc headers',
 109         'bs:' => 'match within the Subject and body',
 110         'dfn:' => 'match filename from diff',
 111         'dfa:' => 'match diff removed (-) lines',
 112         'dfb:' => 'match diff added (+) lines',
 113         'dfhh:' => 'match diff hunk header context (usually a function name)',
 114         'dfctx:' => 'match diff context lines',
 115         'dfpre:' => 'match pre-image git blob ID',
 116         'dfpost:' => 'match post-image git blob ID',
 117         'dfblob:' => 'match either pre or post-image git blob ID',
 118 );
 119 chomp @HELP;
 120
 121 my $mail_query = Search::Xapian::Query->new('T' . 'mail');
 122
 123 sub xdir {
 124         my ($self) = @_;
 125         if ($self->{version} == 1) {
 126                 "$self->{mainrepo}/public-inbox/xapian" . SCHEMA_VERSION;
 127         } else {
 128                 my $dir = "$self->{mainrepo}/xap" . SCHEMA_VERSION;
 129                 my $part = $self->{partition};
 130                 defined $part or die "partition not given";
 131                 $dir .= "/$part";
 132         }
 133 }
 134
 135 sub new {
 136         my ($class, $mainrepo, $altid) = @_;
 137         my $version = 1;
 138         my $ibx = $mainrepo;
 139         if (ref $ibx) {
 140                 $version = $ibx->{version} || 1;
 141                 $mainrepo = $ibx->{mainrepo};
 142         }
 143         my $self = bless {
 144                 mainrepo => $mainrepo,
 145                 altid => $altid,
 146                 version => $version,
 147         }, $class;
 148         if ($version >= 2) {
 149                 my $dir = "$self->{mainrepo}/xap" . SCHEMA_VERSION;
 150                 my $xdb;
 151                 my $parts = 0;
 152                 foreach my $part (<$dir/*>) {
 153                         -d $part && $part =~ m!/\d+\z! or next;
 154                         $parts++;
 155                         my $sub = Search::Xapian::Database->new($part);
 156                         if ($xdb) {
 157                                 $xdb->add_database($sub);
 158                         } else {
 159                                 $xdb = $sub;
 160                         }
 161                 }
 162                 $self->{xdb} = $xdb;
 163                 $self->{skel} = Search::Xapian::Database->new("$dir/skel");
 164         } else {
 165                 $self->{xdb} = Search::Xapian::Database->new($self->xdir);
 166         }
 167         $self;
 168 }
 169
 170 sub reopen {
 171         my ($self) = @_;
 172         $self->{xdb}->reopen;
 173         if (my $skel = $self->{skel}) {
 174                 $skel->reopen;
 175         }
 176 }
 177
 178 # read-only
 179 sub query {
 180         my ($self, $query_string, $opts) = @_;
 181         my $query;
 182
 183         $opts ||= {};
 184         unless ($query_string eq '') {
 185                 $query = $self->qp->parse_query($query_string, QP_FLAGS);
 186                 $opts->{relevance} = 1 unless exists $opts->{relevance};
 187         }
 188
 189         _do_enquire($self, $query, $opts);
 190 }
 191
 192 sub get_thread {
 193         my ($self, $mid, $opts) = @_;
 194         my $smsg = retry_reopen($self, sub { lookup_skeleton($self, $mid) });
 195
 196         return { total => 0, msgs => [] } unless $smsg;
 197         my $qtid = Search::Xapian::Query->new('G' . $smsg->thread_id);
 198         my $path = $smsg->path;
 199         if (defined $path && $path ne '') {
 200                 my $path = id_compress($smsg->path);
 201                 my $qsub = Search::Xapian::Query->new('XPATH' . $path);
 202                 $qtid = Search::Xapian::Query->new(OP_OR, $qtid, $qsub);
 203         }
 204         $opts ||= {};
 205         $opts->{limit} ||= 1000;
 206
 207         # always sort threads by timestamp, this makes life easier
 208         # for the threading algorithm (in SearchThread.pm)
 209         $opts->{asc} = 1;
 210         $opts->{enquire} = enquire_skel($self);
 211         _do_enquire($self, $qtid, $opts);
 212 }
 213
 214 sub retry_reopen {
 215         my ($self, $cb) = @_;
 216         my $ret;
 217         for (1..10) {
 218                 eval { $ret = $cb->() };
 219                 return $ret unless $@;
 220                 # Exception: The revision being read has been discarded -
 221                 # you should call Xapian::Database::reopen()
 222                 if (ref($@) eq 'Search::Xapian::DatabaseModifiedError') {
 223                         reopen($self);
 224                 } else {
 225                         warn "ref: ", ref($@), "\n";
 226                         die;
 227                 }
 228         }
 229 }
 230
 231 sub _do_enquire {
 232         my ($self, $query, $opts) = @_;
 233         retry_reopen($self, sub { _enquire_once($self, $query, $opts) });
 234 }
 235
 236 sub _enquire_once {
 237         my ($self, $query, $opts) = @_;
 238         my $enquire = $opts->{enquire} || enquire($self);
 239         if (defined $query) {
 240                 $query = Search::Xapian::Query->new(OP_AND,$query,$mail_query);
 241         } else {
 242                 $query = $mail_query;
 243         }
 244         $enquire->set_query($query);
 245         $opts ||= {};
 246         my $desc = !$opts->{asc};
 247         if ($opts->{relevance}) {
 248                 $enquire->set_sort_by_relevance_then_value(TS, $desc);
 249         } elsif ($opts->{num}) {
 250                 $enquire->set_sort_by_value(NUM, 0);
 251         } else {
 252                 $enquire->set_sort_by_value_then_relevance(TS, $desc);
 253         }
 254         my $offset = $opts->{offset} || 0;
 255         my $limit = $opts->{limit} || 50;
 256         my $mset = $enquire->get_mset($offset, $limit);
 257         return $mset if $opts->{mset};
 258         my @msgs = map {
 259                 PublicInbox::SearchMsg->load_doc($_->get_document);
 260         } $mset->items;
 261
 262         { total => $mset->get_matches_estimated, msgs => \@msgs }
 263 }
 264
 265 # read-write
 266 sub stemmer { Search::Xapian::Stem->new($LANG) }
 267
 268 # read-only
 269 sub qp {
 270         my ($self) = @_;
 271
 272         my $qp = $self->{query_parser};
 273         return $qp if $qp;
 274
 275         # new parser
 276         $qp = Search::Xapian::QueryParser->new;
 277         $qp->set_default_op(OP_AND);
 278         $qp->set_database($self->{xdb});
 279         $qp->set_stemmer($self->stemmer);
 280         $qp->set_stemming_strategy(STEM_SOME);
 281         $qp->add_valuerangeprocessor(
 282                 Search::Xapian::NumberValueRangeProcessor->new(YYYYMMDD, 'd:'));
 283
 284         while (my ($name, $prefix) = each %bool_pfx_external) {
 285                 $qp->add_boolean_prefix($name, $prefix);
 286         }
 287
 288         # we do not actually create AltId objects,
 289         # just parse the spec to avoid the extra DB handles for now.
 290         if (my $altid = $self->{altid}) {
 291                 my $user_pfx = $self->{-user_pfx} ||= [];
 292                 for (@$altid) {
 293                         # $_ = 'serial:gmane:/path/to/gmane.msgmap.sqlite3'
 294                         /\Aserial:(\w+):/ or next;
 295                         my $pfx = $1;
 296                         push @$user_pfx, "$pfx:", <<EOF;
 297 alternate serial number  e.g. $pfx:12345 (boolean)
 298 EOF
 299                         # gmane => XGMANE
 300                         $qp->add_boolean_prefix($pfx, 'X'.uc($pfx));
 301                 }
 302                 chomp @$user_pfx;
 303         }
 304
 305         while (my ($name, $prefix) = each %prob_prefix) {
 306                 $qp->add_prefix($name, $_) foreach split(/ /, $prefix);
 307         }
 308
 309         $self->{query_parser} = $qp;
 310 }
 311
 312 sub num_range_processor {
 313         $_[0]->{nrp} ||= Search::Xapian::NumberValueRangeProcessor->new(NUM);
 314 }
 315
 316 # only used for NNTP server
 317 sub query_xover {
 318         my ($self, $beg, $end, $offset) = @_;
 319         my $qp = Search::Xapian::QueryParser->new;
 320         $qp->set_database($self->{skel} || $self->{xdb});
 321         $qp->add_valuerangeprocessor($self->num_range_processor);
 322         my $query = $qp->parse_query("$beg..$end", QP_FLAGS);
 323
 324         my $opts = {
 325                 enquire => enquire_skel($self),
 326                 num => 1,
 327                 limit => 200,
 328                 offset => $offset,
 329         };
 330         _do_enquire($self, $query, $opts);
 331 }
 332
 333 sub lookup_skeleton {
 334         my ($self, $mid) = @_;
 335         my $skel = $self->{skel} or return lookup_message($self, $mid);
 336         $mid = mid_clean($mid);
 337         my $term = 'Q' . $mid;
 338         my $smsg;
 339         my $beg = $skel->postlist_begin($term);
 340         if ($beg != $skel->postlist_end($term)) {
 341                 my $doc_id = $beg->get_docid;
 342                 if (defined $doc_id) {
 343                         # raises on error:
 344                         my $doc = $skel->get_document($doc_id);
 345                         $smsg = PublicInbox::SearchMsg->wrap($doc, $mid);
 346                         $smsg->{doc_id} = $doc_id;
 347                 }
 348         }
 349         $smsg;
 350 }
 351
 352 sub lookup_message {
 353         my ($self, $mid) = @_;
 354         $mid = mid_clean($mid);
 355
 356         my $doc_id = $self->find_first_doc_id('Q' . $mid);
 357         my $smsg;
 358         if (defined $doc_id) {
 359                 # raises on error:
 360                 my $doc = $self->{xdb}->get_document($doc_id);
 361                 $smsg = PublicInbox::SearchMsg->wrap($doc, $mid);
 362                 $smsg->{doc_id} = $doc_id;
 363         }
 364         $smsg;
 365 }
 366
 367 sub lookup_mail { # no ghosts!
 368         my ($self, $mid) = @_;
 369         retry_reopen($self, sub {
 370                 my $smsg = lookup_message($self, $mid) or return;
 371                 $smsg->load_expand;
 372         });
 373 }
 374
 375 sub each_smsg_by_mid {
 376         my ($self, $mid, $cb) = @_;
 377         my $xdb = $self->{xdb};
 378         # XXX retry_reopen isn't necessary for V2Writable, but the PSGI
 379         # interface will need it...
 380         my ($head, $tail) = $self->find_doc_ids('Q' . $mid);
 381         for (; $head->nequal($tail); $head->inc) {
 382                 my $doc_id = $head->get_docid;
 383                 my $doc = $xdb->get_document($doc_id);
 384                 my $smsg = PublicInbox::SearchMsg->wrap($doc, $mid);
 385                 $smsg->{doc_id} = $doc_id;
 386                 $cb->($smsg) or return;
 387         }
 388 }
 389
 390 sub find_unique_doc_id {
 391         my ($self, $termval) = @_;
 392
 393         my ($begin, $end) = $self->find_doc_ids($termval);
 394
 395         return undef if $begin->equal($end); # not found
 396
 397         my $rv = $begin->get_docid;
 398
 399         # sanity check
 400         $begin->inc;
 401         $begin->equal($end) or die "Term '$termval' is not unique\n";
 402         $rv;
 403 }
 404
 405 # returns begin and end PostingIterator
 406 sub find_doc_ids {
 407         my ($self, $termval) = @_;
 408         my $db = $self->{xdb};
 409
 410         ($db->postlist_begin($termval), $db->postlist_end($termval));
 411 }
 412
 413 sub find_first_doc_id {
 414         my ($self, $termval) = @_;
 415
 416         my ($begin, $end) = $self->find_doc_ids($termval);
 417
 418         return undef if $begin->equal($end); # not found
 419
 420         $begin->get_docid;
 421 }
 422
 423 # normalize subjects so they are suitable as pathnames for URLs
 424 # XXX: consider for removal
 425 sub subject_path {
 426         my $subj = pop;
 427         $subj = subject_normalized($subj);
 428         $subj =~ s![^a-zA-Z0-9_\.~/\-]+!_!g;
 429         lc($subj);
 430 }
 431
 432 sub subject_normalized {
 433         my $subj = pop;
 434         $subj =~ s/\A\s+//s; # no leading space
 435         $subj =~ s/\s+\z//s; # no trailing space
 436         $subj =~ s/\s+/ /gs; # no redundant spaces
 437         $subj =~ s/\.+\z//; # no trailing '.'
 438         $subj =~ s/$REPLY_RE//igo; # remove reply prefix
 439         $subj;
 440 }
 441
 442 sub enquire {
 443         my ($self) = @_;
 444         $self->{enquire} ||= Search::Xapian::Enquire->new($self->{xdb});
 445 }
 446
 447 sub enquire_skel {
 448         my ($self) = @_;
 449         if (my $skel = $self->{skel}) {
 450                 $self->{enquire_skel} ||= Search::Xapian::Enquire->new($skel);
 451         } else {
 452                 enquire($self);
 453         }
 454 }
 455
 456 sub help {
 457         my ($self) = @_;
 458         $self->qp; # parse altids
 459         my @ret = @HELP;
 460         if (my $user_pfx = $self->{-user_pfx}) {
 461                 push @ret, @$user_pfx;
 462         }
 463         \@ret;
 464 }
 465
 466 1;