lib/PublicInbox/SearchIdx.pm

   1 # Copyright (C) 2015-2019 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 # based on notmuch, but with no concept of folders, files or flags
   4 #
   5 # Indexes mail with Xapian and our (SQLite-based) ::Msgmap for use
   6 # with the web and NNTP interfaces.  This index maintains thread
   7 # relationships for use by PublicInbox::SearchThread.
   8 # This writes to the search index.
   9 package PublicInbox::SearchIdx;
  10 use strict;
  11 use warnings;
  12 use base qw(PublicInbox::Search PublicInbox::Lock);
  13 use PublicInbox::MIME;
  14 use PublicInbox::InboxWritable;
  15 use PublicInbox::MID qw/mid_clean id_compress mid_mime mids_for_index/;
  16 use PublicInbox::MsgIter;
  17 use Carp qw(croak);
  18 use POSIX qw(strftime);
  19 use PublicInbox::OverIdx;
  20 use PublicInbox::Spawn qw(spawn);
  21 use PublicInbox::Git qw(git_unquote);
  22 my $X = \%PublicInbox::Search::X;
  23 my ($DB_CREATE_OR_OPEN, $DB_OPEN);
  24 use constant {
  25         BATCH_BYTES => defined($ENV{XAPIAN_FLUSH_THRESHOLD}) ?
  26                         0x7fffffff : 1_000_000,
  27         DEBUG => !!$ENV{DEBUG},
  28 };
  29
  30 my $xapianlevels = qr/\A(?:full|medium)\z/;
  31
  32 sub new {
  33         my ($class, $ibx, $creat, $shard) = @_;
  34         ref $ibx or die "BUG: expected PublicInbox::Inbox object: $ibx";
  35         my $levels = qr/\A(?:full|medium|basic)\z/;
  36         my $inboxdir = $ibx->{inboxdir};
  37         my $version = $ibx->{version} || 1;
  38         my $indexlevel = 'full';
  39         my $altid = $ibx->{altid};
  40         if ($altid) {
  41                 require PublicInbox::AltId;
  42                 $altid = [ map { PublicInbox::AltId->new($ibx, $_); } @$altid ];
  43         }
  44         if ($ibx->{indexlevel}) {
  45                 if ($ibx->{indexlevel} =~ $levels) {
  46                         $indexlevel = $ibx->{indexlevel};
  47                 } else {
  48                         die("Invalid indexlevel $ibx->{indexlevel}\n");
  49                 }
  50         }
  51         $ibx = PublicInbox::InboxWritable->new($ibx);
  52         my $self = bless {
  53                 inboxdir => $inboxdir,
  54                 -inbox => $ibx,
  55                 git => $ibx->git,
  56                 -altid => $altid,
  57                 version => $version,
  58                 indexlevel => $indexlevel,
  59         }, $class;
  60         $ibx->umask_prepare;
  61         if ($version == 1) {
  62                 $self->{lock_path} = "$inboxdir/ssoma.lock";
  63                 my $dir = $self->xdir;
  64                 $self->{over} = PublicInbox::OverIdx->new("$dir/over.sqlite3");
  65         } elsif ($version == 2) {
  66                 defined $shard or die "shard is required for v2\n";
  67                 # shard is a number
  68                 $self->{shard} = $shard;
  69                 $self->{lock_path} = undef;
  70         } else {
  71                 die "unsupported inbox version=$version\n";
  72         }
  73         $self->{creat} = ($creat || 0) == 1;
  74         $self;
  75 }
  76
  77 sub need_xapian ($) { $_[0]->{indexlevel} =~ $xapianlevels }
  78
  79 sub _xdb_release {
  80         my ($self) = @_;
  81         if (need_xapian($self)) {
  82                 my $xdb = delete $self->{xdb} or croak 'not acquired';
  83                 $xdb->close;
  84         }
  85         $self->lock_release if $self->{creat};
  86         undef;
  87 }
  88
  89 sub load_xapian_writable () {
  90         return 1 if $X->{WritableDatabase};
  91         PublicInbox::Search::load_xapian() or return;
  92         my $xap = $PublicInbox::Search::Xap;
  93         for (qw(Document TermGenerator WritableDatabase)) {
  94                 $X->{$_} = $xap.'::'.$_;
  95         }
  96         eval 'require '.$X->{WritableDatabase} or die;
  97         *sortable_serialise = $xap.'::sortable_serialise';
  98         $DB_CREATE_OR_OPEN = eval($xap.'::DB_CREATE_OR_OPEN()');
  99         $DB_OPEN = eval($xap.'::DB_OPEN()');
 100         1;
 101 }
 102
 103 sub _xdb_acquire {
 104         my ($self) = @_;
 105         my $flag;
 106         my $dir = $self->xdir;
 107         if (need_xapian($self)) {
 108                 croak 'already acquired' if $self->{xdb};
 109                 load_xapian_writable();
 110                 $flag = $self->{creat} ? $DB_CREATE_OR_OPEN : $DB_OPEN;
 111         }
 112         if ($self->{creat}) {
 113                 require File::Path;
 114                 $self->lock_acquire;
 115
 116                 # don't create empty Xapian directories if we don't need Xapian
 117                 my $is_shard = defined($self->{shard});
 118                 if (!$is_shard || ($is_shard && need_xapian($self))) {
 119                         File::Path::mkpath($dir);
 120                 }
 121         }
 122         return unless defined $flag;
 123         my $xdb = eval { ($X->{WritableDatabase})->new($dir, $flag) };
 124         if ($@) {
 125                 die "Failed opening $dir: ", $@;
 126         }
 127         $self->{xdb} = $xdb;
 128 }
 129
 130 sub add_val ($$$) {
 131         my ($doc, $col, $num) = @_;
 132         $num = sortable_serialise($num);
 133         $doc->add_value($col, $num);
 134 }
 135
 136 sub index_text ($$$$)
 137 {
 138         my ($self, $field, $n, $text) = @_;
 139         my $tg = $self->term_generator;
 140
 141         if ($self->{indexlevel} eq 'full') {
 142                 $tg->index_text($field, $n, $text);
 143                 $tg->increase_termpos;
 144         } else {
 145                 $tg->index_text_without_positions($field, $n, $text);
 146         }
 147 }
 148
 149 sub index_users ($$) {
 150         my ($self, $smsg) = @_;
 151
 152         my $from = $smsg->from;
 153         my $to = $smsg->to;
 154         my $cc = $smsg->cc;
 155
 156         $self->index_text($from, 1, 'A'); # A - author
 157         $self->index_text($to, 1, 'XTO') if $to ne '';
 158         $self->index_text($cc, 1, 'XCC') if $cc ne '';
 159 }
 160
 161 sub index_diff_inc ($$$$) {
 162         my ($self, $text, $pfx, $xnq) = @_;
 163         if (@$xnq) {
 164                 $self->index_text(join("\n", @$xnq), 1, 'XNQ');
 165                 @$xnq = ();
 166         }
 167         $self->index_text($text, 1, $pfx);
 168 }
 169
 170 sub index_old_diff_fn {
 171         my ($self, $seen, $fa, $fb, $xnq) = @_;
 172
 173         # no renames or space support for traditional diffs,
 174         # find the number of leading common paths to strip:
 175         my @fa = split('/', $fa);
 176         my @fb = split('/', $fb);
 177         while (scalar(@fa) && scalar(@fb)) {
 178                 $fa = join('/', @fa);
 179                 $fb = join('/', @fb);
 180                 if ($fa eq $fb) {
 181                         unless ($seen->{$fa}++) {
 182                                 $self->index_diff_inc($fa, 'XDFN', $xnq);
 183                         }
 184                         return 1;
 185                 }
 186                 shift @fa;
 187                 shift @fb;
 188         }
 189         0;
 190 }
 191
 192 sub index_diff ($$$) {
 193         my ($self, $lines, $doc) = @_;
 194         my %seen;
 195         my $in_diff;
 196         my @xnq;
 197         my $xnq = \@xnq;
 198         foreach (@$lines) {
 199                 if ($in_diff && s/^ //) { # diff context
 200                         $self->index_diff_inc($_, 'XDFCTX', $xnq);
 201                 } elsif (/^-- $/) { # email signature begins
 202                         $in_diff = undef;
 203                 } elsif (m!^diff --git ("?a/.+) ("?b/.+)\z!) {
 204                         my ($fa, $fb) = ($1, $2);
 205                         my $fn = (split('/', git_unquote($fa), 2))[1];
 206                         $seen{$fn}++ or $self->index_diff_inc($fn, 'XDFN', $xnq);
 207                         $fn = (split('/', git_unquote($fb), 2))[1];
 208                         $seen{$fn}++ or $self->index_diff_inc($fn, 'XDFN', $xnq);
 209                         $in_diff = 1;
 210                 # traditional diff:
 211                 } elsif (m/^diff -(.+) (\S+) (\S+)$/) {
 212                         my ($opt, $fa, $fb) = ($1, $2, $3);
 213                         push @xnq, $_;
 214                         # only support unified:
 215                         next unless $opt =~ /[uU]/;
 216                         $in_diff = $self->index_old_diff_fn(\%seen, $fa, $fb,
 217                                                         $xnq);
 218                 } elsif (m!^--- ("?a/.+)!) {
 219                         my $fn = $1;
 220                         $fn = (split('/', git_unquote($fn), 2))[1];
 221                         $seen{$fn}++ or $self->index_diff_inc($fn, 'XDFN', $xnq);
 222                         $in_diff = 1;
 223                 } elsif (m!^\+\+\+ ("?b/.+)!)  {
 224                         my $fn = $1;
 225                         $fn = (split('/', git_unquote($fn), 2))[1];
 226                         $seen{$fn}++ or $self->index_diff_inc($fn, 'XDFN', $xnq);
 227                         $in_diff = 1;
 228                 } elsif (/^--- (\S+)/) {
 229                         $in_diff = $1;
 230                         push @xnq, $_;
 231                 } elsif (defined $in_diff && /^\+\+\+ (\S+)/) {
 232                         $in_diff = $self->index_old_diff_fn(\%seen, $in_diff, $1,
 233                                                         $xnq);
 234                 } elsif ($in_diff && s/^\+//) { # diff added
 235                         $self->index_diff_inc($_, 'XDFB', $xnq);
 236                 } elsif ($in_diff && s/^-//) { # diff removed
 237                         $self->index_diff_inc($_, 'XDFA', $xnq);
 238                 } elsif (m!^index ([a-f0-9]+)\.\.([a-f0-9]+)!) {
 239                         my ($ba, $bb) = ($1, $2);
 240                         index_git_blob_id($doc, 'XDFPRE', $ba);
 241                         index_git_blob_id($doc, 'XDFPOST', $bb);
 242                         $in_diff = 1;
 243                 } elsif (/^@@ (?:\S+) (?:\S+) @@\s*$/) {
 244                         # traditional diff w/o -p
 245                 } elsif (/^@@ (?:\S+) (?:\S+) @@\s*(\S+.*)$/) {
 246                         # hunk header context
 247                         $self->index_diff_inc($1, 'XDFHH', $xnq);
 248                 # ignore the following lines:
 249                 } elsif (/^(?:dis)similarity index/ ||
 250                                 /^(?:old|new) mode/ ||
 251                                 /^(?:deleted|new) file mode/ ||
 252                                 /^(?:copy|rename) (?:from|to) / ||
 253                                 /^(?:dis)?similarity index / ||
 254                                 /^\\ No newline at end of file/ ||
 255                                 /^Binary files .* differ/) {
 256                         push @xnq, $_;
 257                 } elsif ($_ eq '') {
 258                         $in_diff = undef;
 259                 } else {
 260                         push @xnq, $_;
 261                         warn "non-diff line: $_\n" if DEBUG && $_ ne '';
 262                         $in_diff = undef;
 263                 }
 264         }
 265
 266         $self->index_text(join("\n", @xnq), 1, 'XNQ');
 267 }
 268
 269 sub index_body ($$$) {
 270         my ($self, $lines, $doc) = @_;
 271         my $txt = join("\n", @$lines);
 272         if ($doc) {
 273                 # does it look like a diff?
 274                 if ($txt =~ /^(?:diff|---|\+\+\+) /ms) {
 275                         $txt = undef;
 276                         $self->index_diff($lines, $doc);
 277                 } else {
 278                         $self->index_text($txt, 1, 'XNQ');
 279                 }
 280         } else {
 281                 $self->index_text($txt, 0, 'XQUOT');
 282         }
 283         @$lines = ();
 284 }
 285
 286 sub add_xapian ($$$$$) {
 287         my ($self, $mime, $num, $oid, $mids, $mid0) = @_;
 288         my $smsg = PublicInbox::SearchMsg->new($mime);
 289         my $doc = $X->{Document}->new;
 290         my $subj = $smsg->subject;
 291         add_val($doc, PublicInbox::Search::TS(), $smsg->ts);
 292         my @ds = gmtime($smsg->ds);
 293         my $yyyymmdd = strftime('%Y%m%d', @ds);
 294         add_val($doc, PublicInbox::Search::YYYYMMDD(), $yyyymmdd);
 295         my $dt = strftime('%Y%m%d%H%M%S', @ds);
 296         add_val($doc, PublicInbox::Search::DT(), $dt);
 297
 298         my $tg = $self->term_generator;
 299
 300         $tg->set_document($doc);
 301         $self->index_text($subj, 1, 'S') if $subj;
 302         $self->index_users($smsg);
 303
 304         msg_iter($mime, sub {
 305                 my ($part, $depth, @idx) = @{$_[0]};
 306                 my $ct = $part->content_type || 'text/plain';
 307                 my $fn = $part->filename;
 308                 if (defined $fn && $fn ne '') {
 309                         $self->index_text($fn, 1, 'XFN');
 310                 }
 311
 312                 my ($s, undef) = msg_part_text($part, $ct);
 313                 defined $s or return;
 314
 315                 my (@orig, @quot);
 316                 my @lines = split(/\n/, $s);
 317                 while (defined(my $l = shift @lines)) {
 318                         if ($l =~ /^>/) {
 319                                 $self->index_body(\@orig, $doc) if @orig;
 320                                 push @quot, $l;
 321                         } else {
 322                                 $self->index_body(\@quot, 0) if @quot;
 323                                 push @orig, $l;
 324                         }
 325                 }
 326                 $self->index_body(\@quot, 0) if @quot;
 327                 $self->index_body(\@orig, $doc) if @orig;
 328         });
 329
 330         foreach my $mid (@$mids) {
 331                 $self->index_text($mid, 1, 'XM');
 332
 333                 # because too many Message-IDs are prefixed with
 334                 # "Pine.LNX."...
 335                 if ($mid =~ /\w{12,}/) {
 336                         my @long = ($mid =~ /(\w{3,}+)/g);
 337                         $self->index_text(join(' ', @long), 1, 'XM');
 338                 }
 339         }
 340         $smsg->{to} = $smsg->{cc} = '';
 341         PublicInbox::OverIdx::parse_references($smsg, $mid0, $mids);
 342         my $data = $smsg->to_doc_data($oid, $mid0);
 343         $doc->set_data($data);
 344         if (my $altid = $self->{-altid}) {
 345                 foreach my $alt (@$altid) {
 346                         my $pfx = $alt->{xprefix};
 347                         foreach my $mid (@$mids) {
 348                                 my $id = $alt->mid2alt($mid);
 349                                 next unless defined $id;
 350                                 $doc->add_boolean_term($pfx . $id);
 351                         }
 352                 }
 353         }
 354         $doc->add_boolean_term('Q' . $_) foreach @$mids;
 355         $self->{xdb}->replace_document($num, $doc);
 356 }
 357
 358 sub add_message {
 359         # mime = Email::MIME object
 360         my ($self, $mime, $bytes, $num, $oid, $mid0) = @_;
 361         my $mids = mids_for_index($mime->header_obj);
 362         $mid0 = $mids->[0] unless defined $mid0; # v1 compatibility
 363         unless (defined $num) { # v1
 364                 $self->_msgmap_init;
 365                 $num = index_mm($self, $mime);
 366         }
 367         eval {
 368                 if (need_xapian($self)) {
 369                         $self->add_xapian($mime, $num, $oid, $mids, $mid0)
 370                 }
 371                 if (my $over = $self->{over}) {
 372                         $over->add_overview($mime, $bytes, $num, $oid, $mid0);
 373                 }
 374         };
 375
 376         if ($@) {
 377                 warn "failed to index message <".join('> <',@$mids).">: $@\n";
 378                 return undef;
 379         }
 380         $num;
 381 }
 382
 383 # returns begin and end PostingIterator
 384 sub find_doc_ids {
 385         my ($self, $termval) = @_;
 386         my $db = $self->{xdb};
 387
 388         ($db->postlist_begin($termval), $db->postlist_end($termval));
 389 }
 390
 391 # v1 only
 392 sub batch_do {
 393         my ($self, $termval, $cb) = @_;
 394         my $batch_size = 1000; # don't let @ids grow too large to avoid OOM
 395         while (1) {
 396                 my ($head, $tail) = $self->find_doc_ids($termval);
 397                 return if $head == $tail;
 398                 my @ids;
 399                 for (; $head != $tail && @ids < $batch_size; $head++) {
 400                         push @ids, $head->get_docid;
 401                 }
 402                 $cb->(\@ids);
 403         }
 404 }
 405
 406 # v1 only, where $mid is unique
 407 sub remove_message {
 408         my ($self, $mid) = @_;
 409         $mid = mid_clean($mid);
 410
 411         if (my $over = $self->{over}) {
 412                 my $nr = eval { $over->remove_oid(undef, $mid) };
 413                 if ($@) {
 414                         warn "failed to remove <$mid> from overview: $@\n";
 415                 } elsif ($nr == 0) {
 416                         warn "<$mid> missing for removal from overview\n";
 417                 }
 418         }
 419         return unless need_xapian($self);
 420         my $db = $self->{xdb};
 421         my $nr = 0;
 422         eval {
 423                 batch_do($self, 'Q' . $mid, sub {
 424                         my ($ids) = @_;
 425                         $db->delete_document($_) for @$ids;
 426                         $nr = scalar @$ids;
 427                 });
 428         };
 429         if ($@) {
 430                 warn "failed to remove <$mid> from Xapian: $@\n";
 431         } elsif ($nr == 0) {
 432                 warn "<$mid> missing for removal from Xapian\n";
 433         }
 434 }
 435
 436 # MID is a hint in V2
 437 sub remove_by_oid {
 438         my ($self, $oid, $mid) = @_;
 439
 440         $self->{over}->remove_oid($oid, $mid) if $self->{over};
 441
 442         return unless need_xapian($self);
 443         my $db = $self->{xdb};
 444
 445         # XXX careful, we cannot use batch_do here since we conditionally
 446         # delete documents based on other factors, so we cannot call
 447         # find_doc_ids twice.
 448         my ($head, $tail) = $self->find_doc_ids('Q' . $mid);
 449         return if $head == $tail;
 450
 451         # there is only ONE element in @delete unless we
 452         # have bugs in our v2writable deduplication check
 453         my @delete;
 454         for (; $head != $tail; $head++) {
 455                 my $docid = $head->get_docid;
 456                 my $doc = $db->get_document($docid);
 457                 my $smsg = PublicInbox::SearchMsg->wrap($mid);
 458                 $smsg->load_expand($doc);
 459                 if ($smsg->{blob} eq $oid) {
 460                         push(@delete, $docid);
 461                 }
 462         }
 463         $db->delete_document($_) foreach @delete;
 464         scalar(@delete);
 465 }
 466
 467 sub term_generator { # write-only
 468         my ($self) = @_;
 469
 470         my $tg = $self->{term_generator};
 471         return $tg if $tg;
 472
 473         $tg = $X->{TermGenerator}->new;
 474         $tg->set_stemmer($self->stemmer);
 475
 476         $self->{term_generator} = $tg;
 477 }
 478
 479 sub index_git_blob_id {
 480         my ($doc, $pfx, $objid) = @_;
 481
 482         my $len = length($objid);
 483         for (my $len = length($objid); $len >= 7; ) {
 484                 $doc->add_term($pfx.$objid);
 485                 $objid = substr($objid, 0, --$len);
 486         }
 487 }
 488
 489 sub unindex_blob {
 490         my ($self, $mime) = @_;
 491         my $mid = eval { mid_clean(mid_mime($mime)) };
 492         $self->remove_message($mid) if defined $mid;
 493 }
 494
 495 sub index_mm {
 496         my ($self, $mime) = @_;
 497         my $mid = mid_clean(mid_mime($mime));
 498         my $mm = $self->{mm};
 499         my $num;
 500
 501         if (defined $self->{regen_down}) {
 502                 $num = $mm->num_for($mid) and return $num;
 503
 504                 while (($num = $self->{regen_down}--) > 0) {
 505                         if ($mm->mid_set($num, $mid) != 0) {
 506                                 return $num;
 507                         }
 508                 }
 509         } elsif (defined $self->{regen_up}) {
 510                 $num = $mm->num_for($mid) and return $num;
 511
 512                 # this is to fixup old bugs due to add-remove-add
 513                 while (($num = ++$self->{regen_up})) {
 514                         if ($mm->mid_set($num, $mid) != 0) {
 515                                 return $num;
 516                         }
 517                 }
 518         }
 519
 520         $num = $mm->mid_insert($mid) and return $num;
 521
 522         # fallback to num_for since filters like RubyLang set the number
 523         $mm->num_for($mid);
 524 }
 525
 526 sub unindex_mm {
 527         my ($self, $mime) = @_;
 528         $self->{mm}->mid_delete(mid_clean(mid_mime($mime)));
 529 }
 530
 531 sub index_both {
 532         my ($self, $mime, $bytes, $blob) = @_;
 533         my $num = index_mm($self, $mime);
 534         add_message($self, $mime, $bytes, $num, $blob);
 535 }
 536
 537 sub unindex_both {
 538         my ($self, $mime) = @_;
 539         unindex_blob($self, $mime);
 540         unindex_mm($self, $mime);
 541 }
 542
 543 sub do_cat_mail {
 544         my ($git, $blob, $sizeref) = @_;
 545         my $mime = eval {
 546                 my $str = $git->cat_file($blob, $sizeref);
 547                 # fixup bugs from import:
 548                 $$str =~ s/\A[\r\n]*From [^\r\n]*\r?\n//s;
 549                 PublicInbox::MIME->new($str);
 550         };
 551         $@ ? undef : $mime;
 552 }
 553
 554 # called by public-inbox-index
 555 sub index_sync {
 556         my ($self, $opts) = @_;
 557         delete $self->{lock_path} if $opts->{-skip_lock};
 558         $self->{-inbox}->with_umask(sub { $self->_index_sync($opts) })
 559 }
 560
 561 sub batch_adjust ($$$$$) {
 562         my ($max, $bytes, $batch_cb, $latest, $nr) = @_;
 563         $$max -= $bytes;
 564         if ($$max <= 0) {
 565                 $$max = BATCH_BYTES;
 566                 $batch_cb->($nr, $latest);
 567         }
 568 }
 569
 570 # only for v1
 571 sub read_log {
 572         my ($self, $log, $add_cb, $del_cb, $batch_cb) = @_;
 573         my $hex = '[a-f0-9]';
 574         my $h40 = $hex .'{40}';
 575         my $addmsg = qr!^:000000 100644 \S+ ($h40) A\t${hex}{2}/${hex}{38}$!;
 576         my $delmsg = qr!^:100644 000000 ($h40) \S+ D\t${hex}{2}/${hex}{38}$!;
 577         my $git = $self->{git};
 578         my $latest;
 579         my $bytes;
 580         my $max = BATCH_BYTES;
 581         local $/ = "\n";
 582         my %D;
 583         my $line;
 584         my $newest;
 585         my $nr = 0;
 586         while (defined($line = <$log>)) {
 587                 if ($line =~ /$addmsg/o) {
 588                         my $blob = $1;
 589                         if (delete $D{$blob}) {
 590                                 if (defined $self->{regen_down}) {
 591                                         my $num = $self->{regen_down}--;
 592                                         $self->{mm}->num_highwater($num);
 593                                 }
 594                                 next;
 595                         }
 596                         my $mime = do_cat_mail($git, $blob, \$bytes) or next;
 597                         batch_adjust(\$max, $bytes, $batch_cb, $latest, ++$nr);
 598                         $add_cb->($self, $mime, $bytes, $blob);
 599                 } elsif ($line =~ /$delmsg/o) {
 600                         my $blob = $1;
 601                         $D{$blob} = 1;
 602                 } elsif ($line =~ /^commit ($h40)/o) {
 603                         $latest = $1;
 604                         $newest ||= $latest;
 605                 }
 606         }
 607         close($log) or die "git log failed: \$?=$?";
 608         # get the leftovers
 609         foreach my $blob (keys %D) {
 610                 my $mime = do_cat_mail($git, $blob, \$bytes) or next;
 611                 $del_cb->($self, $mime);
 612         }
 613         $batch_cb->($nr, $latest, $newest);
 614 }
 615
 616 sub _msgmap_init {
 617         my ($self) = @_;
 618         die "BUG: _msgmap_init is only for v1\n" if $self->{version} != 1;
 619         $self->{mm} ||= eval {
 620                 require PublicInbox::Msgmap;
 621                 PublicInbox::Msgmap->new($self->{inboxdir}, 1);
 622         };
 623 }
 624
 625 sub _git_log {
 626         my ($self, $opts, $range) = @_;
 627         my $git = $self->{git};
 628
 629         if (index($range, '..') < 0) {
 630                 # don't show annoying git errrors to users who run -index
 631                 # on empty inboxes
 632                 $git->qx(qw(rev-parse -q --verify), "$range^0");
 633                 if ($?) {
 634                         open my $fh, '<', '/dev/null' or
 635                                 die "failed to open /dev/null: $!\n";
 636                         return $fh;
 637                 }
 638         }
 639
 640         # Count the new files so they can be added newest to oldest
 641         # and still have numbers increasing from oldest to newest
 642         my $fcount = 0;
 643         my $pr = $opts->{-progress};
 644         $pr->("counting changes\n\t$range ... ") if $pr;
 645         # can't use 'rev-list --count' if we use --diff-filter
 646         my $fh = $git->popen(qw(log --pretty=tformat:%h
 647                              --no-notes --no-color --no-renames
 648                              --diff-filter=AM), $range);
 649         ++$fcount while <$fh>;
 650         close $fh or die "git log failed: \$?=$?";
 651         my $high = $self->{mm}->num_highwater;
 652         $pr->("$fcount\n") if $pr; # continue previous line
 653         $self->{ntodo} = $fcount;
 654
 655         if (index($range, '..') < 0) {
 656                 if ($high && $high == $fcount) {
 657                         # fix up old bugs in full indexes which caused messages to
 658                         # not appear in Msgmap
 659                         $self->{regen_up} = $high;
 660                 } else {
 661                         # normal regen is for for fresh data
 662                         $self->{regen_down} = $fcount;
 663                 }
 664         } else {
 665                 # Give oldest messages the smallest numbers
 666                 $self->{regen_down} = $high + $fcount;
 667         }
 668
 669         $git->popen(qw/log --no-notes --no-color --no-renames
 670                                 --raw -r --no-abbrev/, $range);
 671 }
 672
 673 # --is-ancestor requires git 1.8.0+
 674 sub is_ancestor ($$$) {
 675         my ($git, $cur, $tip) = @_;
 676         return 0 unless $git->check($cur);
 677         my $cmd = [ 'git', "--git-dir=$git->{git_dir}",
 678                 qw(merge-base --is-ancestor), $cur, $tip ];
 679         my $pid = spawn($cmd);
 680         defined $pid or die "spawning ".join(' ', @$cmd)." failed: $!";
 681         waitpid($pid, 0) == $pid or die join(' ', @$cmd) .' did not finish';
 682         $? == 0;
 683 }
 684
 685 sub need_update ($$$) {
 686         my ($self, $cur, $new) = @_;
 687         my $git = $self->{git};
 688         return 1 if $cur && !is_ancestor($git, $cur, $new);
 689         my $range = $cur eq '' ? $new : "$cur..$new";
 690         chomp(my $n = $git->qx(qw(rev-list --count), $range));
 691         ($n eq '' || $n > 0);
 692 }
 693
 694 # The last git commit we indexed with Xapian or SQLite (msgmap)
 695 # This needs to account for cases where Xapian or SQLite is
 696 # out-of-date with respect to the other.
 697 sub _last_x_commit {
 698         my ($self, $mm) = @_;
 699         my $lm = $mm->last_commit || '';
 700         my $lx = '';
 701         if (need_xapian($self)) {
 702                 $lx = $self->{xdb}->get_metadata('last_commit') || '';
 703         } else {
 704                 $lx = $lm;
 705         }
 706         # Use last_commit from msgmap if it is older or unset
 707         if (!$lm || ($lx && $lm && is_ancestor($self->{git}, $lm, $lx))) {
 708                 $lx = $lm;
 709         }
 710         $lx;
 711 }
 712
 713 sub reindex_from ($$) {
 714         my ($reindex, $last_commit) = @_;
 715         return $last_commit unless $reindex;
 716         ref($reindex) eq 'HASH' ? $reindex->{from} : '';
 717 }
 718
 719 # indexes all unindexed messages (v1 only)
 720 sub _index_sync {
 721         my ($self, $opts) = @_;
 722         my $tip = $opts->{ref} || 'HEAD';
 723         my ($last_commit, $lx, $xlog);
 724         my $git = $self->{git};
 725         $git->batch_prepare;
 726         my $pr = $opts->{-progress};
 727
 728         my $xdb = $self->begin_txn_lazy;
 729         my $mm = _msgmap_init($self);
 730         do {
 731                 if ($xlog) {
 732                         close($xlog) or die "git log failed: \$?=$?";
 733                         $xlog = undef;
 734                 }
 735                 $last_commit = _last_x_commit($self, $mm);
 736                 $lx = reindex_from($opts->{reindex}, $last_commit);
 737
 738                 $self->{over}->rollback_lazy;
 739                 $self->{over}->disconnect;
 740                 $git->cleanup;
 741                 delete $self->{txn};
 742                 $xdb->cancel_transaction if $xdb;
 743                 $xdb = _xdb_release($self);
 744
 745                 # ensure we leak no FDs to "git log" with Xapian <= 1.2
 746                 my $range = $lx eq '' ? $tip : "$lx..$tip";
 747                 $xlog = _git_log($self, $opts, $range);
 748
 749                 $xdb = $self->begin_txn_lazy;
 750         } while (_last_x_commit($self, $mm) ne $last_commit);
 751
 752         my $dbh = $mm->{dbh} if $mm;
 753         my $cb = sub {
 754                 my ($nr, $commit, $newest) = @_;
 755                 if ($dbh) {
 756                         if ($newest) {
 757                                 my $cur = $mm->last_commit || '';
 758                                 if (need_update($self, $cur, $newest)) {
 759                                         $mm->last_commit($newest);
 760                                 }
 761                         }
 762                         $dbh->commit;
 763                 }
 764                 if ($newest && need_xapian($self)) {
 765                         my $cur = $xdb->get_metadata('last_commit');
 766                         if (need_update($self, $cur, $newest)) {
 767                                 $xdb->set_metadata('last_commit', $newest);
 768                         }
 769                 }
 770                 $self->commit_txn_lazy;
 771                 $git->cleanup;
 772                 $xdb = _xdb_release($self);
 773                 # let another process do some work... <
 774                 $pr->("indexed $nr/$self->{ntodo}\n") if $pr && $nr;
 775                 if (!$newest) {
 776                         $xdb = $self->begin_txn_lazy;
 777                         $dbh->begin_work if $dbh;
 778                 }
 779         };
 780
 781         $dbh->begin_work;
 782         read_log($self, $xlog, *index_both, *unindex_both, $cb);
 783 }
 784
 785 sub DESTROY {
 786         # order matters for unlocking
 787         $_[0]->{xdb} = undef;
 788         $_[0]->{lockfh} = undef;
 789 }
 790
 791 # remote_* subs are only used by SearchIdxPart
 792 sub remote_commit {
 793         my ($self) = @_;
 794         if (my $w = $self->{w}) {
 795                 print $w "commit\n" or die "failed to write commit: $!";
 796         } else {
 797                 $self->commit_txn_lazy;
 798         }
 799 }
 800
 801 sub remote_close {
 802         my ($self) = @_;
 803         if (my $w = delete $self->{w}) {
 804                 my $pid = delete $self->{pid} or die "no process to wait on\n";
 805                 print $w "close\n" or die "failed to write to pid:$pid: $!\n";
 806                 close $w or die "failed to close pipe for pid:$pid: $!\n";
 807                 waitpid($pid, 0) == $pid or die "remote process did not finish";
 808                 $? == 0 or die ref($self)." pid:$pid exited with: $?";
 809         } else {
 810                 die "transaction in progress $self\n" if $self->{txn};
 811                 $self->_xdb_release if $self->{xdb};
 812         }
 813 }
 814
 815 sub remote_remove {
 816         my ($self, $oid, $mid) = @_;
 817         if (my $w = $self->{w}) {
 818                 # triggers remove_by_oid in a shard
 819                 print $w "D $oid $mid\n" or die "failed to write remove $!";
 820         } else {
 821                 $self->begin_txn_lazy;
 822                 $self->remove_by_oid($oid, $mid);
 823         }
 824 }
 825
 826 sub begin_txn_lazy {
 827         my ($self) = @_;
 828         return if $self->{txn};
 829
 830         $self->{-inbox}->with_umask(sub {
 831                 my $xdb = $self->{xdb} || $self->_xdb_acquire;
 832                 $self->{over}->begin_lazy if $self->{over};
 833                 $xdb->begin_transaction if $xdb;
 834                 $self->{txn} = 1;
 835                 $xdb;
 836         });
 837 }
 838
 839 sub commit_txn_lazy {
 840         my ($self) = @_;
 841         delete $self->{txn} or return;
 842         $self->{-inbox}->with_umask(sub {
 843                 if (my $xdb = $self->{xdb}) {
 844
 845                         # store 'indexlevel=medium' in v2 shard=0 and
 846                         # v1 (only one shard)
 847                         # This metadata is read by Admin::detect_indexlevel:
 848                         if (!$self->{shard} # undef or 0, not >0
 849                             && $self->{indexlevel} eq 'medium') {
 850                                 $xdb->set_metadata('indexlevel', 'medium');
 851                         }
 852
 853                         $xdb->commit_transaction;
 854                 }
 855                 $self->{over}->commit_lazy if $self->{over};
 856         });
 857 }
 858
 859 sub worker_done {
 860         my ($self) = @_;
 861         if (need_xapian($self)) {
 862                 die "$$ $0 xdb not released\n" if $self->{xdb};
 863         }
 864         die "$$ $0 still in transaction\n" if $self->{txn};
 865 }
 866
 867 1;