lib/PublicInbox/Search.pm

   1 # Copyright (C) 2015 all contributors <meta@public-inbox.org>
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 # based on notmuch, but with no concept of folders, files or flags
   4 #
   5 # Read-only search interface for use by the web and NNTP interfaces
   6 package PublicInbox::Search;
   7 use strict;
   8 use warnings;
   9
  10 # values for searching
  11 use constant TS => 0; # timestamp
  12 use constant NUM => 1; # NNTP article number
  13 use constant BYTES => 2; # :bytes as defined in RFC 3977
  14 use constant LINES => 3; # :lines as defined in RFC 3977
  15 use constant YYYYMMDD => 4; # for searching in the WWW UI
  16
  17 use Search::Xapian qw/:standard/;
  18 use PublicInbox::SearchMsg;
  19 use Email::MIME;
  20 use PublicInbox::MID qw/mid_clean id_compress/;
  21
  22 # This is English-only, everything else is non-standard and may be confused as
  23 # a prefix common in patch emails
  24 our $REPLY_RE = qr/^re:\s+/i;
  25 our $LANG = 'english';
  26
  27 use constant {
  28         # SCHEMA_VERSION history
  29         # 0 - initial
  30         # 1 - subject_path is lower-cased
  31         # 2 - subject_path is id_compress in the index, only
  32         # 3 - message-ID is compressed if it includes '%' (hack!)
  33         # 4 - change "Re: " normalization, avoid circular Reference ghosts
  34         # 5 - subject_path drops trailing '.'
  35         # 6 - preserve References: order in document data
  36         # 7 - remove references and inreplyto terms
  37         # 8 - remove redundant/unneeded document data
  38         # 9 - disable Message-ID compression (SHA-1)
  39         # 10 - optimize doc for NNTP overviews
  40         # 11 - merge threads when vivifying ghosts
  41         # 12 - change YYYYMMDD value column to numeric
  42         SCHEMA_VERSION => 12,
  43
  44         # n.b. FLAG_PURE_NOT is expensive not suitable for a public website
  45         # as it could become a denial-of-service vector
  46         QP_FLAGS => FLAG_PHRASE|FLAG_BOOLEAN|FLAG_LOVEHATE|FLAG_WILDCARD,
  47 };
  48
  49 # setup prefixes
  50 my %bool_pfx_internal = (
  51         type => 'T', # "mail" or "ghost"
  52         thread => 'G', # newsGroup (or similar entity - e.g. a web forum name)
  53 );
  54
  55 my %bool_pfx_external = (
  56         # do we still need these? probably not..
  57         path => 'XPATH',
  58         mid => 'Q', # uniQue id (Message-ID)
  59 );
  60
  61 my %prob_prefix = (
  62         # for mairix compatibility
  63         s => 'S',
  64         m => 'XMID', # 'mid:' (bool) is exact, 'm:' (prob) can do partial
  65         f => 'A',
  66         t => 'XTO',
  67         tc => 'XTO XCC',
  68         c => 'XCC',
  69         tcf => 'XTO XCC A',
  70         a => 'XTO XCC A',
  71         b => 'XNQ XQUOT',
  72         bs => 'XNQ XQUOT S',
  73         n => 'XFN',
  74
  75         q => 'XQUOT',
  76         nq => 'XNQ',
  77
  78         # default:
  79         '' => 'XMID S A XNQ XQUOT XFN',
  80 );
  81
  82 # not documenting m: and mid: for now, the using the URLs works w/o Xapian
  83 our @HELP = (
  84         's:' => 'match within Subject  e.g. s:"a quick brown fox"',
  85         'd:' => <<EOF,
  86 date range as YYYYMMDD  e.g. d:19931002..20101002
  87 Open-ended ranges such as d:19931002.. and d:..20101002
  88 are also supported
  89 EOF
  90         'b:' => 'match within message body, including text attachments',
  91         'nq:' => 'match non-quoted text within message body',
  92         'quot:' => 'match quoted text within message body',
  93         'n:' => 'match filename of attachment(s)',
  94         't:' => 'match within the To header',
  95         'c:' => 'match within the Cc header',
  96         'f:' => 'match within the From header',
  97         'a:' => 'match within the To, Cc, and From headers',
  98         'tc:' => 'match within the To and Cc headers',
  99         'bs:' => 'match within the Subject and body',
 100 );
 101 chomp @HELP;
 102 # TODO:
 103 # df (filenames from diff)
 104 # da (diff a/ removed lines)
 105 # db (diff b/ added lines)
 106
 107 my %all_pfx = (%bool_pfx_internal, %bool_pfx_external, %prob_prefix);
 108
 109 sub xpfx { $all_pfx{$_[0]} }
 110
 111 our %PFX2TERM_RMAP;
 112 my %meta_pfx = (mid => 1, thread => 1, path => 1);
 113 while (my ($k, $v) = each %all_pfx) {
 114         $PFX2TERM_RMAP{$v} = $k if $meta_pfx{$k};
 115 }
 116
 117 my $mail_query = Search::Xapian::Query->new(xpfx('type') . 'mail');
 118
 119 sub xdir {
 120         my (undef, $git_dir) = @_;
 121         "$git_dir/public-inbox/xapian" . SCHEMA_VERSION;
 122 }
 123
 124 sub new {
 125         my ($class, $git_dir, $altid) = @_;
 126         my $dir = $class->xdir($git_dir);
 127         my $db = Search::Xapian::Database->new($dir);
 128         bless { xdb => $db, git_dir => $git_dir, altid => $altid }, $class;
 129 }
 130
 131 sub reopen { $_[0]->{xdb}->reopen }
 132
 133 # read-only
 134 sub query {
 135         my ($self, $query_string, $opts) = @_;
 136         my $query;
 137
 138         $opts ||= {};
 139         unless ($query_string eq '') {
 140                 $query = $self->qp->parse_query($query_string, QP_FLAGS);
 141                 $opts->{relevance} = 1 unless exists $opts->{relevance};
 142         }
 143
 144         _do_enquire($self, $query, $opts);
 145 }
 146
 147 sub get_thread {
 148         my ($self, $mid, $opts) = @_;
 149         my $smsg = eval { $self->lookup_message($mid) };
 150
 151         return { total => 0, msgs => [] } unless $smsg;
 152         my $qtid = Search::Xapian::Query->new(xpfx('thread').$smsg->thread_id);
 153         my $path = $smsg->path;
 154         if (defined $path && $path ne '') {
 155                 my $path = id_compress($smsg->path);
 156                 my $qsub = Search::Xapian::Query->new(xpfx('path').$path);
 157                 $qtid = Search::Xapian::Query->new(OP_OR, $qtid, $qsub);
 158         }
 159         $opts ||= {};
 160         $opts->{limit} ||= 1000;
 161
 162         # always sort threads by timestamp, this makes life easier
 163         # for the threading algorithm (in SearchThread.pm)
 164         $opts->{asc} = 1;
 165
 166         _do_enquire($self, $qtid, $opts);
 167 }
 168
 169 sub retry_reopen {
 170         my ($self, $cb) = @_;
 171         my $ret;
 172         for (1..10) {
 173                 eval { $ret = $cb->() };
 174                 return $ret unless $@;
 175                 # Exception: The revision being read has been discarded -
 176                 # you should call Xapian::Database::reopen()
 177                 if (ref($@) eq 'Search::Xapian::DatabaseModifiedError') {
 178                         reopen($self);
 179                 } else {
 180                         die;
 181                 }
 182         }
 183 }
 184
 185 sub _do_enquire {
 186         my ($self, $query, $opts) = @_;
 187         retry_reopen($self, sub { _enquire_once($self, $query, $opts) });
 188 }
 189
 190 sub _enquire_once {
 191         my ($self, $query, $opts) = @_;
 192         my $enquire = $self->enquire;
 193         if (defined $query) {
 194                 $query = Search::Xapian::Query->new(OP_AND,$query,$mail_query);
 195         } else {
 196                 $query = $mail_query;
 197         }
 198         $enquire->set_query($query);
 199         $opts ||= {};
 200         my $desc = !$opts->{asc};
 201         if ($opts->{relevance}) {
 202                 $enquire->set_sort_by_relevance_then_value(TS, $desc);
 203         } elsif ($opts->{num}) {
 204                 $enquire->set_sort_by_value(NUM, 0);
 205         } else {
 206                 $enquire->set_sort_by_value_then_relevance(TS, $desc);
 207         }
 208         my $offset = $opts->{offset} || 0;
 209         my $limit = $opts->{limit} || 50;
 210         my $mset = $enquire->get_mset($offset, $limit);
 211         return $mset if $opts->{mset};
 212         my @msgs = map {
 213                 PublicInbox::SearchMsg->load_doc($_->get_document);
 214         } $mset->items;
 215
 216         { total => $mset->get_matches_estimated, msgs => \@msgs }
 217 }
 218
 219 # read-write
 220 sub stemmer { Search::Xapian::Stem->new($LANG) }
 221
 222 # read-only
 223 sub qp {
 224         my ($self) = @_;
 225
 226         my $qp = $self->{query_parser};
 227         return $qp if $qp;
 228
 229         # new parser
 230         $qp = Search::Xapian::QueryParser->new;
 231         $qp->set_default_op(OP_AND);
 232         $qp->set_database($self->{xdb});
 233         $qp->set_stemmer($self->stemmer);
 234         $qp->set_stemming_strategy(STEM_SOME);
 235         $qp->add_valuerangeprocessor(
 236                 Search::Xapian::NumberValueRangeProcessor->new(YYYYMMDD, 'd:'));
 237
 238         while (my ($name, $prefix) = each %bool_pfx_external) {
 239                 $qp->add_boolean_prefix($name, $prefix);
 240         }
 241
 242         # we do not actually create AltId objects,
 243         # just parse the spec to avoid the extra DB handles for now.
 244         if (my $altid = $self->{altid}) {
 245                 my $user_pfx = $self->{-user_pfx} ||= [];
 246                 for (@$altid) {
 247                         # $_ = 'serial:gmane:/path/to/gmane.msgmap.sqlite3'
 248                         /\Aserial:(\w+):/ or next;
 249                         my $pfx = $1;
 250                         push @$user_pfx, "$pfx:", <<EOF;
 251 alternate serial number  e.g. $pfx:12345 (boolean)
 252 EOF
 253                         # gmane => XGMANE
 254                         $qp->add_boolean_prefix($pfx, 'X'.uc($pfx));
 255                 }
 256                 chomp @$user_pfx;
 257         }
 258
 259         while (my ($name, $prefix) = each %prob_prefix) {
 260                 $qp->add_prefix($name, $_) foreach split(/ /, $prefix);
 261         }
 262
 263         $self->{query_parser} = $qp;
 264 }
 265
 266 sub num_range_processor {
 267         $_[0]->{nrp} ||= Search::Xapian::NumberValueRangeProcessor->new(NUM);
 268 }
 269
 270 # only used for NNTP server
 271 sub query_xover {
 272         my ($self, $beg, $end, $offset) = @_;
 273         my $qp = Search::Xapian::QueryParser->new;
 274         $qp->set_database($self->{xdb});
 275         $qp->add_valuerangeprocessor($self->num_range_processor);
 276         my $query = $qp->parse_query("$beg..$end", QP_FLAGS);
 277
 278         _do_enquire($self, $query, {num => 1, limit => 200, offset => $offset});
 279 }
 280
 281 sub lookup_message {
 282         my ($self, $mid) = @_;
 283         $mid = mid_clean($mid);
 284
 285         my $doc_id = $self->find_unique_doc_id('mid', $mid);
 286         my $smsg;
 287         if (defined $doc_id) {
 288                 # raises on error:
 289                 my $doc = $self->{xdb}->get_document($doc_id);
 290                 $smsg = PublicInbox::SearchMsg->wrap($doc, $mid);
 291                 $smsg->doc_id($doc_id);
 292         }
 293         $smsg;
 294 }
 295
 296 sub lookup_mail { # no ghosts!
 297         my ($self, $mid) = @_;
 298         my $smsg = lookup_message($self, $mid) or return;
 299         PublicInbox::SearchMsg->load_doc($smsg->{doc});
 300 }
 301
 302 sub find_unique_doc_id {
 303         my ($self, $term, $value) = @_;
 304
 305         my ($begin, $end) = $self->find_doc_ids($term, $value);
 306
 307         return undef if $begin->equal($end); # not found
 308
 309         my $rv = $begin->get_docid;
 310
 311         # sanity check
 312         $begin->inc;
 313         $begin->equal($end) or die "Term '$term:$value' is not unique\n";
 314         $rv;
 315 }
 316
 317 # returns begin and end PostingIterator
 318 sub find_doc_ids {
 319         my ($self, $term, $value) = @_;
 320
 321         $self->find_doc_ids_for_term(xpfx($term) . $value);
 322 }
 323
 324 # returns begin and end PostingIterator
 325 sub find_doc_ids_for_term {
 326         my ($self, $term) = @_;
 327         my $db = $self->{xdb};
 328
 329         ($db->postlist_begin($term), $db->postlist_end($term));
 330 }
 331
 332 # normalize subjects so they are suitable as pathnames for URLs
 333 sub subject_path {
 334         my $subj = pop;
 335         $subj = subject_normalized($subj);
 336         $subj =~ s![^a-zA-Z0-9_\.~/\-]+!_!g;
 337         lc($subj);
 338 }
 339
 340 sub subject_normalized {
 341         my $subj = pop;
 342         $subj =~ s/\A\s+//s; # no leading space
 343         $subj =~ s/\s+\z//s; # no trailing space
 344         $subj =~ s/\s+/ /gs; # no redundant spaces
 345         $subj =~ s/\.+\z//; # no trailing '.'
 346         $subj =~ s/$REPLY_RE//igo; # remove reply prefix
 347         $subj;
 348 }
 349
 350 # for doc data
 351 sub subject_summary {
 352         my $subj = pop;
 353         my $max = 68;
 354         if (length($subj) > $max) {
 355                 my @subj = split(/\s+/, $subj);
 356                 $subj = '';
 357                 my $l;
 358
 359                 while ($l = shift @subj) {
 360                         my $new = $subj . $l . ' ';
 361                         last if length($new) >= $max;
 362                         $subj = $new;
 363                 }
 364                 if ($subj ne '') {
 365                         my $r = scalar @subj ? ' ...' : '';
 366                         $subj =~ s/ \z/$r/s;
 367                 } else {
 368                         # subject has one REALLY long word, and NOT spam? wtf
 369                         @subj = ($l =~ /\A(.{1,72})/);
 370                         $subj = $subj[0] . ' ...';
 371                 }
 372         }
 373         $subj;
 374 }
 375
 376 sub enquire {
 377         my ($self) = @_;
 378         $self->{enquire} ||= Search::Xapian::Enquire->new($self->{xdb});
 379 }
 380
 381 sub help {
 382         my ($self) = @_;
 383         $self->qp; # parse altids
 384         my @ret = @HELP;
 385         if (my $user_pfx = $self->{-user_pfx}) {
 386                 push @ret, @$user_pfx;
 387         }
 388         \@ret;
 389 }
 390
 391 1;