lib/PublicInbox/Search.pm

   1 # Copyright (C) 2015, all contributors <meta@public-inbox.org>
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 # based on notmuch, but with no concept of folders, files or flags
   4 package PublicInbox::Search;
   5 use strict;
   6 use warnings;
   7 use PublicInbox::SearchMsg;
   8 use Search::Xapian qw/:standard/;
   9 use Email::MIME;
  10 use PublicInbox::MID qw/mid_clean mid_compressed/;
  11
  12 # This is English-only, everything else is non-standard and may be confused as
  13 # a prefix common in patch emails
  14 our $REPLY_RE = qr/^re:\s+/i;
  15 our $LANG = 'english';
  16
  17 use constant {
  18         TS => 0,
  19         # SCHEMA_VERSION history
  20         # 0 - initial
  21         # 1 - subject_path is lower-cased
  22         # 2 - subject_path is mid_compressed in the index, only
  23         # 3 - message-ID is compressed if it includes '%' (hack!)
  24         # 4 - change "Re: " normalization, avoid circular Reference ghosts
  25         # 5 - subject_path drops trailing '.'
  26         SCHEMA_VERSION => 5,
  27         QP_FLAGS => FLAG_PHRASE|FLAG_BOOLEAN|FLAG_LOVEHATE|FLAG_WILDCARD,
  28 };
  29
  30 # setup prefixes
  31 my %bool_pfx_internal = (
  32         type => 'T', # "mail" or "ghost"
  33         mid => 'Q', # uniQue id (Message-ID or mid_compressed)
  34 );
  35
  36 my %bool_pfx_external = (
  37         path => 'XPATH',
  38         thread => 'G', # newsGroup (or similar entity - e.g. a web forum name)
  39         references => 'XREFS',
  40         inreplyto => 'XIRT',
  41 );
  42
  43 my %prob_prefix = (
  44         subject => 'S',
  45 );
  46
  47 my %all_pfx = (%bool_pfx_internal, %bool_pfx_external, %prob_prefix);
  48
  49 sub xpfx { $all_pfx{$_[0]} }
  50
  51 our %PFX2TERM_RMAP;
  52 while (my ($k, $v) = each %all_pfx) {
  53         next if $prob_prefix{$k};
  54         $PFX2TERM_RMAP{$v} = $k;
  55 }
  56
  57 my $mail_query = Search::Xapian::Query->new(xpfx('type') . 'mail');
  58
  59 sub new {
  60         my ($class, $git_dir, $writable) = @_;
  61         # allow concurrent versions for easier rollback:
  62         my $dir = "$git_dir/public-inbox/xapian" . SCHEMA_VERSION;
  63         my $db;
  64
  65         if ($writable) { # not used by the WWW interface
  66                 require Search::Xapian::WritableDatabase;
  67                 my $flag = Search::Xapian::DB_OPEN;
  68                 if ($writable == 1) {
  69                         require File::Path;
  70                         File::Path::mkpath($dir);
  71                         $flag = Search::Xapian::DB_CREATE_OR_OPEN;
  72                 }
  73                 $db = Search::Xapian::WritableDatabase->new($dir, $flag);
  74         } else {
  75                 $db = Search::Xapian::Database->new($dir);
  76         }
  77         bless { xdb => $db, git_dir => $git_dir }, $class;
  78 }
  79
  80 sub reopen { $_[0]->{xdb}->reopen }
  81
  82 sub add_message {
  83         my ($self, $mime) = @_; # mime = Email::MIME object
  84         my $db = $self->{xdb};
  85
  86         my $doc_id;
  87         my $mid_orig = mid_clean($mime->header_obj->header_raw('Message-ID'));
  88         my $mid = mid_compressed($mid_orig);
  89         my $was_ghost = 0;
  90         my $ct_msg = $mime->header('Content-Type') || 'text/plain';
  91
  92         eval {
  93                 my $smsg = $self->lookup_message($mid);
  94                 my $doc;
  95
  96                 if ($smsg) {
  97                         $smsg->ensure_metadata;
  98                         # convert a ghost to a regular message
  99                         # it will also clobber any existing regular message
 100                         $smsg->mime($mime);
 101                         $doc = $smsg->{doc};
 102
 103                         my $type = xpfx('type');
 104                         eval {
 105                                 $doc->remove_term($type . 'ghost');
 106                                 $was_ghost = 1;
 107                         };
 108
 109                         # probably does not exist:
 110                         eval { $doc->remove_term($type . 'mail') };
 111                         $doc->add_term($type . 'mail');
 112                 }  else {
 113                         $smsg = PublicInbox::SearchMsg->new($mime);
 114                         $doc = $smsg->{doc};
 115                         $doc->add_term(xpfx('mid') . $mid);
 116                 }
 117
 118                 my $subj = $smsg->subject;
 119
 120                 if (length $subj) {
 121                         $doc->add_term(xpfx('subject') . $subj);
 122
 123                         my $path = subject_path($subj);
 124                         $doc->add_term(xpfx('path') . mid_compressed($path));
 125                 }
 126
 127                 my $from = $smsg->from_name;
 128                 my $date = $smsg->date;
 129                 my $ts = Search::Xapian::sortable_serialise($smsg->ts);
 130                 $doc->add_value(PublicInbox::Search::TS, $ts);
 131
 132                 $doc->set_data($smsg->to_doc_data);
 133
 134                 my $tg = $self->term_generator;
 135
 136                 $tg->set_document($doc);
 137                 $tg->index_text($subj, 1, 'S') if $subj;
 138                 $tg->increase_termpos;
 139                 $tg->index_text($subj) if $subj;
 140                 $tg->increase_termpos;
 141
 142                 $tg->index_text($smsg->from->format);
 143                 $tg->increase_termpos;
 144
 145                 $mime->walk_parts(sub {
 146                         my ($part) = @_;
 147                         return if $part->subparts; # walk_parts already recurses
 148                         my $ct = $part->content_type || $ct_msg;
 149
 150                         # account for filter bugs...
 151                         $ct =~ m!\btext/plain\b!i or return;
 152
 153                         my (@orig, @quot);
 154                         my $body = $part->body;
 155                         $part->body_set('');
 156                         my @lines = split(/\n/, $body);
 157                         while (defined(my $l = shift @lines)) {
 158                                 if ($l =~ /^\s*>/) {
 159                                         push @quot, $l;
 160                                 } else {
 161                                         push @orig, $l;
 162                                 }
 163                         }
 164                         if (@quot) {
 165                                 $tg->index_text(join("\n", @quot), 0);
 166                                 @quot = ();
 167                                 $tg->increase_termpos;
 168                         }
 169                         if (@orig) {
 170                                 $tg->index_text(join("\n", @orig));
 171                                 @orig = ();
 172                                 $tg->increase_termpos;
 173                         }
 174                 });
 175
 176                 if ($was_ghost) {
 177                         $doc_id = $smsg->doc_id;
 178                         $self->link_message($smsg, 0);
 179                         $db->replace_document($doc_id, $doc);
 180                 } else {
 181                         $self->link_message($smsg, 0);
 182                         $doc_id = $db->add_document($doc);
 183                 }
 184         };
 185
 186         if ($@) {
 187                 warn "failed to index message <$mid_orig>: $@\n";
 188                 return undef;
 189         }
 190         $doc_id;
 191 }
 192
 193 # returns deleted doc_id on success, undef on missing
 194 sub remove_message {
 195         my ($self, $mid_orig) = @_;
 196         my $db = $self->{xdb};
 197         my $doc_id;
 198         $mid_orig = mid_clean($mid_orig);
 199         my $mid = mid_compressed($mid_orig);
 200
 201         eval {
 202                 $doc_id = $self->find_unique_doc_id('mid', $mid);
 203                 $db->delete_document($doc_id) if defined $doc_id;
 204         };
 205
 206         if ($@) {
 207                 warn "failed to remove message <$mid_orig>: $@\n";
 208                 return undef;
 209         }
 210         $doc_id;
 211 }
 212
 213 # read-only
 214 sub query {
 215         my ($self, $query_string, $opts) = @_;
 216         my $query = $self->qp->parse_query($query_string, QP_FLAGS);
 217
 218         $self->do_enquire($query, $opts);
 219 }
 220
 221 sub get_subject_path {
 222         my ($self, $path, $opts) = @_;
 223         my $query = $self->qp->parse_query("path:".mid_compressed($path), 0);
 224         $self->do_enquire($query);
 225 }
 226
 227 # given a message ID, get followups to a message
 228 sub get_followups {
 229         my ($self, $mid, $opts) = @_;
 230         $mid = mid_clean($mid);
 231         $mid = mid_compressed($mid);
 232         my $qp = $self->qp;
 233         my $irt = $qp->parse_query("inreplyto:$mid", 0);
 234         my $ref = $qp->parse_query("references:$mid", 0);
 235         my $query = Search::Xapian::Query->new(OP_OR, $irt, $ref);
 236
 237         $self->do_enquire($query);
 238 }
 239
 240 sub get_thread {
 241         my ($self, $mid, $opts) = @_;
 242         my $smsg = eval { $self->lookup_message($mid) };
 243
 244         return { count => 0, msgs => [] } unless $smsg;
 245         my $qp = $self->qp;
 246         my $qtid = $qp->parse_query('thread:'.$smsg->thread_id);
 247         my $qsub = $qp->parse_query('path:'.mid_compressed($smsg->path));
 248         my $query = Search::Xapian::Query->new(OP_OR, $qtid, $qsub);
 249         $self->do_enquire($query);
 250 }
 251
 252 # private subs below
 253
 254 sub do_enquire {
 255         my ($self, $query, $opts) = @_;
 256         my $enquire = $self->enquire;
 257
 258         $query = Search::Xapian::Query->new(OP_AND, $query, $mail_query);
 259         $enquire->set_query($query);
 260         $enquire->set_sort_by_relevance_then_value(TS, 0);
 261         $opts ||= {};
 262         my $offset = $opts->{offset} || 0;
 263         my $limit = $opts->{limit} || 50;
 264         my $mset = $enquire->get_mset($offset, $limit);
 265         my @msgs = map {
 266                 PublicInbox::SearchMsg->load_doc($_->get_document);
 267         } $mset->items;
 268
 269         { count => $mset->get_matches_estimated, msgs => \@msgs }
 270 }
 271
 272 # read-write
 273 sub stemmer { Search::Xapian::Stem->new($LANG) }
 274
 275 # read-only
 276 sub qp {
 277         my ($self) = @_;
 278
 279         my $qp = $self->{query_parser};
 280         return $qp if $qp;
 281
 282         # new parser
 283         $qp = Search::Xapian::QueryParser->new;
 284         $qp->set_default_op(OP_AND);
 285         $qp->set_database($self->{xdb});
 286         $qp->set_stemmer($self->stemmer);
 287         $qp->set_stemming_strategy(STEM_SOME);
 288         $qp->add_valuerangeprocessor($self->ts_range_processor);
 289         $qp->add_valuerangeprocessor($self->date_range_processor);
 290
 291         while (my ($name, $prefix) = each %bool_pfx_external) {
 292                 $qp->add_boolean_prefix($name, $prefix);
 293         }
 294
 295         while (my ($name, $prefix) = each %prob_prefix) {
 296                 $qp->add_prefix($name, $prefix);
 297         }
 298
 299         $self->{query_parser} = $qp;
 300 }
 301
 302 sub term_generator { # write-only
 303         my ($self) = @_;
 304
 305         my $tg = $self->{term_generator};
 306         return $tg if $tg;
 307
 308         $tg = Search::Xapian::TermGenerator->new;
 309         $tg->set_stemmer($self->stemmer);
 310
 311         $self->{term_generator} = $tg;
 312 }
 313
 314 sub next_doc_id { $_[0]->{xdb}->get_lastdocid + 1 }
 315
 316 # increments last_thread_id counter
 317 # returns a 64-bit integer represented as a hex string
 318 sub next_thread_id {
 319         my ($self) = @_;
 320         my $db = $self->{xdb};
 321         my $last_thread_id = int($db->get_metadata('last_thread_id') || 0);
 322
 323         $db->set_metadata('last_thread_id', ++$last_thread_id);
 324
 325         $last_thread_id;
 326 }
 327
 328 sub ts_range_processor {
 329         $_[0]->{tsrp} ||= Search::Xapian::NumberValueRangeProcessor->new(TS);
 330 }
 331
 332 sub date_range_processor {
 333         $_[0]->{drp} ||= Search::Xapian::DateValueRangeProcessor->new(TS);
 334 }
 335
 336 sub link_message {
 337         my ($self, $smsg, $is_ghost) = @_;
 338
 339         if ($is_ghost) {
 340                 $smsg->ensure_metadata;
 341         } else {
 342                 $self->link_message_to_parents($smsg);
 343         }
 344 }
 345
 346 sub link_message_to_parents {
 347         my ($self, $smsg) = @_;
 348         my $doc = $smsg->{doc};
 349         my $mid = mid_compressed($smsg->mid);
 350         my $mime = $smsg->mime;
 351         my $refs = $mime->header_obj->header_raw('References');
 352         my @refs = $refs ? ($refs =~ /<([^>]+)>/g) : ();
 353         my $irt = $mime->header_obj->header_raw('In-Reply-To');
 354         if ($irt) {
 355                 if ($irt =~ /<([^>]+)>/) {
 356                         $irt = $1;
 357                 }
 358
 359                 # maybe some crazies will try to make a circular reference:
 360                 if ($irt eq $mid) {
 361                         $irt = undef;
 362                 } else {
 363                         push @refs, $irt;
 364                 }
 365         }
 366
 367         my $tid;
 368         if (@refs) {
 369                 my @crefs = map { mid_compressed($_) } @refs;
 370                 my %uniq = ($mid => 1);
 371
 372                 # prevent circular references via References: here:
 373                 @refs = ();
 374                 foreach my $ref (@crefs) {
 375                         next if $uniq{$ref};
 376                         $uniq{$ref} = 1;
 377                         push @refs, $ref;
 378                 }
 379                 $irt = undef if (defined $irt && !$uniq{$irt});
 380         }
 381         if (@refs) {
 382                 if (defined $irt) {
 383                         $doc->add_term(xpfx('inreplyto') . $irt);
 384                 }
 385
 386                 my $ref_pfx = xpfx('references');
 387
 388                 # first ref *should* be the thread root,
 389                 # but we can never trust clients to do the right thing
 390                 my $ref = shift @refs;
 391                 $doc->add_term($ref_pfx . $ref);
 392                 $tid = $self->_resolve_mid_to_tid($ref);
 393
 394                 # the rest of the refs should point to this tid:
 395                 foreach $ref (@refs) {
 396                         $doc->add_term($ref_pfx . $ref);
 397                         my $ptid = $self->_resolve_mid_to_tid($ref);
 398                         if ($tid ne $ptid) {
 399                                 $self->merge_threads($tid, $ptid);
 400                         }
 401                 }
 402         } else {
 403                 $tid = $self->next_thread_id;
 404         }
 405         $doc->add_term(xpfx('thread') . $tid);
 406 }
 407
 408 sub lookup_message {
 409         my ($self, $mid) = @_;
 410         $mid = mid_clean($mid);
 411         $mid = mid_compressed($mid);
 412
 413         my $doc_id = $self->find_unique_doc_id('mid', $mid);
 414         my $smsg;
 415         if (defined $doc_id) {
 416                 # raises on error:
 417                 my $doc = $self->{xdb}->get_document($doc_id);
 418                 $smsg = PublicInbox::SearchMsg->wrap($doc, $mid);
 419                 $smsg->doc_id($doc_id);
 420         }
 421         $smsg;
 422 }
 423
 424 sub find_unique_doc_id {
 425         my ($self, $term, $value) = @_;
 426
 427         my ($begin, $end) = $self->find_doc_ids($term, $value);
 428
 429         return undef if $begin->equal($end); # not found
 430
 431         my $rv = $begin->get_docid;
 432
 433         # sanity check
 434         $begin->inc;
 435         $begin->equal($end) or die "Term '$term:$value' is not unique\n";
 436         $rv;
 437 }
 438
 439 # returns begin and end PostingIterator
 440 sub find_doc_ids {
 441         my ($self, $term, $value) = @_;
 442
 443         $self->find_doc_ids_for_term(xpfx($term) . $value);
 444 }
 445
 446 # returns begin and end PostingIterator
 447 sub find_doc_ids_for_term {
 448         my ($self, $term) = @_;
 449         my $db = $self->{xdb};
 450
 451         ($db->postlist_begin($term), $db->postlist_end($term));
 452 }
 453
 454 # this will create a ghost as necessary
 455 sub _resolve_mid_to_tid {
 456         my ($self, $mid) = @_;
 457
 458         my $smsg = $self->lookup_message($mid) || $self->create_ghost($mid);
 459         $smsg->thread_id;
 460 }
 461
 462 sub create_ghost {
 463         my ($self, $mid, $tid) = @_;
 464
 465         $mid = mid_compressed($mid);
 466         $tid = $self->next_thread_id unless defined $tid;
 467
 468         my $doc = Search::Xapian::Document->new;
 469         $doc->add_term(xpfx('mid') . $mid);
 470         $doc->add_term(xpfx('thread') . $tid);
 471         $doc->add_term(xpfx('type') . 'ghost');
 472
 473         my $smsg = PublicInbox::SearchMsg->wrap($doc, $mid);
 474         $self->link_message($smsg, 1);
 475         $self->{xdb}->add_document($doc);
 476
 477         $smsg;
 478 }
 479
 480 sub merge_threads {
 481         my ($self, $winner_tid, $loser_tid) = @_;
 482         my ($head, $tail) = $self->find_doc_ids('thread', $loser_tid);
 483         my $thread_pfx = xpfx('thread');
 484         my $db = $self->{xdb};
 485
 486         for (; $head != $tail; $head->inc) {
 487                 my $docid = $head->get_docid;
 488                 my $doc = $db->get_document($docid);
 489                 $doc->remove_term($thread_pfx . $loser_tid);
 490                 $doc->add_term($thread_pfx . $winner_tid);
 491                 $db->replace_document($docid, $doc);
 492         }
 493 }
 494
 495 # normalize subjects so they are suitable as pathnames for URLs
 496 sub subject_path {
 497         my $subj = pop;
 498         $subj = subject_normalized($subj);
 499         $subj =~ s![^a-zA-Z0-9_\.~/\-]+!_!g;
 500         lc($subj);
 501 }
 502
 503 sub subject_normalized {
 504         my $subj = pop;
 505         $subj =~ s/\A\s+//s; # no leading space
 506         $subj =~ s/\s+\z//s; # no trailing space
 507         $subj =~ s/\s+/ /gs; # no redundant spaces
 508         $subj =~ s/\.+\z//; # no trailing '.'
 509         $subj =~ s/$REPLY_RE//igo; # remove reply prefix
 510         $subj;
 511 }
 512
 513 sub do_cat_mail {
 514         my ($git, $blob) = @_;
 515         my $mime = eval {
 516                 my $str = $git->cat_file($blob);
 517                 Email::MIME->new($str);
 518         };
 519         $@ ? undef : $mime;
 520 }
 521
 522 sub index_blob {
 523         my ($self, $git, $blob) = @_;
 524         my $mime = do_cat_mail($git, $blob) or return;
 525         eval { $self->add_message($mime) };
 526         warn "W: index_blob $blob: $@\n" if $@;
 527 }
 528
 529 sub unindex_blob {
 530         my ($self, $git, $blob) = @_;
 531         my $mime = do_cat_mail($git, $blob) or return;
 532         my $mid = $mime->header_obj->header_raw('Message-ID');
 533         eval { $self->remove_message($mid) } if defined $mid;
 534         warn "W: unindex_blob $blob: $@\n" if $@;
 535 }
 536
 537 sub enquire {
 538         my ($self) = @_;
 539         $self->{enquire} ||= Search::Xapian::Enquire->new($self->{xdb});
 540 }
 541
 542 # indexes all unindexed messages
 543 sub index_sync {
 544         my ($self) = @_;
 545         require PublicInbox::GitCatFile;
 546         my $db = $self->{xdb};
 547         my $hex = '[a-f0-9]';
 548         my $h40 = $hex .'{40}';
 549         my $addmsg = qr!^:000000 100644 \S+ ($h40) A\t${hex}{2}/${hex}{38}$!;
 550         my $delmsg = qr!^:100644 000000 ($h40) \S+ D\t${hex}{2}/${hex}{38}$!;
 551
 552         $db->begin_transaction;
 553         eval {
 554                 my $git = PublicInbox::GitCatFile->new($self->{git_dir});
 555
 556                 my $latest = $db->get_metadata('last_commit');
 557                 my $range = length $latest ? "$latest..HEAD" : 'HEAD';
 558                 $latest = undef;
 559
 560                 # get indexed messages
 561                 my @cmd = ('git', "--git-dir=$self->{git_dir}", "log",
 562                             qw/--reverse --no-notes --no-color --raw -r
 563                                --no-abbrev/, $range);
 564                 my $pid = open(my $log, '-|', @cmd) or
 565                         die('open` '.join(' ', @cmd) . " pipe failed: $!\n");
 566
 567                 while (my $line = <$log>) {
 568                         if ($line =~ /$addmsg/o) {
 569                                 $self->index_blob($git, $1);
 570                         } elsif ($line =~ /$delmsg/o) {
 571                                 $self->unindex_blob($git, $1);
 572                         } elsif ($line =~ /^commit ($h40)/o) {
 573                                 $latest = $1;
 574                         }
 575                 }
 576                 close $log;
 577                 $db->set_metadata('last_commit', $latest) if defined $latest;
 578         };
 579         if ($@) {
 580                 warn "indexing failed: $@\n";
 581                 $db->cancel_transaction;
 582         } else {
 583                 $db->commit_transaction;
 584         }
 585 }
 586
 587 1;