lib/PublicInbox/Search.pm

   1 # Copyright (C) 2015 all contributors <meta@public-inbox.org>
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 # based on notmuch, but with no concept of folders, files or flags
   4 package PublicInbox::Search;
   5 use strict;
   6 use warnings;
   7 use constant TS => 0;
   8 use Search::Xapian qw/:standard/;
   9 use PublicInbox::SearchMsg;
  10 use Email::MIME;
  11 use PublicInbox::MID qw/mid_clean mid_compress/;
  12
  13 # This is English-only, everything else is non-standard and may be confused as
  14 # a prefix common in patch emails
  15 our $REPLY_RE = qr/^re:\s+/i;
  16 our $LANG = 'english';
  17
  18 use constant {
  19         # SCHEMA_VERSION history
  20         # 0 - initial
  21         # 1 - subject_path is lower-cased
  22         # 2 - subject_path is mid_compress in the index, only
  23         # 3 - message-ID is compressed if it includes '%' (hack!)
  24         # 4 - change "Re: " normalization, avoid circular Reference ghosts
  25         # 5 - subject_path drops trailing '.'
  26         # 6 - preserve References: order in document data
  27         # 7 - remove references and inreplyto terms
  28         # 8 - remove redundant/unneeded document data
  29         # 9 - disable Message-ID compression
  30         SCHEMA_VERSION => 9,
  31
  32         # n.b. FLAG_PURE_NOT is expensive not suitable for a public website
  33         # as it could become a denial-of-service vector
  34         QP_FLAGS => FLAG_PHRASE|FLAG_BOOLEAN|FLAG_LOVEHATE|FLAG_WILDCARD,
  35 };
  36
  37 # setup prefixes
  38 my %bool_pfx_internal = (
  39         type => 'T', # "mail" or "ghost"
  40         thread => 'G', # newsGroup (or similar entity - e.g. a web forum name)
  41 );
  42
  43 my %bool_pfx_external = (
  44         path => 'XPATH',
  45         mid => 'Q', # uniQue id (Message-ID)
  46 );
  47
  48 my %prob_prefix = (
  49         subject => 'S',
  50         s => 'S', # for mairix compatibility
  51         m => 'Q', # 'mid' is exact, 'm' can do partial
  52 );
  53
  54 my %all_pfx = (%bool_pfx_internal, %bool_pfx_external, %prob_prefix);
  55
  56 sub xpfx { $all_pfx{$_[0]} }
  57
  58 our %PFX2TERM_RMAP;
  59 my %meta_pfx = (mid => 1, thread => 1, path => 1);
  60 while (my ($k, $v) = each %all_pfx) {
  61         $PFX2TERM_RMAP{$v} = $k if $meta_pfx{$k};
  62 }
  63
  64 my $mail_query = Search::Xapian::Query->new(xpfx('type') . 'mail');
  65
  66 sub xdir {
  67         my (undef, $git_dir) = @_;
  68         "$git_dir/public-inbox/xapian" . SCHEMA_VERSION;
  69 }
  70
  71 sub new {
  72         my ($class, $git_dir) = @_;
  73         my $dir = $class->xdir($git_dir);
  74         my $db = Search::Xapian::Database->new($dir);
  75         bless { xdb => $db, git_dir => $git_dir }, $class;
  76 }
  77
  78 sub reopen { $_[0]->{xdb}->reopen }
  79
  80 # read-only
  81 sub query {
  82         my ($self, $query_string, $opts) = @_;
  83         my $query;
  84
  85         $opts ||= {};
  86         unless ($query_string eq '') {
  87                 $query = $self->qp->parse_query($query_string, QP_FLAGS);
  88                 $opts->{relevance} = 1 unless exists $opts->{relevance};
  89         }
  90
  91         $self->do_enquire($query, $opts);
  92 }
  93
  94 sub get_subject_path {
  95         my ($self, $path, $opts) = @_;
  96         my $q = Search::Xapian::Query->new(xpfx("path").mid_compress($path));
  97         $self->do_enquire($q, $opts);
  98 }
  99
 100 sub get_thread {
 101         my ($self, $mid, $opts) = @_;
 102         my $smsg = eval { $self->lookup_message($mid) };
 103
 104         return { total => 0, msgs => [] } unless $smsg;
 105         my $qtid = Search::Xapian::Query->new(xpfx('thread').$smsg->thread_id);
 106         my $path = mid_compress($smsg->path);
 107         my $qsub = Search::Xapian::Query->new(xpfx('path').$path);
 108         my $query = Search::Xapian::Query->new(OP_OR, $qtid, $qsub);
 109         $self->do_enquire($query, $opts);
 110 }
 111
 112 sub do_enquire {
 113         my ($self, $query, $opts) = @_;
 114         my $enquire = $self->enquire;
 115         if (defined $query) {
 116                 $query = Search::Xapian::Query->new(OP_AND,$query,$mail_query);
 117         } else {
 118                 $query = $mail_query;
 119         }
 120         $enquire->set_query($query);
 121         $opts ||= {};
 122         my $desc = !$opts->{asc};
 123         if ($opts->{relevance}) {
 124                 $enquire->set_sort_by_relevance_then_value(TS, $desc);
 125         } else {
 126                 $enquire->set_sort_by_value_then_relevance(TS, $desc);
 127         }
 128         my $offset = $opts->{offset} || 0;
 129         my $limit = $opts->{limit} || 50;
 130         my $mset = $enquire->get_mset($offset, $limit);
 131         return $mset if $opts->{mset};
 132         my @msgs = map {
 133                 PublicInbox::SearchMsg->load_doc($_->get_document);
 134         } $mset->items;
 135
 136         { total => $mset->get_matches_estimated, msgs => \@msgs }
 137 }
 138
 139 # read-write
 140 sub stemmer { Search::Xapian::Stem->new($LANG) }
 141
 142 # read-only
 143 sub qp {
 144         my ($self) = @_;
 145
 146         my $qp = $self->{query_parser};
 147         return $qp if $qp;
 148
 149         # new parser
 150         $qp = Search::Xapian::QueryParser->new;
 151         $qp->set_default_op(OP_AND);
 152         $qp->set_database($self->{xdb});
 153         $qp->set_stemmer($self->stemmer);
 154         $qp->set_stemming_strategy(STEM_SOME);
 155         $qp->add_valuerangeprocessor($self->ts_range_processor);
 156         $qp->add_valuerangeprocessor($self->date_range_processor);
 157
 158         while (my ($name, $prefix) = each %bool_pfx_external) {
 159                 $qp->add_boolean_prefix($name, $prefix);
 160         }
 161
 162         while (my ($name, $prefix) = each %prob_prefix) {
 163                 $qp->add_prefix($name, $prefix);
 164         }
 165
 166         $self->{query_parser} = $qp;
 167 }
 168
 169 sub ts_range_processor {
 170         $_[0]->{tsrp} ||= Search::Xapian::NumberValueRangeProcessor->new(TS);
 171 }
 172
 173 sub date_range_processor {
 174         $_[0]->{drp} ||= Search::Xapian::DateValueRangeProcessor->new(TS);
 175 }
 176
 177 sub lookup_message {
 178         my ($self, $mid) = @_;
 179         $mid = mid_clean($mid);
 180
 181         my $doc_id = $self->find_unique_doc_id('mid', $mid);
 182         my $smsg;
 183         if (defined $doc_id) {
 184                 # raises on error:
 185                 my $doc = $self->{xdb}->get_document($doc_id);
 186                 $smsg = PublicInbox::SearchMsg->wrap($doc, $mid);
 187                 $smsg->doc_id($doc_id);
 188         }
 189         $smsg;
 190 }
 191
 192 sub find_unique_doc_id {
 193         my ($self, $term, $value) = @_;
 194
 195         my ($begin, $end) = $self->find_doc_ids($term, $value);
 196
 197         return undef if $begin->equal($end); # not found
 198
 199         my $rv = $begin->get_docid;
 200
 201         # sanity check
 202         $begin->inc;
 203         $begin->equal($end) or die "Term '$term:$value' is not unique\n";
 204         $rv;
 205 }
 206
 207 # returns begin and end PostingIterator
 208 sub find_doc_ids {
 209         my ($self, $term, $value) = @_;
 210
 211         $self->find_doc_ids_for_term(xpfx($term) . $value);
 212 }
 213
 214 # returns begin and end PostingIterator
 215 sub find_doc_ids_for_term {
 216         my ($self, $term) = @_;
 217         my $db = $self->{xdb};
 218
 219         ($db->postlist_begin($term), $db->postlist_end($term));
 220 }
 221
 222 # normalize subjects so they are suitable as pathnames for URLs
 223 sub subject_path {
 224         my $subj = pop;
 225         $subj = subject_normalized($subj);
 226         $subj =~ s![^a-zA-Z0-9_\.~/\-]+!_!g;
 227         lc($subj);
 228 }
 229
 230 sub subject_normalized {
 231         my $subj = pop;
 232         $subj =~ s/\A\s+//s; # no leading space
 233         $subj =~ s/\s+\z//s; # no trailing space
 234         $subj =~ s/\s+/ /gs; # no redundant spaces
 235         $subj =~ s/\.+\z//; # no trailing '.'
 236         $subj =~ s/$REPLY_RE//igo; # remove reply prefix
 237         $subj;
 238 }
 239
 240 # for doc data
 241 sub subject_summary {
 242         my $subj = pop;
 243         my $max = 68;
 244         if (length($subj) > $max) {
 245                 my @subj = split(/\s+/, $subj);
 246                 $subj = '';
 247                 my $l;
 248
 249                 while ($l = shift @subj) {
 250                         my $new = $subj . $l . ' ';
 251                         last if length($new) >= $max;
 252                         $subj = $new;
 253                 }
 254                 if ($subj ne '') {
 255                         my $r = scalar @subj ? ' ...' : '';
 256                         $subj =~ s/ \z/$r/s;
 257                 } else {
 258                         # subject has one REALLY long word, and NOT spam? wtf
 259                         @subj = ($l =~ /\A(.{1,72})/);
 260                         $subj = $subj[0] . ' ...';
 261                 }
 262         }
 263         $subj;
 264 }
 265
 266 sub enquire {
 267         my ($self) = @_;
 268         $self->{enquire} ||= Search::Xapian::Enquire->new($self->{xdb});
 269 }
 270
 271 1;