lib/PublicInbox/Search.pm

   1 # Copyright (C) 2015-2018 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 # based on notmuch, but with no concept of folders, files or flags
   4 #
   5 # Read-only search interface for use by the web and NNTP interfaces
   6 package PublicInbox::Search;
   7 use strict;
   8 use warnings;
   9
  10 # values for searching
  11 use constant TS => 0; # timestamp
  12 use constant NUM => 1; # NNTP article number
  13 use constant BYTES => 2; # :bytes as defined in RFC 3977
  14 use constant LINES => 3; # :lines as defined in RFC 3977
  15 use constant YYYYMMDD => 4; # for searching in the WWW UI
  16
  17 use Search::Xapian qw/:standard/;
  18 use PublicInbox::SearchMsg;
  19 use PublicInbox::MIME;
  20 use PublicInbox::MID qw/mid_clean id_compress/;
  21
  22 # This is English-only, everything else is non-standard and may be confused as
  23 # a prefix common in patch emails
  24 our $REPLY_RE = qr/^re:\s+/i;
  25 our $LANG = 'english';
  26
  27 use constant {
  28         # SCHEMA_VERSION history
  29         # 0 - initial
  30         # 1 - subject_path is lower-cased
  31         # 2 - subject_path is id_compress in the index, only
  32         # 3 - message-ID is compressed if it includes '%' (hack!)
  33         # 4 - change "Re: " normalization, avoid circular Reference ghosts
  34         # 5 - subject_path drops trailing '.'
  35         # 6 - preserve References: order in document data
  36         # 7 - remove references and inreplyto terms
  37         # 8 - remove redundant/unneeded document data
  38         # 9 - disable Message-ID compression (SHA-1)
  39         # 10 - optimize doc for NNTP overviews
  40         # 11 - merge threads when vivifying ghosts
  41         # 12 - change YYYYMMDD value column to numeric
  42         # 13 - fix threading for empty References/In-Reply-To
  43         #      (commit 83425ef12e4b65cdcecd11ddcb38175d4a91d5a0)
  44         # 14 - fix ghost root vivification
  45         SCHEMA_VERSION => 14,
  46
  47         # n.b. FLAG_PURE_NOT is expensive not suitable for a public website
  48         # as it could become a denial-of-service vector
  49         QP_FLAGS => FLAG_PHRASE|FLAG_BOOLEAN|FLAG_LOVEHATE|FLAG_WILDCARD,
  50 };
  51
  52 # setup prefixes
  53 my %bool_pfx_internal = (
  54         type => 'T', # "mail" or "ghost"
  55         thread => 'G', # newsGroup (or similar entity - e.g. a web forum name)
  56 );
  57
  58 my %bool_pfx_external = (
  59         mid => 'XMID', # Message-ID (full/exact)
  60 );
  61
  62 my %prob_prefix = (
  63         # for mairix compatibility
  64         s => 'S',
  65         m => 'XM', # 'mid:' (bool) is exact, 'm:' (prob) can do partial
  66         f => 'A',
  67         t => 'XTO',
  68         tc => 'XTO XCC',
  69         c => 'XCC',
  70         tcf => 'XTO XCC A',
  71         a => 'XTO XCC A',
  72         b => 'XNQ XQUOT',
  73         bs => 'XNQ XQUOT S',
  74         n => 'XFN',
  75
  76         q => 'XQUOT',
  77         nq => 'XNQ',
  78         dfn => 'XDFN',
  79         dfa => 'XDFA',
  80         dfb => 'XDFB',
  81         dfhh => 'XDFHH',
  82         dfctx => 'XDFCTX',
  83         dfpre => 'XDFPRE',
  84         dfpost => 'XDFPOST',
  85         dfblob => 'XDFPRE XDFPOST',
  86
  87         # default:
  88         '' => 'XM S A XNQ XQUOT XFN',
  89 );
  90
  91 # not documenting m: and mid: for now, the using the URLs works w/o Xapian
  92 our @HELP = (
  93         's:' => 'match within Subject  e.g. s:"a quick brown fox"',
  94         'd:' => <<EOF,
  95 date range as YYYYMMDD  e.g. d:19931002..20101002
  96 Open-ended ranges such as d:19931002.. and d:..20101002
  97 are also supported
  98 EOF
  99         'b:' => 'match within message body, including text attachments',
 100         'nq:' => 'match non-quoted text within message body',
 101         'q:' => 'match quoted text within message body',
 102         'n:' => 'match filename of attachment(s)',
 103         't:' => 'match within the To header',
 104         'c:' => 'match within the Cc header',
 105         'f:' => 'match within the From header',
 106         'a:' => 'match within the To, Cc, and From headers',
 107         'tc:' => 'match within the To and Cc headers',
 108         'bs:' => 'match within the Subject and body',
 109         'dfn:' => 'match filename from diff',
 110         'dfa:' => 'match diff removed (-) lines',
 111         'dfb:' => 'match diff added (+) lines',
 112         'dfhh:' => 'match diff hunk header context (usually a function name)',
 113         'dfctx:' => 'match diff context lines',
 114         'dfpre:' => 'match pre-image git blob ID',
 115         'dfpost:' => 'match post-image git blob ID',
 116         'dfblob:' => 'match either pre or post-image git blob ID',
 117 );
 118 chomp @HELP;
 119
 120 my $mail_query = Search::Xapian::Query->new('T' . 'mail');
 121
 122 sub xdir {
 123         my ($self) = @_;
 124         if ($self->{version} == 1) {
 125                 "$self->{mainrepo}/public-inbox/xapian" . SCHEMA_VERSION;
 126         } else {
 127                 my $dir = "$self->{mainrepo}/xap" . SCHEMA_VERSION;
 128                 my $part = $self->{partition};
 129                 defined $part or die "partition not given";
 130                 $dir .= "/$part";
 131         }
 132 }
 133
 134 sub new {
 135         my ($class, $mainrepo, $altid) = @_;
 136         my $version = 1;
 137         my $ibx = $mainrepo;
 138         if (ref $ibx) {
 139                 $version = $ibx->{version} || 1;
 140                 $mainrepo = $ibx->{mainrepo};
 141         }
 142         my $self = bless {
 143                 mainrepo => $mainrepo,
 144                 altid => $altid,
 145                 version => $version,
 146         }, $class;
 147         if ($version >= 2) {
 148                 my $dir = "$self->{mainrepo}/xap" . SCHEMA_VERSION;
 149                 my $xdb;
 150                 my $parts = 0;
 151                 foreach my $part (<$dir/*>) {
 152                         -d $part && $part =~ m!/\d+\z! or next;
 153                         $parts++;
 154                         my $sub = Search::Xapian::Database->new($part);
 155                         if ($xdb) {
 156                                 $xdb->add_database($sub);
 157                         } else {
 158                                 $xdb = $sub;
 159                         }
 160                 }
 161                 warn "v2 repo with $parts found in $dir\n";
 162                 $self->{xdb} = $xdb;
 163                 $self->{skel} = Search::Xapian::Database->new("$dir/all");
 164         } else {
 165                 $self->{xdb} = Search::Xapian::Database->new($self->xdir);
 166         }
 167         $self;
 168 }
 169
 170 sub reopen { $_[0]->{xdb}->reopen }
 171
 172 # read-only
 173 sub query {
 174         my ($self, $query_string, $opts) = @_;
 175         my $query;
 176
 177         $opts ||= {};
 178         unless ($query_string eq '') {
 179                 $query = $self->qp->parse_query($query_string, QP_FLAGS);
 180                 $opts->{relevance} = 1 unless exists $opts->{relevance};
 181         }
 182
 183         _do_enquire($self, $query, $opts);
 184 }
 185
 186 sub get_thread {
 187         my ($self, $mid, $opts) = @_;
 188         my $smsg = retry_reopen($self, sub { lookup_skeleton($self, $mid) });
 189
 190         return { total => 0, msgs => [] } unless $smsg;
 191         my $qtid = Search::Xapian::Query->new('G' . $smsg->thread_id);
 192         my $path = $smsg->path;
 193         if (defined $path && $path ne '') {
 194                 my $path = id_compress($smsg->path);
 195                 my $qsub = Search::Xapian::Query->new('XPATH' . $path);
 196                 $qtid = Search::Xapian::Query->new(OP_OR, $qtid, $qsub);
 197         }
 198         $opts ||= {};
 199         $opts->{limit} ||= 1000;
 200
 201         # always sort threads by timestamp, this makes life easier
 202         # for the threading algorithm (in SearchThread.pm)
 203         $opts->{asc} = 1;
 204
 205         _do_enquire($self, $qtid, $opts);
 206 }
 207
 208 sub retry_reopen {
 209         my ($self, $cb) = @_;
 210         my $ret;
 211         for (1..10) {
 212                 eval { $ret = $cb->() };
 213                 return $ret unless $@;
 214                 # Exception: The revision being read has been discarded -
 215                 # you should call Xapian::Database::reopen()
 216                 if (ref($@) eq 'Search::Xapian::DatabaseModifiedError') {
 217                         reopen($self);
 218                 } else {
 219                         warn "ref: ", ref($@), "\n";
 220                         die;
 221                 }
 222         }
 223 }
 224
 225 sub _do_enquire {
 226         my ($self, $query, $opts) = @_;
 227         retry_reopen($self, sub { _enquire_once($self, $query, $opts) });
 228 }
 229
 230 sub _enquire_once {
 231         my ($self, $query, $opts) = @_;
 232         my $enquire = $self->enquire;
 233         if (defined $query) {
 234                 $query = Search::Xapian::Query->new(OP_AND,$query,$mail_query);
 235         } else {
 236                 $query = $mail_query;
 237         }
 238         $enquire->set_query($query);
 239         $opts ||= {};
 240         my $desc = !$opts->{asc};
 241         if ($opts->{relevance}) {
 242                 $enquire->set_sort_by_relevance_then_value(TS, $desc);
 243         } elsif ($opts->{num}) {
 244                 $enquire->set_sort_by_value(NUM, 0);
 245         } else {
 246                 $enquire->set_sort_by_value_then_relevance(TS, $desc);
 247         }
 248         my $offset = $opts->{offset} || 0;
 249         my $limit = $opts->{limit} || 50;
 250         my $mset = $enquire->get_mset($offset, $limit);
 251         return $mset if $opts->{mset};
 252         my @msgs = map {
 253                 PublicInbox::SearchMsg->load_doc($_->get_document);
 254         } $mset->items;
 255
 256         { total => $mset->get_matches_estimated, msgs => \@msgs }
 257 }
 258
 259 # read-write
 260 sub stemmer { Search::Xapian::Stem->new($LANG) }
 261
 262 # read-only
 263 sub qp {
 264         my ($self) = @_;
 265
 266         my $qp = $self->{query_parser};
 267         return $qp if $qp;
 268
 269         # new parser
 270         $qp = Search::Xapian::QueryParser->new;
 271         $qp->set_default_op(OP_AND);
 272         $qp->set_database($self->{xdb});
 273         $qp->set_stemmer($self->stemmer);
 274         $qp->set_stemming_strategy(STEM_SOME);
 275         $qp->add_valuerangeprocessor(
 276                 Search::Xapian::NumberValueRangeProcessor->new(YYYYMMDD, 'd:'));
 277
 278         while (my ($name, $prefix) = each %bool_pfx_external) {
 279                 $qp->add_boolean_prefix($name, $prefix);
 280         }
 281
 282         # we do not actually create AltId objects,
 283         # just parse the spec to avoid the extra DB handles for now.
 284         if (my $altid = $self->{altid}) {
 285                 my $user_pfx = $self->{-user_pfx} ||= [];
 286                 for (@$altid) {
 287                         # $_ = 'serial:gmane:/path/to/gmane.msgmap.sqlite3'
 288                         /\Aserial:(\w+):/ or next;
 289                         my $pfx = $1;
 290                         push @$user_pfx, "$pfx:", <<EOF;
 291 alternate serial number  e.g. $pfx:12345 (boolean)
 292 EOF
 293                         # gmane => XGMANE
 294                         $qp->add_boolean_prefix($pfx, 'X'.uc($pfx));
 295                 }
 296                 chomp @$user_pfx;
 297         }
 298
 299         while (my ($name, $prefix) = each %prob_prefix) {
 300                 $qp->add_prefix($name, $_) foreach split(/ /, $prefix);
 301         }
 302
 303         $self->{query_parser} = $qp;
 304 }
 305
 306 sub num_range_processor {
 307         $_[0]->{nrp} ||= Search::Xapian::NumberValueRangeProcessor->new(NUM);
 308 }
 309
 310 # only used for NNTP server
 311 sub query_xover {
 312         my ($self, $beg, $end, $offset) = @_;
 313         my $qp = Search::Xapian::QueryParser->new;
 314         $qp->set_database($self->{xdb});
 315         $qp->add_valuerangeprocessor($self->num_range_processor);
 316         my $query = $qp->parse_query("$beg..$end", QP_FLAGS);
 317
 318         _do_enquire($self, $query, {num => 1, limit => 200, offset => $offset});
 319 }
 320
 321 sub lookup_skeleton {
 322         my ($self, $mid) = @_;
 323         my $skel = $self->{skel} or return lookup_message($self, $mid);
 324         $mid = mid_clean($mid);
 325         my $term = 'XMID' . $mid;
 326         my $smsg;
 327         my $beg = $skel->postlist_begin($term);
 328         if ($beg != $skel->postlist_end($term)) {
 329                 my $doc_id = $beg->get_docid;
 330                 if (defined $doc_id) {
 331                         # raises on error:
 332                         my $doc = $skel->get_document($doc_id);
 333                         $smsg = PublicInbox::SearchMsg->wrap($doc, $mid);
 334                         $smsg->{doc_id} = $doc_id;
 335                 }
 336         }
 337         $smsg;
 338 }
 339
 340 sub lookup_message {
 341         my ($self, $mid) = @_;
 342         $mid = mid_clean($mid);
 343
 344         my $doc_id = $self->find_first_doc_id('XMID' . $mid);
 345         my $smsg;
 346         if (defined $doc_id) {
 347                 # raises on error:
 348                 my $doc = $self->{xdb}->get_document($doc_id);
 349                 $smsg = PublicInbox::SearchMsg->wrap($doc, $mid);
 350                 $smsg->{doc_id} = $doc_id;
 351         }
 352         $smsg;
 353 }
 354
 355 sub lookup_mail { # no ghosts!
 356         my ($self, $mid) = @_;
 357         retry_reopen($self, sub {
 358                 my $smsg = lookup_message($self, $mid) or return;
 359                 $smsg->load_expand;
 360         });
 361 }
 362
 363 sub find_unique_doc_id {
 364         my ($self, $termval) = @_;
 365
 366         my ($begin, $end) = $self->find_doc_ids($termval);
 367
 368         return undef if $begin->equal($end); # not found
 369
 370         my $rv = $begin->get_docid;
 371
 372         # sanity check
 373         $begin->inc;
 374         $begin->equal($end) or die "Term '$termval' is not unique\n";
 375         $rv;
 376 }
 377
 378 # returns begin and end PostingIterator
 379 sub find_doc_ids {
 380         my ($self, $termval) = @_;
 381         my $db = $self->{xdb};
 382
 383         ($db->postlist_begin($termval), $db->postlist_end($termval));
 384 }
 385
 386 sub find_first_doc_id {
 387         my ($self, $termval) = @_;
 388
 389         my ($begin, $end) = $self->find_doc_ids($termval);
 390
 391         return undef if $begin->equal($end); # not found
 392
 393         $begin->get_docid;
 394 }
 395
 396 # normalize subjects so they are suitable as pathnames for URLs
 397 # XXX: consider for removal
 398 sub subject_path {
 399         my $subj = pop;
 400         $subj = subject_normalized($subj);
 401         $subj =~ s![^a-zA-Z0-9_\.~/\-]+!_!g;
 402         lc($subj);
 403 }
 404
 405 sub subject_normalized {
 406         my $subj = pop;
 407         $subj =~ s/\A\s+//s; # no leading space
 408         $subj =~ s/\s+\z//s; # no trailing space
 409         $subj =~ s/\s+/ /gs; # no redundant spaces
 410         $subj =~ s/\.+\z//; # no trailing '.'
 411         $subj =~ s/$REPLY_RE//igo; # remove reply prefix
 412         $subj;
 413 }
 414
 415 sub enquire {
 416         my ($self) = @_;
 417         $self->{enquire} ||= Search::Xapian::Enquire->new($self->{xdb});
 418 }
 419
 420 sub help {
 421         my ($self) = @_;
 422         $self->qp; # parse altids
 423         my @ret = @HELP;
 424         if (my $user_pfx = $self->{-user_pfx}) {
 425                 push @ret, @$user_pfx;
 426         }
 427         \@ret;
 428 }
 429
 430 1;