lib/PublicInbox/SearchIdx.pm

   1 # Copyright (C) 2015 all contributors <meta@public-inbox.org>
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 # based on notmuch, but with no concept of folders, files or flags
   4 #
   5 # Indexes mail with Xapian and our (SQLite-based) ::Msgmap for use
   6 # with the web and NNTP interfaces.  This index maintains thread
   7 # relationships for use by PublicInbox::SearchThread.
   8 # This writes to the search index.
   9 package PublicInbox::SearchIdx;
  10 use strict;
  11 use warnings;
  12 use Fcntl qw(:flock :DEFAULT);
  13 use PublicInbox::MIME;
  14 use Email::MIME::ContentType;
  15 $Email::MIME::ContentType::STRICT_PARAMS = 0;
  16 use base qw(PublicInbox::Search);
  17 use PublicInbox::MID qw/mid_clean id_compress mid_mime/;
  18 use PublicInbox::MsgIter;
  19 use Carp qw(croak);
  20 use POSIX qw(strftime);
  21 require PublicInbox::Git;
  22 *xpfx = *PublicInbox::Search::xpfx;
  23
  24 use constant MAX_MID_SIZE => 244; # max term size - 1 in Xapian
  25 use constant {
  26         PERM_UMASK => 0,
  27         OLD_PERM_GROUP => 1,
  28         OLD_PERM_EVERYBODY => 2,
  29         PERM_GROUP => 0660,
  30         PERM_EVERYBODY => 0664,
  31 };
  32
  33 sub new {
  34         my ($class, $inbox, $creat) = @_;
  35         my $git_dir = $inbox;
  36         my $altid;
  37         if (ref $inbox) {
  38                 $git_dir = $inbox->{mainrepo};
  39                 $altid = $inbox->{altid};
  40                 if ($altid) {
  41                         require PublicInbox::AltId;
  42                         $altid = [ map {
  43                                 PublicInbox::AltId->new($inbox, $_);
  44                         } @$altid ];
  45                 }
  46         }
  47         require Search::Xapian::WritableDatabase;
  48         my $self = bless { git_dir => $git_dir, -altid => $altid }, $class;
  49         my $perm = $self->_git_config_perm;
  50         my $umask = _umask_for($perm);
  51         $self->{umask} = $umask;
  52         $self->{lock_path} = "$git_dir/ssoma.lock";
  53         $self->{git} = PublicInbox::Git->new($git_dir);
  54         $self->{creat} = ($creat || 0) == 1;
  55         $self;
  56 }
  57
  58 sub _xdb_release {
  59         my ($self) = @_;
  60         my $xdb = delete $self->{xdb} or croak 'not acquired';
  61         $xdb->close;
  62         _lock_release($self) if $self->{creat};
  63         undef;
  64 }
  65
  66 sub _xdb_acquire {
  67         my ($self) = @_;
  68         croak 'already acquired' if $self->{xdb};
  69         my $dir = PublicInbox::Search->xdir($self->{git_dir});
  70         my $flag = Search::Xapian::DB_OPEN;
  71         if ($self->{creat}) {
  72                 require File::Path;
  73                 _lock_acquire($self);
  74                 File::Path::mkpath($dir);
  75                 $self->{batch_size} = 100;
  76                 $flag = Search::Xapian::DB_CREATE_OR_OPEN;
  77         }
  78         $self->{xdb} = Search::Xapian::WritableDatabase->new($dir, $flag);
  79 }
  80
  81 # we only acquire the flock if creating or reindexing;
  82 # PublicInbox::Import already has the lock on its own.
  83 sub _lock_acquire {
  84         my ($self) = @_;
  85         croak 'already locked' if $self->{lockfh};
  86         sysopen(my $lockfh, $self->{lock_path}, O_WRONLY|O_CREAT) or
  87                 die "failed to open lock $self->{lock_path}: $!\n";
  88         flock($lockfh, LOCK_EX) or die "lock failed: $!\n";
  89         $self->{lockfh} = $lockfh;
  90 }
  91
  92 sub _lock_release {
  93         my ($self) = @_;
  94         my $lockfh = delete $self->{lockfh} or croak 'not locked';
  95         flock($lockfh, LOCK_UN) or die "unlock failed: $!\n";
  96         close $lockfh or die "close failed: $!\n";
  97 }
  98
  99 sub add_val ($$$) {
 100         my ($doc, $col, $num) = @_;
 101         $num = Search::Xapian::sortable_serialise($num);
 102         $doc->add_value($col, $num);
 103 }
 104
 105 sub add_values ($$$) {
 106         my ($smsg, $bytes, $num) = @_;
 107
 108         my $ts = $smsg->ts;
 109         my $doc = $smsg->{doc};
 110         add_val($doc, &PublicInbox::Search::TS, $ts);
 111
 112         defined($num) and add_val($doc, &PublicInbox::Search::NUM, $num);
 113
 114         defined($bytes) and add_val($doc, &PublicInbox::Search::BYTES, $bytes);
 115
 116         add_val($doc, &PublicInbox::Search::LINES,
 117                         $smsg->{mime}->body_raw =~ tr!\n!\n!);
 118
 119         my $yyyymmdd = strftime('%Y%m%d', gmtime($ts));
 120         add_val($doc, PublicInbox::Search::YYYYMMDD, $yyyymmdd);
 121 }
 122
 123 sub index_users ($$) {
 124         my ($tg, $smsg) = @_;
 125
 126         my $from = $smsg->from;
 127         my $to = $smsg->to;
 128         my $cc = $smsg->cc;
 129
 130         $tg->index_text($from, 1, 'A'); # A - author
 131         $tg->increase_termpos;
 132         $tg->index_text($to, 1, 'XTO') if $to ne '';
 133         $tg->increase_termpos;
 134         $tg->index_text($cc, 1, 'XCC') if $cc ne '';
 135         $tg->increase_termpos;
 136 }
 137
 138 sub index_body ($$$) {
 139         my ($tg, $lines, $inc) = @_;
 140         $tg->index_text(join("\n", @$lines), $inc, $inc ? 'XNQ' : 'XQUOT');
 141         @$lines = ();
 142         $tg->increase_termpos;
 143 }
 144
 145 sub add_message {
 146         my ($self, $mime, $bytes, $num, $blob) = @_; # mime = Email::MIME object
 147         my $db = $self->{xdb};
 148
 149         my ($doc_id, $old_tid);
 150         my $mid = mid_clean(mid_mime($mime));
 151
 152         eval {
 153                 die 'Message-ID too long' if length($mid) > MAX_MID_SIZE;
 154                 my $smsg = $self->lookup_message($mid);
 155                 if ($smsg) {
 156                         # convert a ghost to a regular message
 157                         # it will also clobber any existing regular message
 158                         $doc_id = $smsg->{doc_id};
 159                         $old_tid = $smsg->thread_id;
 160                 }
 161                 $smsg = PublicInbox::SearchMsg->new($mime);
 162                 my $doc = $smsg->{doc};
 163                 $doc->add_term(xpfx('mid') . $mid);
 164
 165                 my $subj = $smsg->subject;
 166                 if ($subj ne '') {
 167                         my $path = $self->subject_path($subj);
 168                         $doc->add_term(xpfx('path') . id_compress($path));
 169                 }
 170
 171                 add_values($smsg, $bytes, $num);
 172
 173                 my $tg = $self->term_generator;
 174
 175                 $tg->set_document($doc);
 176                 $tg->index_text($subj, 1, 'S') if $subj;
 177                 $tg->increase_termpos;
 178
 179                 index_users($tg, $smsg);
 180
 181                 msg_iter($mime, sub {
 182                         my ($part, $depth, @idx) = @{$_[0]};
 183                         my $ct = $part->content_type || 'text/plain';
 184                         my $fn = $part->filename;
 185                         if (defined $fn && $fn ne '') {
 186                                 $tg->index_text($fn, 1, 'XFN');
 187                         }
 188
 189                         return if $ct =~ m!\btext/x?html\b!i;
 190
 191                         my $s = eval { $part->body_str };
 192                         if ($@) {
 193                                 if ($ct =~ m!\btext/plain\b!i) {
 194                                         # Try to assume UTF-8 because Alpine
 195                                         # seems to do wacky things and set
 196                                         # charset=X-UNKNOWN
 197                                         $part->charset_set('UTF-8');
 198                                         $s = eval { $part->body_str };
 199                                         $s = $part->body if $@;
 200                                 }
 201                         }
 202                         defined $s or return;
 203
 204                         my (@orig, @quot);
 205                         my $body = $part->body;
 206                         my @lines = split(/\n/, $body);
 207                         while (defined(my $l = shift @lines)) {
 208                                 if ($l =~ /^>/) {
 209                                         index_body($tg, \@orig, 1) if @orig;
 210                                         push @quot, $l;
 211                                 } else {
 212                                         index_body($tg, \@quot, 0) if @quot;
 213                                         push @orig, $l;
 214                                 }
 215                         }
 216                         index_body($tg, \@quot, 0) if @quot;
 217                         index_body($tg, \@orig, 1) if @orig;
 218                 });
 219
 220                 link_message($self, $smsg, $old_tid);
 221                 $tg->index_text($mid, 1, 'XMID');
 222                 $doc->set_data($smsg->to_doc_data($blob));
 223
 224                 if (my $altid = $self->{-altid}) {
 225                         foreach my $alt (@$altid) {
 226                                 my $id = $alt->mid2alt($mid);
 227                                 next unless defined $id;
 228                                 $doc->add_term($alt->{xprefix} . $id);
 229                         }
 230                 }
 231                 if (defined $doc_id) {
 232                         $db->replace_document($doc_id, $doc);
 233                 } else {
 234                         $doc_id = $db->add_document($doc);
 235                 }
 236         };
 237
 238         if ($@) {
 239                 warn "failed to index message <$mid>: $@\n";
 240                 return undef;
 241         }
 242         $doc_id;
 243 }
 244
 245 # returns deleted doc_id on success, undef on missing
 246 sub remove_message {
 247         my ($self, $mid) = @_;
 248         my $db = $self->{xdb};
 249         my $doc_id;
 250         $mid = mid_clean($mid);
 251
 252         eval {
 253                 $doc_id = $self->find_unique_doc_id('mid', $mid);
 254                 $db->delete_document($doc_id) if defined $doc_id;
 255         };
 256
 257         if ($@) {
 258                 warn "failed to remove message <$mid>: $@\n";
 259                 return undef;
 260         }
 261         $doc_id;
 262 }
 263
 264 sub term_generator { # write-only
 265         my ($self) = @_;
 266
 267         my $tg = $self->{term_generator};
 268         return $tg if $tg;
 269
 270         $tg = Search::Xapian::TermGenerator->new;
 271         $tg->set_stemmer($self->stemmer);
 272
 273         $self->{term_generator} = $tg;
 274 }
 275
 276 # increments last_thread_id counter
 277 # returns a 64-bit integer represented as a hex string
 278 sub next_thread_id {
 279         my ($self) = @_;
 280         my $db = $self->{xdb};
 281         my $last_thread_id = int($db->get_metadata('last_thread_id') || 0);
 282
 283         $db->set_metadata('last_thread_id', ++$last_thread_id);
 284
 285         $last_thread_id;
 286 }
 287
 288 sub link_message {
 289         my ($self, $smsg, $old_tid) = @_;
 290         my $doc = $smsg->{doc};
 291         my $mid = $smsg->mid;
 292         my $mime = $smsg->{mime};
 293         my $hdr = $mime->header_obj;
 294         my $refs = $hdr->header_raw('References');
 295         my @refs = defined $refs ? ($refs =~ /<([^>]+)>/g) : ();
 296         my $irt = $hdr->header_raw('In-Reply-To');
 297         if (defined $irt) {
 298                 if ($irt eq '') {
 299                         $irt = undef;
 300                 } else {
 301                         $irt = mid_clean($irt);
 302                         $irt = undef if $mid eq $irt;
 303                 }
 304         }
 305
 306         my $tid;
 307         if (@refs) {
 308                 my %uniq = ($mid => 1);
 309                 my @orig_refs = @refs;
 310                 @refs = ();
 311
 312                 if (defined $irt) {
 313                         # to check MAX_MID_SIZE
 314                         push @orig_refs, $irt;
 315
 316                         # below, we will ensure IRT (if specified)
 317                         # is the last References
 318                         $uniq{$irt} = 1;
 319                 }
 320
 321                 # prevent circular references via References: here:
 322                 foreach my $ref (@orig_refs) {
 323                         if (length($ref) > MAX_MID_SIZE) {
 324                                 warn "References: <$ref> too long, ignoring\n";
 325                         }
 326                         next if $uniq{$ref};
 327                         $uniq{$ref} = 1;
 328                         push @refs, $ref;
 329                 }
 330         }
 331
 332         # last References should be IRT, but some mail clients do things
 333         # out of order, so trust IRT over References iff IRT exists
 334         push @refs, $irt if defined $irt;
 335
 336         if (@refs) {
 337                 $smsg->{references} = '<'.join('> <', @refs).'>';
 338
 339                 # first ref *should* be the thread root,
 340                 # but we can never trust clients to do the right thing
 341                 my $ref = shift @refs;
 342                 $tid = $self->_resolve_mid_to_tid($ref);
 343                 $self->merge_threads($tid, $old_tid) if defined $old_tid;
 344
 345                 # the rest of the refs should point to this tid:
 346                 foreach $ref (@refs) {
 347                         my $ptid = $self->_resolve_mid_to_tid($ref);
 348                         merge_threads($self, $tid, $ptid);
 349                 }
 350         } else {
 351                 $tid = $self->next_thread_id;
 352         }
 353         $doc->add_term(xpfx('thread') . $tid);
 354 }
 355
 356 sub index_blob {
 357         my ($self, $mime, $bytes, $num, $blob) = @_;
 358         $self->add_message($mime, $bytes, $num, $blob);
 359 }
 360
 361 sub unindex_blob {
 362         my ($self, $mime) = @_;
 363         my $mid = eval { mid_clean(mid_mime($mime)) };
 364         $self->remove_message($mid) if defined $mid;
 365 }
 366
 367 sub index_mm {
 368         my ($self, $mime) = @_;
 369         $self->{mm}->mid_insert(mid_clean(mid_mime($mime)));
 370 }
 371
 372 sub unindex_mm {
 373         my ($self, $mime) = @_;
 374         $self->{mm}->mid_delete(mid_clean(mid_mime($mime)));
 375 }
 376
 377 sub index_mm2 {
 378         my ($self, $mime, $bytes, $blob) = @_;
 379         my $num = $self->{mm}->num_for(mid_clean(mid_mime($mime)));
 380         index_blob($self, $mime, $bytes, $num, $blob);
 381 }
 382
 383 sub unindex_mm2 {
 384         my ($self, $mime) = @_;
 385         $self->{mm}->mid_delete(mid_clean(mid_mime($mime)));
 386         unindex_blob($self, $mime);
 387 }
 388
 389 sub index_both {
 390         my ($self, $mime, $bytes, $blob) = @_;
 391         my $num = index_mm($self, $mime);
 392         index_blob($self, $mime, $bytes, $num, $blob);
 393 }
 394
 395 sub unindex_both {
 396         my ($self, $mime) = @_;
 397         unindex_blob($self, $mime);
 398         unindex_mm($self, $mime);
 399 }
 400
 401 sub do_cat_mail {
 402         my ($git, $blob, $sizeref) = @_;
 403         my $mime = eval {
 404                 my $str = $git->cat_file($blob, $sizeref);
 405                 # fixup bugs from import:
 406                 $$str =~ s/\A[\r\n]*From [^\r\n]*\r?\n//s;
 407                 PublicInbox::MIME->new($str);
 408         };
 409         $@ ? undef : $mime;
 410 }
 411
 412 sub index_sync {
 413         my ($self, $opts) = @_;
 414         with_umask($self, sub { $self->_index_sync($opts) });
 415 }
 416
 417 sub rlog {
 418         my ($self, $log, $add_cb, $del_cb, $batch_cb) = @_;
 419         my $hex = '[a-f0-9]';
 420         my $h40 = $hex .'{40}';
 421         my $addmsg = qr!^:000000 100644 \S+ ($h40) A\t${hex}{2}/${hex}{38}$!;
 422         my $delmsg = qr!^:100644 000000 ($h40) \S+ D\t${hex}{2}/${hex}{38}$!;
 423         my $git = $self->{git};
 424         my $latest;
 425         my $bytes;
 426         my $max = $self->{batch_size}; # may be undef
 427         local $/ = "\n";
 428         my $line;
 429         while (defined($line = <$log>)) {
 430                 if ($line =~ /$addmsg/o) {
 431                         my $blob = $1;
 432                         my $mime = do_cat_mail($git, $blob, \$bytes) or next;
 433                         $add_cb->($self, $mime, $bytes, $blob);
 434                 } elsif ($line =~ /$delmsg/o) {
 435                         my $blob = $1;
 436                         my $mime = do_cat_mail($git, $blob) or next;
 437                         $del_cb->($self, $mime);
 438                 } elsif ($line =~ /^commit ($h40)/o) {
 439                         if (defined $max && --$max <= 0) {
 440                                 $max = $self->{batch_size};
 441                                 $batch_cb->($latest, 1);
 442                         }
 443                         $latest = $1;
 444                 }
 445         }
 446         $batch_cb->($latest, 0);
 447 }
 448
 449 sub _msgmap_init {
 450         my ($self) = @_;
 451         $self->{mm} = eval {
 452                 require PublicInbox::Msgmap;
 453                 PublicInbox::Msgmap->new($self->{git_dir}, 1);
 454         };
 455 }
 456
 457 sub _git_log {
 458         my ($self, $range) = @_;
 459         $self->{git}->popen(qw/log --reverse --no-notes --no-color
 460                                 --raw -r --no-abbrev/, $range);
 461 }
 462
 463 # indexes all unindexed messages
 464 sub _index_sync {
 465         my ($self, $opts) = @_;
 466         my $tip = $opts->{ref} || 'HEAD';
 467         my $reindex = $opts->{reindex};
 468         my ($mkey, $last_commit, $lx, $xlog);
 469         $self->{git}->batch_prepare;
 470         my $xdb = _xdb_acquire($self);
 471         $xdb->begin_transaction;
 472         do {
 473                 $xlog = undef;
 474                 $mkey = 'last_commit';
 475                 $last_commit = $xdb->get_metadata('last_commit');
 476                 $lx = $last_commit;
 477                 if ($reindex) {
 478                         $lx = '';
 479                         $mkey = undef if $last_commit ne '';
 480                 }
 481                 $xdb->cancel_transaction;
 482                 $xdb = _xdb_release($self);
 483
 484                 # ensure we leak no FDs to "git log"
 485                 my $range = $lx eq '' ? $tip : "$lx..$tip";
 486                 $xlog = _git_log($self, $range);
 487
 488                 $xdb = _xdb_acquire($self);
 489                 $xdb->begin_transaction;
 490         } while ($xdb->get_metadata('last_commit') ne $last_commit);
 491
 492         my $mm = _msgmap_init($self);
 493         my $dbh = $mm->{dbh} if $mm;
 494         my $mm_only;
 495         my $cb = sub {
 496                 my ($commit, $more) = @_;
 497                 if ($dbh) {
 498                         $mm->last_commit($commit) if $commit;
 499                         $dbh->commit;
 500                 }
 501                 if (!$mm_only) {
 502                         $xdb->set_metadata($mkey, $commit) if $mkey && $commit;
 503                         $xdb->commit_transaction;
 504                         $xdb = _xdb_release($self);
 505                 }
 506                 # let another process do some work... <
 507                 if ($more) {
 508                         if (!$mm_only) {
 509                                 $xdb = _xdb_acquire($self);
 510                                 $xdb->begin_transaction;
 511                         }
 512                         $dbh->begin_work if $dbh;
 513                 }
 514         };
 515
 516         if ($mm) {
 517                 $dbh->begin_work;
 518                 my $lm = $mm->last_commit || '';
 519                 if ($lm eq $lx) {
 520                         # Common case is the indexes are synced,
 521                         # we only need to run git-log once:
 522                         rlog($self, $xlog, *index_both, *unindex_both, $cb);
 523                 } else {
 524                         # Uncommon case, msgmap and xapian are out-of-sync
 525                         # do not care for performance (but git is fast :>)
 526                         # This happens if we have to reindex Xapian since
 527                         # msgmap is a frozen format and our Xapian format
 528                         # is evolving.
 529                         my $r = $lm eq '' ? $tip : "$lm..$tip";
 530
 531                         # first, ensure msgmap is up-to-date:
 532                         my $mkey_prev = $mkey;
 533                         $mkey = undef; # ignore xapian, for now
 534                         my $mlog = _git_log($self, $r);
 535                         $mm_only = 1;
 536                         rlog($self, $mlog, *index_mm, *unindex_mm, $cb);
 537                         $mm_only = $mlog = undef;
 538
 539                         # now deal with Xapian
 540                         $mkey = $mkey_prev;
 541                         $dbh = undef;
 542                         rlog($self, $xlog, *index_mm2, *unindex_mm2, $cb);
 543                 }
 544         } else {
 545                 # user didn't install DBD::SQLite and DBI
 546                 rlog($self, $xlog, *index_blob, *unindex_blob, $cb);
 547         }
 548 }
 549
 550 # this will create a ghost as necessary
 551 sub _resolve_mid_to_tid {
 552         my ($self, $mid) = @_;
 553
 554         my $smsg = $self->lookup_message($mid) || $self->create_ghost($mid);
 555         $smsg->thread_id;
 556 }
 557
 558 sub create_ghost {
 559         my ($self, $mid) = @_;
 560
 561         my $tid = $self->next_thread_id;
 562         my $doc = Search::Xapian::Document->new;
 563         $doc->add_term(xpfx('mid') . $mid);
 564         $doc->add_term(xpfx('thread') . $tid);
 565         $doc->add_term(xpfx('type') . 'ghost');
 566
 567         my $smsg = PublicInbox::SearchMsg->wrap($doc, $mid);
 568         $self->{xdb}->add_document($doc);
 569
 570         $smsg;
 571 }
 572
 573 sub merge_threads {
 574         my ($self, $winner_tid, $loser_tid) = @_;
 575         return if $winner_tid == $loser_tid;
 576         my ($head, $tail) = $self->find_doc_ids('thread', $loser_tid);
 577         my $thread_pfx = xpfx('thread');
 578         my $db = $self->{xdb};
 579
 580         for (; $head != $tail; $head->inc) {
 581                 my $docid = $head->get_docid;
 582                 my $doc = $db->get_document($docid);
 583                 $doc->remove_term($thread_pfx . $loser_tid);
 584                 $doc->add_term($thread_pfx . $winner_tid);
 585                 $db->replace_document($docid, $doc);
 586         }
 587 }
 588
 589 sub _read_git_config_perm {
 590         my ($self) = @_;
 591         my @cmd = qw(config core.sharedRepository);
 592         my $fh = PublicInbox::Git->new($self->{git_dir})->popen(@cmd);
 593         local $/ = "\n";
 594         my $perm = <$fh>;
 595         chomp $perm if defined $perm;
 596         $perm;
 597 }
 598
 599 sub _git_config_perm {
 600         my $self = shift;
 601         my $perm = scalar @_ ? $_[0] : _read_git_config_perm($self);
 602         return PERM_GROUP if (!defined($perm) || $perm eq '');
 603         return PERM_UMASK if ($perm eq 'umask');
 604         return PERM_GROUP if ($perm eq 'group');
 605         if ($perm =~ /\A(?:all|world|everybody)\z/) {
 606                 return PERM_EVERYBODY;
 607         }
 608         return PERM_GROUP if ($perm =~ /\A(?:true|yes|on|1)\z/);
 609         return PERM_UMASK if ($perm =~ /\A(?:false|no|off|0)\z/);
 610
 611         my $i = oct($perm);
 612         return PERM_UMASK if ($i == PERM_UMASK);
 613         return PERM_GROUP if ($i == OLD_PERM_GROUP);
 614         return PERM_EVERYBODY if ($i == OLD_PERM_EVERYBODY);
 615
 616         if (($i & 0600) != 0600) {
 617                 die "core.sharedRepository mode invalid: ".
 618                     sprintf('%.3o', $i) . "\nOwner must have permissions\n";
 619         }
 620         ($i & 0666);
 621 }
 622
 623 sub _umask_for {
 624         my ($perm) = @_; # _git_config_perm return value
 625         my $rv = $perm;
 626         return umask if $rv == 0;
 627
 628         # set +x bit if +r or +w were set
 629         $rv |= 0100 if ($rv & 0600);
 630         $rv |= 0010 if ($rv & 0060);
 631         $rv |= 0001 if ($rv & 0006);
 632         (~$rv & 0777);
 633 }
 634
 635 sub with_umask {
 636         my ($self, $cb) = @_;
 637         my $old = umask $self->{umask};
 638         my $rv = eval { $cb->() };
 639         my $err = $@;
 640         umask $old;
 641         die $err if $@;
 642         $rv;
 643 }
 644
 645 sub DESTROY {
 646         # order matters for unlocking
 647         $_[0]->{xdb} = undef;
 648         $_[0]->{lockfh} = undef;
 649 }
 650
 651 1;