lib/PublicInbox/SearchIdx.pm

   1 # Copyright (C) 2015-2020 all contributors <meta@public-inbox.org>
   2 # License: AGPL-3.0+ <https://www.gnu.org/licenses/agpl-3.0.txt>
   3 # based on notmuch, but with no concept of folders, files or flags
   4 #
   5 # Indexes mail with Xapian and our (SQLite-based) ::Msgmap for use
   6 # with the web and NNTP interfaces.  This index maintains thread
   7 # relationships for use by PublicInbox::SearchThread.
   8 # This writes to the search index.
   9 package PublicInbox::SearchIdx;
  10 use strict;
  11 use warnings;
  12 use base qw(PublicInbox::Search PublicInbox::Lock);
  13 use PublicInbox::MIME;
  14 use PublicInbox::InboxWritable;
  15 use PublicInbox::MID qw/mid_clean mid_mime mids_for_index/;
  16 use PublicInbox::MsgIter;
  17 use Carp qw(croak);
  18 use POSIX qw(strftime);
  19 use PublicInbox::OverIdx;
  20 use PublicInbox::Spawn qw(spawn);
  21 use PublicInbox::Git qw(git_unquote);
  22 use PublicInbox::MsgTime qw(msg_timestamp msg_datestamp);
  23 my $X = \%PublicInbox::Search::X;
  24 my ($DB_CREATE_OR_OPEN, $DB_OPEN);
  25 use constant {
  26         BATCH_BYTES => defined($ENV{XAPIAN_FLUSH_THRESHOLD}) ?
  27                         0x7fffffff : 1_000_000,
  28         DEBUG => !!$ENV{DEBUG},
  29 };
  30
  31 my $xapianlevels = qr/\A(?:full|medium)\z/;
  32
  33 sub new {
  34         my ($class, $ibx, $creat, $shard) = @_;
  35         ref $ibx or die "BUG: expected PublicInbox::Inbox object: $ibx";
  36         my $levels = qr/\A(?:full|medium|basic)\z/;
  37         my $inboxdir = $ibx->{inboxdir};
  38         my $version = $ibx->version;
  39         my $indexlevel = 'full';
  40         my $altid = $ibx->{altid};
  41         if ($altid) {
  42                 require PublicInbox::AltId;
  43                 $altid = [ map { PublicInbox::AltId->new($ibx, $_); } @$altid ];
  44         }
  45         if ($ibx->{indexlevel}) {
  46                 if ($ibx->{indexlevel} =~ $levels) {
  47                         $indexlevel = $ibx->{indexlevel};
  48                 } else {
  49                         die("Invalid indexlevel $ibx->{indexlevel}\n");
  50                 }
  51         }
  52         $ibx = PublicInbox::InboxWritable->new($ibx);
  53         my $self = bless {
  54                 inboxdir => $inboxdir,
  55                 -inbox => $ibx,
  56                 git => $ibx->git,
  57                 -altid => $altid,
  58                 ibx_ver => $version,
  59                 indexlevel => $indexlevel,
  60         }, $class;
  61         $self->{-set_indexlevel_once} = 1 if $indexlevel eq 'medium';
  62         $ibx->umask_prepare;
  63         if ($version == 1) {
  64                 $self->{lock_path} = "$inboxdir/ssoma.lock";
  65                 my $dir = $self->xdir;
  66                 $self->{over} = PublicInbox::OverIdx->new("$dir/over.sqlite3");
  67                 $self->{index_max_size} = $ibx->{index_max_size};
  68         } elsif ($version == 2) {
  69                 defined $shard or die "shard is required for v2\n";
  70                 # shard is a number
  71                 $self->{shard} = $shard;
  72                 $self->{lock_path} = undef;
  73         } else {
  74                 die "unsupported inbox version=$version\n";
  75         }
  76         $self->{creat} = ($creat || 0) == 1;
  77         $self;
  78 }
  79
  80 sub need_xapian ($) { $_[0]->{indexlevel} =~ $xapianlevels }
  81
  82 sub _xdb_release {
  83         my ($self) = @_;
  84         if (need_xapian($self)) {
  85                 my $xdb = delete $self->{xdb} or croak 'not acquired';
  86                 $xdb->close;
  87         }
  88         $self->lock_release if $self->{creat};
  89         undef;
  90 }
  91
  92 sub load_xapian_writable () {
  93         return 1 if $X->{WritableDatabase};
  94         PublicInbox::Search::load_xapian() or return;
  95         my $xap = $PublicInbox::Search::Xap;
  96         for (qw(Document TermGenerator WritableDatabase)) {
  97                 $X->{$_} = $xap.'::'.$_;
  98         }
  99         eval 'require '.$X->{WritableDatabase} or die;
 100         *sortable_serialise = $xap.'::sortable_serialise';
 101         $DB_CREATE_OR_OPEN = eval($xap.'::DB_CREATE_OR_OPEN()');
 102         $DB_OPEN = eval($xap.'::DB_OPEN()');
 103         1;
 104 }
 105
 106 sub _xdb_acquire {
 107         my ($self) = @_;
 108         my $flag;
 109         my $dir = $self->xdir;
 110         if (need_xapian($self)) {
 111                 croak 'already acquired' if $self->{xdb};
 112                 load_xapian_writable();
 113                 $flag = $self->{creat} ? $DB_CREATE_OR_OPEN : $DB_OPEN;
 114         }
 115         if ($self->{creat}) {
 116                 require File::Path;
 117                 $self->lock_acquire;
 118
 119                 # don't create empty Xapian directories if we don't need Xapian
 120                 my $is_shard = defined($self->{shard});
 121                 if (!$is_shard || ($is_shard && need_xapian($self))) {
 122                         File::Path::mkpath($dir);
 123                 }
 124         }
 125         return unless defined $flag;
 126         my $xdb = eval { ($X->{WritableDatabase})->new($dir, $flag) };
 127         if ($@) {
 128                 die "Failed opening $dir: ", $@;
 129         }
 130         $self->{xdb} = $xdb;
 131 }
 132
 133 sub add_val ($$$) {
 134         my ($doc, $col, $num) = @_;
 135         $num = sortable_serialise($num);
 136         $doc->add_value($col, $num);
 137 }
 138
 139 sub term_generator ($) { # write-only
 140         my ($self) = @_;
 141
 142         $self->{term_generator} //= do {
 143                 my $tg = $X->{TermGenerator}->new;
 144                 $tg->set_stemmer($self->stemmer);
 145                 $tg;
 146         }
 147 }
 148
 149 sub index_text ($$$$) {
 150         my ($self, $text, $wdf_inc, $prefix) = @_;
 151         my $tg = term_generator($self); # man Search::Xapian::TermGenerator
 152
 153         if ($self->{indexlevel} eq 'full') {
 154                 $tg->index_text($text, $wdf_inc, $prefix);
 155                 $tg->increase_termpos;
 156         } else {
 157                 $tg->index_text_without_positions($text, $wdf_inc, $prefix);
 158         }
 159 }
 160
 161 sub index_users ($$) {
 162         my ($self, $smsg) = @_;
 163
 164         my $from = $smsg->from;
 165         my $to = $smsg->to;
 166         my $cc = $smsg->cc;
 167
 168         index_text($self, $from, 1, 'A'); # A - author
 169         index_text($self, $to, 1, 'XTO') if $to ne '';
 170         index_text($self, $cc, 1, 'XCC') if $cc ne '';
 171 }
 172
 173 sub index_diff_inc ($$$$) {
 174         my ($self, $text, $pfx, $xnq) = @_;
 175         if (@$xnq) {
 176                 index_text($self, join("\n", @$xnq), 1, 'XNQ');
 177                 @$xnq = ();
 178         }
 179         index_text($self, $text, 1, $pfx);
 180 }
 181
 182 sub index_old_diff_fn {
 183         my ($self, $seen, $fa, $fb, $xnq) = @_;
 184
 185         # no renames or space support for traditional diffs,
 186         # find the number of leading common paths to strip:
 187         my @fa = split('/', $fa);
 188         my @fb = split('/', $fb);
 189         while (scalar(@fa) && scalar(@fb)) {
 190                 $fa = join('/', @fa);
 191                 $fb = join('/', @fb);
 192                 if ($fa eq $fb) {
 193                         unless ($seen->{$fa}++) {
 194                                 index_diff_inc($self, $fa, 'XDFN', $xnq);
 195                         }
 196                         return 1;
 197                 }
 198                 shift @fa;
 199                 shift @fb;
 200         }
 201         0;
 202 }
 203
 204 sub index_diff ($$$) {
 205         my ($self, $txt, $doc) = @_;
 206         my %seen;
 207         my $in_diff;
 208         my @xnq;
 209         my $xnq = \@xnq;
 210         foreach (split(/\n/, $txt)) {
 211                 if ($in_diff && s/^ //) { # diff context
 212                         index_diff_inc($self, $_, 'XDFCTX', $xnq);
 213                 } elsif (/^-- $/) { # email signature begins
 214                         $in_diff = undef;
 215                 } elsif (m!^diff --git "?[^/]+/.+ "?[^/]+/.+\z!) {
 216                         # wait until "---" and "+++" to capture filenames
 217                         $in_diff = 1;
 218                 # traditional diff:
 219                 } elsif (m/^diff -(.+) (\S+) (\S+)$/) {
 220                         my ($opt, $fa, $fb) = ($1, $2, $3);
 221                         push @xnq, $_;
 222                         # only support unified:
 223                         next unless $opt =~ /[uU]/;
 224                         $in_diff = index_old_diff_fn($self, \%seen, $fa, $fb,
 225                                                         $xnq);
 226                 } elsif (m!^--- ("?[^/]+/.+)!) {
 227                         my $fn = $1;
 228                         $fn = (split('/', git_unquote($fn), 2))[1];
 229                         $seen{$fn}++ or index_diff_inc($self, $fn, 'XDFN', $xnq);
 230                         $in_diff = 1;
 231                 } elsif (m!^\+\+\+ ("?[^/]+/.+)!)  {
 232                         my $fn = $1;
 233                         $fn = (split('/', git_unquote($fn), 2))[1];
 234                         $seen{$fn}++ or index_diff_inc($self, $fn, 'XDFN', $xnq);
 235                         $in_diff = 1;
 236                 } elsif (/^--- (\S+)/) {
 237                         $in_diff = $1;
 238                         push @xnq, $_;
 239                 } elsif (defined $in_diff && /^\+\+\+ (\S+)/) {
 240                         $in_diff = index_old_diff_fn($self, \%seen, $in_diff,
 241                                                         $1, $xnq);
 242                 } elsif ($in_diff && s/^\+//) { # diff added
 243                         index_diff_inc($self, $_, 'XDFB', $xnq);
 244                 } elsif ($in_diff && s/^-//) { # diff removed
 245                         index_diff_inc($self, $_, 'XDFA', $xnq);
 246                 } elsif (m!^index ([a-f0-9]+)\.\.([a-f0-9]+)!) {
 247                         my ($ba, $bb) = ($1, $2);
 248                         index_git_blob_id($doc, 'XDFPRE', $ba);
 249                         index_git_blob_id($doc, 'XDFPOST', $bb);
 250                         $in_diff = 1;
 251                 } elsif (/^@@ (?:\S+) (?:\S+) @@\s*$/) {
 252                         # traditional diff w/o -p
 253                 } elsif (/^@@ (?:\S+) (?:\S+) @@\s*(\S+.*)$/) {
 254                         # hunk header context
 255                         index_diff_inc($self, $1, 'XDFHH', $xnq);
 256                 # ignore the following lines:
 257                 } elsif (/^(?:dis)similarity index/ ||
 258                                 /^(?:old|new) mode/ ||
 259                                 /^(?:deleted|new) file mode/ ||
 260                                 /^(?:copy|rename) (?:from|to) / ||
 261                                 /^(?:dis)?similarity index / ||
 262                                 /^\\ No newline at end of file/ ||
 263                                 /^Binary files .* differ/) {
 264                         push @xnq, $_;
 265                 } elsif ($_ eq '') {
 266                         # possible to be in diff context, some mail may be
 267                         # stripped by MUA or even GNU diff(1).  "git apply"
 268                         # treats a bare "\n" as diff context, too
 269                 } else {
 270                         push @xnq, $_;
 271                         warn "non-diff line: $_\n" if DEBUG && $_ ne '';
 272                         $in_diff = undef;
 273                 }
 274         }
 275
 276         index_text($self, join("\n", @xnq), 1, 'XNQ');
 277 }
 278
 279 sub index_xapian { # msg_iter callback
 280         my $part = $_[0]->[0]; # ignore $depth and @idx
 281         my ($self, $doc) = @{$_[1]};
 282         my $ct = $part->content_type || 'text/plain';
 283         my $fn = $part->filename;
 284         if (defined $fn && $fn ne '') {
 285                 index_text($self, $fn, 1, 'XFN');
 286         }
 287
 288         my ($s, undef) = msg_part_text($part, $ct);
 289         defined $s or return;
 290         $_[0]->[0] = $part = undef; # free memory
 291
 292         # split off quoted and unquoted blocks:
 293         my @sections = PublicInbox::MsgIter::split_quotes($s);
 294         undef $s; # free memory
 295         for my $txt (@sections) {
 296                 if ($txt =~ /\A>/) {
 297                         index_text($self, $txt, 0, 'XQUOT');
 298                 } else {
 299                         # does it look like a diff?
 300                         if ($txt =~ /^(?:diff|---|\+\+\+) /ms) {
 301                                 index_diff($self, $txt, $doc);
 302                         } else {
 303                                 index_text($self, $txt, 1, 'XNQ');
 304                         }
 305                 }
 306                 undef $txt; # free memory
 307         }
 308 }
 309
 310 sub add_xapian ($$$$) {
 311         my ($self, $mime, $smsg, $mids) = @_;
 312         $smsg->{mime} = $mime; # XXX dangerous
 313         my $hdr = $mime->header_obj;
 314         my $doc = $X->{Document}->new;
 315         my $subj = $smsg->subject;
 316         add_val($doc, PublicInbox::Search::TS(), $smsg->{ts});
 317         my @ds = gmtime($smsg->{ds});
 318         my $yyyymmdd = strftime('%Y%m%d', @ds);
 319         add_val($doc, PublicInbox::Search::YYYYMMDD(), $yyyymmdd);
 320         my $dt = strftime('%Y%m%d%H%M%S', @ds);
 321         add_val($doc, PublicInbox::Search::DT(), $dt);
 322
 323         my $tg = term_generator($self);
 324
 325         $tg->set_document($doc);
 326         index_text($self, $subj, 1, 'S') if $subj;
 327         index_users($self, $smsg);
 328
 329         msg_iter($mime, \&index_xapian, [ $self, $doc ]);
 330         foreach my $mid (@$mids) {
 331                 index_text($self, $mid, 1, 'XM');
 332
 333                 # because too many Message-IDs are prefixed with
 334                 # "Pine.LNX."...
 335                 if ($mid =~ /\w{12,}/) {
 336                         my @long = ($mid =~ /(\w{3,}+)/g);
 337                         index_text($self, join(' ', @long), 1, 'XM');
 338                 }
 339         }
 340         $smsg->{to} = $smsg->{cc} = ''; # WWW doesn't need these, only NNTP
 341         PublicInbox::OverIdx::parse_references($smsg, $hdr, $mids);
 342         my $data = $smsg->to_doc_data;
 343         $doc->set_data($data);
 344         if (my $altid = $self->{-altid}) {
 345                 foreach my $alt (@$altid) {
 346                         my $pfx = $alt->{xprefix};
 347                         foreach my $mid (@$mids) {
 348                                 my $id = $alt->mid2alt($mid);
 349                                 next unless defined $id;
 350                                 $doc->add_boolean_term($pfx . $id);
 351                         }
 352                 }
 353         }
 354         $doc->add_boolean_term('Q' . $_) foreach @$mids;
 355         $self->{xdb}->replace_document($smsg->{num}, $doc);
 356 }
 357
 358 sub _msgmap_init ($) {
 359         my ($self) = @_;
 360         die "BUG: _msgmap_init is only for v1\n" if $self->{ibx_ver} != 1;
 361         $self->{mm} //= eval {
 362                 require PublicInbox::Msgmap;
 363                 PublicInbox::Msgmap->new($self->{inboxdir}, 1);
 364         };
 365 }
 366
 367 sub add_message {
 368         # mime = Email::MIME object
 369         my ($self, $mime, $smsg) = @_;
 370         my $hdr = $mime->header_obj;
 371         my $mids = mids_for_index($hdr);
 372         $smsg //= bless { blob => '' }, 'PublicInbox::Smsg'; # test-only compat
 373         $smsg->{mid} //= $mids->[0]; # v1 compatibility
 374         $smsg->{num} //= do { # v1
 375                 _msgmap_init($self);
 376                 index_mm($self, $mime);
 377         };
 378
 379         # v1 and tests only:
 380         $smsg->{ds} //= msg_datestamp($hdr, $self->{autime});
 381         $smsg->{ts} //= msg_timestamp($hdr, $self->{cotime});
 382
 383         eval {
 384                 # order matters, overview stores every possible piece of
 385                 # data in doc_data (deflated).  Xapian only stores a subset
 386                 # of the fields which exist in over.sqlite3.  We may stop
 387                 # storing doc_data in Xapian sometime after we get multi-inbox
 388                 # search working.
 389                 if (my $over = $self->{over}) { # v1 only
 390                         $over->add_overview($mime, $smsg);
 391                 }
 392                 if (need_xapian($self)) {
 393                         add_xapian($self, $mime, $smsg, $mids);
 394                 }
 395         };
 396
 397         if ($@) {
 398                 warn "failed to index message <".join('> <',@$mids).">: $@\n";
 399                 return undef;
 400         }
 401         $smsg->{num};
 402 }
 403
 404 # returns begin and end PostingIterator
 405 sub find_doc_ids {
 406         my ($self, $termval) = @_;
 407         my $db = $self->{xdb};
 408
 409         ($db->postlist_begin($termval), $db->postlist_end($termval));
 410 }
 411
 412 # v1 only
 413 sub batch_do {
 414         my ($self, $termval, $cb) = @_;
 415         my $batch_size = 1000; # don't let @ids grow too large to avoid OOM
 416         while (1) {
 417                 my ($head, $tail) = $self->find_doc_ids($termval);
 418                 return if $head == $tail;
 419                 my @ids;
 420                 for (; $head != $tail && @ids < $batch_size; $head++) {
 421                         push @ids, $head->get_docid;
 422                 }
 423                 $cb->(\@ids);
 424         }
 425 }
 426
 427 # v1 only, where $mid is unique
 428 sub remove_message {
 429         my ($self, $mid) = @_;
 430         $mid = mid_clean($mid);
 431
 432         if (my $over = $self->{over}) {
 433                 my $nr = eval { $over->remove_oid(undef, $mid) };
 434                 if ($@) {
 435                         warn "failed to remove <$mid> from overview: $@\n";
 436                 } elsif ($nr == 0) {
 437                         warn "<$mid> missing for removal from overview\n";
 438                 }
 439         }
 440         return unless need_xapian($self);
 441         my $db = $self->{xdb};
 442         my $nr = 0;
 443         eval {
 444                 batch_do($self, 'Q' . $mid, sub {
 445                         my ($ids) = @_;
 446                         $db->delete_document($_) for @$ids;
 447                         $nr += scalar @$ids;
 448                 });
 449         };
 450         if ($@) {
 451                 warn "failed to remove <$mid> from Xapian: $@\n";
 452         } elsif ($nr == 0) {
 453                 warn "<$mid> missing for removal from Xapian\n";
 454         }
 455 }
 456
 457 # MID is a hint in V2
 458 sub remove_by_oid {
 459         my ($self, $oid, $mid) = @_;
 460
 461         $self->{over}->remove_oid($oid, $mid) if $self->{over};
 462
 463         return unless need_xapian($self);
 464         my $db = $self->{xdb};
 465
 466         # XXX careful, we cannot use batch_do here since we conditionally
 467         # delete documents based on other factors, so we cannot call
 468         # find_doc_ids twice.
 469         my ($head, $tail) = $self->find_doc_ids('Q' . $mid);
 470         return if $head == $tail;
 471
 472         # there is only ONE element in @delete unless we
 473         # have bugs in our v2writable deduplication check
 474         my @delete;
 475         for (; $head != $tail; $head++) {
 476                 my $docid = $head->get_docid;
 477                 my $doc = $db->get_document($docid);
 478                 my $smsg = PublicInbox::Smsg->wrap($mid);
 479                 $smsg->load_expand($doc);
 480                 if ($smsg->{blob} eq $oid) {
 481                         push(@delete, $docid);
 482                 }
 483         }
 484         $db->delete_document($_) foreach @delete;
 485         scalar(@delete);
 486 }
 487
 488 sub index_git_blob_id {
 489         my ($doc, $pfx, $objid) = @_;
 490
 491         my $len = length($objid);
 492         for (my $len = length($objid); $len >= 7; ) {
 493                 $doc->add_term($pfx.$objid);
 494                 $objid = substr($objid, 0, --$len);
 495         }
 496 }
 497
 498 sub unindex_blob {
 499         my ($self, $mime) = @_;
 500         my $mid = eval { mid_mime($mime) };
 501         $self->remove_message($mid) if defined $mid;
 502 }
 503
 504 sub index_mm {
 505         my ($self, $mime) = @_;
 506         my $mid = mid_mime($mime);
 507         my $mm = $self->{mm};
 508         my $num;
 509
 510         if (defined $self->{regen_down}) {
 511                 $num = $mm->num_for($mid) and return $num;
 512
 513                 while (($num = $self->{regen_down}--) > 0) {
 514                         if ($mm->mid_set($num, $mid) != 0) {
 515                                 return $num;
 516                         }
 517                 }
 518         } elsif (defined $self->{regen_up}) {
 519                 $num = $mm->num_for($mid) and return $num;
 520
 521                 # this is to fixup old bugs due to add-remove-add
 522                 while (($num = ++$self->{regen_up})) {
 523                         if ($mm->mid_set($num, $mid) != 0) {
 524                                 return $num;
 525                         }
 526                 }
 527         }
 528
 529         $num = $mm->mid_insert($mid) and return $num;
 530
 531         # fallback to num_for since filters like RubyLang set the number
 532         $mm->num_for($mid);
 533 }
 534
 535 sub unindex_mm {
 536         my ($self, $mime) = @_;
 537         $self->{mm}->mid_delete(mid_mime($mime));
 538 }
 539
 540 sub index_both {
 541         my ($self, $mime, $smsg) = @_;
 542         my $num = index_mm($self, $mime);
 543         $smsg->{num} = $num;
 544         add_message($self, $mime, $smsg);
 545 }
 546
 547 sub unindex_both {
 548         my ($self, $mime) = @_;
 549         unindex_blob($self, $mime);
 550         unindex_mm($self, $mime);
 551 }
 552
 553 sub do_cat_mail {
 554         my ($git, $blob, $sizeref) = @_;
 555         my $str = $git->cat_file($blob, $sizeref) or
 556                 die "BUG: $blob not found in $git->{git_dir}";
 557         PublicInbox::MIME->new($str);
 558 }
 559
 560 # called by public-inbox-index
 561 sub index_sync {
 562         my ($self, $opts) = @_;
 563         delete $self->{lock_path} if $opts->{-skip_lock};
 564         $self->{-inbox}->with_umask(sub { $self->_index_sync($opts) })
 565 }
 566
 567 sub batch_adjust ($$$$$) {
 568         my ($max, $bytes, $batch_cb, $latest, $nr) = @_;
 569         $$max -= $bytes;
 570         if ($$max <= 0) {
 571                 $$max = BATCH_BYTES;
 572                 $batch_cb->($nr, $latest);
 573         }
 574 }
 575
 576 sub too_big ($$$) {
 577         my ($self, $git, $oid) = @_;
 578         my $max_size = $self->{index_max_size} or return;
 579         my (undef, undef, $size) = $git->check($oid);
 580         die "E: bad $oid in $git->{git_dir}\n" if !defined($size);
 581         return if $size <= $max_size;
 582         warn "W: skipping $oid ($size > $max_size)\n";
 583         1;
 584 }
 585
 586 # only for v1
 587 sub read_log {
 588         my ($self, $log, $add_cb, $del_cb, $batch_cb) = @_;
 589         my $hex = '[a-f0-9]';
 590         my $h40 = $hex .'{40}';
 591         my $addmsg = qr!^:000000 100644 \S+ ($h40) A\t${hex}{2}/${hex}{38}$!;
 592         my $delmsg = qr!^:100644 000000 ($h40) \S+ D\t${hex}{2}/${hex}{38}$!;
 593         my $git = $self->{git};
 594         my $latest;
 595         my $bytes;
 596         my $max = BATCH_BYTES;
 597         local $/ = "\n";
 598         my %D;
 599         my $line;
 600         my $newest;
 601         my $nr = 0;
 602         while (defined($line = <$log>)) {
 603                 if ($line =~ /$addmsg/o) {
 604                         my $blob = $1;
 605                         if (delete $D{$blob}) {
 606                                 if (defined $self->{regen_down}) {
 607                                         my $num = $self->{regen_down}--;
 608                                         $self->{mm}->num_highwater($num);
 609                                 }
 610                                 next;
 611                         }
 612                         next if too_big($self, $git, $blob);
 613                         my $mime = do_cat_mail($git, $blob, \$bytes);
 614                         my $smsg = bless {}, 'PublicInbox::Smsg';
 615                         batch_adjust(\$max, $bytes, $batch_cb, $latest, ++$nr);
 616                         $smsg->{blob} = $blob;
 617                         $smsg->{bytes} = $bytes;
 618                         $add_cb->($self, $mime, $smsg);
 619                 } elsif ($line =~ /$delmsg/o) {
 620                         my $blob = $1;
 621                         $D{$blob} = 1 unless too_big($self, $git, $blob);
 622                 } elsif ($line =~ /^commit ($h40)/o) {
 623                         $latest = $1;
 624                         $newest ||= $latest;
 625                 } elsif ($line =~ /^author .*? ([0-9]+) [\-\+][0-9]+$/) {
 626                         $self->{autime} = $1;
 627                 } elsif ($line =~ /^committer .*? ([0-9]+) [\-\+][0-9]+$/) {
 628                         $self->{cotime} = $1;
 629                 }
 630         }
 631         close($log) or die "git log failed: \$?=$?";
 632         # get the leftovers
 633         foreach my $blob (keys %D) {
 634                 my $mime = do_cat_mail($git, $blob, \$bytes);
 635                 $del_cb->($self, $mime);
 636         }
 637         $batch_cb->($nr, $latest, $newest);
 638 }
 639
 640 sub _git_log {
 641         my ($self, $opts, $range) = @_;
 642         my $git = $self->{git};
 643
 644         if (index($range, '..') < 0) {
 645                 # don't show annoying git errors to users who run -index
 646                 # on empty inboxes
 647                 $git->qx(qw(rev-parse -q --verify), "$range^0");
 648                 if ($?) {
 649                         open my $fh, '<', '/dev/null' or
 650                                 die "failed to open /dev/null: $!\n";
 651                         return $fh;
 652                 }
 653         }
 654
 655         # Count the new files so they can be added newest to oldest
 656         # and still have numbers increasing from oldest to newest
 657         my $fcount = 0;
 658         my $pr = $opts->{-progress};
 659         $pr->("counting changes\n\t$range ... ") if $pr;
 660         # can't use 'rev-list --count' if we use --diff-filter
 661         my $fh = $git->popen(qw(log --pretty=tformat:%h
 662                              --no-notes --no-color --no-renames
 663                              --diff-filter=AM), $range);
 664         ++$fcount while <$fh>;
 665         close $fh or die "git log failed: \$?=$?";
 666         my $high = $self->{mm}->num_highwater;
 667         $pr->("$fcount\n") if $pr; # continue previous line
 668         $self->{ntodo} = $fcount;
 669
 670         if (index($range, '..') < 0) {
 671                 if ($high && $high == $fcount) {
 672                         # fix up old bugs in full indexes which caused messages to
 673                         # not appear in Msgmap
 674                         $self->{regen_up} = $high;
 675                 } else {
 676                         # normal regen is for for fresh data
 677                         $self->{regen_down} = $fcount;
 678                 }
 679         } else {
 680                 # Give oldest messages the smallest numbers
 681                 $self->{regen_down} = $high + $fcount;
 682         }
 683
 684         $git->popen(qw/log --pretty=raw --no-notes --no-color --no-renames
 685                                 --raw -r --no-abbrev/, $range);
 686 }
 687
 688 # --is-ancestor requires git 1.8.0+
 689 sub is_ancestor ($$$) {
 690         my ($git, $cur, $tip) = @_;
 691         return 0 unless $git->check($cur);
 692         my $cmd = [ 'git', "--git-dir=$git->{git_dir}",
 693                 qw(merge-base --is-ancestor), $cur, $tip ];
 694         my $pid = spawn($cmd);
 695         waitpid($pid, 0) == $pid or die join(' ', @$cmd) .' did not finish';
 696         $? == 0;
 697 }
 698
 699 sub need_update ($$$) {
 700         my ($self, $cur, $new) = @_;
 701         my $git = $self->{git};
 702         return 1 if $cur && !is_ancestor($git, $cur, $new);
 703         my $range = $cur eq '' ? $new : "$cur..$new";
 704         chomp(my $n = $git->qx(qw(rev-list --count), $range));
 705         ($n eq '' || $n > 0);
 706 }
 707
 708 # The last git commit we indexed with Xapian or SQLite (msgmap)
 709 # This needs to account for cases where Xapian or SQLite is
 710 # out-of-date with respect to the other.
 711 sub _last_x_commit {
 712         my ($self, $mm) = @_;
 713         my $lm = $mm->last_commit || '';
 714         my $lx = '';
 715         if (need_xapian($self)) {
 716                 $lx = $self->{xdb}->get_metadata('last_commit') || '';
 717         } else {
 718                 $lx = $lm;
 719         }
 720         # Use last_commit from msgmap if it is older or unset
 721         if (!$lm || ($lx && $lm && is_ancestor($self->{git}, $lm, $lx))) {
 722                 $lx = $lm;
 723         }
 724         $lx;
 725 }
 726
 727 sub reindex_from ($$) {
 728         my ($reindex, $last_commit) = @_;
 729         return $last_commit unless $reindex;
 730         ref($reindex) eq 'HASH' ? $reindex->{from} : '';
 731 }
 732
 733 # indexes all unindexed messages (v1 only)
 734 sub _index_sync {
 735         my ($self, $opts) = @_;
 736         my $tip = $opts->{ref} || 'HEAD';
 737         my ($last_commit, $lx, $xlog);
 738         my $git = $self->{git};
 739         $git->batch_prepare;
 740         my $pr = $opts->{-progress};
 741
 742         my $xdb = $self->begin_txn_lazy;
 743         my $mm = _msgmap_init($self);
 744         do {
 745                 if ($xlog) {
 746                         close($xlog) or die "git log failed: \$?=$?";
 747                         $xlog = undef;
 748                 }
 749                 $last_commit = _last_x_commit($self, $mm);
 750                 $lx = reindex_from($opts->{reindex}, $last_commit);
 751
 752                 $self->{over}->rollback_lazy;
 753                 $self->{over}->disconnect;
 754                 $git->cleanup;
 755                 delete $self->{txn};
 756                 $xdb->cancel_transaction if $xdb;
 757                 $xdb = _xdb_release($self);
 758
 759                 # ensure we leak no FDs to "git log" with Xapian <= 1.2
 760                 my $range = $lx eq '' ? $tip : "$lx..$tip";
 761                 $xlog = _git_log($self, $opts, $range);
 762
 763                 $xdb = $self->begin_txn_lazy;
 764         } while (_last_x_commit($self, $mm) ne $last_commit);
 765
 766         my $dbh = $mm->{dbh} if $mm;
 767         my $cb = sub {
 768                 my ($nr, $commit, $newest) = @_;
 769                 if ($dbh) {
 770                         if ($newest) {
 771                                 my $cur = $mm->last_commit || '';
 772                                 if (need_update($self, $cur, $newest)) {
 773                                         $mm->last_commit($newest);
 774                                 }
 775                         }
 776                         $dbh->commit;
 777                 }
 778                 if ($newest && need_xapian($self)) {
 779                         my $cur = $xdb->get_metadata('last_commit');
 780                         if (need_update($self, $cur, $newest)) {
 781                                 $xdb->set_metadata('last_commit', $newest);
 782                         }
 783                 }
 784                 $self->commit_txn_lazy;
 785                 $git->cleanup;
 786                 $xdb = _xdb_release($self);
 787                 # let another process do some work... <
 788                 $pr->("indexed $nr/$self->{ntodo}\n") if $pr && $nr;
 789                 if (!$newest) {
 790                         $xdb = $self->begin_txn_lazy;
 791                         $dbh->begin_work if $dbh;
 792                 }
 793         };
 794
 795         $dbh->begin_work;
 796         read_log($self, $xlog, *index_both, *unindex_both, $cb);
 797 }
 798
 799 sub DESTROY {
 800         # order matters for unlocking
 801         $_[0]->{xdb} = undef;
 802         $_[0]->{lockfh} = undef;
 803 }
 804
 805 # remote_* subs are only used by SearchIdxPart
 806 sub remote_commit {
 807         my ($self) = @_;
 808         if (my $w = $self->{w}) {
 809                 print $w "commit\n" or die "failed to write commit: $!";
 810         } else {
 811                 $self->commit_txn_lazy;
 812         }
 813 }
 814
 815 sub remote_close {
 816         my ($self) = @_;
 817         if (my $w = delete $self->{w}) {
 818                 my $pid = delete $self->{pid} or die "no process to wait on\n";
 819                 print $w "close\n" or die "failed to write to pid:$pid: $!\n";
 820                 close $w or die "failed to close pipe for pid:$pid: $!\n";
 821                 waitpid($pid, 0) == $pid or die "remote process did not finish";
 822                 $? == 0 or die ref($self)." pid:$pid exited with: $?";
 823         } else {
 824                 die "transaction in progress $self\n" if $self->{txn};
 825                 $self->_xdb_release if $self->{xdb};
 826         }
 827 }
 828
 829 sub remote_remove {
 830         my ($self, $oid, $mid) = @_;
 831         if (my $w = $self->{w}) {
 832                 # triggers remove_by_oid in a shard
 833                 print $w "D $oid $mid\n" or die "failed to write remove $!";
 834         } else {
 835                 $self->begin_txn_lazy;
 836                 $self->remove_by_oid($oid, $mid);
 837         }
 838 }
 839
 840 sub begin_txn_lazy {
 841         my ($self) = @_;
 842         return if $self->{txn};
 843
 844         $self->{-inbox}->with_umask(sub {
 845                 my $xdb = $self->{xdb} || $self->_xdb_acquire;
 846                 $self->{over}->begin_lazy if $self->{over};
 847                 $xdb->begin_transaction if $xdb;
 848                 $self->{txn} = 1;
 849                 $xdb;
 850         });
 851 }
 852
 853 # store 'indexlevel=medium' in v2 shard=0 and v1 (only one shard)
 854 # This metadata is read by Admin::detect_indexlevel:
 855 sub set_indexlevel {
 856         my ($self) = @_;
 857
 858         if (!$self->{shard} && # undef or 0, not >0
 859                         delete($self->{-set_indexlevel_once})) {
 860                 my $xdb = $self->{xdb};
 861                 my $level = $xdb->get_metadata('indexlevel');
 862                 if (!$level || $level ne 'medium') {
 863                         $xdb->set_metadata('indexlevel', 'medium');
 864                 }
 865         }
 866 }
 867
 868 sub commit_txn_lazy {
 869         my ($self) = @_;
 870         delete $self->{txn} or return;
 871         $self->{-inbox}->with_umask(sub {
 872                 if (my $xdb = $self->{xdb}) {
 873                         set_indexlevel($self);
 874                         $xdb->commit_transaction;
 875                 }
 876                 $self->{over}->commit_lazy if $self->{over};
 877         });
 878 }
 879
 880 sub worker_done {
 881         my ($self) = @_;
 882         if (need_xapian($self)) {
 883                 die "$$ $0 xdb not released\n" if $self->{xdb};
 884         }
 885         die "$$ $0 still in transaction\n" if $self->{txn};
 886 }
 887
 888 1;