lib/PublicInbox/Search.pm

   1 # Copyright (C) 2015, all contributors <meta@public-inbox.org>
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 # based on notmuch, but with no concept of folders, files or flags
   4 package PublicInbox::Search;
   5 use strict;
   6 use warnings;
   7 use PublicInbox::SearchMsg;
   8 use base qw/Exporter/;
   9 use Search::Xapian qw/:standard/;
  10 require PublicInbox::View;
  11 use Date::Parse qw/str2time/;
  12 use POSIX qw//;
  13 use Email::MIME;
  14 use PublicInbox::MID qw/mid_clean mid_compressed/;
  15
  16 our @EXPORT = qw/xpfx/;
  17
  18 use constant {
  19         TS => 0,
  20         SCHEMA_VERSION => 0,
  21         LANG => 'english',
  22         QP_FLAGS => FLAG_PHRASE|FLAG_BOOLEAN|FLAG_LOVEHATE|FLAG_WILDCARD,
  23 };
  24
  25 # setup prefixes
  26 my %bool_pfx_internal = (
  27         type => 'T', # "mail" or "ghost"
  28         mid => 'Q', # uniQue id (Message-ID or mid_compressed)
  29 );
  30
  31 my %bool_pfx_external = (
  32         path => 'XPATH',
  33         thread => 'G', # newsGroup (or similar entity - e.g. a web forum name)
  34         references => 'XREFS',
  35         inreplyto => 'XIRT',
  36 );
  37
  38 my %prob_prefix = (
  39         subject => 'S',
  40 );
  41
  42 my %all_pfx = (%bool_pfx_internal, %bool_pfx_external, %prob_prefix);
  43
  44 sub xpfx { $all_pfx{$_[0]} }
  45
  46 our %PFX2TERM_RMAP;
  47 while (my ($k, $v) = each %all_pfx) {
  48         next if $prob_prefix{$k};
  49         $PFX2TERM_RMAP{$v} = $k;
  50 }
  51
  52 my $mail_query = Search::Xapian::Query->new(xpfx('type') . 'mail');
  53
  54 sub new {
  55         my ($class, $git_dir, $writable) = @_;
  56         # allow concurrent versions for easier rollback:
  57         my $dir = "$git_dir/public-inbox/xapian" . SCHEMA_VERSION;
  58         my $db;
  59
  60         if ($writable) { # not used by the WWW interface
  61                 require Search::Xapian::WritableDatabase;
  62                 require File::Path;
  63                 File::Path::mkpath($dir);
  64                 $db = Search::Xapian::WritableDatabase->new($dir,
  65                                         Search::Xapian::DB_CREATE_OR_OPEN);
  66         } else {
  67                 $db = Search::Xapian::Database->new($dir);
  68         }
  69         bless { xdb => $db, git_dir => $git_dir }, $class;
  70 }
  71
  72 sub reopen { $_[0]->{xdb}->reopen }
  73
  74 sub add_message {
  75         my ($self, $mime) = @_; # mime = Email::MIME object
  76         my $db = $self->{xdb};
  77
  78         my $doc_id;
  79         my $mid = mid_clean($mime->header('Message-ID'));
  80         $mid = mid_compressed($mid);
  81         my $was_ghost = 0;
  82         my $ct_msg = $mime->header('Content-Type') || 'text/plain';
  83         my $enc_msg = PublicInbox::View::enc_for($ct_msg);
  84
  85         $db->begin_transaction;
  86         eval {
  87                 my $smsg = $self->lookup_message($mid);
  88                 my $doc;
  89
  90                 if ($smsg) {
  91                         $smsg->ensure_metadata;
  92                         # convert a ghost to a regular message
  93                         # it will also clobber any existing regular message
  94                         $smsg->mime($mime);
  95                         $doc = $smsg->{doc};
  96
  97                         my $type = xpfx('type');
  98                         eval {
  99                                 $doc->remove_term($type . 'ghost');
 100                                 $was_ghost = 1;
 101                         };
 102
 103                         # probably does not exist:
 104                         eval { $doc->remove_term($type . 'mail') };
 105                         $doc->add_term($type . 'mail');
 106                 }  else {
 107                         $smsg = PublicInbox::SearchMsg->new($mime);
 108                         $doc = $smsg->{doc};
 109                         $doc->add_term(xpfx('mid') . $mid);
 110                 }
 111
 112                 my $subj = $mime->header('Subject');
 113                 $subj = '' unless defined $subj;
 114
 115                 if (length $subj) {
 116                         $doc->add_term(xpfx('subject') . $subj);
 117
 118                         my $path = subject_path($subj);
 119                         $doc->add_term(xpfx('path') . $path);
 120                 }
 121
 122                 my $from = $mime->header('From') || '';
 123                 my @from;
 124
 125                 if ($from) {
 126                         @from = Email::Address->parse($from);
 127                         $from = $from[0]->name;
 128                 }
 129
 130                 my $ts = eval { str2time($mime->header('Date')) } || 0;
 131                 my $date = POSIX::strftime('%Y-%m-%d %H:%M', gmtime($ts));
 132                 $ts = Search::Xapian::sortable_serialise($ts);
 133                 $doc->add_value(PublicInbox::Search::TS, $ts);
 134
 135                 # this is what we show in index results:
 136                 $subj =~ tr/\n/ /;
 137                 $from =~ tr/\n/ /;
 138                 $doc->set_data("$mid\n$subj\n$from\n$date");
 139
 140                 my $tg = $self->term_generator;
 141
 142                 $tg->set_document($doc);
 143                 $tg->index_text($subj, 1, 'S') if $subj;
 144                 $tg->increase_termpos;
 145                 $tg->index_text($subj) if $subj;
 146                 $tg->increase_termpos;
 147
 148                 if (@from) {
 149                         $tg->index_text($from[0]->format);
 150                         $tg->increase_termpos;
 151                 }
 152
 153                 $mime->walk_parts(sub {
 154                         my ($part) = @_;
 155                         return if $part->subparts; # walk_parts already recurses
 156                         my $ct = $part->content_type || $ct_msg;
 157
 158                         # account for filter bugs...
 159                         $ct =~ m!\btext/plain\b!i or return;
 160
 161                         my $enc = PublicInbox::View::enc_for($ct, $enc_msg);
 162                         my (@orig, @quot);
 163                         foreach my $l (split(/\n/, $enc->decode($part->body))) {
 164                                 if ($l =~ /^\s*>/) {
 165                                         push @quot, $l;
 166                                 } else {
 167                                         push @orig, $l;
 168                                 }
 169                         }
 170                         if (@quot) {
 171                                 $tg->index_text(join("\n", @quot), 0);
 172                                 $tg->increase_termpos;
 173                         }
 174                         if (@orig) {
 175                                 $tg->index_text(join("\n", @orig));
 176                                 $tg->increase_termpos;
 177                         }
 178                 });
 179
 180                 if ($was_ghost) {
 181                         $doc_id = $smsg->doc_id;
 182                         $self->link_message($smsg, 0);
 183                         $db->replace_document($doc_id, $doc);
 184                 } else {
 185                         $self->link_message($smsg, 0);
 186                         $doc_id = $db->add_document($doc);
 187                 }
 188         };
 189
 190         if ($@) {
 191                 warn "failed to index message <$mid>: $@\n";
 192                 $db->cancel_transaction;
 193         } else {
 194                 $db->commit_transaction;
 195         }
 196         $doc_id;
 197 }
 198
 199 # returns deleted doc_id on success, undef on missing
 200 sub remove_message {
 201         my ($self, $mid) = @_;
 202         my $db = $self->{xdb};
 203         my $doc_id;
 204         $mid = mid_clean($mid);
 205         $mid = mid_compressed($mid);
 206
 207         $db->begin_transaction;
 208         eval {
 209                 $doc_id = $self->find_unique_doc_id('mid', $mid);
 210                 $db->delete_document($doc_id) if defined $doc_id;
 211         };
 212
 213         if ($@) {
 214                 warn "failed to remove message <$mid>: $@\n";
 215                 $db->cancel_transaction;
 216         } else {
 217                 $db->commit_transaction;
 218         }
 219         $doc_id;
 220 }
 221
 222 # read-only
 223 sub query {
 224         my ($self, $query_string, $opts) = @_;
 225         my $query = $self->qp->parse_query($query_string, QP_FLAGS);
 226
 227         $query = Search::Xapian::Query->new(OP_AND, $mail_query, $query);
 228         $self->do_enquire($query, $opts);
 229 }
 230
 231 # given a message ID, get replies to a message
 232 sub get_replies {
 233         my ($self, $mid, $opts) = @_;
 234         $mid = mid_clean($mid);
 235         $mid = mid_compressed($mid);
 236         my $qp = $self->qp;
 237         my $irt = $qp->parse_query("inreplyto:$mid", 0);
 238         my $ref = $qp->parse_query("references:$mid", 0);
 239         my $query = Search::Xapian::Query->new(OP_OR, $irt, $ref);
 240
 241         $self->do_enquire($query);
 242 }
 243
 244 sub get_thread {
 245         my ($self, $mid, $opts) = @_;
 246         my $smsg = eval { $self->lookup_message($mid) };
 247
 248         return { count => 0, msgs => [] } unless $smsg;
 249         my $qp = $self->qp;
 250         my $qtid = $qp->parse_query('thread:'.$smsg->thread_id);
 251         my $qsub = $qp->parse_query('path:'.$smsg->path);
 252         my $query = Search::Xapian::Query->new(OP_OR, $qtid, $qsub);
 253         $self->do_enquire($query);
 254 }
 255
 256 # private subs below
 257
 258 sub do_enquire {
 259         my ($self, $query, $opts) = @_;
 260         my $enquire = $self->enquire;
 261
 262         $enquire->set_query($query);
 263         $enquire->set_sort_by_relevance_then_value(TS, 0);
 264         $opts ||= {};
 265         my $offset = $opts->{offset} || 0;
 266         my $limit = $opts->{limit} || 50;
 267         my $mset = $enquire->get_mset($offset, $limit);
 268         my @msgs = map { $_->get_document->get_data } $mset->items;
 269
 270         { count => $mset->get_matches_estimated, msgs => \@msgs }
 271 }
 272
 273 # read-write
 274 sub stemmer { Search::Xapian::Stem->new(LANG) }
 275
 276 # read-only
 277 sub qp {
 278         my ($self) = @_;
 279
 280         my $qp = $self->{query_parser};
 281         return $qp if $qp;
 282
 283         # new parser
 284         $qp = Search::Xapian::QueryParser->new;
 285         $qp->set_default_op(OP_AND);
 286         $qp->set_database($self->{xdb});
 287         $qp->set_stemmer($self->stemmer);
 288         $qp->set_stemming_strategy(STEM_SOME);
 289         $qp->add_valuerangeprocessor($self->ts_range_processor);
 290         $qp->add_valuerangeprocessor($self->date_range_processor);
 291
 292         while (my ($name, $prefix) = each %bool_pfx_external) {
 293                 $qp->add_boolean_prefix($name, $prefix);
 294         }
 295
 296         while (my ($name, $prefix) = each %prob_prefix) {
 297                 $qp->add_prefix($name, $prefix);
 298         }
 299
 300         $self->{query_parser} = $qp;
 301 }
 302
 303 sub term_generator { # write-only
 304         my ($self) = @_;
 305
 306         my $tg = $self->{term_generator};
 307         return $tg if $tg;
 308
 309         $tg = Search::Xapian::TermGenerator->new;
 310         $tg->set_stemmer($self->stemmer);
 311
 312         $self->{term_generator} = $tg;
 313 }
 314
 315 sub next_doc_id { $_[0]->{xdb}->get_lastdocid + 1 }
 316
 317 # increments last_thread_id counter
 318 # returns a 64-bit integer represented as a hex string
 319 sub next_thread_id {
 320         my ($self) = @_;
 321         my $db = $self->{xdb};
 322         my $last_thread_id = int($db->get_metadata('last_thread_id') || 0);
 323
 324         $db->set_metadata('last_thread_id', ++$last_thread_id);
 325
 326         $last_thread_id;
 327 }
 328
 329 sub ts_range_processor {
 330         $_[0]->{tsrp} ||= Search::Xapian::NumberValueRangeProcessor->new(TS);
 331 }
 332
 333 sub date_range_processor {
 334         $_[0]->{drp} ||= Search::Xapian::DateValueRangeProcessor->new(TS);
 335 }
 336
 337 sub link_message {
 338         my ($self, $smsg, $is_ghost) = @_;
 339
 340         if ($is_ghost) {
 341                 $smsg->ensure_metadata;
 342         } else {
 343                 $self->link_message_to_parents($smsg);
 344         }
 345 }
 346
 347 sub link_message_to_parents {
 348         my ($self, $smsg) = @_;
 349         my $doc = $smsg->{doc};
 350         my $mid = mid_compressed($smsg->mid);
 351         my $mime = $smsg->mime;
 352         my $refs = $mime->header('References');
 353         my @refs = $refs ? ($refs =~ /<([^>]+)>/g) : ();
 354         my $irt = $mime->header('In-Reply-To');
 355         if ($irt) {
 356                 if ($irt =~ /<([^>]+)>/) {
 357                         $irt = $1;
 358                 }
 359                 push @refs, $irt;
 360         }
 361
 362         my $tid;
 363         if (@refs) {
 364                 @refs = map { mid_compressed($_) } @refs;
 365                 my %uniq;
 366                 @refs = grep { !$uniq{$_}++ } @refs; # uniq
 367
 368                 $doc->add_term(xpfx('inreplyto') . $refs[-1]);
 369
 370                 my $ref_pfx = xpfx('references');
 371
 372                 # first ref *should* be the thread root,
 373                 # but we can never trust clients to do the right thing
 374                 my $ref = shift @refs;
 375                 $doc->add_term($ref_pfx . $ref);
 376                 $tid = $self->_resolve_mid_to_tid($ref);
 377
 378                 # the rest of the refs should point to this tid:
 379                 foreach $ref (@refs) {
 380                         $doc->add_term($ref_pfx . $ref);
 381                         my $ptid = $self->_resolve_mid_to_tid($ref);
 382                         if ($tid ne $ptid) {
 383                                 $self->merge_threads($tid, $ptid);
 384                         }
 385                 }
 386         } else {
 387                 $tid = $self->next_thread_id;
 388         }
 389         $doc->add_term(xpfx('thread') . $tid);
 390 }
 391
 392 sub lookup_message {
 393         my ($self, $mid) = @_;
 394         $mid = mid_clean($mid);
 395         $mid = mid_compressed($mid);
 396
 397         my $doc_id = $self->find_unique_doc_id('mid', $mid);
 398         my $smsg;
 399         if (defined $doc_id) {
 400                 # raises on error:
 401                 my $doc = $self->{xdb}->get_document($doc_id);
 402                 $smsg = PublicInbox::SearchMsg->wrap($doc, $mid);
 403                 $smsg->doc_id($doc_id);
 404         }
 405         $smsg;
 406 }
 407
 408 sub find_unique_doc_id {
 409         my ($self, $term, $value) = @_;
 410
 411         my ($begin, $end) = $self->find_doc_ids($term, $value);
 412
 413         return undef if $begin->equal($end); # not found
 414
 415         my $rv = $begin->get_docid;
 416
 417         # sanity check
 418         $begin->inc;
 419         $begin->equal($end) or die "Term '$term:$value' is not unique\n";
 420         $rv;
 421 }
 422
 423 # returns begin and end PostingIterator
 424 sub find_doc_ids {
 425         my ($self, $term, $value) = @_;
 426
 427         $self->find_doc_ids_for_term(xpfx($term) . $value);
 428 }
 429
 430 # returns begin and end PostingIterator
 431 sub find_doc_ids_for_term {
 432         my ($self, $term) = @_;
 433         my $db = $self->{xdb};
 434
 435         ($db->postlist_begin($term), $db->postlist_end($term));
 436 }
 437
 438 # this will create a ghost as necessary
 439 sub _resolve_mid_to_tid {
 440         my ($self, $mid) = @_;
 441
 442         my $smsg = $self->lookup_message($mid) || $self->create_ghost($mid);
 443         $smsg->thread_id;
 444 }
 445
 446 sub create_ghost {
 447         my ($self, $mid, $tid) = @_;
 448
 449         $mid = mid_compressed($mid);
 450         $tid = $self->next_thread_id unless defined $tid;
 451
 452         my $doc = Search::Xapian::Document->new;
 453         $doc->add_term(xpfx('mid') . $mid);
 454         $doc->add_term(xpfx('thread') . $tid);
 455         $doc->add_term(xpfx('type') . 'ghost');
 456
 457         my $smsg = PublicInbox::SearchMsg->wrap($doc, $mid);
 458         $self->link_message($smsg, 1);
 459         $self->{xdb}->add_document($doc);
 460
 461         $smsg;
 462 }
 463
 464 sub merge_threads {
 465         my ($self, $winner_tid, $loser_tid) = @_;
 466         my ($head, $tail) = $self->find_doc_ids('thread', $loser_tid);
 467         my $thread_pfx = xpfx('thread');
 468         my $db = $self->{xdb};
 469
 470         for (; $head != $tail; $head->inc) {
 471                 my $docid = $head->get_docid;
 472                 my $doc = $db->get_document($docid);
 473                 $doc->remove_term($thread_pfx . $loser_tid);
 474                 $doc->add_term($thread_pfx . $winner_tid);
 475                 $db->replace_document($docid, $doc);
 476         }
 477 }
 478
 479 # normalize subjects so they are suitable as pathnames for URLs
 480 sub subject_path {
 481         my ($subj) = @_;
 482
 483         $subj =~ s/\A\s+//;
 484         $subj =~ s/\s+\z//;
 485         $subj =~ s/^(?:re|aw):\s*//i; # remove reply prefix (aw: German)
 486         $subj =~ s![^a-zA-Z0-9_\.~/\-]+!_!g;
 487         $subj;
 488 }
 489
 490 sub do_cat_mail {
 491         my ($git, $blob) = @_;
 492         my $mime = eval {
 493                 my $str = $git->cat_file($blob);
 494                 Email::MIME->new($str);
 495         };
 496         $@ ? undef : $mime;
 497 }
 498
 499 sub index_blob {
 500         my ($self, $git, $blob) = @_;
 501         my $mime = do_cat_mail($git, $blob) or return;
 502         eval { $self->add_message($mime) };
 503         warn "W: index_blob $blob: $@\n" if $@;
 504 }
 505
 506 sub unindex_blob {
 507         my ($self, $git, $blob) = @_;
 508         my $mime = do_cat_mail($git, $blob) or return;
 509         my $mid = $mime->header('Message-ID');
 510         eval { $self->remove_message($mid) } if defined $mid;
 511         warn "W: unindex_blob $blob: $@\n" if $@;
 512 }
 513
 514 sub enquire {
 515         my ($self) = @_;
 516         $self->{enquire} ||= Search::Xapian::Enquire->new($self->{xdb});
 517 }
 518
 519 # indexes all unindexed messages
 520 sub index_sync {
 521         my ($self, $git) = @_;
 522         my $db = $self->{xdb};
 523         my $latest = $db->get_metadata('last_commit');
 524         my $range = length $latest ? "$latest..HEAD" : 'HEAD';
 525         $latest = undef;
 526
 527         my $hex = '[a-f0-9]';
 528         my $h40 = $hex .'{40}';
 529         my $addmsg = qr!^:000000 100644 \S+ ($h40) A\t${hex}{2}/${hex}{38}$!;
 530         my $delmsg = qr!^:100644 000000 ($h40) \S+ D\t${hex}{2}/${hex}{38}$!;
 531
 532         # get indexed messages
 533         my @cmd = ('git', "--git-dir=$git->{git_dir}", "log",
 534                     qw/--reverse --no-notes --no-color --raw -r --no-abbrev/,
 535                     $range);
 536
 537         my $pid = open(my $log, '-|', @cmd) or
 538                 die('open` '.join(' ', @cmd) . " pipe failed: $!\n");
 539         my $last;
 540         while (my $line = <$log>) {
 541                 if ($line =~ /$addmsg/o) {
 542                         $self->index_blob($git, $1);
 543                 } elsif ($line =~ /$delmsg/o) {
 544                         $self->unindex_blob($git, $1);
 545                 } elsif ($line =~ /^commit ($h40)/o) {
 546                         my $commit = $1;
 547                         if (defined $latest) {
 548                                 $db->set_metadata('last_commit', $latest)
 549                         }
 550                         $latest = $commit;
 551                 }
 552         }
 553         close $log;
 554         $db->set_metadata('last_commit', $latest) if defined $latest;
 555 }
 556
 557 1;