lib/PublicInbox/Search.pm

   1 # Copyright (C) 2015-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 # based on notmuch, but with no concept of folders, files or flags
   4 #
   5 # Read-only search interface for use by the web and NNTP interfaces
   6 package PublicInbox::Search;
   7 use strict;
   8 use parent qw(Exporter);
   9 our @EXPORT_OK = qw(retry_reopen);
  10 use List::Util qw(max);
  11
  12 # values for searching, changing the numeric value breaks
  13 # compatibility with old indices (so don't change them it)
  14 use constant {
  15         TS => 0, # Received: header in Unix time (IMAP INTERNALDATE)
  16         YYYYMMDD => 1, # Date: header for searching in the WWW UI
  17         DT => 2, # Date: YYYYMMDDHHMMSS
  18
  19         # added for public-inbox 1.6.0+
  20         BYTES => 3, # IMAP RFC822.SIZE
  21         UID => 4, # IMAP UID == NNTP article number == Xapian docid
  22         THREADID => 5, # RFC 8474, RFC 8621
  23
  24         # TODO
  25         # REPLYCNT => ?, # IMAP ANSWERED
  26
  27         # SCHEMA_VERSION history
  28         # 0 - initial
  29         # 1 - subject_path is lower-cased
  30         # 2 - subject_path is id_compress in the index, only
  31         # 3 - message-ID is compressed if it includes '%' (hack!)
  32         # 4 - change "Re: " normalization, avoid circular Reference ghosts
  33         # 5 - subject_path drops trailing '.'
  34         # 6 - preserve References: order in document data
  35         # 7 - remove references and inreplyto terms
  36         # 8 - remove redundant/unneeded document data
  37         # 9 - disable Message-ID compression (SHA-1)
  38         # 10 - optimize doc for NNTP overviews
  39         # 11 - merge threads when vivifying ghosts
  40         # 12 - change YYYYMMDD value column to numeric
  41         # 13 - fix threading for empty References/In-Reply-To
  42         #      (commit 83425ef12e4b65cdcecd11ddcb38175d4a91d5a0)
  43         # 14 - fix ghost root vivification
  44         # 15 - see public-inbox-v2-format(5)
  45         #      further bumps likely unnecessary, we'll suggest in-place
  46         #      "--reindex" use for further fixes and tweaks:
  47         #
  48         #      public-inbox v1.5.0 adds (still SCHEMA_VERSION=15):
  49         #      * "lid:" and "l:" for List-Id searches
  50         #
  51         #      v1.6.0 adds BYTES, UID and THREADID values
  52         SCHEMA_VERSION => 15,
  53 };
  54
  55 use PublicInbox::Smsg;
  56 use PublicInbox::Over;
  57 our $QP_FLAGS;
  58 our %X = map { $_ => 0 } qw(BoolWeight Database Enquire QueryParser Stem Query);
  59 our $Xap; # 'Search::Xapian' or 'Xapian'
  60 our $NVRP; # '$Xap::'.('NumberValueRangeProcessor' or 'NumberRangeProcessor')
  61 our $ENQ_ASCENDING;
  62
  63 sub load_xapian () {
  64         return 1 if defined $Xap;
  65         # n.b. PI_XAPIAN is intended for development use only.  We still
  66         # favor Search::Xapian since that's what's available in current
  67         # Debian stable (10.x) and derived distros.
  68         for my $x (($ENV{PI_XAPIAN} // 'Search::Xapian'), 'Xapian') {
  69                 eval "require $x";
  70                 next if $@;
  71
  72                 $x->import(qw(:standard));
  73                 $Xap = $x;
  74
  75                 # `version_string' was added in Xapian 1.1
  76                 my $xver = eval('v'.eval($x.'::version_string()')) //
  77                                 eval('v'.eval($x.'::xapian_version_string()'));
  78
  79                 # NumberRangeProcessor was added in Xapian 1.3.6,
  80                 # NumberValueRangeProcessor was removed for 1.5.0+,
  81                 # favor the older /Value/ variant since that's what our
  82                 # (currently) preferred Search::Xapian supports
  83                 $NVRP = $x.'::'.($x eq 'Xapian' && $xver ge v1.5 ?
  84                         'NumberRangeProcessor' : 'NumberValueRangeProcessor');
  85                 $X{$_} = $Xap.'::'.$_ for (keys %X);
  86
  87                 # ENQ_ASCENDING doesn't seem exported by SWIG Xapian.pm,
  88                 # so lets hope this part of the ABI is stable because it's
  89                 # just an integer:
  90                 $ENQ_ASCENDING = $x eq 'Xapian' ?
  91                                 1 : Search::Xapian::ENQ_ASCENDING();
  92
  93                 *sortable_serialise = $x.'::sortable_serialise';
  94                 # n.b. FLAG_PURE_NOT is expensive not suitable for a public
  95                 # website as it could become a denial-of-service vector
  96                 # FLAG_PHRASE also seems to cause performance problems chert
  97                 # (and probably earlier Xapian DBs).  glass seems fine...
  98                 # TODO: make this an option, maybe?
  99                 # or make indexlevel=medium as default
 100                 $QP_FLAGS = FLAG_PHRASE() | FLAG_BOOLEAN() | FLAG_LOVEHATE() |
 101                                 FLAG_WILDCARD();
 102                 return 1;
 103         }
 104         undef;
 105 }
 106
 107 # This is English-only, everything else is non-standard and may be confused as
 108 # a prefix common in patch emails
 109 our $LANG = 'english';
 110
 111 # note: the non-X term prefix allocations are shared with
 112 # Xapian omega, see xapian-applications/omega/docs/termprefixes.rst
 113 my %bool_pfx_external = (
 114         mid => 'Q', # Message-ID (full/exact), this is mostly uniQue
 115         lid => 'G', # newsGroup (or similar entity), just inside <>
 116         dfpre => 'XDFPRE',
 117         dfpost => 'XDFPOST',
 118         dfblob => 'XDFPRE XDFPOST',
 119 );
 120
 121 my $non_quoted_body = 'XNQ XDFN XDFA XDFB XDFHH XDFCTX XDFPRE XDFPOST';
 122 my %prob_prefix = (
 123         # for mairix compatibility
 124         s => 'S',
 125         m => 'XM', # 'mid:' (bool) is exact, 'm:' (prob) can do partial
 126         l => 'XL', # 'lid:' (bool) is exact, 'l:' (prob) can do partial
 127         f => 'A',
 128         t => 'XTO',
 129         tc => 'XTO XCC',
 130         c => 'XCC',
 131         tcf => 'XTO XCC A',
 132         a => 'XTO XCC A',
 133         b => $non_quoted_body . ' XQUOT',
 134         bs => $non_quoted_body . ' XQUOT S',
 135         n => 'XFN',
 136
 137         q => 'XQUOT',
 138         nq => $non_quoted_body,
 139         dfn => 'XDFN',
 140         dfa => 'XDFA',
 141         dfb => 'XDFB',
 142         dfhh => 'XDFHH',
 143         dfctx => 'XDFCTX',
 144
 145         # default:
 146         '' => 'XM S A XQUOT XFN ' . $non_quoted_body,
 147 );
 148
 149 # not documenting m: and mid: for now, the using the URLs works w/o Xapian
 150 # not documenting lid: for now, either, it is probably redundant with l:,
 151 # especially since we don't offer boolean searches for To/Cc/From
 152 # headers, either
 153 our @HELP = (
 154         's:' => 'match within Subject  e.g. s:"a quick brown fox"',
 155         'd:' => <<EOF,
 156 date range as YYYYMMDD  e.g. d:19931002..20101002
 157 Open-ended ranges such as d:19931002.. and d:..20101002
 158 are also supported
 159 EOF
 160         'dt:' => <<EOF,
 161 date-time range as YYYYMMDDhhmmss (e.g. dt:19931002011000..19931002011200)
 162 EOF
 163         'b:' => 'match within message body, including text attachments',
 164         'nq:' => 'match non-quoted text within message body',
 165         'q:' => 'match quoted text within message body',
 166         'n:' => 'match filename of attachment(s)',
 167         't:' => 'match within the To header',
 168         'c:' => 'match within the Cc header',
 169         'f:' => 'match within the From header',
 170         'a:' => 'match within the To, Cc, and From headers',
 171         'tc:' => 'match within the To and Cc headers',
 172         'l:' => 'match contents of the List-Id header',
 173         'bs:' => 'match within the Subject and body',
 174         'dfn:' => 'match filename from diff',
 175         'dfa:' => 'match diff removed (-) lines',
 176         'dfb:' => 'match diff added (+) lines',
 177         'dfhh:' => 'match diff hunk header context (usually a function name)',
 178         'dfctx:' => 'match diff context lines',
 179         'dfpre:' => 'match pre-image git blob ID',
 180         'dfpost:' => 'match post-image git blob ID',
 181         'dfblob:' => 'match either pre or post-image git blob ID',
 182 );
 183 chomp @HELP;
 184
 185 sub xdir ($;$) {
 186         my ($self, $rdonly) = @_;
 187         if ($rdonly || !defined($self->{shard})) {
 188                 $self->{xpfx};
 189         } else { # v2 only:
 190                 "$self->{xpfx}/$self->{shard}";
 191         }
 192 }
 193
 194 # returns all shards as separate Xapian::Database objects w/o combining
 195 sub xdb_shards_flat ($) {
 196         my ($self) = @_;
 197         my $xpfx = $self->{xpfx};
 198         my (@xdb, $slow_phrase);
 199         if ($xpfx =~ m/xapian${\SCHEMA_VERSION}\z/) {
 200                 @xdb = ($X{Database}->new($xpfx));
 201                 $self->{qp_flags} |= FLAG_PHRASE() if !-f "$xpfx/iamchert";
 202         } else {
 203                 opendir(my $dh, $xpfx) or return (); # not initialized yet
 204                 # We need numeric sorting so shard[0] is first for reading
 205                 # Xapian metadata, if needed
 206                 my $last = max(grep(/\A[0-9]+\z/, readdir($dh))) // return ();
 207                 for (0..$last) {
 208                         my $shard_dir = "$self->{xpfx}/$_";
 209                         push @xdb, $X{Database}->new($shard_dir);
 210                         $slow_phrase ||= -f "$shard_dir/iamchert";
 211                 }
 212                 $self->{qp_flags} |= FLAG_PHRASE() if !$slow_phrase;
 213         }
 214         @xdb;
 215 }
 216
 217 sub _xdb {
 218         my ($self) = @_;
 219         $self->{qp_flags} //= $QP_FLAGS;
 220         my @xdb = xdb_shards_flat($self) or return;
 221         $self->{nshard} = scalar(@xdb);
 222         my $xdb = shift @xdb;
 223         $xdb->add_database($_) for @xdb;
 224         $xdb;
 225 }
 226
 227 # v2 Xapian docids don't conflict, so they're identical to
 228 # NNTP article numbers and IMAP UIDs.
 229 # https://trac.xapian.org/wiki/FAQ/MultiDatabaseDocumentID
 230 sub mdocid {
 231         my ($nshard, $mitem) = @_;
 232         my $docid = $mitem->get_docid;
 233         int(($docid - 1) / $nshard) + 1;
 234 }
 235
 236 sub mset_to_artnums {
 237         my ($self, $mset) = @_;
 238         my $nshard = $self->{nshard};
 239         [ map { mdocid($nshard, $_) } $mset->items ];
 240 }
 241
 242 sub xdb ($) {
 243         my ($self) = @_;
 244         $self->{xdb} //= do {
 245                 load_xapian();
 246                 $self->_xdb;
 247         };
 248 }
 249
 250 sub new {
 251         my ($class, $ibx) = @_;
 252         ref $ibx or die "BUG: expected PublicInbox::Inbox object: $ibx";
 253         my $xap = $ibx->version > 1 ? 'xap' : 'public-inbox/xapian';
 254         bless {
 255                 xpfx => "$ibx->{inboxdir}/$xap" . SCHEMA_VERSION,
 256                 altid => $ibx->{altid},
 257         }, $class;
 258 }
 259
 260 sub reopen {
 261         my ($self) = @_;
 262         if (my $xdb = $self->{xdb}) {
 263                 $xdb->reopen;
 264         }
 265         $self; # make chaining easier
 266 }
 267
 268 # read-only
 269 sub mset {
 270         my ($self, $query_string, $opts) = @_;
 271         $opts ||= {};
 272         my $qp = $self->{qp} //= qparse_new($self);
 273         my $query = $qp->parse_query($query_string, $self->{qp_flags});
 274         $opts->{relevance} = 1 unless exists $opts->{relevance};
 275         _do_enquire($self, $query, $opts);
 276 }
 277
 278 sub retry_reopen {
 279         my ($self, $cb, @arg) = @_;
 280         for my $i (1..10) {
 281                 if (wantarray) {
 282                         my @ret;
 283                         eval { @ret = $cb->($self, @arg) };
 284                         return @ret unless $@;
 285                 } else {
 286                         my $ret;
 287                         eval { $ret = $cb->($self, @arg) };
 288                         return $ret unless $@;
 289                 }
 290                 # Exception: The revision being read has been discarded -
 291                 # you should call Xapian::Database::reopen()
 292                 if (ref($@) =~ /\bDatabaseModifiedError\b/) {
 293                         warn "reopen try #$i on $@\n";
 294                         reopen($self);
 295                 } else {
 296                         # let caller decide how to spew, because ExtMsg queries
 297                         # get wonky and trigger:
 298                         # "something terrible happened at .../Xapian/Enquire.pm"
 299                         die;
 300                 }
 301         }
 302         die "Too many Xapian database modifications in progress\n";
 303 }
 304
 305 sub _do_enquire {
 306         my ($self, $query, $opts) = @_;
 307         retry_reopen($self, \&_enquire_once, $query, $opts);
 308 }
 309
 310 # returns true if all docs have the THREADID value
 311 sub has_threadid ($) {
 312         my ($self) = @_;
 313         (xdb($self)->get_metadata('has_threadid') // '') eq '1';
 314 }
 315
 316 sub _enquire_once { # retry_reopen callback
 317         my ($self, $query, $opts) = @_;
 318         my $xdb = xdb($self);
 319         if (defined(my $eidx_key = $opts->{eidx_key})) {
 320                 $query = $X{Query}->new(OP_FILTER(), $query, 'O'.$eidx_key);
 321         }
 322         if (defined(my $uid_range = $opts->{uid_range})) {
 323                 my $range = $X{Query}->new(OP_VALUE_RANGE(), UID,
 324                                         sortable_serialise($uid_range->[0]),
 325                                         sortable_serialise($uid_range->[1]));
 326                 $query = $X{Query}->new(OP_FILTER(), $query, $range);
 327         }
 328         my $enquire = $X{Enquire}->new($xdb);
 329         $enquire->set_query($query);
 330         $opts ||= {};
 331         my $desc = !$opts->{asc};
 332         if (($opts->{mset} || 0) == 2) { # mset == 2: ORDER BY docid/UID
 333                 $enquire->set_docid_order($ENQ_ASCENDING);
 334                 $enquire->set_weighting_scheme($X{BoolWeight}->new);
 335         } elsif ($opts->{relevance}) {
 336                 $enquire->set_sort_by_relevance_then_value(TS, $desc);
 337         } else {
 338                 $enquire->set_sort_by_value_then_relevance(TS, $desc);
 339         }
 340
 341         # `mairix -t / --threads' or JMAP collapseThreads
 342         if ($opts->{thread} && has_threadid($self)) {
 343                 $enquire->set_collapse_key(THREADID);
 344         }
 345         $enquire->get_mset($opts->{offset} || 0, $opts->{limit} || 50);
 346 }
 347
 348 sub mset_to_smsg {
 349         my ($self, $ibx, $mset) = @_;
 350         my $nshard = $self->{nshard};
 351         my $i = 0;
 352         my %order = map { mdocid($nshard, $_) => ++$i } $mset->items;
 353         my @msgs = sort {
 354                 $order{$a->{num}} <=> $order{$b->{num}}
 355         } @{$ibx->over->get_all(keys %order)};
 356         wantarray ? ($mset->get_matches_estimated, \@msgs) : \@msgs;
 357 }
 358
 359 # read-write
 360 sub stemmer { $X{Stem}->new($LANG) }
 361
 362 # read-only
 363 sub qparse_new ($) {
 364         my ($self) = @_;
 365
 366         my $xdb = xdb($self);
 367         my $qp = $X{QueryParser}->new;
 368         $qp->set_default_op(OP_AND());
 369         $qp->set_database($xdb);
 370         $qp->set_stemmer(stemmer($self));
 371         $qp->set_stemming_strategy(STEM_SOME());
 372         my $cb = $qp->can('set_max_wildcard_expansion') //
 373                 $qp->can('set_max_expansion'); # Xapian 1.5.0+
 374         $cb->($qp, 100);
 375         $cb = $qp->can('add_valuerangeprocessor') //
 376                 $qp->can('add_rangeprocessor'); # Xapian 1.5.0+
 377         $cb->($qp, $NVRP->new(YYYYMMDD, 'd:'));
 378         $cb->($qp, $NVRP->new(DT, 'dt:'));
 379
 380         # for IMAP, undocumented for WWW and may be split off go away
 381         $cb->($qp, $NVRP->new(BYTES, 'bytes:'));
 382         $cb->($qp, $NVRP->new(TS, 'ts:'));
 383         $cb->($qp, $NVRP->new(UID, 'uid:'));
 384
 385         while (my ($name, $prefix) = each %bool_pfx_external) {
 386                 $qp->add_boolean_prefix($name, $_) foreach split(/ /, $prefix);
 387         }
 388
 389         # we do not actually create AltId objects,
 390         # just parse the spec to avoid the extra DB handles for now.
 391         if (my $altid = $self->{altid}) {
 392                 my $user_pfx = $self->{-user_pfx} = [];
 393                 for (@$altid) {
 394                         # $_ = 'serial:gmane:/path/to/gmane.msgmap.sqlite3'
 395                         # note: Xapian supports multibyte UTF-8, /^[0-9]+$/,
 396                         # and '_' with prefixes matching \w+
 397                         /\Aserial:(\w+):/ or next;
 398                         my $pfx = $1;
 399                         push @$user_pfx, "$pfx:", <<EOF;
 400 alternate serial number  e.g. $pfx:12345 (boolean)
 401 EOF
 402                         # gmane => XGMANE
 403                         $qp->add_boolean_prefix($pfx, 'X'.uc($pfx));
 404                 }
 405                 chomp @$user_pfx;
 406         }
 407
 408         while (my ($name, $prefix) = each %prob_prefix) {
 409                 $qp->add_prefix($name, $_) foreach split(/ /, $prefix);
 410         }
 411         $qp;
 412 }
 413
 414 sub help {
 415         my ($self) = @_;
 416         $self->{qp} //= qparse_new($self); # parse altids
 417         my @ret = @HELP;
 418         if (my $user_pfx = $self->{-user_pfx}) {
 419                 push @ret, @$user_pfx;
 420         }
 421         \@ret;
 422 }
 423
 424 1;