lib/PublicInbox/Search.pm

   1 # Copyright (C) 2015, all contributors <meta@public-inbox.org>
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 # based on notmuch, but with no concept of folders, files or flags
   4 package PublicInbox::Search;
   5 use strict;
   6 use warnings;
   7 use PublicInbox::SearchMsg;
   8 use Search::Xapian qw/:standard/;
   9 require PublicInbox::View;
  10 use Email::MIME;
  11 use PublicInbox::MID qw/mid_clean mid_compressed/;
  12
  13 use constant {
  14         TS => 0,
  15         # SCHEMA_VERSION history
  16         # 0 - initial
  17         # 1 - subject_path is lower-cased
  18         # 2 - subject_path is mid_compressed in the index, only
  19         # 3 - message-ID is compressed if it includes '%' (hack!)
  20         SCHEMA_VERSION => 3,
  21         LANG => 'english',
  22         QP_FLAGS => FLAG_PHRASE|FLAG_BOOLEAN|FLAG_LOVEHATE|FLAG_WILDCARD,
  23 };
  24
  25 # setup prefixes
  26 my %bool_pfx_internal = (
  27         type => 'T', # "mail" or "ghost"
  28         mid => 'Q', # uniQue id (Message-ID or mid_compressed)
  29 );
  30
  31 my %bool_pfx_external = (
  32         path => 'XPATH',
  33         thread => 'G', # newsGroup (or similar entity - e.g. a web forum name)
  34         references => 'XREFS',
  35         inreplyto => 'XIRT',
  36 );
  37
  38 my %prob_prefix = (
  39         subject => 'S',
  40 );
  41
  42 my %all_pfx = (%bool_pfx_internal, %bool_pfx_external, %prob_prefix);
  43
  44 sub xpfx { $all_pfx{$_[0]} }
  45
  46 our %PFX2TERM_RMAP;
  47 while (my ($k, $v) = each %all_pfx) {
  48         next if $prob_prefix{$k};
  49         $PFX2TERM_RMAP{$v} = $k;
  50 }
  51
  52 my $mail_query = Search::Xapian::Query->new(xpfx('type') . 'mail');
  53
  54 sub new {
  55         my ($class, $git_dir, $writable) = @_;
  56         # allow concurrent versions for easier rollback:
  57         my $dir = "$git_dir/public-inbox/xapian" . SCHEMA_VERSION;
  58         my $db;
  59
  60         if ($writable) { # not used by the WWW interface
  61                 require Search::Xapian::WritableDatabase;
  62                 my $flag = Search::Xapian::DB_OPEN;
  63                 if ($writable == 1) {
  64                         require File::Path;
  65                         File::Path::mkpath($dir);
  66                         $flag = Search::Xapian::DB_CREATE_OR_OPEN;
  67                 }
  68                 $db = Search::Xapian::WritableDatabase->new($dir, $flag);
  69         } else {
  70                 $db = Search::Xapian::Database->new($dir);
  71         }
  72         bless { xdb => $db, git_dir => $git_dir }, $class;
  73 }
  74
  75 sub reopen { $_[0]->{xdb}->reopen }
  76
  77 sub add_message {
  78         my ($self, $mime) = @_; # mime = Email::MIME object
  79         my $db = $self->{xdb};
  80
  81         my $doc_id;
  82         my $mid = mid_clean($mime->header_obj->header_raw('Message-ID'));
  83         $mid = mid_compressed($mid);
  84         my $was_ghost = 0;
  85         my $ct_msg = $mime->header('Content-Type') || 'text/plain';
  86         my $enc_msg = PublicInbox::View::enc_for($ct_msg);
  87
  88         eval {
  89                 my $smsg = $self->lookup_message($mid);
  90                 my $doc;
  91
  92                 if ($smsg) {
  93                         $smsg->ensure_metadata;
  94                         # convert a ghost to a regular message
  95                         # it will also clobber any existing regular message
  96                         $smsg->mime($mime);
  97                         $doc = $smsg->{doc};
  98
  99                         my $type = xpfx('type');
 100                         eval {
 101                                 $doc->remove_term($type . 'ghost');
 102                                 $was_ghost = 1;
 103                         };
 104
 105                         # probably does not exist:
 106                         eval { $doc->remove_term($type . 'mail') };
 107                         $doc->add_term($type . 'mail');
 108                 }  else {
 109                         $smsg = PublicInbox::SearchMsg->new($mime);
 110                         $doc = $smsg->{doc};
 111                         $doc->add_term(xpfx('mid') . $mid);
 112                 }
 113
 114                 my $subj = $smsg->subject;
 115
 116                 if (length $subj) {
 117                         $doc->add_term(xpfx('subject') . $subj);
 118
 119                         my $path = subject_path($subj);
 120                         $doc->add_term(xpfx('path') . mid_compressed($path));
 121                 }
 122
 123                 my $from = $smsg->from_name;
 124                 my $date = $smsg->date;
 125                 my $ts = Search::Xapian::sortable_serialise($smsg->ts);
 126                 $doc->add_value(PublicInbox::Search::TS, $ts);
 127
 128                 $doc->set_data($smsg->to_doc_data);
 129
 130                 my $tg = $self->term_generator;
 131
 132                 $tg->set_document($doc);
 133                 $tg->index_text($subj, 1, 'S') if $subj;
 134                 $tg->increase_termpos;
 135                 $tg->index_text($subj) if $subj;
 136                 $tg->increase_termpos;
 137
 138                 $tg->index_text($smsg->from->format);
 139                 $tg->increase_termpos;
 140
 141                 $mime->walk_parts(sub {
 142                         my ($part) = @_;
 143                         return if $part->subparts; # walk_parts already recurses
 144                         my $ct = $part->content_type || $ct_msg;
 145
 146                         # account for filter bugs...
 147                         $ct =~ m!\btext/plain\b!i or return;
 148
 149                         my $enc = PublicInbox::View::enc_for($ct, $enc_msg);
 150                         my (@orig, @quot);
 151                         foreach my $l (split(/\n/, $enc->decode($part->body))) {
 152                                 if ($l =~ /^\s*>/) {
 153                                         push @quot, $l;
 154                                 } else {
 155                                         push @orig, $l;
 156                                 }
 157                         }
 158                         if (@quot) {
 159                                 $tg->index_text(join("\n", @quot), 0);
 160                                 $tg->increase_termpos;
 161                         }
 162                         if (@orig) {
 163                                 $tg->index_text(join("\n", @orig));
 164                                 $tg->increase_termpos;
 165                         }
 166                 });
 167
 168                 if ($was_ghost) {
 169                         $doc_id = $smsg->doc_id;
 170                         $self->link_message($smsg, 0);
 171                         $db->replace_document($doc_id, $doc);
 172                 } else {
 173                         $self->link_message($smsg, 0);
 174                         $doc_id = $db->add_document($doc);
 175                 }
 176         };
 177
 178         if ($@) {
 179                 warn "failed to index message <$mid>: $@\n";
 180                 return undef;
 181         }
 182         $doc_id;
 183 }
 184
 185 # returns deleted doc_id on success, undef on missing
 186 sub remove_message {
 187         my ($self, $mid) = @_;
 188         my $db = $self->{xdb};
 189         my $doc_id;
 190         $mid = mid_clean($mid);
 191         $mid = mid_compressed($mid);
 192
 193         eval {
 194                 $doc_id = $self->find_unique_doc_id('mid', $mid);
 195                 $db->delete_document($doc_id) if defined $doc_id;
 196         };
 197
 198         if ($@) {
 199                 warn "failed to remove message <$mid>: $@\n";
 200                 return undef;
 201         }
 202         $doc_id;
 203 }
 204
 205 # read-only
 206 sub query {
 207         my ($self, $query_string, $opts) = @_;
 208         my $query = $self->qp->parse_query($query_string, QP_FLAGS);
 209
 210         $query = Search::Xapian::Query->new(OP_AND, $mail_query, $query);
 211         $self->do_enquire($query, $opts);
 212 }
 213
 214 sub get_subject_path {
 215         my ($self, $path, $opts) = @_;
 216         my $query = $self->qp->parse_query("path:".mid_compressed($path), 0);
 217         $self->do_enquire($query);
 218 }
 219
 220 # given a message ID, get followups to a message
 221 sub get_followups {
 222         my ($self, $mid, $opts) = @_;
 223         $mid = mid_clean($mid);
 224         $mid = mid_compressed($mid);
 225         my $qp = $self->qp;
 226         my $irt = $qp->parse_query("inreplyto:$mid", 0);
 227         my $ref = $qp->parse_query("references:$mid", 0);
 228         my $query = Search::Xapian::Query->new(OP_OR, $irt, $ref);
 229
 230         $self->do_enquire($query);
 231 }
 232
 233 sub get_thread {
 234         my ($self, $mid, $opts) = @_;
 235         my $smsg = eval { $self->lookup_message($mid) };
 236
 237         return { count => 0, msgs => [] } unless $smsg;
 238         my $qp = $self->qp;
 239         my $qtid = $qp->parse_query('thread:'.$smsg->thread_id);
 240         my $qsub = $qp->parse_query('path:'.mid_compressed($smsg->path));
 241         my $query = Search::Xapian::Query->new(OP_OR, $qtid, $qsub);
 242         $self->do_enquire($query);
 243 }
 244
 245 # private subs below
 246
 247 sub do_enquire {
 248         my ($self, $query, $opts) = @_;
 249         my $enquire = $self->enquire;
 250
 251         $enquire->set_query($query);
 252         $enquire->set_sort_by_relevance_then_value(TS, 0);
 253         $opts ||= {};
 254         my $offset = $opts->{offset} || 0;
 255         my $limit = $opts->{limit} || 50;
 256         my $mset = $enquire->get_mset($offset, $limit);
 257         my @msgs = map {
 258                 PublicInbox::SearchMsg->load_doc($_->get_document);
 259         } $mset->items;
 260
 261         { count => $mset->get_matches_estimated, msgs => \@msgs }
 262 }
 263
 264 # read-write
 265 sub stemmer { Search::Xapian::Stem->new(LANG) }
 266
 267 # read-only
 268 sub qp {
 269         my ($self) = @_;
 270
 271         my $qp = $self->{query_parser};
 272         return $qp if $qp;
 273
 274         # new parser
 275         $qp = Search::Xapian::QueryParser->new;
 276         $qp->set_default_op(OP_AND);
 277         $qp->set_database($self->{xdb});
 278         $qp->set_stemmer($self->stemmer);
 279         $qp->set_stemming_strategy(STEM_SOME);
 280         $qp->add_valuerangeprocessor($self->ts_range_processor);
 281         $qp->add_valuerangeprocessor($self->date_range_processor);
 282
 283         while (my ($name, $prefix) = each %bool_pfx_external) {
 284                 $qp->add_boolean_prefix($name, $prefix);
 285         }
 286
 287         while (my ($name, $prefix) = each %prob_prefix) {
 288                 $qp->add_prefix($name, $prefix);
 289         }
 290
 291         $self->{query_parser} = $qp;
 292 }
 293
 294 sub term_generator { # write-only
 295         my ($self) = @_;
 296
 297         my $tg = $self->{term_generator};
 298         return $tg if $tg;
 299
 300         $tg = Search::Xapian::TermGenerator->new;
 301         $tg->set_stemmer($self->stemmer);
 302
 303         $self->{term_generator} = $tg;
 304 }
 305
 306 sub next_doc_id { $_[0]->{xdb}->get_lastdocid + 1 }
 307
 308 # increments last_thread_id counter
 309 # returns a 64-bit integer represented as a hex string
 310 sub next_thread_id {
 311         my ($self) = @_;
 312         my $db = $self->{xdb};
 313         my $last_thread_id = int($db->get_metadata('last_thread_id') || 0);
 314
 315         $db->set_metadata('last_thread_id', ++$last_thread_id);
 316
 317         $last_thread_id;
 318 }
 319
 320 sub ts_range_processor {
 321         $_[0]->{tsrp} ||= Search::Xapian::NumberValueRangeProcessor->new(TS);
 322 }
 323
 324 sub date_range_processor {
 325         $_[0]->{drp} ||= Search::Xapian::DateValueRangeProcessor->new(TS);
 326 }
 327
 328 sub link_message {
 329         my ($self, $smsg, $is_ghost) = @_;
 330
 331         if ($is_ghost) {
 332                 $smsg->ensure_metadata;
 333         } else {
 334                 $self->link_message_to_parents($smsg);
 335         }
 336 }
 337
 338 sub link_message_to_parents {
 339         my ($self, $smsg) = @_;
 340         my $doc = $smsg->{doc};
 341         my $mid = mid_compressed($smsg->mid);
 342         my $mime = $smsg->mime;
 343         my $refs = $mime->header_obj->header_raw('References');
 344         my @refs = $refs ? ($refs =~ /<([^>]+)>/g) : ();
 345         my $irt = $mime->header_obj->header_raw('In-Reply-To');
 346         if ($irt) {
 347                 if ($irt =~ /<([^>]+)>/) {
 348                         $irt = $1;
 349                 }
 350                 push @refs, $irt;
 351         }
 352
 353         my $tid;
 354         if (@refs) {
 355                 @refs = map { mid_compressed($_) } @refs;
 356                 my %uniq;
 357                 @refs = grep { !$uniq{$_}++ } @refs; # uniq
 358
 359                 $doc->add_term(xpfx('inreplyto') . $refs[-1]);
 360
 361                 my $ref_pfx = xpfx('references');
 362
 363                 # first ref *should* be the thread root,
 364                 # but we can never trust clients to do the right thing
 365                 my $ref = shift @refs;
 366                 $doc->add_term($ref_pfx . $ref);
 367                 $tid = $self->_resolve_mid_to_tid($ref);
 368
 369                 # the rest of the refs should point to this tid:
 370                 foreach $ref (@refs) {
 371                         $doc->add_term($ref_pfx . $ref);
 372                         my $ptid = $self->_resolve_mid_to_tid($ref);
 373                         if ($tid ne $ptid) {
 374                                 $self->merge_threads($tid, $ptid);
 375                         }
 376                 }
 377         } else {
 378                 $tid = $self->next_thread_id;
 379         }
 380         $doc->add_term(xpfx('thread') . $tid);
 381 }
 382
 383 sub lookup_message {
 384         my ($self, $mid) = @_;
 385         $mid = mid_clean($mid);
 386         $mid = mid_compressed($mid);
 387
 388         my $doc_id = $self->find_unique_doc_id('mid', $mid);
 389         my $smsg;
 390         if (defined $doc_id) {
 391                 # raises on error:
 392                 my $doc = $self->{xdb}->get_document($doc_id);
 393                 $smsg = PublicInbox::SearchMsg->wrap($doc, $mid);
 394                 $smsg->doc_id($doc_id);
 395         }
 396         $smsg;
 397 }
 398
 399 sub find_unique_doc_id {
 400         my ($self, $term, $value) = @_;
 401
 402         my ($begin, $end) = $self->find_doc_ids($term, $value);
 403
 404         return undef if $begin->equal($end); # not found
 405
 406         my $rv = $begin->get_docid;
 407
 408         # sanity check
 409         $begin->inc;
 410         $begin->equal($end) or die "Term '$term:$value' is not unique\n";
 411         $rv;
 412 }
 413
 414 # returns begin and end PostingIterator
 415 sub find_doc_ids {
 416         my ($self, $term, $value) = @_;
 417
 418         $self->find_doc_ids_for_term(xpfx($term) . $value);
 419 }
 420
 421 # returns begin and end PostingIterator
 422 sub find_doc_ids_for_term {
 423         my ($self, $term) = @_;
 424         my $db = $self->{xdb};
 425
 426         ($db->postlist_begin($term), $db->postlist_end($term));
 427 }
 428
 429 # this will create a ghost as necessary
 430 sub _resolve_mid_to_tid {
 431         my ($self, $mid) = @_;
 432
 433         my $smsg = $self->lookup_message($mid) || $self->create_ghost($mid);
 434         $smsg->thread_id;
 435 }
 436
 437 sub create_ghost {
 438         my ($self, $mid, $tid) = @_;
 439
 440         $mid = mid_compressed($mid);
 441         $tid = $self->next_thread_id unless defined $tid;
 442
 443         my $doc = Search::Xapian::Document->new;
 444         $doc->add_term(xpfx('mid') . $mid);
 445         $doc->add_term(xpfx('thread') . $tid);
 446         $doc->add_term(xpfx('type') . 'ghost');
 447
 448         my $smsg = PublicInbox::SearchMsg->wrap($doc, $mid);
 449         $self->link_message($smsg, 1);
 450         $self->{xdb}->add_document($doc);
 451
 452         $smsg;
 453 }
 454
 455 sub merge_threads {
 456         my ($self, $winner_tid, $loser_tid) = @_;
 457         my ($head, $tail) = $self->find_doc_ids('thread', $loser_tid);
 458         my $thread_pfx = xpfx('thread');
 459         my $db = $self->{xdb};
 460
 461         for (; $head != $tail; $head->inc) {
 462                 my $docid = $head->get_docid;
 463                 my $doc = $db->get_document($docid);
 464                 $doc->remove_term($thread_pfx . $loser_tid);
 465                 $doc->add_term($thread_pfx . $winner_tid);
 466                 $db->replace_document($docid, $doc);
 467         }
 468 }
 469
 470 # normalize subjects so they are suitable as pathnames for URLs
 471 sub subject_path {
 472         my $subj = pop;
 473
 474         $subj =~ s/\A\s+//;
 475         $subj =~ s/\s+\z//;
 476         $subj =~ s/^(?:re|aw):\s*//i; # remove reply prefix (aw: German)
 477         $subj =~ s![^a-zA-Z0-9_\.~/\-]+!_!g;
 478         lc($subj);
 479 }
 480
 481 sub do_cat_mail {
 482         my ($git, $blob) = @_;
 483         my $mime = eval {
 484                 my $str = $git->cat_file($blob);
 485                 Email::MIME->new($str);
 486         };
 487         $@ ? undef : $mime;
 488 }
 489
 490 sub index_blob {
 491         my ($self, $git, $blob) = @_;
 492         my $mime = do_cat_mail($git, $blob) or return;
 493         eval { $self->add_message($mime) };
 494         warn "W: index_blob $blob: $@\n" if $@;
 495 }
 496
 497 sub unindex_blob {
 498         my ($self, $git, $blob) = @_;
 499         my $mime = do_cat_mail($git, $blob) or return;
 500         my $mid = $mime->header_obj->header_raw('Message-ID');
 501         eval { $self->remove_message($mid) } if defined $mid;
 502         warn "W: unindex_blob $blob: $@\n" if $@;
 503 }
 504
 505 sub enquire {
 506         my ($self) = @_;
 507         $self->{enquire} ||= Search::Xapian::Enquire->new($self->{xdb});
 508 }
 509
 510 # indexes all unindexed messages
 511 sub index_sync {
 512         my ($self) = @_;
 513         require PublicInbox::GitCatFile;
 514         my $db = $self->{xdb};
 515         my $hex = '[a-f0-9]';
 516         my $h40 = $hex .'{40}';
 517         my $addmsg = qr!^:000000 100644 \S+ ($h40) A\t${hex}{2}/${hex}{38}$!;
 518         my $delmsg = qr!^:100644 000000 ($h40) \S+ D\t${hex}{2}/${hex}{38}$!;
 519
 520         $db->begin_transaction;
 521         eval {
 522                 my $git = PublicInbox::GitCatFile->new($self->{git_dir});
 523
 524                 my $latest = $db->get_metadata('last_commit');
 525                 my $range = length $latest ? "$latest..HEAD" : 'HEAD';
 526                 $latest = undef;
 527
 528                 # get indexed messages
 529                 my @cmd = ('git', "--git-dir=$self->{git_dir}", "log",
 530                             qw/--reverse --no-notes --no-color --raw -r
 531                                --no-abbrev/, $range);
 532                 my $pid = open(my $log, '-|', @cmd) or
 533                         die('open` '.join(' ', @cmd) . " pipe failed: $!\n");
 534
 535                 while (my $line = <$log>) {
 536                         if ($line =~ /$addmsg/o) {
 537                                 $self->index_blob($git, $1);
 538                         } elsif ($line =~ /$delmsg/o) {
 539                                 $self->unindex_blob($git, $1);
 540                         } elsif ($line =~ /^commit ($h40)/o) {
 541                                 $latest = $1;
 542                         }
 543                 }
 544                 close $log;
 545                 $db->set_metadata('last_commit', $latest) if defined $latest;
 546         };
 547         if ($@) {
 548                 warn "indexing failed: $@\n";
 549                 $db->cancel_transaction;
 550         } else {
 551                 $db->commit_transaction;
 552         }
 553 }
 554
 555 1;