lib/PublicInbox/SearchIdx.pm

   1 # Copyright (C) 2015 all contributors <meta@public-inbox.org>
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 # based on notmuch, but with no concept of folders, files or flags
   4 #
   5 # Indexes mail with Xapian and our (SQLite-based) ::Msgmap for use
   6 # with the web and NNTP interfaces.  This index maintains thread
   7 # relationships for use by PublicInbox::SearchThread.
   8 # This writes to the search index.
   9 package PublicInbox::SearchIdx;
  10 use strict;
  11 use warnings;
  12 use Fcntl qw(:flock :DEFAULT);
  13 use PublicInbox::MIME;
  14 use Email::MIME::ContentType;
  15 $Email::MIME::ContentType::STRICT_PARAMS = 0;
  16 use base qw(PublicInbox::Search);
  17 use PublicInbox::MID qw/mid_clean id_compress mid_mime/;
  18 use PublicInbox::MsgIter;
  19 use Carp qw(croak);
  20 use POSIX qw(strftime);
  21 require PublicInbox::Git;
  22
  23 use constant MAX_MID_SIZE => 244; # max term size - 1 in Xapian
  24 use constant {
  25         PERM_UMASK => 0,
  26         OLD_PERM_GROUP => 1,
  27         OLD_PERM_EVERYBODY => 2,
  28         PERM_GROUP => 0660,
  29         PERM_EVERYBODY => 0664,
  30 };
  31
  32 sub new {
  33         my ($class, $inbox, $creat) = @_;
  34         my $git_dir = $inbox;
  35         my $altid;
  36         if (ref $inbox) {
  37                 $git_dir = $inbox->{mainrepo};
  38                 $altid = $inbox->{altid};
  39                 if ($altid) {
  40                         require PublicInbox::AltId;
  41                         $altid = [ map {
  42                                 PublicInbox::AltId->new($inbox, $_);
  43                         } @$altid ];
  44                 }
  45         }
  46         require Search::Xapian::WritableDatabase;
  47         my $self = bless { git_dir => $git_dir, -altid => $altid }, $class;
  48         my $perm = $self->_git_config_perm;
  49         my $umask = _umask_for($perm);
  50         $self->{umask} = $umask;
  51         $self->{lock_path} = "$git_dir/ssoma.lock";
  52         $self->{git} = PublicInbox::Git->new($git_dir);
  53         $self->{creat} = ($creat || 0) == 1;
  54         $self;
  55 }
  56
  57 sub _xdb_release {
  58         my ($self) = @_;
  59         my $xdb = delete $self->{xdb} or croak 'not acquired';
  60         $xdb->close;
  61         _lock_release($self) if $self->{creat};
  62         undef;
  63 }
  64
  65 sub _xdb_acquire {
  66         my ($self) = @_;
  67         croak 'already acquired' if $self->{xdb};
  68         my $dir = PublicInbox::Search->xdir($self->{git_dir});
  69         my $flag = Search::Xapian::DB_OPEN;
  70         if ($self->{creat}) {
  71                 require File::Path;
  72                 _lock_acquire($self);
  73                 File::Path::mkpath($dir);
  74                 $self->{batch_size} = 100;
  75                 $flag = Search::Xapian::DB_CREATE_OR_OPEN;
  76         }
  77         $self->{xdb} = Search::Xapian::WritableDatabase->new($dir, $flag);
  78 }
  79
  80 # we only acquire the flock if creating or reindexing;
  81 # PublicInbox::Import already has the lock on its own.
  82 sub _lock_acquire {
  83         my ($self) = @_;
  84         croak 'already locked' if $self->{lockfh};
  85         sysopen(my $lockfh, $self->{lock_path}, O_WRONLY|O_CREAT) or
  86                 die "failed to open lock $self->{lock_path}: $!\n";
  87         flock($lockfh, LOCK_EX) or die "lock failed: $!\n";
  88         $self->{lockfh} = $lockfh;
  89 }
  90
  91 sub _lock_release {
  92         my ($self) = @_;
  93         my $lockfh = delete $self->{lockfh} or croak 'not locked';
  94         flock($lockfh, LOCK_UN) or die "unlock failed: $!\n";
  95         close $lockfh or die "close failed: $!\n";
  96 }
  97
  98 sub add_val ($$$) {
  99         my ($doc, $col, $num) = @_;
 100         $num = Search::Xapian::sortable_serialise($num);
 101         $doc->add_value($col, $num);
 102 }
 103
 104 sub add_values ($$$) {
 105         my ($smsg, $bytes, $num) = @_;
 106
 107         my $ts = $smsg->ts;
 108         my $doc = $smsg->{doc};
 109         add_val($doc, &PublicInbox::Search::TS, $ts);
 110
 111         defined($num) and add_val($doc, &PublicInbox::Search::NUM, $num);
 112
 113         defined($bytes) and add_val($doc, &PublicInbox::Search::BYTES, $bytes);
 114
 115         add_val($doc, &PublicInbox::Search::LINES,
 116                         $smsg->{mime}->body_raw =~ tr!\n!\n!);
 117
 118         my $yyyymmdd = strftime('%Y%m%d', gmtime($ts));
 119         add_val($doc, PublicInbox::Search::YYYYMMDD, $yyyymmdd);
 120 }
 121
 122 sub index_users ($$) {
 123         my ($tg, $smsg) = @_;
 124
 125         my $from = $smsg->from;
 126         my $to = $smsg->to;
 127         my $cc = $smsg->cc;
 128
 129         $tg->index_text($from, 1, 'A'); # A - author
 130         $tg->increase_termpos;
 131         $tg->index_text($to, 1, 'XTO') if $to ne '';
 132         $tg->increase_termpos;
 133         $tg->index_text($cc, 1, 'XCC') if $cc ne '';
 134         $tg->increase_termpos;
 135 }
 136
 137 sub index_body ($$$) {
 138         my ($tg, $lines, $inc) = @_;
 139         $tg->index_text(join("\n", @$lines), $inc, $inc ? 'XNQ' : 'XQUOT');
 140         @$lines = ();
 141         $tg->increase_termpos;
 142 }
 143
 144 sub add_message {
 145         my ($self, $mime, $bytes, $num, $blob) = @_; # mime = Email::MIME object
 146         my $db = $self->{xdb};
 147
 148         my ($doc_id, $old_tid);
 149         my $mid = mid_clean(mid_mime($mime));
 150
 151         eval {
 152                 die 'Message-ID too long' if length($mid) > MAX_MID_SIZE;
 153                 my $smsg = $self->lookup_message($mid);
 154                 if ($smsg) {
 155                         # convert a ghost to a regular message
 156                         # it will also clobber any existing regular message
 157                         $doc_id = $smsg->{doc_id};
 158                         $old_tid = $smsg->thread_id;
 159                 }
 160                 $smsg = PublicInbox::SearchMsg->new($mime);
 161                 my $doc = $smsg->{doc};
 162                 $doc->add_term('Q' . $mid);
 163
 164                 my $subj = $smsg->subject;
 165                 if ($subj ne '') {
 166                         my $path = $self->subject_path($subj);
 167                         $doc->add_term('XPATH' . id_compress($path));
 168                 }
 169
 170                 add_values($smsg, $bytes, $num);
 171
 172                 my $tg = $self->term_generator;
 173
 174                 $tg->set_document($doc);
 175                 $tg->index_text($subj, 1, 'S') if $subj;
 176                 $tg->increase_termpos;
 177
 178                 index_users($tg, $smsg);
 179
 180                 msg_iter($mime, sub {
 181                         my ($part, $depth, @idx) = @{$_[0]};
 182                         my $ct = $part->content_type || 'text/plain';
 183                         my $fn = $part->filename;
 184                         if (defined $fn && $fn ne '') {
 185                                 $tg->index_text($fn, 1, 'XFN');
 186                         }
 187
 188                         return if $ct =~ m!\btext/x?html\b!i;
 189
 190                         my $s = eval { $part->body_str };
 191                         if ($@) {
 192                                 if ($ct =~ m!\btext/plain\b!i) {
 193                                         # Try to assume UTF-8 because Alpine
 194                                         # seems to do wacky things and set
 195                                         # charset=X-UNKNOWN
 196                                         $part->charset_set('UTF-8');
 197                                         $s = eval { $part->body_str };
 198                                         $s = $part->body if $@;
 199                                 }
 200                         }
 201                         defined $s or return;
 202
 203                         my (@orig, @quot);
 204                         my $body = $part->body;
 205                         my @lines = split(/\n/, $body);
 206                         while (defined(my $l = shift @lines)) {
 207                                 if ($l =~ /^>/) {
 208                                         index_body($tg, \@orig, 1) if @orig;
 209                                         push @quot, $l;
 210                                 } else {
 211                                         index_body($tg, \@quot, 0) if @quot;
 212                                         push @orig, $l;
 213                                 }
 214                         }
 215                         index_body($tg, \@quot, 0) if @quot;
 216                         index_body($tg, \@orig, 1) if @orig;
 217                 });
 218
 219                 link_message($self, $smsg, $old_tid);
 220                 $tg->index_text($mid, 1, 'XMID');
 221                 $doc->set_data($smsg->to_doc_data($blob));
 222
 223                 if (my $altid = $self->{-altid}) {
 224                         foreach my $alt (@$altid) {
 225                                 my $id = $alt->mid2alt($mid);
 226                                 next unless defined $id;
 227                                 $doc->add_term($alt->{xprefix} . $id);
 228                         }
 229                 }
 230                 if (defined $doc_id) {
 231                         $db->replace_document($doc_id, $doc);
 232                 } else {
 233                         $doc_id = $db->add_document($doc);
 234                 }
 235         };
 236
 237         if ($@) {
 238                 warn "failed to index message <$mid>: $@\n";
 239                 return undef;
 240         }
 241         $doc_id;
 242 }
 243
 244 # returns deleted doc_id on success, undef on missing
 245 sub remove_message {
 246         my ($self, $mid) = @_;
 247         my $db = $self->{xdb};
 248         my $doc_id;
 249         $mid = mid_clean($mid);
 250
 251         eval {
 252                 $doc_id = $self->find_unique_doc_id('mid', $mid);
 253                 $db->delete_document($doc_id) if defined $doc_id;
 254         };
 255
 256         if ($@) {
 257                 warn "failed to remove message <$mid>: $@\n";
 258                 return undef;
 259         }
 260         $doc_id;
 261 }
 262
 263 sub term_generator { # write-only
 264         my ($self) = @_;
 265
 266         my $tg = $self->{term_generator};
 267         return $tg if $tg;
 268
 269         $tg = Search::Xapian::TermGenerator->new;
 270         $tg->set_stemmer($self->stemmer);
 271
 272         $self->{term_generator} = $tg;
 273 }
 274
 275 # increments last_thread_id counter
 276 # returns a 64-bit integer represented as a hex string
 277 sub next_thread_id {
 278         my ($self) = @_;
 279         my $db = $self->{xdb};
 280         my $last_thread_id = int($db->get_metadata('last_thread_id') || 0);
 281
 282         $db->set_metadata('last_thread_id', ++$last_thread_id);
 283
 284         $last_thread_id;
 285 }
 286
 287 sub link_message {
 288         my ($self, $smsg, $old_tid) = @_;
 289         my $doc = $smsg->{doc};
 290         my $mid = $smsg->mid;
 291         my $mime = $smsg->{mime};
 292         my $hdr = $mime->header_obj;
 293
 294         # last References should be IRT, but some mail clients do things
 295         # out of order, so trust IRT over References iff IRT exists
 296         my @refs = ($hdr->header_raw('References'),
 297                         $hdr->header_raw('In-Reply-To'));
 298         @refs = ((join(' ', @refs)) =~ /<([^>]+)>/g);
 299
 300         my $tid;
 301         if (@refs) {
 302                 my %uniq = ($mid => 1);
 303                 my @orig_refs = @refs;
 304                 @refs = ();
 305
 306                 # prevent circular references via References: here:
 307                 foreach my $ref (@orig_refs) {
 308                         if (length($ref) > MAX_MID_SIZE) {
 309                                 warn "References: <$ref> too long, ignoring\n";
 310                         }
 311                         next if $uniq{$ref};
 312                         $uniq{$ref} = 1;
 313                         push @refs, $ref;
 314                 }
 315         }
 316
 317         if (@refs) {
 318                 $smsg->{references} = '<'.join('> <', @refs).'>';
 319
 320                 # first ref *should* be the thread root,
 321                 # but we can never trust clients to do the right thing
 322                 my $ref = shift @refs;
 323                 $tid = $self->_resolve_mid_to_tid($ref);
 324                 $self->merge_threads($tid, $old_tid) if defined $old_tid;
 325
 326                 # the rest of the refs should point to this tid:
 327                 foreach $ref (@refs) {
 328                         my $ptid = $self->_resolve_mid_to_tid($ref);
 329                         merge_threads($self, $tid, $ptid);
 330                 }
 331         } else {
 332                 $tid = defined $old_tid ? $old_tid : $self->next_thread_id;
 333         }
 334         $doc->add_term('G' . $tid);
 335 }
 336
 337 sub index_blob {
 338         my ($self, $mime, $bytes, $num, $blob) = @_;
 339         $self->add_message($mime, $bytes, $num, $blob);
 340 }
 341
 342 sub unindex_blob {
 343         my ($self, $mime) = @_;
 344         my $mid = eval { mid_clean(mid_mime($mime)) };
 345         $self->remove_message($mid) if defined $mid;
 346 }
 347
 348 sub index_mm {
 349         my ($self, $mime) = @_;
 350         $self->{mm}->mid_insert(mid_clean(mid_mime($mime)));
 351 }
 352
 353 sub unindex_mm {
 354         my ($self, $mime) = @_;
 355         $self->{mm}->mid_delete(mid_clean(mid_mime($mime)));
 356 }
 357
 358 sub index_mm2 {
 359         my ($self, $mime, $bytes, $blob) = @_;
 360         my $num = $self->{mm}->num_for(mid_clean(mid_mime($mime)));
 361         index_blob($self, $mime, $bytes, $num, $blob);
 362 }
 363
 364 sub unindex_mm2 {
 365         my ($self, $mime) = @_;
 366         $self->{mm}->mid_delete(mid_clean(mid_mime($mime)));
 367         unindex_blob($self, $mime);
 368 }
 369
 370 sub index_both {
 371         my ($self, $mime, $bytes, $blob) = @_;
 372         my $num = index_mm($self, $mime);
 373         index_blob($self, $mime, $bytes, $num, $blob);
 374 }
 375
 376 sub unindex_both {
 377         my ($self, $mime) = @_;
 378         unindex_blob($self, $mime);
 379         unindex_mm($self, $mime);
 380 }
 381
 382 sub do_cat_mail {
 383         my ($git, $blob, $sizeref) = @_;
 384         my $mime = eval {
 385                 my $str = $git->cat_file($blob, $sizeref);
 386                 # fixup bugs from import:
 387                 $$str =~ s/\A[\r\n]*From [^\r\n]*\r?\n//s;
 388                 PublicInbox::MIME->new($str);
 389         };
 390         $@ ? undef : $mime;
 391 }
 392
 393 sub index_sync {
 394         my ($self, $opts) = @_;
 395         with_umask($self, sub { $self->_index_sync($opts) });
 396 }
 397
 398 sub rlog {
 399         my ($self, $log, $add_cb, $del_cb, $batch_cb) = @_;
 400         my $hex = '[a-f0-9]';
 401         my $h40 = $hex .'{40}';
 402         my $addmsg = qr!^:000000 100644 \S+ ($h40) A\t${hex}{2}/${hex}{38}$!;
 403         my $delmsg = qr!^:100644 000000 ($h40) \S+ D\t${hex}{2}/${hex}{38}$!;
 404         my $git = $self->{git};
 405         my $latest;
 406         my $bytes;
 407         my $max = $self->{batch_size}; # may be undef
 408         local $/ = "\n";
 409         my $line;
 410         while (defined($line = <$log>)) {
 411                 if ($line =~ /$addmsg/o) {
 412                         my $blob = $1;
 413                         my $mime = do_cat_mail($git, $blob, \$bytes) or next;
 414                         $add_cb->($self, $mime, $bytes, $blob);
 415                 } elsif ($line =~ /$delmsg/o) {
 416                         my $blob = $1;
 417                         my $mime = do_cat_mail($git, $blob) or next;
 418                         $del_cb->($self, $mime);
 419                 } elsif ($line =~ /^commit ($h40)/o) {
 420                         if (defined $max && --$max <= 0) {
 421                                 $max = $self->{batch_size};
 422                                 $batch_cb->($latest, 1);
 423                         }
 424                         $latest = $1;
 425                 }
 426         }
 427         $batch_cb->($latest, 0);
 428 }
 429
 430 sub _msgmap_init {
 431         my ($self) = @_;
 432         $self->{mm} = eval {
 433                 require PublicInbox::Msgmap;
 434                 PublicInbox::Msgmap->new($self->{git_dir}, 1);
 435         };
 436 }
 437
 438 sub _git_log {
 439         my ($self, $range) = @_;
 440         $self->{git}->popen(qw/log --reverse --no-notes --no-color
 441                                 --raw -r --no-abbrev/, $range);
 442 }
 443
 444 # indexes all unindexed messages
 445 sub _index_sync {
 446         my ($self, $opts) = @_;
 447         my $tip = $opts->{ref} || 'HEAD';
 448         my $reindex = $opts->{reindex};
 449         my ($mkey, $last_commit, $lx, $xlog);
 450         $self->{git}->batch_prepare;
 451         my $xdb = _xdb_acquire($self);
 452         $xdb->begin_transaction;
 453         do {
 454                 $xlog = undef;
 455                 $mkey = 'last_commit';
 456                 $last_commit = $xdb->get_metadata('last_commit');
 457                 $lx = $last_commit;
 458                 if ($reindex) {
 459                         $lx = '';
 460                         $mkey = undef if $last_commit ne '';
 461                 }
 462                 $xdb->cancel_transaction;
 463                 $xdb = _xdb_release($self);
 464
 465                 # ensure we leak no FDs to "git log"
 466                 my $range = $lx eq '' ? $tip : "$lx..$tip";
 467                 $xlog = _git_log($self, $range);
 468
 469                 $xdb = _xdb_acquire($self);
 470                 $xdb->begin_transaction;
 471         } while ($xdb->get_metadata('last_commit') ne $last_commit);
 472
 473         my $mm = _msgmap_init($self);
 474         my $dbh = $mm->{dbh} if $mm;
 475         my $mm_only;
 476         my $cb = sub {
 477                 my ($commit, $more) = @_;
 478                 if ($dbh) {
 479                         $mm->last_commit($commit) if $commit;
 480                         $dbh->commit;
 481                 }
 482                 if (!$mm_only) {
 483                         $xdb->set_metadata($mkey, $commit) if $mkey && $commit;
 484                         $xdb->commit_transaction;
 485                         $xdb = _xdb_release($self);
 486                 }
 487                 # let another process do some work... <
 488                 if ($more) {
 489                         if (!$mm_only) {
 490                                 $xdb = _xdb_acquire($self);
 491                                 $xdb->begin_transaction;
 492                         }
 493                         $dbh->begin_work if $dbh;
 494                 }
 495         };
 496
 497         if ($mm) {
 498                 $dbh->begin_work;
 499                 my $lm = $mm->last_commit || '';
 500                 if ($lm eq $lx) {
 501                         # Common case is the indexes are synced,
 502                         # we only need to run git-log once:
 503                         rlog($self, $xlog, *index_both, *unindex_both, $cb);
 504                 } else {
 505                         # Uncommon case, msgmap and xapian are out-of-sync
 506                         # do not care for performance (but git is fast :>)
 507                         # This happens if we have to reindex Xapian since
 508                         # msgmap is a frozen format and our Xapian format
 509                         # is evolving.
 510                         my $r = $lm eq '' ? $tip : "$lm..$tip";
 511
 512                         # first, ensure msgmap is up-to-date:
 513                         my $mkey_prev = $mkey;
 514                         $mkey = undef; # ignore xapian, for now
 515                         my $mlog = _git_log($self, $r);
 516                         $mm_only = 1;
 517                         rlog($self, $mlog, *index_mm, *unindex_mm, $cb);
 518                         $mm_only = $mlog = undef;
 519
 520                         # now deal with Xapian
 521                         $mkey = $mkey_prev;
 522                         $dbh = undef;
 523                         rlog($self, $xlog, *index_mm2, *unindex_mm2, $cb);
 524                 }
 525         } else {
 526                 # user didn't install DBD::SQLite and DBI
 527                 rlog($self, $xlog, *index_blob, *unindex_blob, $cb);
 528         }
 529 }
 530
 531 # this will create a ghost as necessary
 532 sub _resolve_mid_to_tid {
 533         my ($self, $mid) = @_;
 534
 535         my $smsg = $self->lookup_message($mid) || $self->create_ghost($mid);
 536         $smsg->thread_id;
 537 }
 538
 539 sub create_ghost {
 540         my ($self, $mid) = @_;
 541
 542         my $tid = $self->next_thread_id;
 543         my $doc = Search::Xapian::Document->new;
 544         $doc->add_term('Q' . $mid);
 545         $doc->add_term('G' . $tid);
 546         $doc->add_term('T' . 'ghost');
 547
 548         my $smsg = PublicInbox::SearchMsg->wrap($doc, $mid);
 549         $self->{xdb}->add_document($doc);
 550
 551         $smsg;
 552 }
 553
 554 sub merge_threads {
 555         my ($self, $winner_tid, $loser_tid) = @_;
 556         return if $winner_tid == $loser_tid;
 557         my ($head, $tail) = $self->find_doc_ids('G' . $loser_tid);
 558         my $db = $self->{xdb};
 559
 560         for (; $head != $tail; $head->inc) {
 561                 my $docid = $head->get_docid;
 562                 my $doc = $db->get_document($docid);
 563                 $doc->remove_term('G' . $loser_tid);
 564                 $doc->add_term('G' . $winner_tid);
 565                 $db->replace_document($docid, $doc);
 566         }
 567 }
 568
 569 sub _read_git_config_perm {
 570         my ($self) = @_;
 571         my @cmd = qw(config core.sharedRepository);
 572         my $fh = PublicInbox::Git->new($self->{git_dir})->popen(@cmd);
 573         local $/ = "\n";
 574         my $perm = <$fh>;
 575         chomp $perm if defined $perm;
 576         $perm;
 577 }
 578
 579 sub _git_config_perm {
 580         my $self = shift;
 581         my $perm = scalar @_ ? $_[0] : _read_git_config_perm($self);
 582         return PERM_GROUP if (!defined($perm) || $perm eq '');
 583         return PERM_UMASK if ($perm eq 'umask');
 584         return PERM_GROUP if ($perm eq 'group');
 585         if ($perm =~ /\A(?:all|world|everybody)\z/) {
 586                 return PERM_EVERYBODY;
 587         }
 588         return PERM_GROUP if ($perm =~ /\A(?:true|yes|on|1)\z/);
 589         return PERM_UMASK if ($perm =~ /\A(?:false|no|off|0)\z/);
 590
 591         my $i = oct($perm);
 592         return PERM_UMASK if ($i == PERM_UMASK);
 593         return PERM_GROUP if ($i == OLD_PERM_GROUP);
 594         return PERM_EVERYBODY if ($i == OLD_PERM_EVERYBODY);
 595
 596         if (($i & 0600) != 0600) {
 597                 die "core.sharedRepository mode invalid: ".
 598                     sprintf('%.3o', $i) . "\nOwner must have permissions\n";
 599         }
 600         ($i & 0666);
 601 }
 602
 603 sub _umask_for {
 604         my ($perm) = @_; # _git_config_perm return value
 605         my $rv = $perm;
 606         return umask if $rv == 0;
 607
 608         # set +x bit if +r or +w were set
 609         $rv |= 0100 if ($rv & 0600);
 610         $rv |= 0010 if ($rv & 0060);
 611         $rv |= 0001 if ($rv & 0006);
 612         (~$rv & 0777);
 613 }
 614
 615 sub with_umask {
 616         my ($self, $cb) = @_;
 617         my $old = umask $self->{umask};
 618         my $rv = eval { $cb->() };
 619         my $err = $@;
 620         umask $old;
 621         die $err if $err;
 622         $rv;
 623 }
 624
 625 sub DESTROY {
 626         # order matters for unlocking
 627         $_[0]->{xdb} = undef;
 628         $_[0]->{lockfh} = undef;
 629 }
 630
 631 1;