lib/PublicInbox/Search.pm

   1 # Copyright (C) 2015, all contributors <meta@public-inbox.org>
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 # based on notmuch, but with no concept of folders, files or flags
   4 package PublicInbox::Search;
   5 use strict;
   6 use warnings;
   7 use PublicInbox::SearchMsg;
   8 use Search::Xapian qw/:standard/;
   9 use Email::MIME;
  10 use PublicInbox::MID qw/mid_clean mid_compressed/;
  11
  12 # This is English-only, everything else is non-standard and may be confused as
  13 # a prefix common in patch emails
  14 our $REPLY_RE = qr/^re:\s+/i;
  15 our $LANG = 'english';
  16
  17 use constant {
  18         TS => 0,
  19         # SCHEMA_VERSION history
  20         # 0 - initial
  21         # 1 - subject_path is lower-cased
  22         # 2 - subject_path is mid_compressed in the index, only
  23         # 3 - message-ID is compressed if it includes '%' (hack!)
  24         # 4 - change "Re: " normalization, avoid circular Reference ghosts
  25         SCHEMA_VERSION => 4,
  26         QP_FLAGS => FLAG_PHRASE|FLAG_BOOLEAN|FLAG_LOVEHATE|FLAG_WILDCARD,
  27 };
  28
  29 # setup prefixes
  30 my %bool_pfx_internal = (
  31         type => 'T', # "mail" or "ghost"
  32         mid => 'Q', # uniQue id (Message-ID or mid_compressed)
  33 );
  34
  35 my %bool_pfx_external = (
  36         path => 'XPATH',
  37         thread => 'G', # newsGroup (or similar entity - e.g. a web forum name)
  38         references => 'XREFS',
  39         inreplyto => 'XIRT',
  40 );
  41
  42 my %prob_prefix = (
  43         subject => 'S',
  44 );
  45
  46 my %all_pfx = (%bool_pfx_internal, %bool_pfx_external, %prob_prefix);
  47
  48 sub xpfx { $all_pfx{$_[0]} }
  49
  50 our %PFX2TERM_RMAP;
  51 while (my ($k, $v) = each %all_pfx) {
  52         next if $prob_prefix{$k};
  53         $PFX2TERM_RMAP{$v} = $k;
  54 }
  55
  56 my $mail_query = Search::Xapian::Query->new(xpfx('type') . 'mail');
  57
  58 sub new {
  59         my ($class, $git_dir, $writable) = @_;
  60         # allow concurrent versions for easier rollback:
  61         my $dir = "$git_dir/public-inbox/xapian" . SCHEMA_VERSION;
  62         my $db;
  63
  64         if ($writable) { # not used by the WWW interface
  65                 require Search::Xapian::WritableDatabase;
  66                 my $flag = Search::Xapian::DB_OPEN;
  67                 if ($writable == 1) {
  68                         require File::Path;
  69                         File::Path::mkpath($dir);
  70                         $flag = Search::Xapian::DB_CREATE_OR_OPEN;
  71                 }
  72                 $db = Search::Xapian::WritableDatabase->new($dir, $flag);
  73         } else {
  74                 $db = Search::Xapian::Database->new($dir);
  75         }
  76         bless { xdb => $db, git_dir => $git_dir }, $class;
  77 }
  78
  79 sub reopen { $_[0]->{xdb}->reopen }
  80
  81 sub add_message {
  82         my ($self, $mime) = @_; # mime = Email::MIME object
  83         my $db = $self->{xdb};
  84
  85         my $doc_id;
  86         my $mid_orig = mid_clean($mime->header_obj->header_raw('Message-ID'));
  87         my $mid = mid_compressed($mid_orig);
  88         my $was_ghost = 0;
  89         my $ct_msg = $mime->header('Content-Type') || 'text/plain';
  90
  91         eval {
  92                 my $smsg = $self->lookup_message($mid);
  93                 my $doc;
  94
  95                 if ($smsg) {
  96                         $smsg->ensure_metadata;
  97                         # convert a ghost to a regular message
  98                         # it will also clobber any existing regular message
  99                         $smsg->mime($mime);
 100                         $doc = $smsg->{doc};
 101
 102                         my $type = xpfx('type');
 103                         eval {
 104                                 $doc->remove_term($type . 'ghost');
 105                                 $was_ghost = 1;
 106                         };
 107
 108                         # probably does not exist:
 109                         eval { $doc->remove_term($type . 'mail') };
 110                         $doc->add_term($type . 'mail');
 111                 }  else {
 112                         $smsg = PublicInbox::SearchMsg->new($mime);
 113                         $doc = $smsg->{doc};
 114                         $doc->add_term(xpfx('mid') . $mid);
 115                 }
 116
 117                 my $subj = $smsg->subject;
 118
 119                 if (length $subj) {
 120                         $doc->add_term(xpfx('subject') . $subj);
 121
 122                         my $path = subject_path($subj);
 123                         $doc->add_term(xpfx('path') . mid_compressed($path));
 124                 }
 125
 126                 my $from = $smsg->from_name;
 127                 my $date = $smsg->date;
 128                 my $ts = Search::Xapian::sortable_serialise($smsg->ts);
 129                 $doc->add_value(PublicInbox::Search::TS, $ts);
 130
 131                 $doc->set_data($smsg->to_doc_data);
 132
 133                 my $tg = $self->term_generator;
 134
 135                 $tg->set_document($doc);
 136                 $tg->index_text($subj, 1, 'S') if $subj;
 137                 $tg->increase_termpos;
 138                 $tg->index_text($subj) if $subj;
 139                 $tg->increase_termpos;
 140
 141                 $tg->index_text($smsg->from->format);
 142                 $tg->increase_termpos;
 143
 144                 $mime->walk_parts(sub {
 145                         my ($part) = @_;
 146                         return if $part->subparts; # walk_parts already recurses
 147                         my $ct = $part->content_type || $ct_msg;
 148
 149                         # account for filter bugs...
 150                         $ct =~ m!\btext/plain\b!i or return;
 151
 152                         my (@orig, @quot);
 153                         my $body = $part->body;
 154                         $part->body_set('');
 155                         my @lines = split(/\n/, $body);
 156                         while (defined(my $l = shift @lines)) {
 157                                 if ($l =~ /^\s*>/) {
 158                                         push @quot, $l;
 159                                 } else {
 160                                         push @orig, $l;
 161                                 }
 162                         }
 163                         if (@quot) {
 164                                 $tg->index_text(join("\n", @quot), 0);
 165                                 @quot = ();
 166                                 $tg->increase_termpos;
 167                         }
 168                         if (@orig) {
 169                                 $tg->index_text(join("\n", @orig));
 170                                 @orig = ();
 171                                 $tg->increase_termpos;
 172                         }
 173                 });
 174
 175                 if ($was_ghost) {
 176                         $doc_id = $smsg->doc_id;
 177                         $self->link_message($smsg, 0);
 178                         $db->replace_document($doc_id, $doc);
 179                 } else {
 180                         $self->link_message($smsg, 0);
 181                         $doc_id = $db->add_document($doc);
 182                 }
 183         };
 184
 185         if ($@) {
 186                 warn "failed to index message <$mid_orig>: $@\n";
 187                 return undef;
 188         }
 189         $doc_id;
 190 }
 191
 192 # returns deleted doc_id on success, undef on missing
 193 sub remove_message {
 194         my ($self, $mid_orig) = @_;
 195         my $db = $self->{xdb};
 196         my $doc_id;
 197         $mid_orig = mid_clean($mid_orig);
 198         my $mid = mid_compressed($mid_orig);
 199
 200         eval {
 201                 $doc_id = $self->find_unique_doc_id('mid', $mid);
 202                 $db->delete_document($doc_id) if defined $doc_id;
 203         };
 204
 205         if ($@) {
 206                 warn "failed to remove message <$mid_orig>: $@\n";
 207                 return undef;
 208         }
 209         $doc_id;
 210 }
 211
 212 # read-only
 213 sub query {
 214         my ($self, $query_string, $opts) = @_;
 215         my $query = $self->qp->parse_query($query_string, QP_FLAGS);
 216
 217         $query = Search::Xapian::Query->new(OP_AND, $mail_query, $query);
 218         $self->do_enquire($query, $opts);
 219 }
 220
 221 sub get_subject_path {
 222         my ($self, $path, $opts) = @_;
 223         my $query = $self->qp->parse_query("path:".mid_compressed($path), 0);
 224         $self->do_enquire($query);
 225 }
 226
 227 # given a message ID, get followups to a message
 228 sub get_followups {
 229         my ($self, $mid, $opts) = @_;
 230         $mid = mid_clean($mid);
 231         $mid = mid_compressed($mid);
 232         my $qp = $self->qp;
 233         my $irt = $qp->parse_query("inreplyto:$mid", 0);
 234         my $ref = $qp->parse_query("references:$mid", 0);
 235         my $query = Search::Xapian::Query->new(OP_OR, $irt, $ref);
 236
 237         $self->do_enquire($query);
 238 }
 239
 240 sub get_thread {
 241         my ($self, $mid, $opts) = @_;
 242         my $smsg = eval { $self->lookup_message($mid) };
 243
 244         return { count => 0, msgs => [] } unless $smsg;
 245         my $qp = $self->qp;
 246         my $qtid = $qp->parse_query('thread:'.$smsg->thread_id);
 247         my $qsub = $qp->parse_query('path:'.mid_compressed($smsg->path));
 248         my $query = Search::Xapian::Query->new(OP_OR, $qtid, $qsub);
 249         $self->do_enquire($query);
 250 }
 251
 252 # private subs below
 253
 254 sub do_enquire {
 255         my ($self, $query, $opts) = @_;
 256         my $enquire = $self->enquire;
 257
 258         $enquire->set_query($query);
 259         $enquire->set_sort_by_relevance_then_value(TS, 0);
 260         $opts ||= {};
 261         my $offset = $opts->{offset} || 0;
 262         my $limit = $opts->{limit} || 50;
 263         my $mset = $enquire->get_mset($offset, $limit);
 264         my @msgs = map {
 265                 PublicInbox::SearchMsg->load_doc($_->get_document);
 266         } $mset->items;
 267
 268         { count => $mset->get_matches_estimated, msgs => \@msgs }
 269 }
 270
 271 # read-write
 272 sub stemmer { Search::Xapian::Stem->new($LANG) }
 273
 274 # read-only
 275 sub qp {
 276         my ($self) = @_;
 277
 278         my $qp = $self->{query_parser};
 279         return $qp if $qp;
 280
 281         # new parser
 282         $qp = Search::Xapian::QueryParser->new;
 283         $qp->set_default_op(OP_AND);
 284         $qp->set_database($self->{xdb});
 285         $qp->set_stemmer($self->stemmer);
 286         $qp->set_stemming_strategy(STEM_SOME);
 287         $qp->add_valuerangeprocessor($self->ts_range_processor);
 288         $qp->add_valuerangeprocessor($self->date_range_processor);
 289
 290         while (my ($name, $prefix) = each %bool_pfx_external) {
 291                 $qp->add_boolean_prefix($name, $prefix);
 292         }
 293
 294         while (my ($name, $prefix) = each %prob_prefix) {
 295                 $qp->add_prefix($name, $prefix);
 296         }
 297
 298         $self->{query_parser} = $qp;
 299 }
 300
 301 sub term_generator { # write-only
 302         my ($self) = @_;
 303
 304         my $tg = $self->{term_generator};
 305         return $tg if $tg;
 306
 307         $tg = Search::Xapian::TermGenerator->new;
 308         $tg->set_stemmer($self->stemmer);
 309
 310         $self->{term_generator} = $tg;
 311 }
 312
 313 sub next_doc_id { $_[0]->{xdb}->get_lastdocid + 1 }
 314
 315 # increments last_thread_id counter
 316 # returns a 64-bit integer represented as a hex string
 317 sub next_thread_id {
 318         my ($self) = @_;
 319         my $db = $self->{xdb};
 320         my $last_thread_id = int($db->get_metadata('last_thread_id') || 0);
 321
 322         $db->set_metadata('last_thread_id', ++$last_thread_id);
 323
 324         $last_thread_id;
 325 }
 326
 327 sub ts_range_processor {
 328         $_[0]->{tsrp} ||= Search::Xapian::NumberValueRangeProcessor->new(TS);
 329 }
 330
 331 sub date_range_processor {
 332         $_[0]->{drp} ||= Search::Xapian::DateValueRangeProcessor->new(TS);
 333 }
 334
 335 sub link_message {
 336         my ($self, $smsg, $is_ghost) = @_;
 337
 338         if ($is_ghost) {
 339                 $smsg->ensure_metadata;
 340         } else {
 341                 $self->link_message_to_parents($smsg);
 342         }
 343 }
 344
 345 sub link_message_to_parents {
 346         my ($self, $smsg) = @_;
 347         my $doc = $smsg->{doc};
 348         my $mid = mid_compressed($smsg->mid);
 349         my $mime = $smsg->mime;
 350         my $refs = $mime->header_obj->header_raw('References');
 351         my @refs = $refs ? ($refs =~ /<([^>]+)>/g) : ();
 352         my $irt = $mime->header_obj->header_raw('In-Reply-To');
 353         if ($irt) {
 354                 if ($irt =~ /<([^>]+)>/) {
 355                         $irt = $1;
 356                 }
 357
 358                 # maybe some crazies will try to make a circular reference:
 359                 if ($irt eq $mid) {
 360                         $irt = undef;
 361                 } else {
 362                         push @refs, $irt;
 363                 }
 364         }
 365
 366         my $tid;
 367         if (@refs) {
 368                 my @crefs = map { mid_compressed($_) } @refs;
 369                 my %uniq = ($mid => 1);
 370
 371                 # prevent circular references via References: here:
 372                 @refs = ();
 373                 foreach my $ref (@crefs) {
 374                         next if $uniq{$ref};
 375                         $uniq{$ref} = 1;
 376                         push @refs, $ref;
 377                 }
 378                 $irt = undef if (defined $irt && !$uniq{$irt});
 379         }
 380         if (@refs) {
 381                 if (defined $irt) {
 382                         $doc->add_term(xpfx('inreplyto') . $irt);
 383                 }
 384
 385                 my $ref_pfx = xpfx('references');
 386
 387                 # first ref *should* be the thread root,
 388                 # but we can never trust clients to do the right thing
 389                 my $ref = shift @refs;
 390                 $doc->add_term($ref_pfx . $ref);
 391                 $tid = $self->_resolve_mid_to_tid($ref);
 392
 393                 # the rest of the refs should point to this tid:
 394                 foreach $ref (@refs) {
 395                         $doc->add_term($ref_pfx . $ref);
 396                         my $ptid = $self->_resolve_mid_to_tid($ref);
 397                         if ($tid ne $ptid) {
 398                                 $self->merge_threads($tid, $ptid);
 399                         }
 400                 }
 401         } else {
 402                 $tid = $self->next_thread_id;
 403         }
 404         $doc->add_term(xpfx('thread') . $tid);
 405 }
 406
 407 sub lookup_message {
 408         my ($self, $mid) = @_;
 409         $mid = mid_clean($mid);
 410         $mid = mid_compressed($mid);
 411
 412         my $doc_id = $self->find_unique_doc_id('mid', $mid);
 413         my $smsg;
 414         if (defined $doc_id) {
 415                 # raises on error:
 416                 my $doc = $self->{xdb}->get_document($doc_id);
 417                 $smsg = PublicInbox::SearchMsg->wrap($doc, $mid);
 418                 $smsg->doc_id($doc_id);
 419         }
 420         $smsg;
 421 }
 422
 423 sub find_unique_doc_id {
 424         my ($self, $term, $value) = @_;
 425
 426         my ($begin, $end) = $self->find_doc_ids($term, $value);
 427
 428         return undef if $begin->equal($end); # not found
 429
 430         my $rv = $begin->get_docid;
 431
 432         # sanity check
 433         $begin->inc;
 434         $begin->equal($end) or die "Term '$term:$value' is not unique\n";
 435         $rv;
 436 }
 437
 438 # returns begin and end PostingIterator
 439 sub find_doc_ids {
 440         my ($self, $term, $value) = @_;
 441
 442         $self->find_doc_ids_for_term(xpfx($term) . $value);
 443 }
 444
 445 # returns begin and end PostingIterator
 446 sub find_doc_ids_for_term {
 447         my ($self, $term) = @_;
 448         my $db = $self->{xdb};
 449
 450         ($db->postlist_begin($term), $db->postlist_end($term));
 451 }
 452
 453 # this will create a ghost as necessary
 454 sub _resolve_mid_to_tid {
 455         my ($self, $mid) = @_;
 456
 457         my $smsg = $self->lookup_message($mid) || $self->create_ghost($mid);
 458         $smsg->thread_id;
 459 }
 460
 461 sub create_ghost {
 462         my ($self, $mid, $tid) = @_;
 463
 464         $mid = mid_compressed($mid);
 465         $tid = $self->next_thread_id unless defined $tid;
 466
 467         my $doc = Search::Xapian::Document->new;
 468         $doc->add_term(xpfx('mid') . $mid);
 469         $doc->add_term(xpfx('thread') . $tid);
 470         $doc->add_term(xpfx('type') . 'ghost');
 471
 472         my $smsg = PublicInbox::SearchMsg->wrap($doc, $mid);
 473         $self->link_message($smsg, 1);
 474         $self->{xdb}->add_document($doc);
 475
 476         $smsg;
 477 }
 478
 479 sub merge_threads {
 480         my ($self, $winner_tid, $loser_tid) = @_;
 481         my ($head, $tail) = $self->find_doc_ids('thread', $loser_tid);
 482         my $thread_pfx = xpfx('thread');
 483         my $db = $self->{xdb};
 484
 485         for (; $head != $tail; $head->inc) {
 486                 my $docid = $head->get_docid;
 487                 my $doc = $db->get_document($docid);
 488                 $doc->remove_term($thread_pfx . $loser_tid);
 489                 $doc->add_term($thread_pfx . $winner_tid);
 490                 $db->replace_document($docid, $doc);
 491         }
 492 }
 493
 494 # normalize subjects so they are suitable as pathnames for URLs
 495 sub subject_path {
 496         my $subj = pop;
 497         $subj = subject_normalized($subj);
 498         $subj =~ s![^a-zA-Z0-9_\.~/\-]+!_!g;
 499         lc($subj);
 500 }
 501
 502 sub subject_normalized {
 503         my $subj = pop;
 504         $subj =~ s/\A\s+//s; # no leading space
 505         $subj =~ s/\s+\z//s; # no trailing space
 506         $subj =~ s/\s+/ /gs; # no redundant spaces
 507         $subj =~ s/\.+\z//; # no trailing '.'
 508         $subj =~ s/$REPLY_RE//igo; # remove reply prefix
 509         $subj;
 510 }
 511
 512 sub do_cat_mail {
 513         my ($git, $blob) = @_;
 514         my $mime = eval {
 515                 my $str = $git->cat_file($blob);
 516                 Email::MIME->new($str);
 517         };
 518         $@ ? undef : $mime;
 519 }
 520
 521 sub index_blob {
 522         my ($self, $git, $blob) = @_;
 523         my $mime = do_cat_mail($git, $blob) or return;
 524         eval { $self->add_message($mime) };
 525         warn "W: index_blob $blob: $@\n" if $@;
 526 }
 527
 528 sub unindex_blob {
 529         my ($self, $git, $blob) = @_;
 530         my $mime = do_cat_mail($git, $blob) or return;
 531         my $mid = $mime->header_obj->header_raw('Message-ID');
 532         eval { $self->remove_message($mid) } if defined $mid;
 533         warn "W: unindex_blob $blob: $@\n" if $@;
 534 }
 535
 536 sub enquire {
 537         my ($self) = @_;
 538         $self->{enquire} ||= Search::Xapian::Enquire->new($self->{xdb});
 539 }
 540
 541 # indexes all unindexed messages
 542 sub index_sync {
 543         my ($self) = @_;
 544         require PublicInbox::GitCatFile;
 545         my $db = $self->{xdb};
 546         my $hex = '[a-f0-9]';
 547         my $h40 = $hex .'{40}';
 548         my $addmsg = qr!^:000000 100644 \S+ ($h40) A\t${hex}{2}/${hex}{38}$!;
 549         my $delmsg = qr!^:100644 000000 ($h40) \S+ D\t${hex}{2}/${hex}{38}$!;
 550
 551         $db->begin_transaction;
 552         eval {
 553                 my $git = PublicInbox::GitCatFile->new($self->{git_dir});
 554
 555                 my $latest = $db->get_metadata('last_commit');
 556                 my $range = length $latest ? "$latest..HEAD" : 'HEAD';
 557                 $latest = undef;
 558
 559                 # get indexed messages
 560                 my @cmd = ('git', "--git-dir=$self->{git_dir}", "log",
 561                             qw/--reverse --no-notes --no-color --raw -r
 562                                --no-abbrev/, $range);
 563                 my $pid = open(my $log, '-|', @cmd) or
 564                         die('open` '.join(' ', @cmd) . " pipe failed: $!\n");
 565
 566                 while (my $line = <$log>) {
 567                         if ($line =~ /$addmsg/o) {
 568                                 $self->index_blob($git, $1);
 569                         } elsif ($line =~ /$delmsg/o) {
 570                                 $self->unindex_blob($git, $1);
 571                         } elsif ($line =~ /^commit ($h40)/o) {
 572                                 $latest = $1;
 573                         }
 574                 }
 575                 close $log;
 576                 $db->set_metadata('last_commit', $latest) if defined $latest;
 577         };
 578         if ($@) {
 579                 warn "indexing failed: $@\n";
 580                 $db->cancel_transaction;
 581         } else {
 582                 $db->commit_transaction;
 583         }
 584 }
 585
 586 1;