lib/PublicInbox/Search.pm

   1 # Copyright (C) 2015, all contributors <meta@public-inbox.org>
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 # based on notmuch, but with no concept of folders, files or flags
   4 package PublicInbox::Search;
   5 use strict;
   6 use warnings;
   7 use PublicInbox::SearchMsg;
   8 use Search::Xapian qw/:standard/;
   9 require PublicInbox::View;
  10 use Email::MIME;
  11 use PublicInbox::MID qw/mid_clean mid_compressed/;
  12
  13 use constant {
  14         TS => 0,
  15         SCHEMA_VERSION => 0,
  16         LANG => 'english',
  17         QP_FLAGS => FLAG_PHRASE|FLAG_BOOLEAN|FLAG_LOVEHATE|FLAG_WILDCARD,
  18 };
  19
  20 # setup prefixes
  21 my %bool_pfx_internal = (
  22         type => 'T', # "mail" or "ghost"
  23         mid => 'Q', # uniQue id (Message-ID or mid_compressed)
  24 );
  25
  26 my %bool_pfx_external = (
  27         path => 'XPATH',
  28         thread => 'G', # newsGroup (or similar entity - e.g. a web forum name)
  29         references => 'XREFS',
  30         inreplyto => 'XIRT',
  31 );
  32
  33 my %prob_prefix = (
  34         subject => 'S',
  35 );
  36
  37 my %all_pfx = (%bool_pfx_internal, %bool_pfx_external, %prob_prefix);
  38
  39 sub xpfx { $all_pfx{$_[0]} }
  40
  41 our %PFX2TERM_RMAP;
  42 while (my ($k, $v) = each %all_pfx) {
  43         next if $prob_prefix{$k};
  44         $PFX2TERM_RMAP{$v} = $k;
  45 }
  46
  47 my $mail_query = Search::Xapian::Query->new(xpfx('type') . 'mail');
  48
  49 sub new {
  50         my ($class, $git_dir, $writable) = @_;
  51         # allow concurrent versions for easier rollback:
  52         my $dir = "$git_dir/public-inbox/xapian" . SCHEMA_VERSION;
  53         my $db;
  54
  55         if ($writable) { # not used by the WWW interface
  56                 require Search::Xapian::WritableDatabase;
  57                 require File::Path;
  58                 File::Path::mkpath($dir);
  59                 $db = Search::Xapian::WritableDatabase->new($dir,
  60                                         Search::Xapian::DB_CREATE_OR_OPEN);
  61         } else {
  62                 $db = Search::Xapian::Database->new($dir);
  63         }
  64         bless { xdb => $db, git_dir => $git_dir }, $class;
  65 }
  66
  67 sub reopen { $_[0]->{xdb}->reopen }
  68
  69 sub add_message {
  70         my ($self, $mime) = @_; # mime = Email::MIME object
  71         my $db = $self->{xdb};
  72
  73         my $doc_id;
  74         my $mid = mid_clean($mime->header('Message-ID'));
  75         $mid = mid_compressed($mid);
  76         my $was_ghost = 0;
  77         my $ct_msg = $mime->header('Content-Type') || 'text/plain';
  78         my $enc_msg = PublicInbox::View::enc_for($ct_msg);
  79
  80         $db->begin_transaction;
  81         eval {
  82                 my $smsg = $self->lookup_message($mid);
  83                 my $doc;
  84
  85                 if ($smsg) {
  86                         $smsg->ensure_metadata;
  87                         # convert a ghost to a regular message
  88                         # it will also clobber any existing regular message
  89                         $smsg->mime($mime);
  90                         $doc = $smsg->{doc};
  91
  92                         my $type = xpfx('type');
  93                         eval {
  94                                 $doc->remove_term($type . 'ghost');
  95                                 $was_ghost = 1;
  96                         };
  97
  98                         # probably does not exist:
  99                         eval { $doc->remove_term($type . 'mail') };
 100                         $doc->add_term($type . 'mail');
 101                 }  else {
 102                         $smsg = PublicInbox::SearchMsg->new($mime);
 103                         $doc = $smsg->{doc};
 104                         $doc->add_term(xpfx('mid') . $mid);
 105                 }
 106
 107                 my $subj = $smsg->subject;
 108
 109                 if (length $subj) {
 110                         $doc->add_term(xpfx('subject') . $subj);
 111
 112                         my $path = subject_path($subj);
 113                         $doc->add_term(xpfx('path') . $path);
 114                 }
 115
 116                 my $from = $smsg->from_name;
 117                 my $date = $smsg->date;
 118                 my $ts = Search::Xapian::sortable_serialise($smsg->ts);
 119                 $doc->add_value(PublicInbox::Search::TS, $ts);
 120
 121                 $doc->set_data($smsg->to_doc_data);
 122
 123                 my $tg = $self->term_generator;
 124
 125                 $tg->set_document($doc);
 126                 $tg->index_text($subj, 1, 'S') if $subj;
 127                 $tg->increase_termpos;
 128                 $tg->index_text($subj) if $subj;
 129                 $tg->increase_termpos;
 130
 131                 $tg->index_text($smsg->from->format);
 132                 $tg->increase_termpos;
 133
 134                 $mime->walk_parts(sub {
 135                         my ($part) = @_;
 136                         return if $part->subparts; # walk_parts already recurses
 137                         my $ct = $part->content_type || $ct_msg;
 138
 139                         # account for filter bugs...
 140                         $ct =~ m!\btext/plain\b!i or return;
 141
 142                         my $enc = PublicInbox::View::enc_for($ct, $enc_msg);
 143                         my (@orig, @quot);
 144                         foreach my $l (split(/\n/, $enc->decode($part->body))) {
 145                                 if ($l =~ /^\s*>/) {
 146                                         push @quot, $l;
 147                                 } else {
 148                                         push @orig, $l;
 149                                 }
 150                         }
 151                         if (@quot) {
 152                                 $tg->index_text(join("\n", @quot), 0);
 153                                 $tg->increase_termpos;
 154                         }
 155                         if (@orig) {
 156                                 $tg->index_text(join("\n", @orig));
 157                                 $tg->increase_termpos;
 158                         }
 159                 });
 160
 161                 if ($was_ghost) {
 162                         $doc_id = $smsg->doc_id;
 163                         $self->link_message($smsg, 0);
 164                         $db->replace_document($doc_id, $doc);
 165                 } else {
 166                         $self->link_message($smsg, 0);
 167                         $doc_id = $db->add_document($doc);
 168                 }
 169         };
 170
 171         if ($@) {
 172                 warn "failed to index message <$mid>: $@\n";
 173                 $db->cancel_transaction;
 174         } else {
 175                 $db->commit_transaction;
 176         }
 177         $doc_id;
 178 }
 179
 180 # returns deleted doc_id on success, undef on missing
 181 sub remove_message {
 182         my ($self, $mid) = @_;
 183         my $db = $self->{xdb};
 184         my $doc_id;
 185         $mid = mid_clean($mid);
 186         $mid = mid_compressed($mid);
 187
 188         $db->begin_transaction;
 189         eval {
 190                 $doc_id = $self->find_unique_doc_id('mid', $mid);
 191                 $db->delete_document($doc_id) if defined $doc_id;
 192         };
 193
 194         if ($@) {
 195                 warn "failed to remove message <$mid>: $@\n";
 196                 $db->cancel_transaction;
 197         } else {
 198                 $db->commit_transaction;
 199         }
 200         $doc_id;
 201 }
 202
 203 # read-only
 204 sub query {
 205         my ($self, $query_string, $opts) = @_;
 206         my $query = $self->qp->parse_query($query_string, QP_FLAGS);
 207
 208         $query = Search::Xapian::Query->new(OP_AND, $mail_query, $query);
 209         $self->do_enquire($query, $opts);
 210 }
 211
 212 # given a message ID, get replies to a message
 213 sub get_replies {
 214         my ($self, $mid, $opts) = @_;
 215         $mid = mid_clean($mid);
 216         $mid = mid_compressed($mid);
 217         my $qp = $self->qp;
 218         my $irt = $qp->parse_query("inreplyto:$mid", 0);
 219         my $ref = $qp->parse_query("references:$mid", 0);
 220         my $query = Search::Xapian::Query->new(OP_OR, $irt, $ref);
 221
 222         $self->do_enquire($query);
 223 }
 224
 225 sub get_thread {
 226         my ($self, $mid, $opts) = @_;
 227         my $smsg = eval { $self->lookup_message($mid) };
 228
 229         return { count => 0, msgs => [] } unless $smsg;
 230         my $qp = $self->qp;
 231         my $qtid = $qp->parse_query('thread:'.$smsg->thread_id);
 232         my $qsub = $qp->parse_query('path:'.$smsg->path);
 233         my $query = Search::Xapian::Query->new(OP_OR, $qtid, $qsub);
 234         $self->do_enquire($query);
 235 }
 236
 237 # private subs below
 238
 239 sub do_enquire {
 240         my ($self, $query, $opts) = @_;
 241         my $enquire = $self->enquire;
 242
 243         $enquire->set_query($query);
 244         $enquire->set_sort_by_relevance_then_value(TS, 0);
 245         $opts ||= {};
 246         my $offset = $opts->{offset} || 0;
 247         my $limit = $opts->{limit} || 50;
 248         my $mset = $enquire->get_mset($offset, $limit);
 249         my @msgs = map {
 250                 PublicInbox::SearchMsg->load_doc($_->get_document);
 251         } $mset->items;
 252
 253         { count => $mset->get_matches_estimated, msgs => \@msgs }
 254 }
 255
 256 # read-write
 257 sub stemmer { Search::Xapian::Stem->new(LANG) }
 258
 259 # read-only
 260 sub qp {
 261         my ($self) = @_;
 262
 263         my $qp = $self->{query_parser};
 264         return $qp if $qp;
 265
 266         # new parser
 267         $qp = Search::Xapian::QueryParser->new;
 268         $qp->set_default_op(OP_AND);
 269         $qp->set_database($self->{xdb});
 270         $qp->set_stemmer($self->stemmer);
 271         $qp->set_stemming_strategy(STEM_SOME);
 272         $qp->add_valuerangeprocessor($self->ts_range_processor);
 273         $qp->add_valuerangeprocessor($self->date_range_processor);
 274
 275         while (my ($name, $prefix) = each %bool_pfx_external) {
 276                 $qp->add_boolean_prefix($name, $prefix);
 277         }
 278
 279         while (my ($name, $prefix) = each %prob_prefix) {
 280                 $qp->add_prefix($name, $prefix);
 281         }
 282
 283         $self->{query_parser} = $qp;
 284 }
 285
 286 sub term_generator { # write-only
 287         my ($self) = @_;
 288
 289         my $tg = $self->{term_generator};
 290         return $tg if $tg;
 291
 292         $tg = Search::Xapian::TermGenerator->new;
 293         $tg->set_stemmer($self->stemmer);
 294
 295         $self->{term_generator} = $tg;
 296 }
 297
 298 sub next_doc_id { $_[0]->{xdb}->get_lastdocid + 1 }
 299
 300 # increments last_thread_id counter
 301 # returns a 64-bit integer represented as a hex string
 302 sub next_thread_id {
 303         my ($self) = @_;
 304         my $db = $self->{xdb};
 305         my $last_thread_id = int($db->get_metadata('last_thread_id') || 0);
 306
 307         $db->set_metadata('last_thread_id', ++$last_thread_id);
 308
 309         $last_thread_id;
 310 }
 311
 312 sub ts_range_processor {
 313         $_[0]->{tsrp} ||= Search::Xapian::NumberValueRangeProcessor->new(TS);
 314 }
 315
 316 sub date_range_processor {
 317         $_[0]->{drp} ||= Search::Xapian::DateValueRangeProcessor->new(TS);
 318 }
 319
 320 sub link_message {
 321         my ($self, $smsg, $is_ghost) = @_;
 322
 323         if ($is_ghost) {
 324                 $smsg->ensure_metadata;
 325         } else {
 326                 $self->link_message_to_parents($smsg);
 327         }
 328 }
 329
 330 sub link_message_to_parents {
 331         my ($self, $smsg) = @_;
 332         my $doc = $smsg->{doc};
 333         my $mid = mid_compressed($smsg->mid);
 334         my $mime = $smsg->mime;
 335         my $refs = $mime->header('References');
 336         my @refs = $refs ? ($refs =~ /<([^>]+)>/g) : ();
 337         my $irt = $mime->header('In-Reply-To');
 338         if ($irt) {
 339                 if ($irt =~ /<([^>]+)>/) {
 340                         $irt = $1;
 341                 }
 342                 push @refs, $irt;
 343         }
 344
 345         my $tid;
 346         if (@refs) {
 347                 @refs = map { mid_compressed($_) } @refs;
 348                 my %uniq;
 349                 @refs = grep { !$uniq{$_}++ } @refs; # uniq
 350
 351                 $doc->add_term(xpfx('inreplyto') . $refs[-1]);
 352
 353                 my $ref_pfx = xpfx('references');
 354
 355                 # first ref *should* be the thread root,
 356                 # but we can never trust clients to do the right thing
 357                 my $ref = shift @refs;
 358                 $doc->add_term($ref_pfx . $ref);
 359                 $tid = $self->_resolve_mid_to_tid($ref);
 360
 361                 # the rest of the refs should point to this tid:
 362                 foreach $ref (@refs) {
 363                         $doc->add_term($ref_pfx . $ref);
 364                         my $ptid = $self->_resolve_mid_to_tid($ref);
 365                         if ($tid ne $ptid) {
 366                                 $self->merge_threads($tid, $ptid);
 367                         }
 368                 }
 369         } else {
 370                 $tid = $self->next_thread_id;
 371         }
 372         $doc->add_term(xpfx('thread') . $tid);
 373 }
 374
 375 sub lookup_message {
 376         my ($self, $mid) = @_;
 377         $mid = mid_clean($mid);
 378         $mid = mid_compressed($mid);
 379
 380         my $doc_id = $self->find_unique_doc_id('mid', $mid);
 381         my $smsg;
 382         if (defined $doc_id) {
 383                 # raises on error:
 384                 my $doc = $self->{xdb}->get_document($doc_id);
 385                 $smsg = PublicInbox::SearchMsg->wrap($doc, $mid);
 386                 $smsg->doc_id($doc_id);
 387         }
 388         $smsg;
 389 }
 390
 391 sub find_unique_doc_id {
 392         my ($self, $term, $value) = @_;
 393
 394         my ($begin, $end) = $self->find_doc_ids($term, $value);
 395
 396         return undef if $begin->equal($end); # not found
 397
 398         my $rv = $begin->get_docid;
 399
 400         # sanity check
 401         $begin->inc;
 402         $begin->equal($end) or die "Term '$term:$value' is not unique\n";
 403         $rv;
 404 }
 405
 406 # returns begin and end PostingIterator
 407 sub find_doc_ids {
 408         my ($self, $term, $value) = @_;
 409
 410         $self->find_doc_ids_for_term(xpfx($term) . $value);
 411 }
 412
 413 # returns begin and end PostingIterator
 414 sub find_doc_ids_for_term {
 415         my ($self, $term) = @_;
 416         my $db = $self->{xdb};
 417
 418         ($db->postlist_begin($term), $db->postlist_end($term));
 419 }
 420
 421 # this will create a ghost as necessary
 422 sub _resolve_mid_to_tid {
 423         my ($self, $mid) = @_;
 424
 425         my $smsg = $self->lookup_message($mid) || $self->create_ghost($mid);
 426         $smsg->thread_id;
 427 }
 428
 429 sub create_ghost {
 430         my ($self, $mid, $tid) = @_;
 431
 432         $mid = mid_compressed($mid);
 433         $tid = $self->next_thread_id unless defined $tid;
 434
 435         my $doc = Search::Xapian::Document->new;
 436         $doc->add_term(xpfx('mid') . $mid);
 437         $doc->add_term(xpfx('thread') . $tid);
 438         $doc->add_term(xpfx('type') . 'ghost');
 439
 440         my $smsg = PublicInbox::SearchMsg->wrap($doc, $mid);
 441         $self->link_message($smsg, 1);
 442         $self->{xdb}->add_document($doc);
 443
 444         $smsg;
 445 }
 446
 447 sub merge_threads {
 448         my ($self, $winner_tid, $loser_tid) = @_;
 449         my ($head, $tail) = $self->find_doc_ids('thread', $loser_tid);
 450         my $thread_pfx = xpfx('thread');
 451         my $db = $self->{xdb};
 452
 453         for (; $head != $tail; $head->inc) {
 454                 my $docid = $head->get_docid;
 455                 my $doc = $db->get_document($docid);
 456                 $doc->remove_term($thread_pfx . $loser_tid);
 457                 $doc->add_term($thread_pfx . $winner_tid);
 458                 $db->replace_document($docid, $doc);
 459         }
 460 }
 461
 462 # normalize subjects so they are suitable as pathnames for URLs
 463 sub subject_path {
 464         my ($subj) = @_;
 465
 466         $subj =~ s/\A\s+//;
 467         $subj =~ s/\s+\z//;
 468         $subj =~ s/^(?:re|aw):\s*//i; # remove reply prefix (aw: German)
 469         $subj =~ s![^a-zA-Z0-9_\.~/\-]+!_!g;
 470         $subj;
 471 }
 472
 473 sub do_cat_mail {
 474         my ($git, $blob) = @_;
 475         my $mime = eval {
 476                 my $str = $git->cat_file($blob);
 477                 Email::MIME->new($str);
 478         };
 479         $@ ? undef : $mime;
 480 }
 481
 482 sub index_blob {
 483         my ($self, $git, $blob) = @_;
 484         my $mime = do_cat_mail($git, $blob) or return;
 485         eval { $self->add_message($mime) };
 486         warn "W: index_blob $blob: $@\n" if $@;
 487 }
 488
 489 sub unindex_blob {
 490         my ($self, $git, $blob) = @_;
 491         my $mime = do_cat_mail($git, $blob) or return;
 492         my $mid = $mime->header('Message-ID');
 493         eval { $self->remove_message($mid) } if defined $mid;
 494         warn "W: unindex_blob $blob: $@\n" if $@;
 495 }
 496
 497 sub enquire {
 498         my ($self) = @_;
 499         $self->{enquire} ||= Search::Xapian::Enquire->new($self->{xdb});
 500 }
 501
 502 # indexes all unindexed messages
 503 sub index_sync {
 504         my ($self, $git) = @_;
 505         my $db = $self->{xdb};
 506         my $latest = $db->get_metadata('last_commit');
 507         my $range = length $latest ? "$latest..HEAD" : 'HEAD';
 508         $latest = undef;
 509
 510         my $hex = '[a-f0-9]';
 511         my $h40 = $hex .'{40}';
 512         my $addmsg = qr!^:000000 100644 \S+ ($h40) A\t${hex}{2}/${hex}{38}$!;
 513         my $delmsg = qr!^:100644 000000 ($h40) \S+ D\t${hex}{2}/${hex}{38}$!;
 514
 515         # get indexed messages
 516         my @cmd = ('git', "--git-dir=$git->{git_dir}", "log",
 517                     qw/--reverse --no-notes --no-color --raw -r --no-abbrev/,
 518                     $range);
 519
 520         my $pid = open(my $log, '-|', @cmd) or
 521                 die('open` '.join(' ', @cmd) . " pipe failed: $!\n");
 522         my $last;
 523         while (my $line = <$log>) {
 524                 if ($line =~ /$addmsg/o) {
 525                         $self->index_blob($git, $1);
 526                 } elsif ($line =~ /$delmsg/o) {
 527                         $self->unindex_blob($git, $1);
 528                 } elsif ($line =~ /^commit ($h40)/o) {
 529                         my $commit = $1;
 530                         if (defined $latest) {
 531                                 $db->set_metadata('last_commit', $latest)
 532                         }
 533                         $latest = $commit;
 534                 }
 535         }
 536         close $log;
 537         $db->set_metadata('last_commit', $latest) if defined $latest;
 538 }
 539
 540 1;