lib/PublicInbox/Search.pm

   1 # Copyright (C) 2015-2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 # based on notmuch, but with no concept of folders, files or flags
   4 #
   5 # Read-only search interface for use by the web and NNTP interfaces
   6 package PublicInbox::Search;
   7 use strict;
   8 use warnings;
   9
  10 # values for searching
  11 use constant TS => 0; # timestamp
  12 use constant NUM => 1; # NNTP article number
  13 use constant BYTES => 2; # :bytes as defined in RFC 3977
  14 use constant LINES => 3; # :lines as defined in RFC 3977
  15 use constant YYYYMMDD => 4; # for searching in the WWW UI
  16
  17 use Search::Xapian qw/:standard/;
  18 use PublicInbox::SearchMsg;
  19 use PublicInbox::MIME;
  20 use PublicInbox::MID qw/mid_clean id_compress/;
  21
  22 # This is English-only, everything else is non-standard and may be confused as
  23 # a prefix common in patch emails
  24 our $REPLY_RE = qr/^re:\s+/i;
  25 our $LANG = 'english';
  26
  27 use constant {
  28         # SCHEMA_VERSION history
  29         # 0 - initial
  30         # 1 - subject_path is lower-cased
  31         # 2 - subject_path is id_compress in the index, only
  32         # 3 - message-ID is compressed if it includes '%' (hack!)
  33         # 4 - change "Re: " normalization, avoid circular Reference ghosts
  34         # 5 - subject_path drops trailing '.'
  35         # 6 - preserve References: order in document data
  36         # 7 - remove references and inreplyto terms
  37         # 8 - remove redundant/unneeded document data
  38         # 9 - disable Message-ID compression (SHA-1)
  39         # 10 - optimize doc for NNTP overviews
  40         # 11 - merge threads when vivifying ghosts
  41         # 12 - change YYYYMMDD value column to numeric
  42         # 13 - fix threading for empty References/In-Reply-To
  43         #      (commit 83425ef12e4b65cdcecd11ddcb38175d4a91d5a0)
  44         # 14 - fix ghost root vivification
  45         SCHEMA_VERSION => 14,
  46
  47         # n.b. FLAG_PURE_NOT is expensive not suitable for a public website
  48         # as it could become a denial-of-service vector
  49         QP_FLAGS => FLAG_PHRASE|FLAG_BOOLEAN|FLAG_LOVEHATE|FLAG_WILDCARD,
  50 };
  51
  52 # setup prefixes
  53 my %bool_pfx_internal = (
  54         type => 'T', # "mail" or "ghost"
  55         thread => 'G', # newsGroup (or similar entity - e.g. a web forum name)
  56 );
  57
  58 my %bool_pfx_external = (
  59         mid => 'XMID', # Message-ID (full/exact)
  60 );
  61
  62 my %prob_prefix = (
  63         # for mairix compatibility
  64         s => 'S',
  65         m => 'XM', # 'mid:' (bool) is exact, 'm:' (prob) can do partial
  66         f => 'A',
  67         t => 'XTO',
  68         tc => 'XTO XCC',
  69         c => 'XCC',
  70         tcf => 'XTO XCC A',
  71         a => 'XTO XCC A',
  72         b => 'XNQ XQUOT',
  73         bs => 'XNQ XQUOT S',
  74         n => 'XFN',
  75
  76         q => 'XQUOT',
  77         nq => 'XNQ',
  78         dfn => 'XDFN',
  79         dfa => 'XDFA',
  80         dfb => 'XDFB',
  81         dfhh => 'XDFHH',
  82         dfctx => 'XDFCTX',
  83         dfpre => 'XDFPRE',
  84         dfpost => 'XDFPOST',
  85         dfblob => 'XDFPRE XDFPOST',
  86
  87         # default:
  88         '' => 'XM S A XNQ XQUOT XFN',
  89 );
  90
  91 # not documenting m: and mid: for now, the using the URLs works w/o Xapian
  92 our @HELP = (
  93         's:' => 'match within Subject  e.g. s:"a quick brown fox"',
  94         'd:' => <<EOF,
  95 date range as YYYYMMDD  e.g. d:19931002..20101002
  96 Open-ended ranges such as d:19931002.. and d:..20101002
  97 are also supported
  98 EOF
  99         'b:' => 'match within message body, including text attachments',
 100         'nq:' => 'match non-quoted text within message body',
 101         'q:' => 'match quoted text within message body',
 102         'n:' => 'match filename of attachment(s)',
 103         't:' => 'match within the To header',
 104         'c:' => 'match within the Cc header',
 105         'f:' => 'match within the From header',
 106         'a:' => 'match within the To, Cc, and From headers',
 107         'tc:' => 'match within the To and Cc headers',
 108         'bs:' => 'match within the Subject and body',
 109         'dfn:' => 'match filename from diff',
 110         'dfa:' => 'match diff removed (-) lines',
 111         'dfb:' => 'match diff added (+) lines',
 112         'dfhh:' => 'match diff hunk header context (usually a function name)',
 113         'dfctx:' => 'match diff context lines',
 114         'dfpre:' => 'match pre-image git blob ID',
 115         'dfpost:' => 'match post-image git blob ID',
 116         'dfblob:' => 'match either pre or post-image git blob ID',
 117 );
 118 chomp @HELP;
 119
 120 my $mail_query = Search::Xapian::Query->new('T' . 'mail');
 121
 122 sub xdir {
 123         my ($self) = @_;
 124         if ($self->{version} == 1) {
 125                 "$self->{mainrepo}/public-inbox/xapian" . SCHEMA_VERSION;
 126         } else {
 127                 my $dir = "$self->{mainrepo}/xap" . SCHEMA_VERSION;
 128                 my $part = $self->{partition};
 129                 defined $part or die "partition not given";
 130                 $dir .= "/$part";
 131         }
 132 }
 133
 134 sub new {
 135         my ($class, $mainrepo, $altid) = @_;
 136         my $version = 1;
 137         my $ibx = $mainrepo;
 138         if (ref $ibx) {
 139                 $version = $ibx->{version} || 1;
 140                 $mainrepo = $ibx->{mainrepo};
 141         }
 142         my $self = bless {
 143                 mainrepo => $mainrepo,
 144                 altid => $altid,
 145                 version => $version,
 146         }, $class;
 147         if ($version >= 2) {
 148                 my $dir = "$self->{mainrepo}/xap" . SCHEMA_VERSION;
 149                 my $xdb;
 150                 my $parts = 0;
 151                 foreach my $part (<$dir/*>) {
 152                         -d $part && $part =~ m!/\d+\z! or next;
 153                         $parts++;
 154                         my $sub = Search::Xapian::Database->new($part);
 155                         if ($xdb) {
 156                                 $xdb->add_database($sub);
 157                         } else {
 158                                 $xdb = $sub;
 159                         }
 160                 }
 161                 $self->{xdb} = $xdb;
 162                 $self->{skel} = Search::Xapian::Database->new("$dir/skel");
 163         } else {
 164                 $self->{xdb} = Search::Xapian::Database->new($self->xdir);
 165         }
 166         $self;
 167 }
 168
 169 sub reopen {
 170         my ($self) = @_;
 171         $self->{xdb}->reopen;
 172         if (my $skel = $self->{skel}) {
 173                 $skel->reopen;
 174         }
 175 }
 176
 177 # read-only
 178 sub query {
 179         my ($self, $query_string, $opts) = @_;
 180         my $query;
 181
 182         $opts ||= {};
 183         unless ($query_string eq '') {
 184                 $query = $self->qp->parse_query($query_string, QP_FLAGS);
 185                 $opts->{relevance} = 1 unless exists $opts->{relevance};
 186         }
 187
 188         _do_enquire($self, $query, $opts);
 189 }
 190
 191 sub get_thread {
 192         my ($self, $mid, $opts) = @_;
 193         my $smsg = retry_reopen($self, sub { lookup_skeleton($self, $mid) });
 194
 195         return { total => 0, msgs => [] } unless $smsg;
 196         my $qtid = Search::Xapian::Query->new('G' . $smsg->thread_id);
 197         my $path = $smsg->path;
 198         if (defined $path && $path ne '') {
 199                 my $path = id_compress($smsg->path);
 200                 my $qsub = Search::Xapian::Query->new('XPATH' . $path);
 201                 $qtid = Search::Xapian::Query->new(OP_OR, $qtid, $qsub);
 202         }
 203         $opts ||= {};
 204         $opts->{limit} ||= 1000;
 205
 206         # always sort threads by timestamp, this makes life easier
 207         # for the threading algorithm (in SearchThread.pm)
 208         $opts->{asc} = 1;
 209         $opts->{enquire} = enquire_skel($self);
 210         _do_enquire($self, $qtid, $opts);
 211 }
 212
 213 sub retry_reopen {
 214         my ($self, $cb) = @_;
 215         my $ret;
 216         for (1..10) {
 217                 eval { $ret = $cb->() };
 218                 return $ret unless $@;
 219                 # Exception: The revision being read has been discarded -
 220                 # you should call Xapian::Database::reopen()
 221                 if (ref($@) eq 'Search::Xapian::DatabaseModifiedError') {
 222                         reopen($self);
 223                 } else {
 224                         warn "ref: ", ref($@), "\n";
 225                         die;
 226                 }
 227         }
 228 }
 229
 230 sub _do_enquire {
 231         my ($self, $query, $opts) = @_;
 232         retry_reopen($self, sub { _enquire_once($self, $query, $opts) });
 233 }
 234
 235 sub _enquire_once {
 236         my ($self, $query, $opts) = @_;
 237         my $enquire = $opts->{enquire} || enquire($self);
 238         if (defined $query) {
 239                 $query = Search::Xapian::Query->new(OP_AND,$query,$mail_query);
 240         } else {
 241                 $query = $mail_query;
 242         }
 243         $enquire->set_query($query);
 244         $opts ||= {};
 245         my $desc = !$opts->{asc};
 246         if ($opts->{relevance}) {
 247                 $enquire->set_sort_by_relevance_then_value(TS, $desc);
 248         } elsif ($opts->{num}) {
 249                 $enquire->set_sort_by_value(NUM, 0);
 250         } else {
 251                 $enquire->set_sort_by_value_then_relevance(TS, $desc);
 252         }
 253         my $offset = $opts->{offset} || 0;
 254         my $limit = $opts->{limit} || 50;
 255         my $mset = $enquire->get_mset($offset, $limit);
 256         return $mset if $opts->{mset};
 257         my @msgs = map {
 258                 PublicInbox::SearchMsg->load_doc($_->get_document);
 259         } $mset->items;
 260
 261         { total => $mset->get_matches_estimated, msgs => \@msgs }
 262 }
 263
 264 # read-write
 265 sub stemmer { Search::Xapian::Stem->new($LANG) }
 266
 267 # read-only
 268 sub qp {
 269         my ($self) = @_;
 270
 271         my $qp = $self->{query_parser};
 272         return $qp if $qp;
 273
 274         # new parser
 275         $qp = Search::Xapian::QueryParser->new;
 276         $qp->set_default_op(OP_AND);
 277         $qp->set_database($self->{xdb});
 278         $qp->set_stemmer($self->stemmer);
 279         $qp->set_stemming_strategy(STEM_SOME);
 280         $qp->add_valuerangeprocessor(
 281                 Search::Xapian::NumberValueRangeProcessor->new(YYYYMMDD, 'd:'));
 282
 283         while (my ($name, $prefix) = each %bool_pfx_external) {
 284                 $qp->add_boolean_prefix($name, $prefix);
 285         }
 286
 287         # we do not actually create AltId objects,
 288         # just parse the spec to avoid the extra DB handles for now.
 289         if (my $altid = $self->{altid}) {
 290                 my $user_pfx = $self->{-user_pfx} ||= [];
 291                 for (@$altid) {
 292                         # $_ = 'serial:gmane:/path/to/gmane.msgmap.sqlite3'
 293                         /\Aserial:(\w+):/ or next;
 294                         my $pfx = $1;
 295                         push @$user_pfx, "$pfx:", <<EOF;
 296 alternate serial number  e.g. $pfx:12345 (boolean)
 297 EOF
 298                         # gmane => XGMANE
 299                         $qp->add_boolean_prefix($pfx, 'X'.uc($pfx));
 300                 }
 301                 chomp @$user_pfx;
 302         }
 303
 304         while (my ($name, $prefix) = each %prob_prefix) {
 305                 $qp->add_prefix($name, $_) foreach split(/ /, $prefix);
 306         }
 307
 308         $self->{query_parser} = $qp;
 309 }
 310
 311 sub num_range_processor {
 312         $_[0]->{nrp} ||= Search::Xapian::NumberValueRangeProcessor->new(NUM);
 313 }
 314
 315 # only used for NNTP server
 316 sub query_xover {
 317         my ($self, $beg, $end, $offset) = @_;
 318         my $qp = Search::Xapian::QueryParser->new;
 319         $qp->set_database($self->{skel} || $self->{xdb});
 320         $qp->add_valuerangeprocessor($self->num_range_processor);
 321         my $query = $qp->parse_query("$beg..$end", QP_FLAGS);
 322
 323         my $opts = {
 324                 enquire => enquire_skel($self),
 325                 num => 1,
 326                 limit => 200,
 327                 offset => $offset,
 328         };
 329         _do_enquire($self, $query, $opts);
 330 }
 331
 332 sub lookup_skeleton {
 333         my ($self, $mid) = @_;
 334         my $skel = $self->{skel} or return lookup_message($self, $mid);
 335         $mid = mid_clean($mid);
 336         my $term = 'XMID' . $mid;
 337         my $smsg;
 338         my $beg = $skel->postlist_begin($term);
 339         if ($beg != $skel->postlist_end($term)) {
 340                 my $doc_id = $beg->get_docid;
 341                 if (defined $doc_id) {
 342                         # raises on error:
 343                         my $doc = $skel->get_document($doc_id);
 344                         $smsg = PublicInbox::SearchMsg->wrap($doc, $mid);
 345                         $smsg->{doc_id} = $doc_id;
 346                 }
 347         }
 348         $smsg;
 349 }
 350
 351 sub lookup_message {
 352         my ($self, $mid) = @_;
 353         $mid = mid_clean($mid);
 354
 355         my $doc_id = $self->find_first_doc_id('XMID' . $mid);
 356         my $smsg;
 357         if (defined $doc_id) {
 358                 # raises on error:
 359                 my $doc = $self->{xdb}->get_document($doc_id);
 360                 $smsg = PublicInbox::SearchMsg->wrap($doc, $mid);
 361                 $smsg->{doc_id} = $doc_id;
 362         }
 363         $smsg;
 364 }
 365
 366 sub lookup_mail { # no ghosts!
 367         my ($self, $mid) = @_;
 368         retry_reopen($self, sub {
 369                 my $smsg = lookup_message($self, $mid) or return;
 370                 $smsg->load_expand;
 371         });
 372 }
 373
 374 sub find_unique_doc_id {
 375         my ($self, $termval) = @_;
 376
 377         my ($begin, $end) = $self->find_doc_ids($termval);
 378
 379         return undef if $begin->equal($end); # not found
 380
 381         my $rv = $begin->get_docid;
 382
 383         # sanity check
 384         $begin->inc;
 385         $begin->equal($end) or die "Term '$termval' is not unique\n";
 386         $rv;
 387 }
 388
 389 # returns begin and end PostingIterator
 390 sub find_doc_ids {
 391         my ($self, $termval) = @_;
 392         my $db = $self->{xdb};
 393
 394         ($db->postlist_begin($termval), $db->postlist_end($termval));
 395 }
 396
 397 sub find_first_doc_id {
 398         my ($self, $termval) = @_;
 399
 400         my ($begin, $end) = $self->find_doc_ids($termval);
 401
 402         return undef if $begin->equal($end); # not found
 403
 404         $begin->get_docid;
 405 }
 406
 407 # normalize subjects so they are suitable as pathnames for URLs
 408 # XXX: consider for removal
 409 sub subject_path {
 410         my $subj = pop;
 411         $subj = subject_normalized($subj);
 412         $subj =~ s![^a-zA-Z0-9_\.~/\-]+!_!g;
 413         lc($subj);
 414 }
 415
 416 sub subject_normalized {
 417         my $subj = pop;
 418         $subj =~ s/\A\s+//s; # no leading space
 419         $subj =~ s/\s+\z//s; # no trailing space
 420         $subj =~ s/\s+/ /gs; # no redundant spaces
 421         $subj =~ s/\.+\z//; # no trailing '.'
 422         $subj =~ s/$REPLY_RE//igo; # remove reply prefix
 423         $subj;
 424 }
 425
 426 sub enquire {
 427         my ($self) = @_;
 428         $self->{enquire} ||= Search::Xapian::Enquire->new($self->{xdb});
 429 }
 430
 431 sub enquire_skel {
 432         my ($self) = @_;
 433         if (my $skel = $self->{skel}) {
 434                 $self->{enquire_skel} ||= Search::Xapian::Enquire->new($skel);
 435         } else {
 436                 enquire($self);
 437         }
 438 }
 439
 440 sub help {
 441         my ($self) = @_;
 442         $self->qp; # parse altids
 443         my @ret = @HELP;
 444         if (my $user_pfx = $self->{-user_pfx}) {
 445                 push @ret, @$user_pfx;
 446         }
 447         \@ret;
 448 }
 449
 450 1;