lib/PublicInbox/Search.pm

   1 # Copyright (C) 2015 all contributors <meta@public-inbox.org>
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 # based on notmuch, but with no concept of folders, files or flags
   4 #
   5 # Read-only search interface for use by the web and NNTP interfaces
   6 package PublicInbox::Search;
   7 use strict;
   8 use warnings;
   9
  10 # values for searching
  11 use constant TS => 0; # timestamp
  12 use constant NUM => 1; # NNTP article number
  13 use constant BYTES => 2; # :bytes as defined in RFC 3977
  14 use constant LINES => 3; # :lines as defined in RFC 3977
  15
  16 use Search::Xapian qw/:standard/;
  17 use PublicInbox::SearchMsg;
  18 use Email::MIME;
  19 use PublicInbox::MID qw/mid_clean id_compress/;
  20
  21 # This is English-only, everything else is non-standard and may be confused as
  22 # a prefix common in patch emails
  23 our $REPLY_RE = qr/^re:\s+/i;
  24 our $LANG = 'english';
  25
  26 use constant {
  27         # SCHEMA_VERSION history
  28         # 0 - initial
  29         # 1 - subject_path is lower-cased
  30         # 2 - subject_path is id_compress in the index, only
  31         # 3 - message-ID is compressed if it includes '%' (hack!)
  32         # 4 - change "Re: " normalization, avoid circular Reference ghosts
  33         # 5 - subject_path drops trailing '.'
  34         # 6 - preserve References: order in document data
  35         # 7 - remove references and inreplyto terms
  36         # 8 - remove redundant/unneeded document data
  37         # 9 - disable Message-ID compression (SHA-1)
  38         # 10 - optimize doc for NNTP overviews
  39         SCHEMA_VERSION => 10,
  40
  41         # n.b. FLAG_PURE_NOT is expensive not suitable for a public website
  42         # as it could become a denial-of-service vector
  43         QP_FLAGS => FLAG_PHRASE|FLAG_BOOLEAN|FLAG_LOVEHATE|FLAG_WILDCARD,
  44 };
  45
  46 # setup prefixes
  47 my %bool_pfx_internal = (
  48         type => 'T', # "mail" or "ghost"
  49         thread => 'G', # newsGroup (or similar entity - e.g. a web forum name)
  50 );
  51
  52 my %bool_pfx_external = (
  53         path => 'XPATH',
  54         mid => 'Q', # uniQue id (Message-ID)
  55 );
  56
  57 my %prob_prefix = (
  58         subject => 'S',
  59         s => 'S', # for mairix compatibility
  60         m => 'Q', # 'mid' is exact, 'm' can do partial
  61 );
  62
  63 my %all_pfx = (%bool_pfx_internal, %bool_pfx_external, %prob_prefix);
  64
  65 sub xpfx { $all_pfx{$_[0]} }
  66
  67 our %PFX2TERM_RMAP;
  68 my %meta_pfx = (mid => 1, thread => 1, path => 1);
  69 while (my ($k, $v) = each %all_pfx) {
  70         $PFX2TERM_RMAP{$v} = $k if $meta_pfx{$k};
  71 }
  72
  73 my $mail_query = Search::Xapian::Query->new(xpfx('type') . 'mail');
  74
  75 sub xdir {
  76         my (undef, $git_dir) = @_;
  77         "$git_dir/public-inbox/xapian" . SCHEMA_VERSION;
  78 }
  79
  80 sub new {
  81         my ($class, $git_dir) = @_;
  82         my $dir = $class->xdir($git_dir);
  83         my $db = Search::Xapian::Database->new($dir);
  84         bless { xdb => $db, git_dir => $git_dir }, $class;
  85 }
  86
  87 sub reopen { $_[0]->{xdb}->reopen }
  88
  89 # read-only
  90 sub query {
  91         my ($self, $query_string, $opts) = @_;
  92         my $query;
  93
  94         $opts ||= {};
  95         unless ($query_string eq '') {
  96                 $query = $self->qp->parse_query($query_string, QP_FLAGS);
  97                 $opts->{relevance} = 1 unless exists $opts->{relevance};
  98         }
  99
 100         $self->do_enquire($query, $opts);
 101 }
 102
 103 sub get_thread {
 104         my ($self, $mid, $opts) = @_;
 105         my $smsg = eval { $self->lookup_message($mid) };
 106
 107         return { total => 0, msgs => [] } unless $smsg;
 108         my $qtid = Search::Xapian::Query->new(xpfx('thread').$smsg->thread_id);
 109         my $path = id_compress($smsg->path);
 110         my $qsub = Search::Xapian::Query->new(xpfx('path').$path);
 111         my $query = Search::Xapian::Query->new(OP_OR, $qtid, $qsub);
 112         $self->do_enquire($query, $opts);
 113 }
 114
 115 sub do_enquire {
 116         my ($self, $query, $opts) = @_;
 117         my $enquire = $self->enquire;
 118         if (defined $query) {
 119                 $query = Search::Xapian::Query->new(OP_AND,$query,$mail_query);
 120         } else {
 121                 $query = $mail_query;
 122         }
 123         $enquire->set_query($query);
 124         $opts ||= {};
 125         my $desc = !$opts->{asc};
 126         if ($opts->{relevance}) {
 127                 $enquire->set_sort_by_relevance_then_value(TS, $desc);
 128         } else {
 129                 $enquire->set_sort_by_value_then_relevance(TS, $desc);
 130         }
 131         my $offset = $opts->{offset} || 0;
 132         my $limit = $opts->{limit} || 50;
 133         my $mset = $enquire->get_mset($offset, $limit);
 134         return $mset if $opts->{mset};
 135         my @msgs = map {
 136                 PublicInbox::SearchMsg->load_doc($_->get_document);
 137         } $mset->items;
 138
 139         { total => $mset->get_matches_estimated, msgs => \@msgs }
 140 }
 141
 142 # read-write
 143 sub stemmer { Search::Xapian::Stem->new($LANG) }
 144
 145 # read-only
 146 sub qp {
 147         my ($self) = @_;
 148
 149         my $qp = $self->{query_parser};
 150         return $qp if $qp;
 151
 152         # new parser
 153         $qp = Search::Xapian::QueryParser->new;
 154         $qp->set_default_op(OP_AND);
 155         $qp->set_database($self->{xdb});
 156         $qp->set_stemmer($self->stemmer);
 157         $qp->set_stemming_strategy(STEM_SOME);
 158         $qp->add_valuerangeprocessor($self->ts_range_processor);
 159         $qp->add_valuerangeprocessor($self->date_range_processor);
 160
 161         while (my ($name, $prefix) = each %bool_pfx_external) {
 162                 $qp->add_boolean_prefix($name, $prefix);
 163         }
 164
 165         while (my ($name, $prefix) = each %prob_prefix) {
 166                 $qp->add_prefix($name, $prefix);
 167         }
 168
 169         $self->{query_parser} = $qp;
 170 }
 171
 172 sub ts_range_processor {
 173         $_[0]->{tsrp} ||= Search::Xapian::NumberValueRangeProcessor->new(TS);
 174 }
 175
 176 sub date_range_processor {
 177         $_[0]->{drp} ||= Search::Xapian::DateValueRangeProcessor->new(TS);
 178 }
 179
 180 sub num_range_processor {
 181         $_[0]->{nrp} ||= Search::Xapian::NumberValueRangeProcessor->new(NUM);
 182 }
 183
 184 # only used for NNTP server
 185 sub query_xover {
 186         my ($self, $beg, $end, $offset) = @_;
 187         my $enquire = $self->enquire;
 188         my $qp = Search::Xapian::QueryParser->new;
 189         $qp->set_database($self->{xdb});
 190         $qp->add_valuerangeprocessor($self->num_range_processor);
 191         my $query = $qp->parse_query("$beg..$end", QP_FLAGS);
 192         $query = Search::Xapian::Query->new(OP_AND, $mail_query, $query);
 193         $enquire->set_query($query);
 194         $enquire->set_sort_by_value(NUM, 0);
 195         my $limit = 200;
 196         my $mset = $enquire->get_mset($offset, $limit);
 197         my @msgs = map {
 198                 PublicInbox::SearchMsg->load_doc($_->get_document);
 199         } $mset->items;
 200
 201         { total => $mset->get_matches_estimated, msgs => \@msgs }
 202 }
 203
 204 sub lookup_message {
 205         my ($self, $mid) = @_;
 206         $mid = mid_clean($mid);
 207
 208         my $doc_id = $self->find_unique_doc_id('mid', $mid);
 209         my $smsg;
 210         if (defined $doc_id) {
 211                 # raises on error:
 212                 my $doc = $self->{xdb}->get_document($doc_id);
 213                 $smsg = PublicInbox::SearchMsg->wrap($doc, $mid);
 214                 $smsg->doc_id($doc_id);
 215         }
 216         $smsg;
 217 }
 218
 219 sub find_unique_doc_id {
 220         my ($self, $term, $value) = @_;
 221
 222         my ($begin, $end) = $self->find_doc_ids($term, $value);
 223
 224         return undef if $begin->equal($end); # not found
 225
 226         my $rv = $begin->get_docid;
 227
 228         # sanity check
 229         $begin->inc;
 230         $begin->equal($end) or die "Term '$term:$value' is not unique\n";
 231         $rv;
 232 }
 233
 234 # returns begin and end PostingIterator
 235 sub find_doc_ids {
 236         my ($self, $term, $value) = @_;
 237
 238         $self->find_doc_ids_for_term(xpfx($term) . $value);
 239 }
 240
 241 # returns begin and end PostingIterator
 242 sub find_doc_ids_for_term {
 243         my ($self, $term) = @_;
 244         my $db = $self->{xdb};
 245
 246         ($db->postlist_begin($term), $db->postlist_end($term));
 247 }
 248
 249 # normalize subjects so they are suitable as pathnames for URLs
 250 sub subject_path {
 251         my $subj = pop;
 252         $subj = subject_normalized($subj);
 253         $subj =~ s![^a-zA-Z0-9_\.~/\-]+!_!g;
 254         lc($subj);
 255 }
 256
 257 sub subject_normalized {
 258         my $subj = pop;
 259         $subj =~ s/\A\s+//s; # no leading space
 260         $subj =~ s/\s+\z//s; # no trailing space
 261         $subj =~ s/\s+/ /gs; # no redundant spaces
 262         $subj =~ s/\.+\z//; # no trailing '.'
 263         $subj =~ s/$REPLY_RE//igo; # remove reply prefix
 264         $subj;
 265 }
 266
 267 # for doc data
 268 sub subject_summary {
 269         my $subj = pop;
 270         my $max = 68;
 271         if (length($subj) > $max) {
 272                 my @subj = split(/\s+/, $subj);
 273                 $subj = '';
 274                 my $l;
 275
 276                 while ($l = shift @subj) {
 277                         my $new = $subj . $l . ' ';
 278                         last if length($new) >= $max;
 279                         $subj = $new;
 280                 }
 281                 if ($subj ne '') {
 282                         my $r = scalar @subj ? ' ...' : '';
 283                         $subj =~ s/ \z/$r/s;
 284                 } else {
 285                         # subject has one REALLY long word, and NOT spam? wtf
 286                         @subj = ($l =~ /\A(.{1,72})/);
 287                         $subj = $subj[0] . ' ...';
 288                 }
 289         }
 290         $subj;
 291 }
 292
 293 sub enquire {
 294         my ($self) = @_;
 295         $self->{enquire} ||= Search::Xapian::Enquire->new($self->{xdb});
 296 }
 297
 298 1;