lib/PublicInbox/Search.pm

   1 # Copyright (C) 2015 all contributors <meta@public-inbox.org>
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 # based on notmuch, but with no concept of folders, files or flags
   4 #
   5 # Read-only search interface for use by the web and NNTP interfaces
   6 package PublicInbox::Search;
   7 use strict;
   8 use warnings;
   9
  10 # values for searching
  11 use constant TS => 0; # timestamp
  12 use constant NUM => 1; # NNTP article number
  13 use constant BYTES => 2; # :bytes as defined in RFC 3977
  14 use constant LINES => 3; # :lines as defined in RFC 3977
  15 use constant YYYYMMDD => 4; # for searching in the WWW UI
  16
  17 use Search::Xapian qw/:standard/;
  18 use PublicInbox::SearchMsg;
  19 use Email::MIME;
  20 use PublicInbox::MID qw/mid_clean id_compress/;
  21
  22 # This is English-only, everything else is non-standard and may be confused as
  23 # a prefix common in patch emails
  24 our $REPLY_RE = qr/^re:\s+/i;
  25 our $LANG = 'english';
  26
  27 use constant {
  28         # SCHEMA_VERSION history
  29         # 0 - initial
  30         # 1 - subject_path is lower-cased
  31         # 2 - subject_path is id_compress in the index, only
  32         # 3 - message-ID is compressed if it includes '%' (hack!)
  33         # 4 - change "Re: " normalization, avoid circular Reference ghosts
  34         # 5 - subject_path drops trailing '.'
  35         # 6 - preserve References: order in document data
  36         # 7 - remove references and inreplyto terms
  37         # 8 - remove redundant/unneeded document data
  38         # 9 - disable Message-ID compression (SHA-1)
  39         # 10 - optimize doc for NNTP overviews
  40         # 11 - merge threads when vivifying ghosts
  41         # 12 - change YYYYMMDD value column to numeric
  42         SCHEMA_VERSION => 12,
  43
  44         # n.b. FLAG_PURE_NOT is expensive not suitable for a public website
  45         # as it could become a denial-of-service vector
  46         QP_FLAGS => FLAG_PHRASE|FLAG_BOOLEAN|FLAG_LOVEHATE|FLAG_WILDCARD,
  47 };
  48
  49 # setup prefixes
  50 my %bool_pfx_internal = (
  51         type => 'T', # "mail" or "ghost"
  52         thread => 'G', # newsGroup (or similar entity - e.g. a web forum name)
  53 );
  54
  55 my %bool_pfx_external = (
  56         # do we still need these? probably not..
  57         path => 'XPATH',
  58         mid => 'Q', # uniQue id (Message-ID)
  59 );
  60
  61 my %prob_prefix = (
  62         # for mairix compatibility
  63         s => 'S',
  64         m => 'XMID', # 'mid:' (bool) is exact, 'm:' (prob) can do partial
  65         f => 'A',
  66         t => 'XTO',
  67         tc => 'XTO XCC',
  68         c => 'XCC',
  69         tcf => 'XTO XCC A',
  70         a => 'XTO XCC A',
  71         b => 'XNQ XQUOT',
  72         bs => 'XNQ XQUOT S',
  73         n => 'XFN',
  74
  75         q => 'XQUOT',
  76         nq => 'XNQ',
  77
  78         # default:
  79         '' => 'XMID S A XNQ XQUOT XFN',
  80 );
  81
  82 # not documenting m: and mid: for now, the using the URLs works w/o Xapian
  83 our @HELP = (
  84         's:' => 'match within Subject  e.g. s:"a quick brown fox"',
  85         'd:' => <<EOF,
  86 date range as YYYYMMDD  e.g. d:19931002..20101002
  87 Open-ended ranges such as d:19931002.. and d:..20101002
  88 are also supported
  89 EOF
  90         'b:' => 'match within message body, including text attachments',
  91         'nq:' => 'match non-quoted text within message body',
  92         'quot:' => 'match quoted text within message body',
  93         'n:' => 'match filename of attachment(s)',
  94         't:' => 'match within the To header',
  95         'c:' => 'match within the Cc header',
  96         'f:' => 'match within the From header',
  97         'a:' => 'match within the To, Cc, and From headers',
  98         'tc:' => 'match within the To and Cc headers',
  99         'bs:' => 'match within the Subject and body',
 100 );
 101 chomp @HELP;
 102 # TODO:
 103 # df (filenames from diff)
 104 # da (diff a/ removed lines)
 105 # db (diff b/ added lines)
 106
 107 my %all_pfx = (%bool_pfx_internal, %bool_pfx_external, %prob_prefix);
 108
 109 sub xpfx { $all_pfx{$_[0]} }
 110
 111 our %PFX2TERM_RMAP;
 112 my %meta_pfx = (mid => 1, thread => 1, path => 1);
 113 while (my ($k, $v) = each %all_pfx) {
 114         $PFX2TERM_RMAP{$v} = $k if $meta_pfx{$k};
 115 }
 116
 117 my $mail_query = Search::Xapian::Query->new(xpfx('type') . 'mail');
 118
 119 sub xdir {
 120         my (undef, $git_dir) = @_;
 121         "$git_dir/public-inbox/xapian" . SCHEMA_VERSION;
 122 }
 123
 124 sub new {
 125         my ($class, $git_dir, $altid) = @_;
 126         my $dir = $class->xdir($git_dir);
 127         my $db = Search::Xapian::Database->new($dir);
 128         bless { xdb => $db, git_dir => $git_dir, altid => $altid }, $class;
 129 }
 130
 131 sub reopen { $_[0]->{xdb}->reopen }
 132
 133 # read-only
 134 sub query {
 135         my ($self, $query_string, $opts) = @_;
 136         my $query;
 137
 138         $opts ||= {};
 139         unless ($query_string eq '') {
 140                 $query = $self->qp->parse_query($query_string, QP_FLAGS);
 141                 $opts->{relevance} = 1 unless exists $opts->{relevance};
 142         }
 143
 144         _do_enquire($self, $query, $opts);
 145 }
 146
 147 sub get_thread {
 148         my ($self, $mid, $opts) = @_;
 149         my $smsg = eval { $self->lookup_message($mid) };
 150
 151         return { total => 0, msgs => [] } unless $smsg;
 152         my $qtid = Search::Xapian::Query->new(xpfx('thread').$smsg->thread_id);
 153         my $path = $smsg->path;
 154         if (defined $path && $path ne '') {
 155                 my $path = id_compress($smsg->path);
 156                 my $qsub = Search::Xapian::Query->new(xpfx('path').$path);
 157                 $qtid = Search::Xapian::Query->new(OP_OR, $qtid, $qsub);
 158         }
 159         $opts ||= {};
 160         $opts->{limit} ||= 1000;
 161
 162         # always sort threads by timestamp, this makes life easier
 163         # for the threading algorithm (in SearchThread.pm)
 164         $opts->{asc} = 1;
 165
 166         _do_enquire($self, $qtid, $opts);
 167 }
 168
 169 sub _do_enquire {
 170         my ($self, $query, $opts) = @_;
 171         my $ret;
 172         for (1..10) {
 173                 eval { $ret = _enquire_once($self, $query, $opts) };
 174                 return $ret unless $@;
 175                 # Exception: The revision being read has been discarded -
 176                 # you should call Xapian::Database::reopen()
 177                 if (index($@, 'Xapian::Database::reopen') >= 0) {
 178                         reopen($self);
 179                 } else {
 180                         die $@;
 181                 }
 182         }
 183 }
 184
 185 sub _enquire_once {
 186         my ($self, $query, $opts) = @_;
 187         my $enquire = $self->enquire;
 188         if (defined $query) {
 189                 $query = Search::Xapian::Query->new(OP_AND,$query,$mail_query);
 190         } else {
 191                 $query = $mail_query;
 192         }
 193         $enquire->set_query($query);
 194         $opts ||= {};
 195         my $desc = !$opts->{asc};
 196         if ($opts->{relevance}) {
 197                 $enquire->set_sort_by_relevance_then_value(TS, $desc);
 198         } elsif ($opts->{num}) {
 199                 $enquire->set_sort_by_value(NUM, 0);
 200         } else {
 201                 $enquire->set_sort_by_value_then_relevance(TS, $desc);
 202         }
 203         my $offset = $opts->{offset} || 0;
 204         my $limit = $opts->{limit} || 50;
 205         my $mset = $enquire->get_mset($offset, $limit);
 206         return $mset if $opts->{mset};
 207         my @msgs = map {
 208                 PublicInbox::SearchMsg->load_doc($_->get_document);
 209         } $mset->items;
 210
 211         { total => $mset->get_matches_estimated, msgs => \@msgs }
 212 }
 213
 214 # read-write
 215 sub stemmer { Search::Xapian::Stem->new($LANG) }
 216
 217 # read-only
 218 sub qp {
 219         my ($self) = @_;
 220
 221         my $qp = $self->{query_parser};
 222         return $qp if $qp;
 223
 224         # new parser
 225         $qp = Search::Xapian::QueryParser->new;
 226         $qp->set_default_op(OP_AND);
 227         $qp->set_database($self->{xdb});
 228         $qp->set_stemmer($self->stemmer);
 229         $qp->set_stemming_strategy(STEM_SOME);
 230         $qp->add_valuerangeprocessor(
 231                 Search::Xapian::NumberValueRangeProcessor->new(YYYYMMDD, 'd:'));
 232
 233         while (my ($name, $prefix) = each %bool_pfx_external) {
 234                 $qp->add_boolean_prefix($name, $prefix);
 235         }
 236
 237         # we do not actually create AltId objects,
 238         # just parse the spec to avoid the extra DB handles for now.
 239         if (my $altid = $self->{altid}) {
 240                 my $user_pfx = $self->{-user_pfx} ||= [];
 241                 for (@$altid) {
 242                         # $_ = 'serial:gmane:/path/to/gmane.msgmap.sqlite3'
 243                         /\Aserial:(\w+):/ or next;
 244                         my $pfx = $1;
 245                         push @$user_pfx, "$pfx:", <<EOF;
 246 alternate serial number  e.g. $pfx:12345 (boolean)
 247 EOF
 248                         # gmane => XGMANE
 249                         $qp->add_boolean_prefix($pfx, 'X'.uc($pfx));
 250                 }
 251                 chomp @$user_pfx;
 252         }
 253
 254         while (my ($name, $prefix) = each %prob_prefix) {
 255                 $qp->add_prefix($name, $_) foreach split(/ /, $prefix);
 256         }
 257
 258         $self->{query_parser} = $qp;
 259 }
 260
 261 sub num_range_processor {
 262         $_[0]->{nrp} ||= Search::Xapian::NumberValueRangeProcessor->new(NUM);
 263 }
 264
 265 # only used for NNTP server
 266 sub query_xover {
 267         my ($self, $beg, $end, $offset) = @_;
 268         my $qp = Search::Xapian::QueryParser->new;
 269         $qp->set_database($self->{xdb});
 270         $qp->add_valuerangeprocessor($self->num_range_processor);
 271         my $query = $qp->parse_query("$beg..$end", QP_FLAGS);
 272
 273         _do_enquire($self, $query, {num => 1, limit => 200, offset => $offset});
 274 }
 275
 276 sub lookup_message {
 277         my ($self, $mid) = @_;
 278         $mid = mid_clean($mid);
 279
 280         my $doc_id = $self->find_unique_doc_id('mid', $mid);
 281         my $smsg;
 282         if (defined $doc_id) {
 283                 # raises on error:
 284                 my $doc = $self->{xdb}->get_document($doc_id);
 285                 $smsg = PublicInbox::SearchMsg->wrap($doc, $mid);
 286                 $smsg->doc_id($doc_id);
 287         }
 288         $smsg;
 289 }
 290
 291 sub lookup_mail { # no ghosts!
 292         my ($self, $mid) = @_;
 293         my $smsg = lookup_message($self, $mid) or return;
 294         PublicInbox::SearchMsg->load_doc($smsg->{doc});
 295 }
 296
 297 sub find_unique_doc_id {
 298         my ($self, $term, $value) = @_;
 299
 300         my ($begin, $end) = $self->find_doc_ids($term, $value);
 301
 302         return undef if $begin->equal($end); # not found
 303
 304         my $rv = $begin->get_docid;
 305
 306         # sanity check
 307         $begin->inc;
 308         $begin->equal($end) or die "Term '$term:$value' is not unique\n";
 309         $rv;
 310 }
 311
 312 # returns begin and end PostingIterator
 313 sub find_doc_ids {
 314         my ($self, $term, $value) = @_;
 315
 316         $self->find_doc_ids_for_term(xpfx($term) . $value);
 317 }
 318
 319 # returns begin and end PostingIterator
 320 sub find_doc_ids_for_term {
 321         my ($self, $term) = @_;
 322         my $db = $self->{xdb};
 323
 324         ($db->postlist_begin($term), $db->postlist_end($term));
 325 }
 326
 327 # normalize subjects so they are suitable as pathnames for URLs
 328 sub subject_path {
 329         my $subj = pop;
 330         $subj = subject_normalized($subj);
 331         $subj =~ s![^a-zA-Z0-9_\.~/\-]+!_!g;
 332         lc($subj);
 333 }
 334
 335 sub subject_normalized {
 336         my $subj = pop;
 337         $subj =~ s/\A\s+//s; # no leading space
 338         $subj =~ s/\s+\z//s; # no trailing space
 339         $subj =~ s/\s+/ /gs; # no redundant spaces
 340         $subj =~ s/\.+\z//; # no trailing '.'
 341         $subj =~ s/$REPLY_RE//igo; # remove reply prefix
 342         $subj;
 343 }
 344
 345 # for doc data
 346 sub subject_summary {
 347         my $subj = pop;
 348         my $max = 68;
 349         if (length($subj) > $max) {
 350                 my @subj = split(/\s+/, $subj);
 351                 $subj = '';
 352                 my $l;
 353
 354                 while ($l = shift @subj) {
 355                         my $new = $subj . $l . ' ';
 356                         last if length($new) >= $max;
 357                         $subj = $new;
 358                 }
 359                 if ($subj ne '') {
 360                         my $r = scalar @subj ? ' ...' : '';
 361                         $subj =~ s/ \z/$r/s;
 362                 } else {
 363                         # subject has one REALLY long word, and NOT spam? wtf
 364                         @subj = ($l =~ /\A(.{1,72})/);
 365                         $subj = $subj[0] . ' ...';
 366                 }
 367         }
 368         $subj;
 369 }
 370
 371 sub enquire {
 372         my ($self) = @_;
 373         $self->{enquire} ||= Search::Xapian::Enquire->new($self->{xdb});
 374 }
 375
 376 sub help {
 377         my ($self) = @_;
 378         $self->qp; # parse altids
 379         my @ret = @HELP;
 380         if (my $user_pfx = $self->{-user_pfx}) {
 381                 push @ret, @$user_pfx;
 382         }
 383         \@ret;
 384 }
 385
 386 1;