lib/PublicInbox/Search.pm

   1 # Copyright (C) 2015, all contributors <meta@public-inbox.org>
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 # based on notmuch, but with no concept of folders, files or flags
   4 package PublicInbox::Search;
   5 use strict;
   6 use warnings;
   7 use PublicInbox::SearchMsg;
   8 use Search::Xapian qw/:standard/;
   9 require PublicInbox::View;
  10 use Email::MIME;
  11 use PublicInbox::MID qw/mid_clean mid_compressed/;
  12
  13 # This is English-only, everything else is non-standard and may be confused as
  14 # a prefix common in patch emails
  15 our $REPLY_RE = qr/^re:\s+/i;
  16
  17 use constant {
  18         TS => 0,
  19         # SCHEMA_VERSION history
  20         # 0 - initial
  21         # 1 - subject_path is lower-cased
  22         # 2 - subject_path is mid_compressed in the index, only
  23         # 3 - message-ID is compressed if it includes '%' (hack!)
  24         SCHEMA_VERSION => 3,
  25         LANG => 'english',
  26         QP_FLAGS => FLAG_PHRASE|FLAG_BOOLEAN|FLAG_LOVEHATE|FLAG_WILDCARD,
  27 };
  28
  29 # setup prefixes
  30 my %bool_pfx_internal = (
  31         type => 'T', # "mail" or "ghost"
  32         mid => 'Q', # uniQue id (Message-ID or mid_compressed)
  33 );
  34
  35 my %bool_pfx_external = (
  36         path => 'XPATH',
  37         thread => 'G', # newsGroup (or similar entity - e.g. a web forum name)
  38         references => 'XREFS',
  39         inreplyto => 'XIRT',
  40 );
  41
  42 my %prob_prefix = (
  43         subject => 'S',
  44 );
  45
  46 my %all_pfx = (%bool_pfx_internal, %bool_pfx_external, %prob_prefix);
  47
  48 sub xpfx { $all_pfx{$_[0]} }
  49
  50 our %PFX2TERM_RMAP;
  51 while (my ($k, $v) = each %all_pfx) {
  52         next if $prob_prefix{$k};
  53         $PFX2TERM_RMAP{$v} = $k;
  54 }
  55
  56 my $mail_query = Search::Xapian::Query->new(xpfx('type') . 'mail');
  57
  58 sub new {
  59         my ($class, $git_dir, $writable) = @_;
  60         # allow concurrent versions for easier rollback:
  61         my $dir = "$git_dir/public-inbox/xapian" . SCHEMA_VERSION;
  62         my $db;
  63
  64         if ($writable) { # not used by the WWW interface
  65                 require Search::Xapian::WritableDatabase;
  66                 my $flag = Search::Xapian::DB_OPEN;
  67                 if ($writable == 1) {
  68                         require File::Path;
  69                         File::Path::mkpath($dir);
  70                         $flag = Search::Xapian::DB_CREATE_OR_OPEN;
  71                 }
  72                 $db = Search::Xapian::WritableDatabase->new($dir, $flag);
  73         } else {
  74                 $db = Search::Xapian::Database->new($dir);
  75         }
  76         bless { xdb => $db, git_dir => $git_dir }, $class;
  77 }
  78
  79 sub reopen { $_[0]->{xdb}->reopen }
  80
  81 sub add_message {
  82         my ($self, $mime) = @_; # mime = Email::MIME object
  83         my $db = $self->{xdb};
  84
  85         my $doc_id;
  86         my $mid_orig = mid_clean($mime->header_obj->header_raw('Message-ID'));
  87         my $mid = mid_compressed($mid_orig);
  88         my $was_ghost = 0;
  89         my $ct_msg = $mime->header('Content-Type') || 'text/plain';
  90         my $enc_msg = PublicInbox::View::enc_for($ct_msg);
  91
  92         eval {
  93                 my $smsg = $self->lookup_message($mid);
  94                 my $doc;
  95
  96                 if ($smsg) {
  97                         $smsg->ensure_metadata;
  98                         # convert a ghost to a regular message
  99                         # it will also clobber any existing regular message
 100                         $smsg->mime($mime);
 101                         $doc = $smsg->{doc};
 102
 103                         my $type = xpfx('type');
 104                         eval {
 105                                 $doc->remove_term($type . 'ghost');
 106                                 $was_ghost = 1;
 107                         };
 108
 109                         # probably does not exist:
 110                         eval { $doc->remove_term($type . 'mail') };
 111                         $doc->add_term($type . 'mail');
 112                 }  else {
 113                         $smsg = PublicInbox::SearchMsg->new($mime);
 114                         $doc = $smsg->{doc};
 115                         $doc->add_term(xpfx('mid') . $mid);
 116                 }
 117
 118                 my $subj = $smsg->subject;
 119
 120                 if (length $subj) {
 121                         $doc->add_term(xpfx('subject') . $subj);
 122
 123                         my $path = subject_path($subj);
 124                         $doc->add_term(xpfx('path') . mid_compressed($path));
 125                 }
 126
 127                 my $from = $smsg->from_name;
 128                 my $date = $smsg->date;
 129                 my $ts = Search::Xapian::sortable_serialise($smsg->ts);
 130                 $doc->add_value(PublicInbox::Search::TS, $ts);
 131
 132                 $doc->set_data($smsg->to_doc_data);
 133
 134                 my $tg = $self->term_generator;
 135
 136                 $tg->set_document($doc);
 137                 $tg->index_text($subj, 1, 'S') if $subj;
 138                 $tg->increase_termpos;
 139                 $tg->index_text($subj) if $subj;
 140                 $tg->increase_termpos;
 141
 142                 $tg->index_text($smsg->from->format);
 143                 $tg->increase_termpos;
 144
 145                 $mime->walk_parts(sub {
 146                         my ($part) = @_;
 147                         return if $part->subparts; # walk_parts already recurses
 148                         my $ct = $part->content_type || $ct_msg;
 149
 150                         # account for filter bugs...
 151                         $ct =~ m!\btext/plain\b!i or return;
 152
 153                         my $enc = PublicInbox::View::enc_for($ct, $enc_msg);
 154                         my (@orig, @quot);
 155                         foreach my $l (split(/\n/, $enc->decode($part->body))) {
 156                                 if ($l =~ /^\s*>/) {
 157                                         push @quot, $l;
 158                                 } else {
 159                                         push @orig, $l;
 160                                 }
 161                         }
 162                         if (@quot) {
 163                                 $tg->index_text(join("\n", @quot), 0);
 164                                 $tg->increase_termpos;
 165                         }
 166                         if (@orig) {
 167                                 $tg->index_text(join("\n", @orig));
 168                                 $tg->increase_termpos;
 169                         }
 170                 });
 171
 172                 if ($was_ghost) {
 173                         $doc_id = $smsg->doc_id;
 174                         $self->link_message($smsg, 0);
 175                         $db->replace_document($doc_id, $doc);
 176                 } else {
 177                         $self->link_message($smsg, 0);
 178                         $doc_id = $db->add_document($doc);
 179                 }
 180         };
 181
 182         if ($@) {
 183                 warn "failed to index message <$mid_orig>: $@\n";
 184                 return undef;
 185         }
 186         $doc_id;
 187 }
 188
 189 # returns deleted doc_id on success, undef on missing
 190 sub remove_message {
 191         my ($self, $mid_orig) = @_;
 192         my $db = $self->{xdb};
 193         my $doc_id;
 194         $mid_orig = mid_clean($mid_orig);
 195         my $mid = mid_compressed($mid_orig);
 196
 197         eval {
 198                 $doc_id = $self->find_unique_doc_id('mid', $mid);
 199                 $db->delete_document($doc_id) if defined $doc_id;
 200         };
 201
 202         if ($@) {
 203                 warn "failed to remove message <$mid_orig>: $@\n";
 204                 return undef;
 205         }
 206         $doc_id;
 207 }
 208
 209 # read-only
 210 sub query {
 211         my ($self, $query_string, $opts) = @_;
 212         my $query = $self->qp->parse_query($query_string, QP_FLAGS);
 213
 214         $query = Search::Xapian::Query->new(OP_AND, $mail_query, $query);
 215         $self->do_enquire($query, $opts);
 216 }
 217
 218 sub get_subject_path {
 219         my ($self, $path, $opts) = @_;
 220         my $query = $self->qp->parse_query("path:".mid_compressed($path), 0);
 221         $self->do_enquire($query);
 222 }
 223
 224 # given a message ID, get followups to a message
 225 sub get_followups {
 226         my ($self, $mid, $opts) = @_;
 227         $mid = mid_clean($mid);
 228         $mid = mid_compressed($mid);
 229         my $qp = $self->qp;
 230         my $irt = $qp->parse_query("inreplyto:$mid", 0);
 231         my $ref = $qp->parse_query("references:$mid", 0);
 232         my $query = Search::Xapian::Query->new(OP_OR, $irt, $ref);
 233
 234         $self->do_enquire($query);
 235 }
 236
 237 sub get_thread {
 238         my ($self, $mid, $opts) = @_;
 239         my $smsg = eval { $self->lookup_message($mid) };
 240
 241         return { count => 0, msgs => [] } unless $smsg;
 242         my $qp = $self->qp;
 243         my $qtid = $qp->parse_query('thread:'.$smsg->thread_id);
 244         my $qsub = $qp->parse_query('path:'.mid_compressed($smsg->path));
 245         my $query = Search::Xapian::Query->new(OP_OR, $qtid, $qsub);
 246         $self->do_enquire($query);
 247 }
 248
 249 # private subs below
 250
 251 sub do_enquire {
 252         my ($self, $query, $opts) = @_;
 253         my $enquire = $self->enquire;
 254
 255         $enquire->set_query($query);
 256         $enquire->set_sort_by_relevance_then_value(TS, 0);
 257         $opts ||= {};
 258         my $offset = $opts->{offset} || 0;
 259         my $limit = $opts->{limit} || 50;
 260         my $mset = $enquire->get_mset($offset, $limit);
 261         my @msgs = map {
 262                 PublicInbox::SearchMsg->load_doc($_->get_document);
 263         } $mset->items;
 264
 265         { count => $mset->get_matches_estimated, msgs => \@msgs }
 266 }
 267
 268 # read-write
 269 sub stemmer { Search::Xapian::Stem->new(LANG) }
 270
 271 # read-only
 272 sub qp {
 273         my ($self) = @_;
 274
 275         my $qp = $self->{query_parser};
 276         return $qp if $qp;
 277
 278         # new parser
 279         $qp = Search::Xapian::QueryParser->new;
 280         $qp->set_default_op(OP_AND);
 281         $qp->set_database($self->{xdb});
 282         $qp->set_stemmer($self->stemmer);
 283         $qp->set_stemming_strategy(STEM_SOME);
 284         $qp->add_valuerangeprocessor($self->ts_range_processor);
 285         $qp->add_valuerangeprocessor($self->date_range_processor);
 286
 287         while (my ($name, $prefix) = each %bool_pfx_external) {
 288                 $qp->add_boolean_prefix($name, $prefix);
 289         }
 290
 291         while (my ($name, $prefix) = each %prob_prefix) {
 292                 $qp->add_prefix($name, $prefix);
 293         }
 294
 295         $self->{query_parser} = $qp;
 296 }
 297
 298 sub term_generator { # write-only
 299         my ($self) = @_;
 300
 301         my $tg = $self->{term_generator};
 302         return $tg if $tg;
 303
 304         $tg = Search::Xapian::TermGenerator->new;
 305         $tg->set_stemmer($self->stemmer);
 306
 307         $self->{term_generator} = $tg;
 308 }
 309
 310 sub next_doc_id { $_[0]->{xdb}->get_lastdocid + 1 }
 311
 312 # increments last_thread_id counter
 313 # returns a 64-bit integer represented as a hex string
 314 sub next_thread_id {
 315         my ($self) = @_;
 316         my $db = $self->{xdb};
 317         my $last_thread_id = int($db->get_metadata('last_thread_id') || 0);
 318
 319         $db->set_metadata('last_thread_id', ++$last_thread_id);
 320
 321         $last_thread_id;
 322 }
 323
 324 sub ts_range_processor {
 325         $_[0]->{tsrp} ||= Search::Xapian::NumberValueRangeProcessor->new(TS);
 326 }
 327
 328 sub date_range_processor {
 329         $_[0]->{drp} ||= Search::Xapian::DateValueRangeProcessor->new(TS);
 330 }
 331
 332 sub link_message {
 333         my ($self, $smsg, $is_ghost) = @_;
 334
 335         if ($is_ghost) {
 336                 $smsg->ensure_metadata;
 337         } else {
 338                 $self->link_message_to_parents($smsg);
 339         }
 340 }
 341
 342 sub link_message_to_parents {
 343         my ($self, $smsg) = @_;
 344         my $doc = $smsg->{doc};
 345         my $mid = mid_compressed($smsg->mid);
 346         my $mime = $smsg->mime;
 347         my $refs = $mime->header_obj->header_raw('References');
 348         my @refs = $refs ? ($refs =~ /<([^>]+)>/g) : ();
 349         my $irt = $mime->header_obj->header_raw('In-Reply-To');
 350         if ($irt) {
 351                 if ($irt =~ /<([^>]+)>/) {
 352                         $irt = $1;
 353                 }
 354
 355                 # maybe some crazies will try to make a circular reference:
 356                 if ($irt eq $mid) {
 357                         $irt = undef;
 358                 } else {
 359                         push @refs, $irt;
 360                 }
 361         }
 362
 363         my $tid;
 364         if (@refs) {
 365                 my @crefs = map { mid_compressed($_) } @refs;
 366                 my %uniq = ($mid => 1);
 367
 368                 # prevent circular references via References: here:
 369                 @refs = ();
 370                 foreach my $ref (@crefs) {
 371                         next if $uniq{$ref};
 372                         $uniq{$ref} = 1;
 373                         push @refs, $ref;
 374                 }
 375                 $irt = undef if (defined $irt && !$uniq{$irt});
 376         }
 377         if (@refs) {
 378                 if (defined $irt) {
 379                         $doc->add_term(xpfx('inreplyto') . $irt);
 380                 }
 381
 382                 my $ref_pfx = xpfx('references');
 383
 384                 # first ref *should* be the thread root,
 385                 # but we can never trust clients to do the right thing
 386                 my $ref = shift @refs;
 387                 $doc->add_term($ref_pfx . $ref);
 388                 $tid = $self->_resolve_mid_to_tid($ref);
 389
 390                 # the rest of the refs should point to this tid:
 391                 foreach $ref (@refs) {
 392                         $doc->add_term($ref_pfx . $ref);
 393                         my $ptid = $self->_resolve_mid_to_tid($ref);
 394                         if ($tid ne $ptid) {
 395                                 $self->merge_threads($tid, $ptid);
 396                         }
 397                 }
 398         } else {
 399                 $tid = $self->next_thread_id;
 400         }
 401         $doc->add_term(xpfx('thread') . $tid);
 402 }
 403
 404 sub lookup_message {
 405         my ($self, $mid) = @_;
 406         $mid = mid_clean($mid);
 407         $mid = mid_compressed($mid);
 408
 409         my $doc_id = $self->find_unique_doc_id('mid', $mid);
 410         my $smsg;
 411         if (defined $doc_id) {
 412                 # raises on error:
 413                 my $doc = $self->{xdb}->get_document($doc_id);
 414                 $smsg = PublicInbox::SearchMsg->wrap($doc, $mid);
 415                 $smsg->doc_id($doc_id);
 416         }
 417         $smsg;
 418 }
 419
 420 sub find_unique_doc_id {
 421         my ($self, $term, $value) = @_;
 422
 423         my ($begin, $end) = $self->find_doc_ids($term, $value);
 424
 425         return undef if $begin->equal($end); # not found
 426
 427         my $rv = $begin->get_docid;
 428
 429         # sanity check
 430         $begin->inc;
 431         $begin->equal($end) or die "Term '$term:$value' is not unique\n";
 432         $rv;
 433 }
 434
 435 # returns begin and end PostingIterator
 436 sub find_doc_ids {
 437         my ($self, $term, $value) = @_;
 438
 439         $self->find_doc_ids_for_term(xpfx($term) . $value);
 440 }
 441
 442 # returns begin and end PostingIterator
 443 sub find_doc_ids_for_term {
 444         my ($self, $term) = @_;
 445         my $db = $self->{xdb};
 446
 447         ($db->postlist_begin($term), $db->postlist_end($term));
 448 }
 449
 450 # this will create a ghost as necessary
 451 sub _resolve_mid_to_tid {
 452         my ($self, $mid) = @_;
 453
 454         my $smsg = $self->lookup_message($mid) || $self->create_ghost($mid);
 455         $smsg->thread_id;
 456 }
 457
 458 sub create_ghost {
 459         my ($self, $mid, $tid) = @_;
 460
 461         $mid = mid_compressed($mid);
 462         $tid = $self->next_thread_id unless defined $tid;
 463
 464         my $doc = Search::Xapian::Document->new;
 465         $doc->add_term(xpfx('mid') . $mid);
 466         $doc->add_term(xpfx('thread') . $tid);
 467         $doc->add_term(xpfx('type') . 'ghost');
 468
 469         my $smsg = PublicInbox::SearchMsg->wrap($doc, $mid);
 470         $self->link_message($smsg, 1);
 471         $self->{xdb}->add_document($doc);
 472
 473         $smsg;
 474 }
 475
 476 sub merge_threads {
 477         my ($self, $winner_tid, $loser_tid) = @_;
 478         my ($head, $tail) = $self->find_doc_ids('thread', $loser_tid);
 479         my $thread_pfx = xpfx('thread');
 480         my $db = $self->{xdb};
 481
 482         for (; $head != $tail; $head->inc) {
 483                 my $docid = $head->get_docid;
 484                 my $doc = $db->get_document($docid);
 485                 $doc->remove_term($thread_pfx . $loser_tid);
 486                 $doc->add_term($thread_pfx . $winner_tid);
 487                 $db->replace_document($docid, $doc);
 488         }
 489 }
 490
 491 # normalize subjects so they are suitable as pathnames for URLs
 492 sub subject_path {
 493         my $subj = pop;
 494
 495         $subj =~ s/\A\s+//;
 496         $subj =~ s/\s+\z//;
 497         $subj =~ s/$REPLY_RE//igo; # remove reply prefix
 498         $subj =~ s![^a-zA-Z0-9_\.~/\-]+!_!g;
 499         lc($subj);
 500 }
 501
 502 sub do_cat_mail {
 503         my ($git, $blob) = @_;
 504         my $mime = eval {
 505                 my $str = $git->cat_file($blob);
 506                 Email::MIME->new($str);
 507         };
 508         $@ ? undef : $mime;
 509 }
 510
 511 sub index_blob {
 512         my ($self, $git, $blob) = @_;
 513         my $mime = do_cat_mail($git, $blob) or return;
 514         eval { $self->add_message($mime) };
 515         warn "W: index_blob $blob: $@\n" if $@;
 516 }
 517
 518 sub unindex_blob {
 519         my ($self, $git, $blob) = @_;
 520         my $mime = do_cat_mail($git, $blob) or return;
 521         my $mid = $mime->header_obj->header_raw('Message-ID');
 522         eval { $self->remove_message($mid) } if defined $mid;
 523         warn "W: unindex_blob $blob: $@\n" if $@;
 524 }
 525
 526 sub enquire {
 527         my ($self) = @_;
 528         $self->{enquire} ||= Search::Xapian::Enquire->new($self->{xdb});
 529 }
 530
 531 # indexes all unindexed messages
 532 sub index_sync {
 533         my ($self) = @_;
 534         require PublicInbox::GitCatFile;
 535         my $db = $self->{xdb};
 536         my $hex = '[a-f0-9]';
 537         my $h40 = $hex .'{40}';
 538         my $addmsg = qr!^:000000 100644 \S+ ($h40) A\t${hex}{2}/${hex}{38}$!;
 539         my $delmsg = qr!^:100644 000000 ($h40) \S+ D\t${hex}{2}/${hex}{38}$!;
 540
 541         $db->begin_transaction;
 542         eval {
 543                 my $git = PublicInbox::GitCatFile->new($self->{git_dir});
 544
 545                 my $latest = $db->get_metadata('last_commit');
 546                 my $range = length $latest ? "$latest..HEAD" : 'HEAD';
 547                 $latest = undef;
 548
 549                 # get indexed messages
 550                 my @cmd = ('git', "--git-dir=$self->{git_dir}", "log",
 551                             qw/--reverse --no-notes --no-color --raw -r
 552                                --no-abbrev/, $range);
 553                 my $pid = open(my $log, '-|', @cmd) or
 554                         die('open` '.join(' ', @cmd) . " pipe failed: $!\n");
 555
 556                 while (my $line = <$log>) {
 557                         if ($line =~ /$addmsg/o) {
 558                                 $self->index_blob($git, $1);
 559                         } elsif ($line =~ /$delmsg/o) {
 560                                 $self->unindex_blob($git, $1);
 561                         } elsif ($line =~ /^commit ($h40)/o) {
 562                                 $latest = $1;
 563                         }
 564                 }
 565                 close $log;
 566                 $db->set_metadata('last_commit', $latest) if defined $latest;
 567         };
 568         if ($@) {
 569                 warn "indexing failed: $@\n";
 570                 $db->cancel_transaction;
 571         } else {
 572                 $db->commit_transaction;
 573         }
 574 }
 575
 576 1;