lib/PublicInbox/SearchIdx.pm

   1 # Copyright (C) 2015 all contributors <meta@public-inbox.org>
   2 # License: AGPLv3 or later (https://www.gnu.org/licenses/agpl-3.0.txt)
   3 # based on notmuch, but with no concept of folders, files or flags
   4 #
   5 # Indexes mail with Xapian and our (SQLite-based) ::Msgmap for use
   6 # with the web and NNTP interfaces.  This index maintains thread
   7 # relationships for use by Mail::Thread.  This writes to the search
   8 # index.
   9 package PublicInbox::SearchIdx;
  10 use strict;
  11 use warnings;
  12 use base qw(PublicInbox::Search);
  13 use PublicInbox::MID qw/mid_clean id_compress/;
  14 require PublicInbox::Git;
  15 *xpfx = *PublicInbox::Search::xpfx;
  16
  17 use constant MAX_MID_SIZE => 244; # max term size - 1 in Xapian
  18 use constant {
  19         PERM_UMASK => 0,
  20         OLD_PERM_GROUP => 1,
  21         OLD_PERM_EVERYBODY => 2,
  22         PERM_GROUP => 0660,
  23         PERM_EVERYBODY => 0664,
  24 };
  25
  26 sub new {
  27         my ($class, $git_dir, $writable) = @_;
  28         my $dir = $class->xdir($git_dir);
  29         require Search::Xapian::WritableDatabase;
  30         my $flag = Search::Xapian::DB_OPEN;
  31         my $self = bless { git_dir => $git_dir }, $class;
  32         my $perm = $self->_git_config_perm;
  33         my $umask = _umask_for($perm);
  34         $self->{umask} = $umask;
  35         $self->{xdb} = $self->with_umask(sub {
  36                 if ($writable == 1) {
  37                         require File::Path;
  38                         File::Path::mkpath($dir);
  39                         $flag = Search::Xapian::DB_CREATE_OR_OPEN;
  40                 }
  41                 Search::Xapian::WritableDatabase->new($dir, $flag);
  42         });
  43         $self;
  44 }
  45
  46 sub add_val {
  47         my ($doc, $col, $num) = @_;
  48         $num = Search::Xapian::sortable_serialise($num);
  49         $doc->add_value($col, $num);
  50 }
  51
  52 sub add_message {
  53         my ($self, $mime, $bytes, $num) = @_; # mime = Email::MIME object
  54         my $db = $self->{xdb};
  55
  56         my $doc_id;
  57         my $mid = mid_clean($mime->header('Message-ID'));
  58         my $was_ghost = 0;
  59         my $ct_msg = $mime->header('Content-Type') || 'text/plain';
  60
  61         eval {
  62                 die 'Message-ID too long' if length($mid) > MAX_MID_SIZE;
  63                 my $smsg = $self->lookup_message($mid);
  64                 my $doc;
  65
  66                 if ($smsg) {
  67                         $smsg->ensure_metadata;
  68                         # convert a ghost to a regular message
  69                         # it will also clobber any existing regular message
  70                         $smsg->mime($mime);
  71                         $doc = $smsg->{doc};
  72
  73                         my $type = xpfx('type');
  74                         eval {
  75                                 $doc->remove_term($type . 'ghost');
  76                                 $was_ghost = 1;
  77                         };
  78
  79                         # probably does not exist:
  80                         eval { $doc->remove_term($type . 'mail') };
  81                         $doc->add_term($type . 'mail');
  82                 }  else {
  83                         $smsg = PublicInbox::SearchMsg->new($mime);
  84                         $doc = $smsg->{doc};
  85                         $doc->add_term(xpfx('mid') . $mid);
  86                 }
  87
  88                 my $subj = $smsg->subject;
  89
  90                 if ($subj ne '') {
  91                         my $path = $self->subject_path($subj);
  92                         $doc->add_term(xpfx('path') . id_compress($path));
  93                 }
  94
  95                 add_val($doc, &PublicInbox::Search::TS, $smsg->ts);
  96
  97                 defined($num) and
  98                         add_val($doc, &PublicInbox::Search::NUM, $num);
  99
 100                 defined($bytes) and
 101                         add_val($doc, &PublicInbox::Search::BYTES, $bytes);
 102
 103                 add_val($doc, &PublicInbox::Search::LINES,
 104                                 $mime->body_raw =~ tr!\n!\n!);
 105
 106                 my $tg = $self->term_generator;
 107
 108                 $tg->set_document($doc);
 109                 $tg->index_text($subj, 1, 'S') if $subj;
 110                 $tg->increase_termpos;
 111                 $tg->index_text($subj) if $subj;
 112                 $tg->increase_termpos;
 113
 114                 $tg->index_text($smsg->from);
 115                 $tg->increase_termpos;
 116
 117                 $mime->walk_parts(sub {
 118                         my ($part) = @_;
 119                         return if $part->subparts; # walk_parts already recurses
 120                         my $ct = $part->content_type || $ct_msg;
 121
 122                         # account for filter bugs...
 123                         $ct =~ m!\btext/plain\b!i or return;
 124
 125                         my (@orig, @quot);
 126                         my $body = $part->body;
 127                         $part->body_set('');
 128                         my @lines = split(/\n/, $body);
 129                         while (defined(my $l = shift @lines)) {
 130                                 if ($l =~ /^\s*>/) {
 131                                         push @quot, $l;
 132                                 } else {
 133                                         push @orig, $l;
 134                                 }
 135                         }
 136                         if (@quot) {
 137                                 $tg->index_text(join("\n", @quot), 0);
 138                                 @quot = ();
 139                                 $tg->increase_termpos;
 140                         }
 141                         if (@orig) {
 142                                 $tg->index_text(join("\n", @orig));
 143                                 @orig = ();
 144                                 $tg->increase_termpos;
 145                         }
 146                 });
 147
 148                 if ($was_ghost) {
 149                         $doc_id = $smsg->doc_id;
 150                         $self->link_message($smsg, 0);
 151                         $doc->set_data($smsg->to_doc_data);
 152                         $db->replace_document($doc_id, $doc);
 153                 } else {
 154                         $self->link_message($smsg, 0);
 155                         $doc->set_data($smsg->to_doc_data);
 156                         $doc_id = $db->add_document($doc);
 157                 }
 158         };
 159
 160         if ($@) {
 161                 warn "failed to index message <$mid>: $@\n";
 162                 return undef;
 163         }
 164         $doc_id;
 165 }
 166
 167 # returns deleted doc_id on success, undef on missing
 168 sub remove_message {
 169         my ($self, $mid) = @_;
 170         my $db = $self->{xdb};
 171         my $doc_id;
 172         $mid = mid_clean($mid);
 173
 174         eval {
 175                 $doc_id = $self->find_unique_doc_id('mid', $mid);
 176                 $db->delete_document($doc_id) if defined $doc_id;
 177         };
 178
 179         if ($@) {
 180                 warn "failed to remove message <$mid>: $@\n";
 181                 return undef;
 182         }
 183         $doc_id;
 184 }
 185
 186 sub term_generator { # write-only
 187         my ($self) = @_;
 188
 189         my $tg = $self->{term_generator};
 190         return $tg if $tg;
 191
 192         $tg = Search::Xapian::TermGenerator->new;
 193         $tg->set_stemmer($self->stemmer);
 194
 195         $self->{term_generator} = $tg;
 196 }
 197
 198 # increments last_thread_id counter
 199 # returns a 64-bit integer represented as a hex string
 200 sub next_thread_id {
 201         my ($self) = @_;
 202         my $db = $self->{xdb};
 203         my $last_thread_id = int($db->get_metadata('last_thread_id') || 0);
 204
 205         $db->set_metadata('last_thread_id', ++$last_thread_id);
 206
 207         $last_thread_id;
 208 }
 209
 210 sub link_message {
 211         my ($self, $smsg, $is_ghost) = @_;
 212
 213         if ($is_ghost) {
 214                 $smsg->ensure_metadata;
 215         } else {
 216                 $self->link_message_to_parents($smsg);
 217         }
 218 }
 219
 220 sub link_message_to_parents {
 221         my ($self, $smsg) = @_;
 222         my $doc = $smsg->{doc};
 223         my $mid = $smsg->mid;
 224         my $mime = $smsg->mime;
 225         my $refs = $mime->header('References');
 226         my @refs = $refs ? ($refs =~ /<([^>]+)>/g) : ();
 227         if (my $irt = $mime->header('In-Reply-To')) {
 228                 # last References should be $irt
 229                 # we will de-dupe later
 230                 push @refs, mid_clean($irt);
 231         }
 232
 233         my $tid;
 234         if (@refs) {
 235                 my %uniq = ($mid => 1);
 236                 my @orig_refs = @refs;
 237                 @refs = ();
 238
 239                 # prevent circular references via References: here:
 240                 foreach my $ref (@orig_refs) {
 241                         if (length($ref) > MAX_MID_SIZE) {
 242                                 warn "References: <$ref> too long, ignoring\n";
 243                         }
 244                         next if $uniq{$ref};
 245                         $uniq{$ref} = 1;
 246                         push @refs, $ref;
 247                 }
 248         }
 249         if (@refs) {
 250                 $smsg->{references} = '<'.join('> <', @refs).'>';
 251
 252                 # first ref *should* be the thread root,
 253                 # but we can never trust clients to do the right thing
 254                 my $ref = shift @refs;
 255                 $tid = $self->_resolve_mid_to_tid($ref);
 256
 257                 # the rest of the refs should point to this tid:
 258                 foreach $ref (@refs) {
 259                         my $ptid = $self->_resolve_mid_to_tid($ref);
 260                         if ($tid ne $ptid) {
 261                                 $self->merge_threads($tid, $ptid);
 262                         }
 263                 }
 264         } else {
 265                 $tid = $self->next_thread_id;
 266         }
 267         $doc->add_term(xpfx('thread') . $tid);
 268 }
 269
 270 sub index_blob {
 271         my ($self, $git, $mime, $bytes, $num) = @_;
 272         $self->add_message($mime, $bytes, $num);
 273 }
 274
 275 sub unindex_blob {
 276         my ($self, $git, $mime) = @_;
 277         my $mid = mid_clean($mime->header('Message-ID'));
 278         $self->remove_message($mid) if defined $mid;
 279 }
 280
 281 sub index_mm {
 282         my ($self, $git, $mime) = @_;
 283         $self->{mm}->mid_insert(mid_clean($mime->header('Message-ID')));
 284 }
 285
 286 sub unindex_mm {
 287         my ($self, $git, $mime) = @_;
 288         $self->{mm}->mid_delete(mid_clean($mime->header('Message-ID')));
 289 }
 290
 291 sub index_mm2 {
 292         my ($self, $git, $mime, $bytes) = @_;
 293         my $num = $self->{mm}->num_for(mid_clean($mime->header('Message-ID')));
 294         index_blob($self, $git, $mime, $bytes, $num);
 295 }
 296
 297 sub unindex_mm2 {
 298         my ($self, $git, $mime) = @_;
 299         $self->{mm}->mid_delete(mid_clean($mime->header('Message-ID')));
 300         unindex_blob($self, $git, $mime);
 301 }
 302
 303 sub index_both {
 304         my ($self, $git, $mime, $bytes) = @_;
 305         my $num = index_mm($self, $git, $mime);
 306         index_blob($self, $git, $mime, $bytes, $num);
 307 }
 308
 309 sub unindex_both {
 310         my ($self, $git, $mime) = @_;
 311         unindex_blob($self, $git, $mime);
 312         unindex_mm($self, $git, $mime);
 313 }
 314
 315 sub do_cat_mail {
 316         my ($git, $blob, $sizeref) = @_;
 317         my $mime = eval {
 318                 my $str = $git->cat_file($blob, $sizeref);
 319                 Email::MIME->new($str);
 320         };
 321         $@ ? undef : $mime;
 322 }
 323
 324 sub index_sync {
 325         my ($self, $head) = @_;
 326         $self->with_umask(sub { $self->_index_sync($head) });
 327 }
 328
 329 sub rlog {
 330         my ($self, $range, $add_cb, $del_cb) = @_;
 331         my $hex = '[a-f0-9]';
 332         my $h40 = $hex .'{40}';
 333         my $addmsg = qr!^:000000 100644 \S+ ($h40) A\t${hex}{2}/${hex}{38}$!;
 334         my $delmsg = qr!^:100644 000000 ($h40) \S+ D\t${hex}{2}/${hex}{38}$!;
 335         my $git = PublicInbox::Git->new($self->{git_dir});
 336         my $log = $git->popen(qw/log --reverse --no-notes --no-color
 337                                 --raw -r --no-abbrev/, $range);
 338         my $latest;
 339         my $bytes;
 340         while (defined(my $line = <$log>)) {
 341                 if ($line =~ /$addmsg/o) {
 342                         my $mime = do_cat_mail($git, $1, \$bytes) or next;
 343                         $add_cb->($self, $git, $mime, $bytes);
 344                 } elsif ($line =~ /$delmsg/o) {
 345                         my $mime = do_cat_mail($git, $1) or next;
 346                         $del_cb->($self, $git, $mime);
 347                 } elsif ($line =~ /^commit ($h40)/o) {
 348                         $latest = $1;
 349                 }
 350         }
 351         $latest;
 352 }
 353
 354 # indexes all unindexed messages
 355 sub _index_sync {
 356         my ($self, $head) = @_;
 357         my $db = $self->{xdb};
 358         $head ||= 'HEAD';
 359         my $mm = $self->{mm} = eval {
 360                 require PublicInbox::Msgmap;
 361                 PublicInbox::Msgmap->new($self->{git_dir}, 1);
 362         };
 363
 364         $db->begin_transaction;
 365         my $lx = $db->get_metadata('last_commit');
 366         my $range = $lx eq '' ? $head : "$lx..$head";
 367         if ($mm) {
 368                 $mm->{dbh}->begin_work;
 369                 my $lm = $mm->last_commit || '';
 370                 if ($lm eq $lx) {
 371                         # Common case is the indexes are synced,
 372                         # we only need to run git-log once:
 373                         $lx = $self->rlog($range, *index_both, *unindex_both);
 374                         $mm->{dbh}->commit;
 375                         if (defined $lx) {
 376                                 $db->set_metadata('last_commit', $lx);
 377                                 $mm->last_commit($lx);
 378                         }
 379                 } else {
 380                         # dumb case, msgmap and xapian are out-of-sync
 381                         # do not care for performance:
 382                         my $r = $lm eq '' ? $head : "$lm..$head";
 383                         $lm = $self->rlog($r, *index_mm, *unindex_mm);
 384                         $mm->{dbh}->commit;
 385                         $mm->last_commit($lm) if defined $lm;
 386
 387                         $lx = $self->rlog($range, *index_mm2, *unindex_mm2);
 388                         $db->set_metadata('last_commit', $lx) if defined $lx;
 389                 }
 390         } else {
 391                 # user didn't install DBD::SQLite and DBI
 392                 $lx = $self->rlog($range, *index_blob, *unindex_blob);
 393                 $db->set_metadata('last_commit', $lx) if defined $lx;
 394         }
 395         if ($@) {
 396                 $db->cancel_transaction;
 397                 $mm->{dbh}->rollback if $mm;
 398         } else {
 399                 $db->commit_transaction;
 400         }
 401 }
 402
 403 # this will create a ghost as necessary
 404 sub _resolve_mid_to_tid {
 405         my ($self, $mid) = @_;
 406
 407         my $smsg = $self->lookup_message($mid) || $self->create_ghost($mid);
 408         $smsg->thread_id;
 409 }
 410
 411 sub create_ghost {
 412         my ($self, $mid, $tid) = @_;
 413
 414         $tid = $self->next_thread_id unless defined $tid;
 415
 416         my $doc = Search::Xapian::Document->new;
 417         $doc->add_term(xpfx('mid') . $mid);
 418         $doc->add_term(xpfx('thread') . $tid);
 419         $doc->add_term(xpfx('type') . 'ghost');
 420
 421         my $smsg = PublicInbox::SearchMsg->wrap($doc, $mid);
 422         $self->link_message($smsg, 1);
 423         $self->{xdb}->add_document($doc);
 424
 425         $smsg;
 426 }
 427
 428 sub merge_threads {
 429         my ($self, $winner_tid, $loser_tid) = @_;
 430         my ($head, $tail) = $self->find_doc_ids('thread', $loser_tid);
 431         my $thread_pfx = xpfx('thread');
 432         my $db = $self->{xdb};
 433
 434         for (; $head != $tail; $head->inc) {
 435                 my $docid = $head->get_docid;
 436                 my $doc = $db->get_document($docid);
 437                 $doc->remove_term($thread_pfx . $loser_tid);
 438                 $doc->add_term($thread_pfx . $winner_tid);
 439                 $db->replace_document($docid, $doc);
 440         }
 441 }
 442
 443 sub _read_git_config_perm {
 444         my ($self) = @_;
 445         my @cmd = qw(config core.sharedRepository);
 446         my $fh = PublicInbox::Git->new($self->{git_dir})->popen(@cmd);
 447         my $perm = <$fh>;
 448         chomp $perm if defined $perm;
 449         $perm;
 450 }
 451
 452 sub _git_config_perm {
 453         my $self = shift;
 454         my $perm = scalar @_ ? $_[0] : _read_git_config_perm($self);
 455         return PERM_GROUP if (!defined($perm) || $perm eq '');
 456         return PERM_UMASK if ($perm eq 'umask');
 457         return PERM_GROUP if ($perm eq 'group');
 458         if ($perm =~ /\A(?:all|world|everybody)\z/) {
 459                 return PERM_EVERYBODY;
 460         }
 461         return PERM_GROUP if ($perm =~ /\A(?:true|yes|on|1)\z/);
 462         return PERM_UMASK if ($perm =~ /\A(?:false|no|off|0)\z/);
 463
 464         my $i = oct($perm);
 465         return PERM_UMASK if ($i == PERM_UMASK);
 466         return PERM_GROUP if ($i == OLD_PERM_GROUP);
 467         return PERM_EVERYBODY if ($i == OLD_PERM_EVERYBODY);
 468
 469         if (($i & 0600) != 0600) {
 470                 die "core.sharedRepository mode invalid: ".
 471                     sprintf('%.3o', $i) . "\nOwner must have permissions\n";
 472         }
 473         ($i & 0666);
 474 }
 475
 476 sub _umask_for {
 477         my ($perm) = @_; # _git_config_perm return value
 478         my $rv = $perm;
 479         return umask if $rv == 0;
 480
 481         # set +x bit if +r or +w were set
 482         $rv |= 0100 if ($rv & 0600);
 483         $rv |= 0010 if ($rv & 0060);
 484         $rv |= 0001 if ($rv & 0006);
 485         (~$rv & 0777);
 486 }
 487
 488 sub with_umask {
 489         my ($self, $cb) = @_;
 490         my $old = umask $self->{umask};
 491         my $rv = eval { $cb->() };
 492         my $err = $@;
 493         umask $old;
 494         die $err if $@;
 495         $rv;
 496 }
 497
 498 1;