lib/PublicInbox/Search.pm

   1 # Copyright (C) 2015-2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 # based on notmuch, but with no concept of folders, files or flags
   4 #
   5 # Read-only search interface for use by the web and NNTP interfaces
   6 package PublicInbox::Search;
   7 use strict;
   8 use warnings;
   9
  10 # values for searching
  11 use constant TS => 0; # timestamp
  12 use constant NUM => 1; # NNTP article number
  13 use constant BYTES => 2; # :bytes as defined in RFC 3977
  14 use constant LINES => 3; # :lines as defined in RFC 3977
  15 use constant YYYYMMDD => 4; # for searching in the WWW UI
  16
  17 use Search::Xapian qw/:standard/;
  18 use PublicInbox::SearchMsg;
  19 use PublicInbox::MIME;
  20 use PublicInbox::MID qw/mid_clean id_compress/;
  21
  22 # This is English-only, everything else is non-standard and may be confused as
  23 # a prefix common in patch emails
  24 our $REPLY_RE = qr/^re:\s+/i;
  25 our $LANG = 'english';
  26
  27 use constant {
  28         # SCHEMA_VERSION history
  29         # 0 - initial
  30         # 1 - subject_path is lower-cased
  31         # 2 - subject_path is id_compress in the index, only
  32         # 3 - message-ID is compressed if it includes '%' (hack!)
  33         # 4 - change "Re: " normalization, avoid circular Reference ghosts
  34         # 5 - subject_path drops trailing '.'
  35         # 6 - preserve References: order in document data
  36         # 7 - remove references and inreplyto terms
  37         # 8 - remove redundant/unneeded document data
  38         # 9 - disable Message-ID compression (SHA-1)
  39         # 10 - optimize doc for NNTP overviews
  40         # 11 - merge threads when vivifying ghosts
  41         # 12 - change YYYYMMDD value column to numeric
  42         # 13 - fix threading for empty References/In-Reply-To
  43         #      (commit 83425ef12e4b65cdcecd11ddcb38175d4a91d5a0)
  44         # 14 - fix ghost root vivification
  45         SCHEMA_VERSION => 14,
  46
  47         # n.b. FLAG_PURE_NOT is expensive not suitable for a public website
  48         # as it could become a denial-of-service vector
  49         QP_FLAGS => FLAG_PHRASE|FLAG_BOOLEAN|FLAG_LOVEHATE|FLAG_WILDCARD,
  50 };
  51
  52 # setup prefixes
  53 my %bool_pfx_internal = (
  54         type => 'T', # "mail" or "ghost"
  55         thread => 'G', # newsGroup (or similar entity - e.g. a web forum name)
  56 );
  57
  58 my %bool_pfx_external = (
  59         mid => 'XMID', # Message-ID (full/exact)
  60 );
  61
  62 my %prob_prefix = (
  63         # for mairix compatibility
  64         s => 'S',
  65         m => 'XM', # 'mid:' (bool) is exact, 'm:' (prob) can do partial
  66         f => 'A',
  67         t => 'XTO',
  68         tc => 'XTO XCC',
  69         c => 'XCC',
  70         tcf => 'XTO XCC A',
  71         a => 'XTO XCC A',
  72         b => 'XNQ XQUOT',
  73         bs => 'XNQ XQUOT S',
  74         n => 'XFN',
  75
  76         q => 'XQUOT',
  77         nq => 'XNQ',
  78         dfn => 'XDFN',
  79         dfa => 'XDFA',
  80         dfb => 'XDFB',
  81         dfhh => 'XDFHH',
  82         dfctx => 'XDFCTX',
  83         dfpre => 'XDFPRE',
  84         dfpost => 'XDFPOST',
  85         dfblob => 'XDFPRE XDFPOST',
  86
  87         # default:
  88         '' => 'XM S A XNQ XQUOT XFN',
  89 );
  90
  91 # not documenting m: and mid: for now, the using the URLs works w/o Xapian
  92 our @HELP = (
  93         's:' => 'match within Subject  e.g. s:"a quick brown fox"',
  94         'd:' => <<EOF,
  95 date range as YYYYMMDD  e.g. d:19931002..20101002
  96 Open-ended ranges such as d:19931002.. and d:..20101002
  97 are also supported
  98 EOF
  99         'b:' => 'match within message body, including text attachments',
 100         'nq:' => 'match non-quoted text within message body',
 101         'q:' => 'match quoted text within message body',
 102         'n:' => 'match filename of attachment(s)',
 103         't:' => 'match within the To header',
 104         'c:' => 'match within the Cc header',
 105         'f:' => 'match within the From header',
 106         'a:' => 'match within the To, Cc, and From headers',
 107         'tc:' => 'match within the To and Cc headers',
 108         'bs:' => 'match within the Subject and body',
 109         'dfn:' => 'match filename from diff',
 110         'dfa:' => 'match diff removed (-) lines',
 111         'dfb:' => 'match diff added (+) lines',
 112         'dfhh:' => 'match diff hunk header context (usually a function name)',
 113         'dfctx:' => 'match diff context lines',
 114         'dfpre:' => 'match pre-image git blob ID',
 115         'dfpost:' => 'match post-image git blob ID',
 116         'dfblob:' => 'match either pre or post-image git blob ID',
 117 );
 118 chomp @HELP;
 119
 120 my $mail_query = Search::Xapian::Query->new('T' . 'mail');
 121
 122 sub xdir {
 123         my ($self) = @_;
 124         if ($self->{version} == 1) {
 125                 "$self->{mainrepo}/public-inbox/xapian" . SCHEMA_VERSION;
 126         } else {
 127                 my $dir = "$self->{mainrepo}/xap" . SCHEMA_VERSION;
 128                 my $part = $self->{partition};
 129                 defined $part or die "partition not given";
 130                 $dir .= "/$part";
 131         }
 132 }
 133
 134 sub new {
 135         my ($class, $mainrepo, $altid) = @_;
 136         my $version = 1;
 137         my $ibx = $mainrepo;
 138         if (ref $ibx) {
 139                 $version = $ibx->{version} || 1;
 140                 $mainrepo = $ibx->{mainrepo};
 141         }
 142         my $self = bless {
 143                 mainrepo => $mainrepo,
 144                 altid => $altid,
 145                 version => $version,
 146         }, $class;
 147         $self->{xdb} = Search::Xapian::Database->new($self->xdir);
 148         $self;
 149 }
 150
 151 sub reopen { $_[0]->{xdb}->reopen }
 152
 153 # read-only
 154 sub query {
 155         my ($self, $query_string, $opts) = @_;
 156         my $query;
 157
 158         $opts ||= {};
 159         unless ($query_string eq '') {
 160                 $query = $self->qp->parse_query($query_string, QP_FLAGS);
 161                 $opts->{relevance} = 1 unless exists $opts->{relevance};
 162         }
 163
 164         _do_enquire($self, $query, $opts);
 165 }
 166
 167 sub get_thread {
 168         my ($self, $mid, $opts) = @_;
 169         my $smsg = eval { $self->lookup_message($mid) };
 170
 171         return { total => 0, msgs => [] } unless $smsg;
 172         my $qtid = Search::Xapian::Query->new('G' . $smsg->thread_id);
 173         my $path = $smsg->path;
 174         if (defined $path && $path ne '') {
 175                 my $path = id_compress($smsg->path);
 176                 my $qsub = Search::Xapian::Query->new('XPATH' . $path);
 177                 $qtid = Search::Xapian::Query->new(OP_OR, $qtid, $qsub);
 178         }
 179         $opts ||= {};
 180         $opts->{limit} ||= 1000;
 181
 182         # always sort threads by timestamp, this makes life easier
 183         # for the threading algorithm (in SearchThread.pm)
 184         $opts->{asc} = 1;
 185
 186         _do_enquire($self, $qtid, $opts);
 187 }
 188
 189 sub retry_reopen {
 190         my ($self, $cb) = @_;
 191         my $ret;
 192         for (1..10) {
 193                 eval { $ret = $cb->() };
 194                 return $ret unless $@;
 195                 # Exception: The revision being read has been discarded -
 196                 # you should call Xapian::Database::reopen()
 197                 if (ref($@) eq 'Search::Xapian::DatabaseModifiedError') {
 198                         reopen($self);
 199                 } else {
 200                         die;
 201                 }
 202         }
 203 }
 204
 205 sub _do_enquire {
 206         my ($self, $query, $opts) = @_;
 207         retry_reopen($self, sub { _enquire_once($self, $query, $opts) });
 208 }
 209
 210 sub _enquire_once {
 211         my ($self, $query, $opts) = @_;
 212         my $enquire = $self->enquire;
 213         if (defined $query) {
 214                 $query = Search::Xapian::Query->new(OP_AND,$query,$mail_query);
 215         } else {
 216                 $query = $mail_query;
 217         }
 218         $enquire->set_query($query);
 219         $opts ||= {};
 220         my $desc = !$opts->{asc};
 221         if ($opts->{relevance}) {
 222                 $enquire->set_sort_by_relevance_then_value(TS, $desc);
 223         } elsif ($opts->{num}) {
 224                 $enquire->set_sort_by_value(NUM, 0);
 225         } else {
 226                 $enquire->set_sort_by_value_then_relevance(TS, $desc);
 227         }
 228         my $offset = $opts->{offset} || 0;
 229         my $limit = $opts->{limit} || 50;
 230         my $mset = $enquire->get_mset($offset, $limit);
 231         return $mset if $opts->{mset};
 232         my @msgs = map {
 233                 PublicInbox::SearchMsg->load_doc($_->get_document);
 234         } $mset->items;
 235
 236         { total => $mset->get_matches_estimated, msgs => \@msgs }
 237 }
 238
 239 # read-write
 240 sub stemmer { Search::Xapian::Stem->new($LANG) }
 241
 242 # read-only
 243 sub qp {
 244         my ($self) = @_;
 245
 246         my $qp = $self->{query_parser};
 247         return $qp if $qp;
 248
 249         # new parser
 250         $qp = Search::Xapian::QueryParser->new;
 251         $qp->set_default_op(OP_AND);
 252         $qp->set_database($self->{xdb});
 253         $qp->set_stemmer($self->stemmer);
 254         $qp->set_stemming_strategy(STEM_SOME);
 255         $qp->add_valuerangeprocessor(
 256                 Search::Xapian::NumberValueRangeProcessor->new(YYYYMMDD, 'd:'));
 257
 258         while (my ($name, $prefix) = each %bool_pfx_external) {
 259                 $qp->add_boolean_prefix($name, $prefix);
 260         }
 261
 262         # we do not actually create AltId objects,
 263         # just parse the spec to avoid the extra DB handles for now.
 264         if (my $altid = $self->{altid}) {
 265                 my $user_pfx = $self->{-user_pfx} ||= [];
 266                 for (@$altid) {
 267                         # $_ = 'serial:gmane:/path/to/gmane.msgmap.sqlite3'
 268                         /\Aserial:(\w+):/ or next;
 269                         my $pfx = $1;
 270                         push @$user_pfx, "$pfx:", <<EOF;
 271 alternate serial number  e.g. $pfx:12345 (boolean)
 272 EOF
 273                         # gmane => XGMANE
 274                         $qp->add_boolean_prefix($pfx, 'X'.uc($pfx));
 275                 }
 276                 chomp @$user_pfx;
 277         }
 278
 279         while (my ($name, $prefix) = each %prob_prefix) {
 280                 $qp->add_prefix($name, $_) foreach split(/ /, $prefix);
 281         }
 282
 283         $self->{query_parser} = $qp;
 284 }
 285
 286 sub num_range_processor {
 287         $_[0]->{nrp} ||= Search::Xapian::NumberValueRangeProcessor->new(NUM);
 288 }
 289
 290 # only used for NNTP server
 291 sub query_xover {
 292         my ($self, $beg, $end, $offset) = @_;
 293         my $qp = Search::Xapian::QueryParser->new;
 294         $qp->set_database($self->{xdb});
 295         $qp->add_valuerangeprocessor($self->num_range_processor);
 296         my $query = $qp->parse_query("$beg..$end", QP_FLAGS);
 297
 298         _do_enquire($self, $query, {num => 1, limit => 200, offset => $offset});
 299 }
 300
 301 sub lookup_message {
 302         my ($self, $mid) = @_;
 303         $mid = mid_clean($mid);
 304
 305         my $doc_id = $self->find_first_doc_id('XMID' . $mid);
 306         my $smsg;
 307         if (defined $doc_id) {
 308                 # raises on error:
 309                 my $doc = $self->{xdb}->get_document($doc_id);
 310                 $smsg = PublicInbox::SearchMsg->wrap($doc, $mid);
 311                 $smsg->{doc_id} = $doc_id;
 312         }
 313         $smsg;
 314 }
 315
 316 sub lookup_mail { # no ghosts!
 317         my ($self, $mid) = @_;
 318         retry_reopen($self, sub {
 319                 my $smsg = lookup_message($self, $mid) or return;
 320                 $smsg->load_expand;
 321         });
 322 }
 323
 324 sub find_unique_doc_id {
 325         my ($self, $termval) = @_;
 326
 327         my ($begin, $end) = $self->find_doc_ids($termval);
 328
 329         return undef if $begin->equal($end); # not found
 330
 331         my $rv = $begin->get_docid;
 332
 333         # sanity check
 334         $begin->inc;
 335         $begin->equal($end) or die "Term '$termval' is not unique\n";
 336         $rv;
 337 }
 338
 339 # returns begin and end PostingIterator
 340 sub find_doc_ids {
 341         my ($self, $termval) = @_;
 342         my $db = $self->{xdb};
 343
 344         ($db->postlist_begin($termval), $db->postlist_end($termval));
 345 }
 346
 347 sub find_first_doc_id {
 348         my ($self, $termval) = @_;
 349
 350         my ($begin, $end) = $self->find_doc_ids($termval);
 351
 352         return undef if $begin->equal($end); # not found
 353
 354         $begin->get_docid;
 355 }
 356
 357 # normalize subjects so they are suitable as pathnames for URLs
 358 # XXX: consider for removal
 359 sub subject_path {
 360         my $subj = pop;
 361         $subj = subject_normalized($subj);
 362         $subj =~ s![^a-zA-Z0-9_\.~/\-]+!_!g;
 363         lc($subj);
 364 }
 365
 366 sub subject_normalized {
 367         my $subj = pop;
 368         $subj =~ s/\A\s+//s; # no leading space
 369         $subj =~ s/\s+\z//s; # no trailing space
 370         $subj =~ s/\s+/ /gs; # no redundant spaces
 371         $subj =~ s/\.+\z//; # no trailing '.'
 372         $subj =~ s/$REPLY_RE//igo; # remove reply prefix
 373         $subj;
 374 }
 375
 376 sub enquire {
 377         my ($self) = @_;
 378         $self->{enquire} ||= Search::Xapian::Enquire->new($self->{xdb});
 379 }
 380
 381 sub help {
 382         my ($self) = @_;
 383         $self->qp; # parse altids
 384         my @ret = @HELP;
 385         if (my $user_pfx = $self->{-user_pfx}) {
 386                 push @ret, @$user_pfx;
 387         }
 388         \@ret;
 389 }
 390
 391 1;