lib/PublicInbox/Search.pm

   1 # Copyright (C) 2015, all contributors <meta@public-inbox.org>
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 # based on notmuch, but with no concept of folders, files or flags
   4 package PublicInbox::Search;
   5 use strict;
   6 use warnings;
   7 use constant TS => 0;
   8 use Search::Xapian qw/:standard/;
   9 use PublicInbox::SearchMsg;
  10 use Email::MIME;
  11 use PublicInbox::MID qw/mid_clean mid_compress/;
  12
  13 # This is English-only, everything else is non-standard and may be confused as
  14 # a prefix common in patch emails
  15 our $REPLY_RE = qr/^re:\s+/i;
  16 our $LANG = 'english';
  17
  18 use constant {
  19         # SCHEMA_VERSION history
  20         # 0 - initial
  21         # 1 - subject_path is lower-cased
  22         # 2 - subject_path is mid_compress in the index, only
  23         # 3 - message-ID is compressed if it includes '%' (hack!)
  24         # 4 - change "Re: " normalization, avoid circular Reference ghosts
  25         # 5 - subject_path drops trailing '.'
  26         # 6 - preserve References: order in document data
  27         # 7 - remove references and inreplyto terms
  28         # 8 - remove redundant/unneeded document data
  29         SCHEMA_VERSION => 8,
  30         QP_FLAGS => FLAG_PHRASE|FLAG_BOOLEAN|FLAG_LOVEHATE|FLAG_WILDCARD,
  31 };
  32
  33 # setup prefixes
  34 my %bool_pfx_internal = (
  35         type => 'T', # "mail" or "ghost"
  36         mid => 'Q', # uniQue id (Message-ID or mid_compress)
  37 );
  38
  39 my %bool_pfx_external = (
  40         path => 'XPATH',
  41         thread => 'G', # newsGroup (or similar entity - e.g. a web forum name)
  42 );
  43
  44 my %prob_prefix = (
  45         subject => 'S',
  46 );
  47
  48 my %all_pfx = (%bool_pfx_internal, %bool_pfx_external, %prob_prefix);
  49
  50 sub xpfx { $all_pfx{$_[0]} }
  51
  52 our %PFX2TERM_RMAP;
  53 my %meta_pfx = (mid => 1, thread => 1, path => 1);
  54 while (my ($k, $v) = each %all_pfx) {
  55         $PFX2TERM_RMAP{$v} = $k if $meta_pfx{$k};
  56 }
  57
  58 my $mail_query = Search::Xapian::Query->new(xpfx('type') . 'mail');
  59
  60 sub xdir {
  61         my (undef, $git_dir) = @_;
  62         "$git_dir/public-inbox/xapian" . SCHEMA_VERSION;
  63 }
  64
  65 sub new {
  66         my ($class, $git_dir) = @_;
  67         my $dir = $class->xdir($git_dir);
  68         my $db = Search::Xapian::Database->new($dir);
  69         bless { xdb => $db, git_dir => $git_dir }, $class;
  70 }
  71
  72 sub reopen { $_[0]->{xdb}->reopen }
  73
  74 # read-only
  75 sub query {
  76         my ($self, $query_string, $opts) = @_;
  77         my $query = $self->qp->parse_query($query_string, QP_FLAGS);
  78
  79         $opts ||= {};
  80         $opts->{relevance} = 1;
  81         $self->do_enquire($query, $opts);
  82 }
  83
  84 sub get_subject_path {
  85         my ($self, $path, $opts) = @_;
  86         my $query = $self->qp->parse_query("path:".mid_compress($path), 0);
  87         $self->do_enquire($query, $opts);
  88 }
  89
  90 sub get_thread {
  91         my ($self, $mid, $opts) = @_;
  92         my $smsg = eval { $self->lookup_message($mid) };
  93
  94         return { total => 0, msgs => [] } unless $smsg;
  95         my $qp = $self->qp;
  96         my $qtid = $qp->parse_query('thread:'.$smsg->thread_id, 0);
  97         my $qsub = $qp->parse_query('path:'.mid_compress($smsg->path), 0);
  98         my $query = Search::Xapian::Query->new(OP_OR, $qtid, $qsub);
  99         $self->do_enquire($query, $opts);
 100 }
 101
 102 # private subs below
 103
 104 sub do_enquire {
 105         my ($self, $query, $opts) = @_;
 106         my $enquire = $self->enquire;
 107
 108         $query = Search::Xapian::Query->new(OP_AND, $query, $mail_query);
 109         $enquire->set_query($query);
 110         if ($opts->{relevance}) {
 111                 $enquire->set_sort_by_relevance_then_value(TS, 0);
 112         } else {
 113                 $enquire->set_sort_by_value(TS, 0);
 114         }
 115         $opts ||= {};
 116         my $offset = $opts->{offset} || 0;
 117         my $limit = $opts->{limit} || 50;
 118         my $mset = $enquire->get_mset($offset, $limit);
 119         my @msgs = map {
 120                 PublicInbox::SearchMsg->load_doc($_->get_document);
 121         } $mset->items;
 122
 123         { total => $mset->get_matches_estimated, msgs => \@msgs }
 124 }
 125
 126 # read-write
 127 sub stemmer { Search::Xapian::Stem->new($LANG) }
 128
 129 # read-only
 130 sub qp {
 131         my ($self) = @_;
 132
 133         my $qp = $self->{query_parser};
 134         return $qp if $qp;
 135
 136         # new parser
 137         $qp = Search::Xapian::QueryParser->new;
 138         $qp->set_default_op(OP_AND);
 139         $qp->set_database($self->{xdb});
 140         $qp->set_stemmer($self->stemmer);
 141         $qp->set_stemming_strategy(STEM_SOME);
 142         $qp->add_valuerangeprocessor($self->ts_range_processor);
 143         $qp->add_valuerangeprocessor($self->date_range_processor);
 144
 145         while (my ($name, $prefix) = each %bool_pfx_external) {
 146                 $qp->add_boolean_prefix($name, $prefix);
 147         }
 148
 149         while (my ($name, $prefix) = each %prob_prefix) {
 150                 $qp->add_prefix($name, $prefix);
 151         }
 152
 153         $self->{query_parser} = $qp;
 154 }
 155
 156 sub ts_range_processor {
 157         $_[0]->{tsrp} ||= Search::Xapian::NumberValueRangeProcessor->new(TS);
 158 }
 159
 160 sub date_range_processor {
 161         $_[0]->{drp} ||= Search::Xapian::DateValueRangeProcessor->new(TS);
 162 }
 163
 164 sub lookup_message {
 165         my ($self, $mid) = @_;
 166         $mid = mid_clean($mid);
 167         $mid = mid_compress($mid);
 168
 169         my $doc_id = $self->find_unique_doc_id('mid', $mid);
 170         my $smsg;
 171         if (defined $doc_id) {
 172                 # raises on error:
 173                 my $doc = $self->{xdb}->get_document($doc_id);
 174                 $smsg = PublicInbox::SearchMsg->wrap($doc, $mid);
 175                 $smsg->doc_id($doc_id);
 176         }
 177         $smsg;
 178 }
 179
 180 sub find_unique_doc_id {
 181         my ($self, $term, $value) = @_;
 182
 183         my ($begin, $end) = $self->find_doc_ids($term, $value);
 184
 185         return undef if $begin->equal($end); # not found
 186
 187         my $rv = $begin->get_docid;
 188
 189         # sanity check
 190         $begin->inc;
 191         $begin->equal($end) or die "Term '$term:$value' is not unique\n";
 192         $rv;
 193 }
 194
 195 # returns begin and end PostingIterator
 196 sub find_doc_ids {
 197         my ($self, $term, $value) = @_;
 198
 199         $self->find_doc_ids_for_term(xpfx($term) . $value);
 200 }
 201
 202 # returns begin and end PostingIterator
 203 sub find_doc_ids_for_term {
 204         my ($self, $term) = @_;
 205         my $db = $self->{xdb};
 206
 207         ($db->postlist_begin($term), $db->postlist_end($term));
 208 }
 209
 210 # normalize subjects so they are suitable as pathnames for URLs
 211 sub subject_path {
 212         my $subj = pop;
 213         $subj = subject_normalized($subj);
 214         $subj =~ s![^a-zA-Z0-9_\.~/\-]+!_!g;
 215         lc($subj);
 216 }
 217
 218 sub subject_normalized {
 219         my $subj = pop;
 220         $subj =~ s/\A\s+//s; # no leading space
 221         $subj =~ s/\s+\z//s; # no trailing space
 222         $subj =~ s/\s+/ /gs; # no redundant spaces
 223         $subj =~ s/\.+\z//; # no trailing '.'
 224         $subj =~ s/$REPLY_RE//igo; # remove reply prefix
 225         $subj;
 226 }
 227
 228 # for doc data
 229 sub subject_summary {
 230         my $subj = pop;
 231         my $max = 68;
 232         if (length($subj) > $max) {
 233                 my @subj = split(/\s+/, $subj);
 234                 $subj = '';
 235                 my $l;
 236
 237                 while ($l = shift @subj) {
 238                         my $new = $subj . $l . ' ';
 239                         last if length($new) >= $max;
 240                         $subj = $new;
 241                 }
 242                 if ($subj ne '') {
 243                         my $r = scalar @subj ? ' ...' : '';
 244                         $subj =~ s/ \z/$r/s;
 245                 } else {
 246                         # subject has one REALLY long word, and NOT spam? wtf
 247                         @subj = ($l =~ /\A(.{1,72})/);
 248                         $subj = $subj[0] . ' ...';
 249                 }
 250         }
 251         $subj;
 252 }
 253
 254 sub enquire {
 255         my ($self) = @_;
 256         $self->{enquire} ||= Search::Xapian::Enquire->new($self->{xdb});
 257 }
 258
 259 1;