lib/PublicInbox/Search.pm

   1 # Copyright (C) 2015, all contributors <meta@public-inbox.org>
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 # based on notmuch, but with no concept of folders, files or flags
   4 package PublicInbox::Search;
   5 use strict;
   6 use warnings;
   7 use constant TS => 0;
   8 use Search::Xapian qw/:standard/;
   9 use PublicInbox::SearchMsg;
  10 use Email::MIME;
  11 use PublicInbox::MID qw/mid_clean mid_compress/;
  12
  13 # This is English-only, everything else is non-standard and may be confused as
  14 # a prefix common in patch emails
  15 our $REPLY_RE = qr/^re:\s+/i;
  16 our $LANG = 'english';
  17
  18 use constant {
  19         # SCHEMA_VERSION history
  20         # 0 - initial
  21         # 1 - subject_path is lower-cased
  22         # 2 - subject_path is mid_compress in the index, only
  23         # 3 - message-ID is compressed if it includes '%' (hack!)
  24         # 4 - change "Re: " normalization, avoid circular Reference ghosts
  25         # 5 - subject_path drops trailing '.'
  26         # 6 - preserve References: order in document data
  27         # 7 - remove references and inreplyto terms
  28         # 8 - remove redundant/unneeded document data
  29         SCHEMA_VERSION => 8,
  30         QP_FLAGS => FLAG_PHRASE|FLAG_BOOLEAN|FLAG_LOVEHATE|FLAG_WILDCARD,
  31 };
  32
  33 # setup prefixes
  34 my %bool_pfx_internal = (
  35         type => 'T', # "mail" or "ghost"
  36         mid => 'Q', # uniQue id (Message-ID or mid_compress)
  37 );
  38
  39 my %bool_pfx_external = (
  40         path => 'XPATH',
  41         thread => 'G', # newsGroup (or similar entity - e.g. a web forum name)
  42 );
  43
  44 my %prob_prefix = (
  45         subject => 'S',
  46 );
  47
  48 my %all_pfx = (%bool_pfx_internal, %bool_pfx_external, %prob_prefix);
  49
  50 sub xpfx { $all_pfx{$_[0]} }
  51
  52 our %PFX2TERM_RMAP;
  53 my %meta_pfx = (mid => 1, thread => 1, path => 1);
  54 while (my ($k, $v) = each %all_pfx) {
  55         $PFX2TERM_RMAP{$v} = $k if $meta_pfx{$k};
  56 }
  57
  58 my $mail_query = Search::Xapian::Query->new(xpfx('type') . 'mail');
  59
  60 sub xdir {
  61         my (undef, $git_dir) = @_;
  62         "$git_dir/public-inbox/xapian" . SCHEMA_VERSION;
  63 }
  64
  65 sub new {
  66         my ($class, $git_dir) = @_;
  67         my $dir = $class->xdir($git_dir);
  68         my $db = Search::Xapian::Database->new($dir);
  69         bless { xdb => $db, git_dir => $git_dir }, $class;
  70 }
  71
  72 sub reopen { $_[0]->{xdb}->reopen }
  73
  74 # read-only
  75 sub query {
  76         my ($self, $query_string, $opts) = @_;
  77         my $query;
  78
  79         $opts ||= {};
  80         unless ($query_string eq '') {
  81                 $query = $self->qp->parse_query($query_string, QP_FLAGS);
  82                 $opts->{relevance} = 1;
  83         }
  84
  85         $self->do_enquire($query, $opts);
  86 }
  87
  88 sub get_subject_path {
  89         my ($self, $path, $opts) = @_;
  90         my $query = $self->qp->parse_query("path:".mid_compress($path), 0);
  91         $self->do_enquire($query, $opts);
  92 }
  93
  94 sub get_thread {
  95         my ($self, $mid, $opts) = @_;
  96         my $smsg = eval { $self->lookup_message($mid) };
  97
  98         return { total => 0, msgs => [] } unless $smsg;
  99         my $qp = $self->qp;
 100         my $qtid = $qp->parse_query('thread:'.$smsg->thread_id, 0);
 101         my $qsub = $qp->parse_query('path:'.mid_compress($smsg->path), 0);
 102         my $query = Search::Xapian::Query->new(OP_OR, $qtid, $qsub);
 103         $self->do_enquire($query, $opts);
 104 }
 105
 106 # private subs below
 107
 108 sub do_enquire {
 109         my ($self, $query, $opts) = @_;
 110         my $enquire = $self->enquire;
 111         if (defined $query) {
 112                 $query = Search::Xapian::Query->new(OP_AND,$query,$mail_query);
 113         } else {
 114                 $query = $mail_query;
 115         }
 116         $enquire->set_query($query);
 117         if ($opts->{relevance}) {
 118                 $enquire->set_sort_by_relevance_then_value(TS, 1);
 119         } else {
 120                 $enquire->set_sort_by_value(TS, 1);
 121         }
 122         $opts ||= {};
 123         my $offset = $opts->{offset} || 0;
 124         my $limit = $opts->{limit} || 50;
 125         my $mset = $enquire->get_mset($offset, $limit);
 126         my @msgs = map {
 127                 PublicInbox::SearchMsg->load_doc($_->get_document);
 128         } $mset->items;
 129
 130         { total => $mset->get_matches_estimated, msgs => \@msgs }
 131 }
 132
 133 # read-write
 134 sub stemmer { Search::Xapian::Stem->new($LANG) }
 135
 136 # read-only
 137 sub qp {
 138         my ($self) = @_;
 139
 140         my $qp = $self->{query_parser};
 141         return $qp if $qp;
 142
 143         # new parser
 144         $qp = Search::Xapian::QueryParser->new;
 145         $qp->set_default_op(OP_AND);
 146         $qp->set_database($self->{xdb});
 147         $qp->set_stemmer($self->stemmer);
 148         $qp->set_stemming_strategy(STEM_SOME);
 149         $qp->add_valuerangeprocessor($self->ts_range_processor);
 150         $qp->add_valuerangeprocessor($self->date_range_processor);
 151
 152         while (my ($name, $prefix) = each %bool_pfx_external) {
 153                 $qp->add_boolean_prefix($name, $prefix);
 154         }
 155
 156         while (my ($name, $prefix) = each %prob_prefix) {
 157                 $qp->add_prefix($name, $prefix);
 158         }
 159
 160         $self->{query_parser} = $qp;
 161 }
 162
 163 sub ts_range_processor {
 164         $_[0]->{tsrp} ||= Search::Xapian::NumberValueRangeProcessor->new(TS);
 165 }
 166
 167 sub date_range_processor {
 168         $_[0]->{drp} ||= Search::Xapian::DateValueRangeProcessor->new(TS);
 169 }
 170
 171 sub lookup_message {
 172         my ($self, $mid) = @_;
 173         $mid = mid_clean($mid);
 174         $mid = mid_compress($mid);
 175
 176         my $doc_id = $self->find_unique_doc_id('mid', $mid);
 177         my $smsg;
 178         if (defined $doc_id) {
 179                 # raises on error:
 180                 my $doc = $self->{xdb}->get_document($doc_id);
 181                 $smsg = PublicInbox::SearchMsg->wrap($doc, $mid);
 182                 $smsg->doc_id($doc_id);
 183         }
 184         $smsg;
 185 }
 186
 187 sub find_unique_doc_id {
 188         my ($self, $term, $value) = @_;
 189
 190         my ($begin, $end) = $self->find_doc_ids($term, $value);
 191
 192         return undef if $begin->equal($end); # not found
 193
 194         my $rv = $begin->get_docid;
 195
 196         # sanity check
 197         $begin->inc;
 198         $begin->equal($end) or die "Term '$term:$value' is not unique\n";
 199         $rv;
 200 }
 201
 202 # returns begin and end PostingIterator
 203 sub find_doc_ids {
 204         my ($self, $term, $value) = @_;
 205
 206         $self->find_doc_ids_for_term(xpfx($term) . $value);
 207 }
 208
 209 # returns begin and end PostingIterator
 210 sub find_doc_ids_for_term {
 211         my ($self, $term) = @_;
 212         my $db = $self->{xdb};
 213
 214         ($db->postlist_begin($term), $db->postlist_end($term));
 215 }
 216
 217 # normalize subjects so they are suitable as pathnames for URLs
 218 sub subject_path {
 219         my $subj = pop;
 220         $subj = subject_normalized($subj);
 221         $subj =~ s![^a-zA-Z0-9_\.~/\-]+!_!g;
 222         lc($subj);
 223 }
 224
 225 sub subject_normalized {
 226         my $subj = pop;
 227         $subj =~ s/\A\s+//s; # no leading space
 228         $subj =~ s/\s+\z//s; # no trailing space
 229         $subj =~ s/\s+/ /gs; # no redundant spaces
 230         $subj =~ s/\.+\z//; # no trailing '.'
 231         $subj =~ s/$REPLY_RE//igo; # remove reply prefix
 232         $subj;
 233 }
 234
 235 # for doc data
 236 sub subject_summary {
 237         my $subj = pop;
 238         my $max = 68;
 239         if (length($subj) > $max) {
 240                 my @subj = split(/\s+/, $subj);
 241                 $subj = '';
 242                 my $l;
 243
 244                 while ($l = shift @subj) {
 245                         my $new = $subj . $l . ' ';
 246                         last if length($new) >= $max;
 247                         $subj = $new;
 248                 }
 249                 if ($subj ne '') {
 250                         my $r = scalar @subj ? ' ...' : '';
 251                         $subj =~ s/ \z/$r/s;
 252                 } else {
 253                         # subject has one REALLY long word, and NOT spam? wtf
 254                         @subj = ($l =~ /\A(.{1,72})/);
 255                         $subj = $subj[0] . ' ...';
 256                 }
 257         }
 258         $subj;
 259 }
 260
 261 sub enquire {
 262         my ($self) = @_;
 263         $self->{enquire} ||= Search::Xapian::Enquire->new($self->{xdb});
 264 }
 265
 266 1;