lib/PublicInbox/Search.pm

   1 # Copyright (C) 2015, all contributors <meta@public-inbox.org>
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 # based on notmuch, but with no concept of folders, files or flags
   4 package PublicInbox::Search;
   5 use strict;
   6 use warnings;
   7 use PublicInbox::SearchMsg;
   8 use Search::Xapian qw/:standard/;
   9 use Email::MIME;
  10 use PublicInbox::MID qw/mid_clean mid_compressed/;
  11
  12 # This is English-only, everything else is non-standard and may be confused as
  13 # a prefix common in patch emails
  14 our $REPLY_RE = qr/^re:\s+/i;
  15 our $LANG = 'english';
  16
  17 use constant {
  18         TS => 0,
  19         # SCHEMA_VERSION history
  20         # 0 - initial
  21         # 1 - subject_path is lower-cased
  22         # 2 - subject_path is mid_compressed in the index, only
  23         # 3 - message-ID is compressed if it includes '%' (hack!)
  24         # 4 - change "Re: " normalization, avoid circular Reference ghosts
  25         # 5 - subject_path drops trailing '.'
  26         # 6 - preserve References: order in document data
  27         SCHEMA_VERSION => 6,
  28         QP_FLAGS => FLAG_PHRASE|FLAG_BOOLEAN|FLAG_LOVEHATE|FLAG_WILDCARD,
  29 };
  30
  31 # setup prefixes
  32 my %bool_pfx_internal = (
  33         type => 'T', # "mail" or "ghost"
  34         mid => 'Q', # uniQue id (Message-ID or mid_compressed)
  35 );
  36
  37 my %bool_pfx_external = (
  38         path => 'XPATH',
  39         thread => 'G', # newsGroup (or similar entity - e.g. a web forum name)
  40         references => 'XREFS',
  41         inreplyto => 'XIRT',
  42 );
  43
  44 my %prob_prefix = (
  45         subject => 'S',
  46 );
  47
  48 my %all_pfx = (%bool_pfx_internal, %bool_pfx_external, %prob_prefix);
  49
  50 sub xpfx { $all_pfx{$_[0]} }
  51
  52 our %PFX2TERM_RMAP;
  53 my %meta_pfx = (mid => 1, thread => 1, path => 1, type => 1);
  54 while (my ($k, $v) = each %all_pfx) {
  55         $PFX2TERM_RMAP{$v} = $k if $meta_pfx{$k};
  56 }
  57
  58 my $mail_query = Search::Xapian::Query->new(xpfx('type') . 'mail');
  59
  60 sub new {
  61         my ($class, $git_dir, $writable) = @_;
  62         # allow concurrent versions for easier rollback:
  63         my $dir = "$git_dir/public-inbox/xapian" . SCHEMA_VERSION;
  64         my $db;
  65
  66         if ($writable) { # not used by the WWW interface
  67                 require Search::Xapian::WritableDatabase;
  68                 my $flag = Search::Xapian::DB_OPEN;
  69                 if ($writable == 1) {
  70                         require File::Path;
  71                         File::Path::mkpath($dir);
  72                         $flag = Search::Xapian::DB_CREATE_OR_OPEN;
  73                 }
  74                 $db = Search::Xapian::WritableDatabase->new($dir, $flag);
  75         } else {
  76                 $db = Search::Xapian::Database->new($dir);
  77         }
  78         bless { xdb => $db, git_dir => $git_dir }, $class;
  79 }
  80
  81 sub reopen { $_[0]->{xdb}->reopen }
  82
  83 sub add_message {
  84         my ($self, $mime) = @_; # mime = Email::MIME object
  85         my $db = $self->{xdb};
  86
  87         my $doc_id;
  88         my $mid_orig = mid_clean($mime->header_obj->header('Message-ID'));
  89         my $mid = mid_compressed($mid_orig);
  90         my $was_ghost = 0;
  91         my $ct_msg = $mime->header('Content-Type') || 'text/plain';
  92
  93         eval {
  94                 my $smsg = $self->lookup_message($mid);
  95                 my $doc;
  96
  97                 if ($smsg) {
  98                         $smsg->ensure_metadata;
  99                         # convert a ghost to a regular message
 100                         # it will also clobber any existing regular message
 101                         $smsg->mime($mime);
 102                         $doc = $smsg->{doc};
 103
 104                         my $type = xpfx('type');
 105                         eval {
 106                                 $doc->remove_term($type . 'ghost');
 107                                 $was_ghost = 1;
 108                         };
 109
 110                         # probably does not exist:
 111                         eval { $doc->remove_term($type . 'mail') };
 112                         $doc->add_term($type . 'mail');
 113                 }  else {
 114                         $smsg = PublicInbox::SearchMsg->new($mime);
 115                         $doc = $smsg->{doc};
 116                         $doc->add_term(xpfx('mid') . $mid);
 117                 }
 118
 119                 my $subj = $smsg->subject;
 120
 121                 if (length $subj) {
 122                         $doc->add_term(xpfx('subject') . $subj);
 123
 124                         my $path = subject_path($subj);
 125                         $doc->add_term(xpfx('path') . mid_compressed($path));
 126                 }
 127
 128                 my $from = $smsg->from_name;
 129                 my $date = $smsg->date;
 130                 my $ts = Search::Xapian::sortable_serialise($smsg->ts);
 131                 $doc->add_value(PublicInbox::Search::TS, $ts);
 132
 133                 my $tg = $self->term_generator;
 134
 135                 $tg->set_document($doc);
 136                 $tg->index_text($subj, 1, 'S') if $subj;
 137                 $tg->increase_termpos;
 138                 $tg->index_text($subj) if $subj;
 139                 $tg->increase_termpos;
 140
 141                 $tg->index_text($smsg->from->format);
 142                 $tg->increase_termpos;
 143
 144                 $mime->walk_parts(sub {
 145                         my ($part) = @_;
 146                         return if $part->subparts; # walk_parts already recurses
 147                         my $ct = $part->content_type || $ct_msg;
 148
 149                         # account for filter bugs...
 150                         $ct =~ m!\btext/plain\b!i or return;
 151
 152                         my (@orig, @quot);
 153                         my $body = $part->body;
 154                         $part->body_set('');
 155                         my @lines = split(/\n/, $body);
 156                         while (defined(my $l = shift @lines)) {
 157                                 if ($l =~ /^\s*>/) {
 158                                         push @quot, $l;
 159                                 } else {
 160                                         push @orig, $l;
 161                                 }
 162                         }
 163                         if (@quot) {
 164                                 $tg->index_text(join("\n", @quot), 0);
 165                                 @quot = ();
 166                                 $tg->increase_termpos;
 167                         }
 168                         if (@orig) {
 169                                 $tg->index_text(join("\n", @orig));
 170                                 @orig = ();
 171                                 $tg->increase_termpos;
 172                         }
 173                 });
 174
 175                 if ($was_ghost) {
 176                         $doc_id = $smsg->doc_id;
 177                         $self->link_message($smsg, 0);
 178                         $doc->set_data($smsg->to_doc_data);
 179                         $db->replace_document($doc_id, $doc);
 180                 } else {
 181                         $self->link_message($smsg, 0);
 182                         $doc->set_data($smsg->to_doc_data);
 183                         $doc_id = $db->add_document($doc);
 184                 }
 185         };
 186
 187         if ($@) {
 188                 warn "failed to index message <$mid_orig>: $@\n";
 189                 return undef;
 190         }
 191         $doc_id;
 192 }
 193
 194 # returns deleted doc_id on success, undef on missing
 195 sub remove_message {
 196         my ($self, $mid_orig) = @_;
 197         my $db = $self->{xdb};
 198         my $doc_id;
 199         $mid_orig = mid_clean($mid_orig);
 200         my $mid = mid_compressed($mid_orig);
 201
 202         eval {
 203                 $doc_id = $self->find_unique_doc_id('mid', $mid);
 204                 $db->delete_document($doc_id) if defined $doc_id;
 205         };
 206
 207         if ($@) {
 208                 warn "failed to remove message <$mid_orig>: $@\n";
 209                 return undef;
 210         }
 211         $doc_id;
 212 }
 213
 214 # read-only
 215 sub query {
 216         my ($self, $query_string, $opts) = @_;
 217         my $query = $self->qp->parse_query($query_string, QP_FLAGS);
 218
 219         $self->do_enquire($query, $opts);
 220 }
 221
 222 sub get_subject_path {
 223         my ($self, $path, $opts) = @_;
 224         my $query = $self->qp->parse_query("path:".mid_compressed($path), 0);
 225         $self->do_enquire($query);
 226 }
 227
 228 # given a message ID, get followups to a message
 229 sub get_followups {
 230         my ($self, $mid, $opts) = @_;
 231         $mid = mid_clean($mid);
 232         $mid = mid_compressed($mid);
 233         my $qp = $self->qp;
 234         my $irt = $qp->parse_query("inreplyto:$mid", 0);
 235         my $ref = $qp->parse_query("references:$mid", 0);
 236         my $query = Search::Xapian::Query->new(OP_OR, $irt, $ref);
 237
 238         $self->do_enquire($query);
 239 }
 240
 241 sub get_thread {
 242         my ($self, $mid, $opts) = @_;
 243         my $smsg = eval { $self->lookup_message($mid) };
 244
 245         return { count => 0, msgs => [] } unless $smsg;
 246         my $qp = $self->qp;
 247         my $qtid = $qp->parse_query('thread:'.$smsg->thread_id);
 248         my $qsub = $qp->parse_query('path:'.mid_compressed($smsg->path));
 249         my $query = Search::Xapian::Query->new(OP_OR, $qtid, $qsub);
 250         $self->do_enquire($query, $opts);
 251 }
 252
 253 # private subs below
 254
 255 sub do_enquire {
 256         my ($self, $query, $opts) = @_;
 257         my $enquire = $self->enquire;
 258
 259         $query = Search::Xapian::Query->new(OP_AND, $query, $mail_query);
 260         $enquire->set_query($query);
 261         $enquire->set_sort_by_relevance_then_value(TS, 0);
 262         $opts ||= {};
 263         my $offset = $opts->{offset} || 0;
 264         my $limit = $opts->{limit} || 50;
 265         my $mset = $enquire->get_mset($offset, $limit);
 266         my @msgs = map {
 267                 PublicInbox::SearchMsg->load_doc($_->get_document);
 268         } $mset->items;
 269
 270         { count => $mset->get_matches_estimated, msgs => \@msgs }
 271 }
 272
 273 # read-write
 274 sub stemmer { Search::Xapian::Stem->new($LANG) }
 275
 276 # read-only
 277 sub qp {
 278         my ($self) = @_;
 279
 280         my $qp = $self->{query_parser};
 281         return $qp if $qp;
 282
 283         # new parser
 284         $qp = Search::Xapian::QueryParser->new;
 285         $qp->set_default_op(OP_AND);
 286         $qp->set_database($self->{xdb});
 287         $qp->set_stemmer($self->stemmer);
 288         $qp->set_stemming_strategy(STEM_SOME);
 289         $qp->add_valuerangeprocessor($self->ts_range_processor);
 290         $qp->add_valuerangeprocessor($self->date_range_processor);
 291
 292         while (my ($name, $prefix) = each %bool_pfx_external) {
 293                 $qp->add_boolean_prefix($name, $prefix);
 294         }
 295
 296         while (my ($name, $prefix) = each %prob_prefix) {
 297                 $qp->add_prefix($name, $prefix);
 298         }
 299
 300         $self->{query_parser} = $qp;
 301 }
 302
 303 sub term_generator { # write-only
 304         my ($self) = @_;
 305
 306         my $tg = $self->{term_generator};
 307         return $tg if $tg;
 308
 309         $tg = Search::Xapian::TermGenerator->new;
 310         $tg->set_stemmer($self->stemmer);
 311
 312         $self->{term_generator} = $tg;
 313 }
 314
 315 sub next_doc_id { $_[0]->{xdb}->get_lastdocid + 1 }
 316
 317 # increments last_thread_id counter
 318 # returns a 64-bit integer represented as a hex string
 319 sub next_thread_id {
 320         my ($self) = @_;
 321         my $db = $self->{xdb};
 322         my $last_thread_id = int($db->get_metadata('last_thread_id') || 0);
 323
 324         $db->set_metadata('last_thread_id', ++$last_thread_id);
 325
 326         $last_thread_id;
 327 }
 328
 329 sub ts_range_processor {
 330         $_[0]->{tsrp} ||= Search::Xapian::NumberValueRangeProcessor->new(TS);
 331 }
 332
 333 sub date_range_processor {
 334         $_[0]->{drp} ||= Search::Xapian::DateValueRangeProcessor->new(TS);
 335 }
 336
 337 sub link_message {
 338         my ($self, $smsg, $is_ghost) = @_;
 339
 340         if ($is_ghost) {
 341                 $smsg->ensure_metadata;
 342         } else {
 343                 $self->link_message_to_parents($smsg);
 344         }
 345 }
 346
 347 sub link_message_to_parents {
 348         my ($self, $smsg) = @_;
 349         my $doc = $smsg->{doc};
 350         my $mid = mid_compressed($smsg->mid);
 351         my $mime = $smsg->mime;
 352         my $refs = $mime->header_obj->header('References');
 353         my @refs = $refs ? ($refs =~ /<([^>]+)>/g) : ();
 354         my $irt = $mime->header_obj->header('In-Reply-To');
 355         if ($irt) {
 356                 $irt = mid_compressed(mid_clean($irt));
 357
 358                 # maybe some crazies will try to make a circular reference:
 359                 if ($irt eq $mid) {
 360                         $irt = undef;
 361                 } else {
 362                         # last References should be $irt
 363                         # we will de-dupe later
 364                         push @refs, $irt;
 365                 }
 366         }
 367
 368         my $tid;
 369         if (@refs) {
 370                 my @crefs = map { mid_compressed($_) } @refs;
 371                 my %uniq = ($mid => 1);
 372
 373                 # prevent circular references via References: here:
 374                 @refs = ();
 375                 foreach my $ref (@crefs) {
 376                         next if $uniq{$ref};
 377                         $uniq{$ref} = 1;
 378                         push @refs, $ref;
 379                 }
 380         }
 381         if (@refs) {
 382                 $doc->add_term(xpfx('inreplyto') . $irt) if defined $irt;
 383                 $smsg->{references_sorted} = '<'.join('><', @refs).'>';
 384
 385                 my $ref_pfx = xpfx('references');
 386
 387                 # first ref *should* be the thread root,
 388                 # but we can never trust clients to do the right thing
 389                 my $ref = shift @refs;
 390                 $doc->add_term($ref_pfx . $ref);
 391                 $tid = $self->_resolve_mid_to_tid($ref);
 392
 393                 # the rest of the refs should point to this tid:
 394                 foreach $ref (@refs) {
 395                         $doc->add_term($ref_pfx . $ref);
 396                         my $ptid = $self->_resolve_mid_to_tid($ref);
 397                         if ($tid ne $ptid) {
 398                                 $self->merge_threads($tid, $ptid);
 399                         }
 400                 }
 401         } else {
 402                 $tid = $self->next_thread_id;
 403         }
 404         $doc->add_term(xpfx('thread') . $tid);
 405 }
 406
 407 sub lookup_message {
 408         my ($self, $mid) = @_;
 409         $mid = mid_clean($mid);
 410         $mid = mid_compressed($mid);
 411
 412         my $doc_id = $self->find_unique_doc_id('mid', $mid);
 413         my $smsg;
 414         if (defined $doc_id) {
 415                 # raises on error:
 416                 my $doc = $self->{xdb}->get_document($doc_id);
 417                 $smsg = PublicInbox::SearchMsg->wrap($doc, $mid);
 418                 $smsg->doc_id($doc_id);
 419         }
 420         $smsg;
 421 }
 422
 423 sub find_unique_doc_id {
 424         my ($self, $term, $value) = @_;
 425
 426         my ($begin, $end) = $self->find_doc_ids($term, $value);
 427
 428         return undef if $begin->equal($end); # not found
 429
 430         my $rv = $begin->get_docid;
 431
 432         # sanity check
 433         $begin->inc;
 434         $begin->equal($end) or die "Term '$term:$value' is not unique\n";
 435         $rv;
 436 }
 437
 438 # returns begin and end PostingIterator
 439 sub find_doc_ids {
 440         my ($self, $term, $value) = @_;
 441
 442         $self->find_doc_ids_for_term(xpfx($term) . $value);
 443 }
 444
 445 # returns begin and end PostingIterator
 446 sub find_doc_ids_for_term {
 447         my ($self, $term) = @_;
 448         my $db = $self->{xdb};
 449
 450         ($db->postlist_begin($term), $db->postlist_end($term));
 451 }
 452
 453 # this will create a ghost as necessary
 454 sub _resolve_mid_to_tid {
 455         my ($self, $mid) = @_;
 456
 457         my $smsg = $self->lookup_message($mid) || $self->create_ghost($mid);
 458         $smsg->thread_id;
 459 }
 460
 461 sub create_ghost {
 462         my ($self, $mid, $tid) = @_;
 463
 464         $mid = mid_compressed($mid);
 465         $tid = $self->next_thread_id unless defined $tid;
 466
 467         my $doc = Search::Xapian::Document->new;
 468         $doc->add_term(xpfx('mid') . $mid);
 469         $doc->add_term(xpfx('thread') . $tid);
 470         $doc->add_term(xpfx('type') . 'ghost');
 471
 472         my $smsg = PublicInbox::SearchMsg->wrap($doc, $mid);
 473         $self->link_message($smsg, 1);
 474         $self->{xdb}->add_document($doc);
 475
 476         $smsg;
 477 }
 478
 479 sub merge_threads {
 480         my ($self, $winner_tid, $loser_tid) = @_;
 481         my ($head, $tail) = $self->find_doc_ids('thread', $loser_tid);
 482         my $thread_pfx = xpfx('thread');
 483         my $db = $self->{xdb};
 484
 485         for (; $head != $tail; $head->inc) {
 486                 my $docid = $head->get_docid;
 487                 my $doc = $db->get_document($docid);
 488                 $doc->remove_term($thread_pfx . $loser_tid);
 489                 $doc->add_term($thread_pfx . $winner_tid);
 490                 $db->replace_document($docid, $doc);
 491         }
 492 }
 493
 494 # normalize subjects so they are suitable as pathnames for URLs
 495 sub subject_path {
 496         my $subj = pop;
 497         $subj = subject_normalized($subj);
 498         $subj =~ s![^a-zA-Z0-9_\.~/\-]+!_!g;
 499         lc($subj);
 500 }
 501
 502 sub subject_normalized {
 503         my $subj = pop;
 504         $subj =~ s/\A\s+//s; # no leading space
 505         $subj =~ s/\s+\z//s; # no trailing space
 506         $subj =~ s/\s+/ /gs; # no redundant spaces
 507         $subj =~ s/\.+\z//; # no trailing '.'
 508         $subj =~ s/$REPLY_RE//igo; # remove reply prefix
 509         $subj;
 510 }
 511
 512 sub do_cat_mail {
 513         my ($git, $blob) = @_;
 514         my $mime = eval {
 515                 my $str = $git->cat_file($blob);
 516                 Email::MIME->new($str);
 517         };
 518         $@ ? undef : $mime;
 519 }
 520
 521 sub index_blob {
 522         my ($self, $git, $blob) = @_;
 523         my $mime = do_cat_mail($git, $blob) or return;
 524         eval { $self->add_message($mime) };
 525         warn "W: index_blob $blob: $@\n" if $@;
 526 }
 527
 528 sub unindex_blob {
 529         my ($self, $git, $blob) = @_;
 530         my $mime = do_cat_mail($git, $blob) or return;
 531         my $mid = $mime->header_obj->header('Message-ID');
 532         eval { $self->remove_message($mid) } if defined $mid;
 533         warn "W: unindex_blob $blob: $@\n" if $@;
 534 }
 535
 536 sub enquire {
 537         my ($self) = @_;
 538         $self->{enquire} ||= Search::Xapian::Enquire->new($self->{xdb});
 539 }
 540
 541 # indexes all unindexed messages
 542 sub index_sync {
 543         my ($self, $head) = @_;
 544         require PublicInbox::GitCatFile;
 545         my $db = $self->{xdb};
 546         my $hex = '[a-f0-9]';
 547         my $h40 = $hex .'{40}';
 548         my $addmsg = qr!^:000000 100644 \S+ ($h40) A\t${hex}{2}/${hex}{38}$!;
 549         my $delmsg = qr!^:100644 000000 ($h40) \S+ D\t${hex}{2}/${hex}{38}$!;
 550         $head ||= 'HEAD';
 551
 552         $db->begin_transaction;
 553         eval {
 554                 my $git = PublicInbox::GitCatFile->new($self->{git_dir});
 555
 556                 my $latest = $db->get_metadata('last_commit');
 557                 my $range = length $latest ? "$latest..$head" : $head;
 558                 $latest = undef;
 559
 560                 # get indexed messages
 561                 my @cmd = ('git', "--git-dir=$self->{git_dir}", "log",
 562                             qw/--reverse --no-notes --no-color --raw -r
 563                                --no-abbrev/, $range);
 564                 my $pid = open(my $log, '-|', @cmd) or
 565                         die('open` '.join(' ', @cmd) . " pipe failed: $!\n");
 566
 567                 while (my $line = <$log>) {
 568                         if ($line =~ /$addmsg/o) {
 569                                 $self->index_blob($git, $1);
 570                         } elsif ($line =~ /$delmsg/o) {
 571                                 $self->unindex_blob($git, $1);
 572                         } elsif ($line =~ /^commit ($h40)/o) {
 573                                 $latest = $1;
 574                         }
 575                 }
 576                 close $log;
 577                 $db->set_metadata('last_commit', $latest) if defined $latest;
 578         };
 579         if ($@) {
 580                 warn "indexing failed: $@\n";
 581                 $db->cancel_transaction;
 582         } else {
 583                 $db->commit_transaction;
 584         }
 585 }
 586
 587 1;